folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["gflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [gflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AS_IF(
 134   [test "x$OPENSSL_INCLUDES" = "x"],
 135   [
 136     AX_CHECK_OPENSSL([], [AC_MSG_ERROR(["Error: libssl required"])])
 137   ],
 138   [
 139     # AX_CHECK_OPENSSL doesn't seem to play nice with builds started
 140     # via build/bootstrap-osx-homebrew.sh
 141     AC_MSG_WARN(["Using existing OpenSSL flags from environment."])
 142     PKG_CXXFLAGS="$PKG_CXXFLAGS $OPENSSL_INCLUDES"
 143   ]
 144 )
 145 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 146
 147 # check for boost libs
 148 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 149               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 150 AX_BOOST_CONTEXT
 151 AX_BOOST_PROGRAM_OPTIONS
 152 AX_BOOST_THREAD
 153 AX_BOOST_REGEX
 154 AX_BOOST_SYSTEM
 155 AX_BOOST_FILESYSTEM
 156 AX_BOOST_CHRONO
 157
 158 # Check for python interpreter
 159 AM_PATH_PYTHON
 160
 161 # Checks for header files.
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([features.h malloc.h bits/functexcept.h bits/c++config.h])
 164
 165 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 166                 [Couldn't find double-conversion.h, please download from \
 167                  https://github.com/google/double-conversion/])], [])
 168 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 169              [Please install double-conversion library])])
 170
 171 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 172 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 173
 174 AC_ARG_WITH([jemalloc], [
 175   --with-jemalloc     Whether to make folly jemalloc aware
 176 ],[
 177   AC_CHECK_LIB([jemalloc], [xallocx],[
 178     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 179   ],[
 180     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 181   ])
 182 ])
 183
 184 # Checks for typedefs, structures, and compiler characteristics.
 185 AC_C_CONST
 186 AC_C_INLINE
 187 AC_TYPE_SIZE_T
 188 AC_HEADER_TIME
 189 AC_C_VOLATILE
 190 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 191     [folly_cv_prog_cc_int128=no])
 192 if test "$folly_cv_prog_cc_int128" = "yes"; then
 193   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 194   AC_CACHE_CHECK(
 195     [for __int128 type traits],
 196     [folly_cv_prog_cc_int128traits],
 197     [AC_COMPILE_IFELSE(
 198       [AC_LANG_SOURCE([[
 199 #include <type_traits>
 200 static_assert(
 201   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 202   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 203       ]])],
 204       [folly_cv_prog_cc_int128traits=yes],
 205       [folly_cv_prog_cc_int128traits=no])
 206     ])
 207   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 208     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 209   fi
 210 fi
 211
 212 AC_CHECK_TYPES([pthread_spinlock_t])
 213
 214 AC_CACHE_CHECK(
 215   [for ifunc support],
 216   [folly_cv_prog_cc_ifunc],
 217   [AC_COMPILE_IFELSE(
 218     [AC_LANG_SOURCE[
 219       #pragma GCC diagnostic error "-Wattributes"
 220       extern "C" void (*test_ifunc(void))() { return 0; }
 221       void func() __attribute__((ifunc("test_ifunc")));]
 222     ],
 223     [folly_cv_prog_cc_ifunc=yes],
 224     [folly_cv_prog_cc_ifunc=no])])
 225
 226 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 227   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 228 fi
 229
 230 AC_CACHE_CHECK(
 231   [for final and override support],
 232   [folly_cv_c_final_override],
 233   [AC_COMPILE_IFELSE(
 234     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 235                     class D : public C { virtual void g() override {} };]],
 236     [folly_cv_c_final_override=yes],
 237     [folly_cv_c_final_override=no])])
 238
 239 if test "$folly_cv_c_final_override" = "yes"; then
 240   final_val=final
 241   override_val=override
 242 else
 243   final_val=
 244   override_val=
 245 fi
 246
 247 AC_DEFINE_UNQUOTED(
 248   [FINAL], [$final_val],
 249   [Define to "final" if the compiler supports C++11 "final"])
 250 AC_DEFINE_UNQUOTED(
 251   [OVERRIDE], [$override_val],
 252   [Define to "override" if the compiler supports C++11 "override"])
 253
 254 AC_CACHE_CHECK(
 255   [for constexpr strlen],
 256   [folly_cv_func_constexpr_strlen],
 257   [AC_COMPILE_IFELSE(
 258     [AC_LANG_SOURCE[
 259       #include <cstring>
 260       static constexpr int val = strlen("foo");]],
 261     [folly_cv_func_constexpr_strlen=yes],
 262     [folly_cv_func_constexpr_strlen=no])])
 263
 264 if test "$folly_cv_func_constexpr_strlen" = yes; then
 265     AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
 266               [Define to 1 if strlen(3) is constexpr.])
 267 fi
 268
 269 AC_CACHE_CHECK(
 270   [for libc++],
 271   [folly_cv_lib_libcpp],
 272   [AC_COMPILE_IFELSE(
 273     [AC_LANG_SOURCE[
 274       #include <type_traits>
 275       #if !_LIBCPP_VERSION
 276       #error No libc++
 277       #endif
 278       void func() {}]
 279     ],
 280     [folly_cv_lib_libcpp=yes],
 281     [folly_cv_lib_libcpp=no])])
 282
 283 if test "$folly_cv_lib_libcpp" = yes; then
 284   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 285 fi
 286
 287 AC_CACHE_CHECK(
 288   [for c++11 atomic support without GNU Atomic library],
 289   [folly_cv_lib_libatomic],
 290   [AC_LINK_IFELSE(
 291     [AC_LANG_SOURCE[
 292       #include <atomic>
 293       int main() {
 294         struct Test { int val; };
 295         std::atomic<Test> s;
 296         s.is_lock_free();
 297       }
 298     ]],
 299     [folly_cv_lib_libatomic=yes],
 300     [folly_cv_lib_libatomic=no])])
 301
 302 if test "$folly_cv_lib_libatomic" = no; then
 303   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 304                   [Please install the GNU Atomic library])])
 305 fi
 306
 307 AC_CACHE_CHECK(
 308   [for liblinux-vdso support],
 309   [folly_cv_lib_liblinux_vdso],
 310   [AC_RUN_IFELSE(
 311     [AC_LANG_PROGRAM[
 312       #include <dlfcn.h>
 313       int main() {
 314         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 315         if (h == nullptr) {
 316           return -1;
 317         }
 318         dlclose(h);
 319         return 0;
 320       }
 321     ]],
 322     [folly_cv_lib_liblinux_vdso=yes],
 323     [folly_cv_lib_liblinux_vdso=no])])
 324
 325 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 326   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 327 fi
 328
 329 AC_CACHE_CHECK(
 330   [for usable std::is_trivially_copyable],
 331   [folly_cv_decl_std_is_trivially_copyable],
 332   [AC_COMPILE_IFELSE(
 333     [AC_LANG_SOURCE[
 334       #include <type_traits>
 335       const bool val = std::is_trivially_copyable<bool>::value;]
 336     ],
 337     [folly_cv_decl_std_is_trivially_copyable=yes],
 338     [folly_cv_decl_std_is_trivially_copyable=no])])
 339
 340 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 341   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 342             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 343              implementation.])
 344 fi
 345
 346 AC_CACHE_CHECK(
 347   [gflags namespace],
 348   [folly_cv_decl_gflags_namespace],
 349   [AC_COMPILE_IFELSE(
 350     [AC_LANG_SOURCE[
 351       #include <gflags/gflags.h>
 352       void foo() { gflags::GetArgv(); }]
 353     ],
 354     [folly_cv_decl_gflags_namespace=gflags],
 355     [AC_COMPILE_IFELSE(
 356       [AC_LANG_SOURCE[
 357         #include <gflags/gflags.h>
 358         void foo() { google::GetArgv(); }]
 359       ],
 360       [folly_cv_decl_gflags_namespace=google],
 361       [folly_cv_decl_gflags_namespace=error])])])
 362
 363 if test "$folly_cv_decl_gflags_namespace" = error; then
 364   AC_MSG_ERROR([Cannot determine gflags namespace])
 365 else
 366   AC_DEFINE_UNQUOTED(
 367     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 368     [Define to gflags namespace (usually "google" or "gflags")])
 369   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 370      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 371                [Define to 1 if the gflags namespace is not "gflags"])
 372   fi
 373 fi
 374
 375 # Figure out if we support weak symbols. If not, we will link in some null
 376 # stubs for functions that would otherwise be weak.
 377 AC_CACHE_CHECK(
 378   [for weak symbol support],
 379   [folly_cv_prog_cc_weak_symbols],
 380   [AC_LINK_IFELSE(
 381     [AC_LANG_SOURCE[
 382       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 383       int main(int argc, char** argv) {
 384           return configure_link_extern_weak_test == nullptr;
 385       }]],
 386     [folly_cv_prog_cc_weak_symbols="yes"],
 387     [folly_cv_prog_cc_weak_symbols="no"])])
 388
 389 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 390   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 391             [Define to 1 if the linker supports weak symbols.])
 392 fi
 393
 394
 395 # Figure out if we support wchar well
 396 AC_CACHE_CHECK(
 397   [for wchar support],
 398   [folly_cv_prog_cc_wchar_support],
 399   [AC_RUN_IFELSE(
 400     [AC_LANG_SOURCE[
 401       #include <cstddef>
 402       #include <cwchar>
 403
 404       int main(int argc, char** argv) {
 405         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 406       }
 407     ]],
 408     [folly_cv_prog_cc_wchar_support=yes],
 409     [folly_cv_prog_cc_wchar_support=no])])
 410
 411 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 412   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 413 fi
 414
 415 # Figure out whether the architecture supports unaligned accesses
 416 AC_CACHE_CHECK(
 417   [for unaligned access support],
 418   [folly_cv_prog_cc_unaligned_access],
 419   [AC_RUN_IFELSE(
 420     [AC_LANG_SOURCE[
 421       int main(int argc, char** argv) {
 422         char buf[64] = {0};
 423         unsigned long *ptr = (unsigned long *)(buf + 1);
 424         *ptr = 0xdeadbeef;
 425         return (*ptr & 0xff) == 0xef ? 0 : 1;
 426       }
 427     ]],
 428     [folly_cv_prog_cc_unaligned_access=yes],
 429     [folly_cv_prog_cc_unaligned_access=no])])
 430
 431 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 432   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 433 fi
 434
 435 AC_CACHE_CHECK(
 436   [for vsnprintf reporting bad format strings],
 437   [folly_cv_prog_vsnprintf_bad_format],
 438   [AC_RUN_IFELSE(
 439     [AC_LANG_SOURCE[
 440       #include <stdio.h>
 441
 442       int main(int argc, char** argv) {
 443           char buf[256];
 444           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 445       }]],
 446     [folly_cv_prog_vsnprintf_bad_format="yes"],
 447     [folly_cv_prog_vsnprintf_bad_format="no"])])
 448
 449 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 450   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 451             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 452 fi
 453
 454 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 455 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 456   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 457             [Define to 1 if we have cplus_demangle_v3_callback.])
 458 fi
 459
 460 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 461 # want to link with librt if necessary.
 462 AC_SEARCH_LIBS([clock_gettime], [rt],
 463   AC_DEFINE(
 464     [HAVE_CLOCK_GETTIME],
 465     [1],
 466     [Define to 1 if we support clock_gettime(2).]),
 467   [])
 468
 469 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 470 # want to include pthread.h if necessary.
 471 AC_CACHE_CHECK(
 472   [for pthread_atfork support],
 473   [folly_cv_prog_cc_pthread_atfork],
 474   [AC_COMPILE_IFELSE(
 475     [AC_LANG_SOURCE[
 476       #include <pthread.h>
 477       void func() {pthread_atfork(NULL, NULL, NULL);}]
 478     ],
 479     [folly_cv_prog_cc_pthread_atfork=yes],
 480     [folly_cv_prog_cc_pthread_atfork=no])])
 481
 482 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 483   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 484 fi
 485
 486 # Check for XSI-compatible strerror_r as default implementation
 487 AC_CACHE_CHECK(
 488   [for XSI style strerror_r support],
 489   [folly_cv_prog_cc_xsi_strerror_r],
 490   [AC_RUN_IFELSE(
 491     [AC_LANG_SOURCE[
 492       #include <string.h>
 493       #include <errno.h>
 494       int main(int argc, char** argv) {
 495         char buf[1024];
 496         buf[0] = 0;
 497         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 498         return ret;
 499       }
 500     ]],
 501     [folly_cv_prog_cc_xsi_strerror_r=yes],
 502     [folly_cv_prog_cc_xsi_strerror_r=no])])
 503
 504 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 505   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 506 fi
 507
 508 AC_CACHE_CHECK(
 509   [for ext/random and __gnu_cxx::sfmt19937],
 510   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 511   [AC_COMPILE_IFELSE(
 512     [AC_LANG_SOURCE[
 513       #include <ext/random>
 514       int main(int argc, char** argv) {
 515         __gnu_cxx::sfmt19937 rng;
 516         return 0;
 517       }
 518     ]],
 519     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 520     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 521
 522 AC_CACHE_CHECK(
 523   [for VLA (variable-length array) support],
 524   [folly_cv_prog_cc_have_vla],
 525   [AC_COMPILE_IFELSE(
 526     [AC_LANG_SOURCE[
 527       int main(int argc, char** argv) {
 528         unsigned size = argc;
 529         char data[size];
 530         return 0;
 531       }
 532     ]],
 533     [folly_cv_prog_cc_have_vla=yes],
 534     [folly_cv_prog_cc_have_vla=no])])
 535
 536 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 537 AC_DEFINE_UNQUOTED(
 538   [HAVE_VLA],
 539   [$have_vla],
 540   [Define to 1 if the compiler has VLA (variable-length array) support,
 541    otherwise define to 0])
 542
 543 # Checks for library functions.
 544 AC_CHECK_FUNCS([malloc_size \
 545                 malloc_usable_size \
 546                 memrchr \
 547                 pipe2 \
 548                 preadv \
 549                 pwritev \
 550               ])
 551
 552 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 553 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 554 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 555 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 556 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 557 AC_CHECK_HEADER([bzlib.h], AC_CHECK_LIB([bz2], [main]))
 558 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 559
 560 AC_ARG_ENABLE([follytestmain],
 561    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 562    [use_follytestmain=${enableval}], [use_follytestmain=yes])
 563
 564 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 565 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 566 # Check whether we have both the library and the header
 567 have_libdwarf=no
 568 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 569 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 570
 571
 572 AC_ARG_ENABLE([mobile],
 573    AS_HELP_STRING([--enable-mobile],
 574                   [enables using main function from folly for tests]),
 575                   [mobile=${enableval}], [mobile=no])
 576 AS_IF([test "x${mobile}" = "xyes"], [
 577     AC_DEFINE([MOBILE], [1],
 578               [Define to 1 for compiler guards for mobile targets.])
 579 ])
 580
 581 # Include directory that contains "folly" so #include <folly/Foo.h> works
 582 AM_CPPFLAGS='-I$(top_srcdir)/..'
 583 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS $OPENSSL_INCLUDES"
 584 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 585 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 586 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 587 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 588
 589 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 590
 591 AC_SUBST([AM_CPPFLAGS])
 592 AC_SUBST([AM_LDFLAGS])
 593
 594 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 595 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 596 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 597 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 598 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 599 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 600                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 601 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 602 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 603                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 604 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 605 AM_CONDITIONAL([HAVE_LIBDWARF], [test "x${have_libdwarf}" = "xyes"])
 606 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 607
 608 # remove pkg-config deps from dependent libraries
 609 # (at least for pkg-config file purposes)
 610 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 611
 612 # Output
 613 AC_CONFIG_FILES([Makefile
 614                  io/test/Makefile
 615                  libfolly.pc
 616                  test/Makefile
 617                  test/function_benchmark/Makefile
 618                  experimental/Makefile
 619                  experimental/io/test/Makefile
 620                  experimental/symbolizer/Makefile
 621                  init/Makefile])
 622 AC_OUTPUT