folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AC_PROG_INSTALL
  32 AM_PROG_LIBTOOL
  33
  34 AC_LANG([C++])
  35
  36 # Checks for programs.
  37 AC_PROG_CXX
  38 AC_PROG_CC
  39
  40 AC_CXX_COMPILE_STDCXX_1Y
  41
  42 # Be sure to add any -std option to CXXFLAGS before we invoke any
  43 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  44 # before we update CXXFLAGS will not be run with the same options that we use
  45 # during the real build.
  46 STD=""
  47 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  48    STD="-std=c++1y"
  49 fi
  50 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  51    STD="-std=gnu++1y"
  52 fi
  53
  54 CXXFLAGS="$STD $CXXFLAGS"
  55
  56 # expose required -std option via pkg-config
  57 PKG_CXXFLAGS=$STD
  58
  59 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  60 AC_MSG_CHECKING(
  61   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  62 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  63   folly_save_CXXFLAGS="$CXXFLAGS"
  64   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  65   AC_COMPILE_IFELSE(
  66     [AC_LANG_PROGRAM([[]], [[]])],
  67     [folly_cv_cxx_shadow_local_support=yes],
  68     [folly_cv_cxx_shadow_local_support=no])
  69   CXXFLAGS="$folly_save_CXXFLAGS"])
  70 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  71 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  72   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  73   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  74 fi
  75
  76 # Checks for glog and gflags
  77 # There are no symbols with C linkage, so we do a try-run
  78 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  79                 [Please install google-gflags library])])
  80 AC_CACHE_CHECK(
  81   [for gflags viability],
  82   [folly_cv_prog_cc_gflags],
  83   [AC_RUN_IFELSE(
  84     [AC_LANG_SOURCE[
  85       #include <gflags/gflags.h>
  86       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  87       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  88       int main(int argc, char** argv) {
  89         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  90       }
  91     ]],
  92     [folly_cv_prog_cc_gflags=yes],
  93     [folly_cv_prog_cc_gflags=no]
  94   )]
  95 )
  96
  97 if test "$folly_cv_prog_cc_gflags" != "yes"; then
  98   AC_MSG_ERROR(["gflags invalid, see config.log for details"])
  99 fi
 100 FB_CHECK_PKG_CONFIG([GFLAGS], [gflags])
 101
 102 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 103                 [Please install google-glog library])])
 104 AC_CACHE_CHECK(
 105   [for glog viability],
 106   [folly_cv_prog_cc_glog],
 107   [AC_RUN_IFELSE(
 108     [AC_LANG_SOURCE[
 109       #include <glog/logging.h>
 110       int main(int argc, char** argv) {
 111         google::InitGoogleLogging(argv[0]);
 112         google::ShutdownGoogleLogging();
 113         return 0;
 114       }
 115     ]],
 116     [folly_cv_prog_cc_glog=yes],
 117     [folly_cv_prog_cc_glog=no]
 118   )]
 119 )
 120
 121 if test "$folly_cv_prog_cc_glog" != "yes"; then
 122   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 123 fi
 124 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 125
 126 AS_IF(
 127   [test "x$OPENSSL_INCLUDES" = "x"],
 128   [
 129     AX_CHECK_OPENSSL([], [AC_MSG_ERROR(["Error: libssl required"])])
 130   ],
 131   [
 132     # AX_CHECK_OPENSSL doesn't seem to play nice with builds started
 133     # via build/bootstrap-osx-homebrew.sh
 134     AC_MSG_WARN(["Using existing OpenSSL flags from environment."])
 135     PKG_CXXFLAGS="$PKG_CXXFLAGS $OPENSSL_INCLUDES"
 136   ]
 137 )
 138 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 139
 140 # check for boost libs
 141 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 142               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 143 AX_BOOST_CONTEXT
 144 AX_BOOST_PROGRAM_OPTIONS
 145 AX_BOOST_THREAD
 146 AX_BOOST_REGEX
 147 AX_BOOST_SYSTEM
 148 AX_BOOST_FILESYSTEM
 149 AX_BOOST_CHRONO
 150
 151 # Check for python interpreter
 152 AM_PATH_PYTHON
 153
 154 # Checks for header files.
 155 AC_HEADER_STDC
 156 AC_CHECK_HEADERS([features.h malloc.h bits/functexcept.h bits/c++config.h])
 157
 158 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 159                 [Couldn't find double-conversion.h, please download from \
 160                  https://github.com/google/double-conversion/])], [])
 161 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 162              [Please install double-conversion library])])
 163
 164 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 165 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 166
 167 AC_ARG_WITH([jemalloc], [
 168   --with-jemalloc     Whether to make folly jemalloc aware
 169 ],[
 170   AC_CHECK_LIB([jemalloc], [xallocx],[
 171     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 172   ],[
 173     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 174   ])
 175 ])
 176
 177 # Checks for typedefs, structures, and compiler characteristics.
 178 AC_C_CONST
 179 AC_C_INLINE
 180 AC_TYPE_SIZE_T
 181 AC_HEADER_TIME
 182 AC_C_VOLATILE
 183 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 184     [folly_cv_prog_cc_int128=no])
 185 if test "$folly_cv_prog_cc_int128" = "yes"; then
 186   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 187   AC_CACHE_CHECK(
 188     [for __int128 type traits],
 189     [folly_cv_prog_cc_int128traits],
 190     [AC_COMPILE_IFELSE(
 191       [AC_LANG_SOURCE([[
 192 #include <type_traits>
 193 static_assert(
 194   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 195   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 196       ]])],
 197       [folly_cv_prog_cc_int128traits=yes],
 198       [folly_cv_prog_cc_int128traits=no])
 199     ])
 200   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 201     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 202   fi
 203 fi
 204
 205 AC_CHECK_TYPES([pthread_spinlock_t])
 206
 207 AC_CACHE_CHECK(
 208   [for ifunc support],
 209   [folly_cv_prog_cc_ifunc],
 210   [AC_COMPILE_IFELSE(
 211     [AC_LANG_SOURCE[
 212       #pragma GCC diagnostic error "-Wattributes"
 213       extern "C" void (*test_ifunc(void))() { return 0; }
 214       void func() __attribute__((ifunc("test_ifunc")));]
 215     ],
 216     [folly_cv_prog_cc_ifunc=yes],
 217     [folly_cv_prog_cc_ifunc=no])])
 218
 219 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 220   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 221 fi
 222
 223 AC_CACHE_CHECK(
 224   [for final and override support],
 225   [folly_cv_c_final_override],
 226   [AC_COMPILE_IFELSE(
 227     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 228                     class D : public C { virtual void g() override {} };]],
 229     [folly_cv_c_final_override=yes],
 230     [folly_cv_c_final_override=no])])
 231
 232 if test "$folly_cv_c_final_override" = "yes"; then
 233   final_val=final
 234   override_val=override
 235 else
 236   final_val=
 237   override_val=
 238 fi
 239
 240 AC_DEFINE_UNQUOTED(
 241   [FINAL], [$final_val],
 242   [Define to "final" if the compiler supports C++11 "final"])
 243 AC_DEFINE_UNQUOTED(
 244   [OVERRIDE], [$override_val],
 245   [Define to "override" if the compiler supports C++11 "override"])
 246
 247 AC_CACHE_CHECK(
 248   [for libc++],
 249   [folly_cv_lib_libcpp],
 250   [AC_COMPILE_IFELSE(
 251     [AC_LANG_SOURCE[
 252       #include <type_traits>
 253       #if !_LIBCPP_VERSION
 254       #error No libc++
 255       #endif
 256       void func() {}]
 257     ],
 258     [folly_cv_lib_libcpp=yes],
 259     [folly_cv_lib_libcpp=no])])
 260
 261 if test "$folly_cv_lib_libcpp" = yes; then
 262   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 263 fi
 264
 265 AC_CACHE_CHECK(
 266   [for c++11 atomic support without GNU Atomic library],
 267   [folly_cv_lib_libatomic],
 268   [AC_LINK_IFELSE(
 269     [AC_LANG_SOURCE[
 270       #include <atomic>
 271       int main() {
 272         struct Test { int val; };
 273         std::atomic<Test> s;
 274         s.is_lock_free();
 275       }
 276     ]],
 277     [folly_cv_lib_libatomic=yes],
 278     [folly_cv_lib_libatomic=no])])
 279
 280 if test "$folly_cv_lib_libatomic" = no; then
 281   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 282                   [Please install the GNU Atomic library])])
 283 fi
 284
 285 if test "$build_os" = "linux-gnu"; then
 286   AC_HAVE_LIBRARY([dl],[],[AC_MSG_ERROR(
 287                   [Folly depends on libdl])])
 288 fi
 289
 290 AC_CACHE_CHECK(
 291   [for liblinux-vdso support],
 292   [folly_cv_lib_liblinux_vdso],
 293   [AC_RUN_IFELSE(
 294     [AC_LANG_SOURCE[
 295       #include <dlfcn.h>
 296       int main() {
 297         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 298         if (h == nullptr) {
 299           return -1;
 300         }
 301         dlclose(h);
 302         return 0;
 303       }
 304     ]],
 305     [folly_cv_lib_liblinux_vdso=yes],
 306     [folly_cv_lib_liblinux_vdso=no])])
 307
 308 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 309   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 310 fi
 311
 312 AC_DEFINE([HAVE_PTHREAD], [1], [Define to 1 if pthread is avaliable])
 313
 314 AC_CACHE_CHECK(
 315   [for usable std::is_trivially_copyable],
 316   [folly_cv_decl_std_is_trivially_copyable],
 317   [AC_COMPILE_IFELSE(
 318     [AC_LANG_SOURCE[
 319       #include <type_traits>
 320       const bool val = std::is_trivially_copyable<bool>::value;]
 321     ],
 322     [folly_cv_decl_std_is_trivially_copyable=yes],
 323     [folly_cv_decl_std_is_trivially_copyable=no])])
 324
 325 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 326   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 327             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 328              implementation.])
 329 fi
 330
 331 AC_CACHE_CHECK(
 332   [gflags namespace],
 333   [folly_cv_decl_gflags_namespace],
 334   [AC_COMPILE_IFELSE(
 335     [AC_LANG_SOURCE[
 336       #include <gflags/gflags.h>
 337       void foo() { gflags::GetArgv(); }]
 338     ],
 339     [folly_cv_decl_gflags_namespace=gflags],
 340     [AC_COMPILE_IFELSE(
 341       [AC_LANG_SOURCE[
 342         #include <gflags/gflags.h>
 343         void foo() { google::GetArgv(); }]
 344       ],
 345       [folly_cv_decl_gflags_namespace=google],
 346       [folly_cv_decl_gflags_namespace=error])])])
 347
 348 if test "$folly_cv_decl_gflags_namespace" = error; then
 349   AC_MSG_ERROR([Cannot determine gflags namespace])
 350 else
 351   AC_DEFINE_UNQUOTED(
 352     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 353     [Define to gflags namespace (usually "google" or "gflags")])
 354   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 355      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 356                [Define to 1 if the gflags namespace is not "gflags"])
 357   fi
 358 fi
 359
 360 # Figure out if we support weak symbols. If not, we will link in some null
 361 # stubs for functions that would otherwise be weak.
 362 AC_CACHE_CHECK(
 363   [for weak symbol support],
 364   [folly_cv_prog_cc_weak_symbols],
 365   [AC_LINK_IFELSE(
 366     [AC_LANG_SOURCE[
 367       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 368       int main(int argc, char** argv) {
 369           return configure_link_extern_weak_test == nullptr;
 370       }]],
 371     [folly_cv_prog_cc_weak_symbols="yes"],
 372     [folly_cv_prog_cc_weak_symbols="no"])])
 373
 374 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 375   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 376             [Define to 1 if the linker supports weak symbols.])
 377 fi
 378
 379
 380 # Figure out if we support wchar well
 381 AC_CACHE_CHECK(
 382   [for wchar support],
 383   [folly_cv_prog_cc_wchar_support],
 384   [AC_RUN_IFELSE(
 385     [AC_LANG_SOURCE[
 386       #include <cstddef>
 387       #include <cwchar>
 388
 389       int main(int argc, char** argv) {
 390         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 391       }
 392     ]],
 393     [folly_cv_prog_cc_wchar_support=yes],
 394     [folly_cv_prog_cc_wchar_support=no])])
 395
 396 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 397   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 398 fi
 399
 400 # Figure out whether the architecture supports unaligned accesses
 401 AC_CACHE_CHECK(
 402   [for unaligned access support],
 403   [folly_cv_prog_cc_unaligned_access],
 404   [AC_RUN_IFELSE(
 405     [AC_LANG_SOURCE[
 406       int main(int argc, char** argv) {
 407         char buf[64] = {0};
 408         unsigned long *ptr = (unsigned long *)(buf + 1);
 409         *ptr = 0xdeadbeef;
 410         return (*ptr & 0xff) == 0xef ? 0 : 1;
 411       }
 412     ]],
 413     [folly_cv_prog_cc_unaligned_access=yes],
 414     [folly_cv_prog_cc_unaligned_access=no])])
 415
 416 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 417   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 418 fi
 419
 420 AC_CACHE_CHECK(
 421   [for vsnprintf reporting bad format strings],
 422   [folly_cv_prog_vsnprintf_bad_format],
 423   [AC_RUN_IFELSE(
 424     [AC_LANG_SOURCE[
 425       #include <stdio.h>
 426
 427       int main(int argc, char** argv) {
 428           char buf[256];
 429           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 430       }]],
 431     [folly_cv_prog_vsnprintf_bad_format="yes"],
 432     [folly_cv_prog_vsnprintf_bad_format="no"])])
 433
 434 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 435   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 436             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 437 fi
 438
 439 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 440 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 441   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 442             [Define to 1 if we have cplus_demangle_v3_callback.])
 443 fi
 444
 445 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 446 # want to link with librt if necessary.
 447 AC_SEARCH_LIBS([clock_gettime], [rt],
 448   AC_DEFINE(
 449     [HAVE_CLOCK_GETTIME],
 450     [1],
 451     [Define to 1 if we support clock_gettime(2).]),
 452   [])
 453
 454 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 455 # want to include pthread.h if necessary.
 456 AC_CACHE_CHECK(
 457   [for pthread_atfork support],
 458   [folly_cv_prog_cc_pthread_atfork],
 459   [AC_COMPILE_IFELSE(
 460     [AC_LANG_SOURCE[
 461       #include <pthread.h>
 462       void func() {pthread_atfork(NULL, NULL, NULL);}]
 463     ],
 464     [folly_cv_prog_cc_pthread_atfork=yes],
 465     [folly_cv_prog_cc_pthread_atfork=no])])
 466
 467 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 468   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 469 fi
 470
 471 # Check for XSI-compatible strerror_r as default implementation
 472 AC_CACHE_CHECK(
 473   [for XSI style strerror_r support],
 474   [folly_cv_prog_cc_xsi_strerror_r],
 475   [AC_RUN_IFELSE(
 476     [AC_LANG_SOURCE[
 477       #include <string.h>
 478       #include <errno.h>
 479       int main(int argc, char** argv) {
 480         char buf[1024];
 481         buf[0] = 0;
 482         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 483         return ret;
 484       }
 485     ]],
 486     [folly_cv_prog_cc_xsi_strerror_r=yes],
 487     [folly_cv_prog_cc_xsi_strerror_r=no])])
 488
 489 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 490   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 491 fi
 492
 493 AC_CACHE_CHECK(
 494   [for ext/random and __gnu_cxx::sfmt19937],
 495   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 496   [AC_COMPILE_IFELSE(
 497     [AC_LANG_SOURCE[
 498       #include <ext/random>
 499       int main(int argc, char** argv) {
 500         __gnu_cxx::sfmt19937 rng;
 501         return 0;
 502       }
 503     ]],
 504     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 505     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 506
 507 AC_CACHE_CHECK(
 508   [for VLA (variable-length array) support],
 509   [folly_cv_prog_cc_have_vla],
 510   [AC_COMPILE_IFELSE(
 511     [AC_LANG_SOURCE[
 512       int main(int argc, char** argv) {
 513         unsigned size = argc;
 514         char data[size];
 515         return 0;
 516       }
 517     ]],
 518     [folly_cv_prog_cc_have_vla=yes],
 519     [folly_cv_prog_cc_have_vla=no])])
 520
 521 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 522 AC_DEFINE_UNQUOTED(
 523   [HAVE_VLA],
 524   [$have_vla],
 525   [Define to 1 if the compiler has VLA (variable-length array) support,
 526    otherwise define to 0])
 527
 528 # Checks for library functions.
 529 AC_CHECK_FUNCS([malloc_size \
 530                 malloc_usable_size \
 531                 memrchr \
 532                 pipe2 \
 533                 preadv \
 534                 pwritev \
 535               ])
 536
 537 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 538 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 539 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 540 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 541 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 542 AC_CHECK_HEADER([bzlib.h], AC_CHECK_LIB([bz2], [main]))
 543 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 544
 545 AC_ARG_ENABLE([follytestmain],
 546    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 547    [use_follytestmain=${enableval}], [use_follytestmain=yes])
 548
 549 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 550 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 551 # Check whether we have both the library and the header
 552 have_libdwarf=no
 553 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 554 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 555
 556
 557 AC_ARG_ENABLE([mobile],
 558    AS_HELP_STRING([--enable-mobile],
 559                   [enables using main function from folly for tests]),
 560                   [mobile=${enableval}], [mobile=no])
 561 AS_IF([test "x${mobile}" = "xyes"], [
 562     AC_DEFINE([MOBILE], [1],
 563               [Define to 1 for compiler guards for mobile targets.])
 564 ])
 565
 566 AC_ARG_ENABLE([exception-tracer],
 567     AS_HELP_STRING([--enable-exception-tracer], [enables building exception tracer]),
 568     [build_exception_tracer=${enableval}], [build_exception_tracer=no])
 569
 570 # Include directory that contains "folly" so #include <folly/Foo.h> works
 571 AM_CPPFLAGS='-I$(top_srcdir)/..'
 572 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS $OPENSSL_INCLUDES"
 573 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 574 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 575 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 576 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 577
 578 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 579
 580 AC_SUBST([AM_CPPFLAGS])
 581 AC_SUBST([AM_LDFLAGS])
 582
 583 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 584 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 585 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 586 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 587 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 588 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 589                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 590 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 591 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 592                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 593 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 594 AM_CONDITIONAL([HAVE_LIBDWARF], [test "x${have_libdwarf}" = "xyes"])
 595 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 596 AM_CONDITIONAL([EXCEPTION_TRACER], [test "x${build_exception_tracer}" = "xyes"])
 597
 598 # remove pkg-config deps from dependent libraries
 599 # (at least for pkg-config file purposes)
 600 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 601
 602 # Output
 603 AC_CONFIG_FILES([Makefile
 604                  io/test/Makefile
 605                  libfolly.pc
 606                  test/Makefile
 607                  test/function_benchmark/Makefile
 608                  experimental/Makefile
 609                  experimental/io/test/Makefile
 610                  experimental/logging/Makefile
 611                  experimental/logging/example/Makefile
 612                  experimental/symbolizer/Makefile
 613                  init/Makefile
 614                  stats/test/Makefile])
 615
 616 AM_COND_IF([EXCEPTION_TRACER],
 617            [AC_CONFIG_FILES([experimental/exception_tracer/Makefile])])
 618 AC_OUTPUT