folly/configure.ac

   1
   2 #                                               -*- Autoconf -*-
   3 # Process this file with autoconf to produce a configure script.
   4
   5 AC_PREREQ(2.59)
   6
   7 m4_define([folly_version_str], m4_esyscmd_s([cat VERSION]))
   8
   9 AC_INIT([folly], m4_translit(folly_version_str, [:], [.]), [folly@fb.com])
  10
  11 # We assume all revisions are backwards incompatible.
  12 LT_VERSION=folly_version_str:0
  13 AC_SUBST([LT_VERSION])
  14
  15 #declare pkg-config variables
  16 PKG_VERSION=m4_join([.], m4_reverse(m4_translit(folly_version_str, [:], [,])))
  17 AC_SUBST([PKG_VERSION])
  18 AC_SUBST([PKG_CXXFLAGS])
  19 AC_SUBST([PKG_DEPS])
  20 AC_SUBST([PKG_LIBS])
  21
  22 AC_CONFIG_SRCDIR([Likely.h])
  23 AC_CONFIG_HEADERS([config.h])
  24 AX_PREFIX_CONFIG_H([folly-config.h], [folly], [config.h])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 nostdinc subdir-objects])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AX_CONFIG_FEATURE_DEFAULT_DISABLED
  32 AX_CONFIG_FEATURE(
  33         [deprecated-assoc],
  34         [supports deprecated associative containers (hash_map/hash_set)],
  35         [HAVE_DEPRECATED_ASSOC],
  36         [Define if you want to support deprecated associative containers])
  37
  38 AC_PROG_INSTALL
  39 AM_PROG_LIBTOOL
  40
  41 AC_LANG([C++])
  42
  43 # Checks for programs.
  44 AC_PROG_CXX
  45 AC_PROG_CC
  46
  47 AC_CXX_COMPILE_STDCXX_1Y
  48
  49 # Be sure to add any -std option to CXXFLAGS before we invoke any
  50 # AC_COMPILE_IFELSE() or similar macros. Any such macros that are invoked
  51 # before we update CXXFLAGS will not be run with the same options that we use
  52 # during the real build.
  53 STD=""
  54 if test "x$ac_cv_cxx_compile_cxx1y_cxx" = xyes; then
  55    STD="-std=c++1y"
  56 fi
  57 if test "x$ac_cv_cxx_compile_cxx1y_gxx" = xyes; then
  58    STD="-std=gnu++1y"
  59 fi
  60
  61 CXXFLAGS="$STD $CXXFLAGS"
  62
  63 # expose required -std option via pkg-config
  64 PKG_CXXFLAGS=$STD
  65
  66 # See if -Wshadow-local and -Wshadow-compatible-local are supported
  67 AC_MSG_CHECKING(
  68   [whether -Wshadow-local and -Wshadow-compatible-local are supported])
  69 AC_CACHE_VAL([folly_cv_cxx_shadow_local_support], [
  70   folly_save_CXXFLAGS="$CXXFLAGS"
  71   CXXFLAGS="$CXXFLAGS -Wshadow-local -Wshadow-compatible-local"
  72   AC_COMPILE_IFELSE(
  73     [AC_LANG_PROGRAM([[]], [[]])],
  74     [folly_cv_cxx_shadow_local_support=yes],
  75     [folly_cv_cxx_shadow_local_support=no])
  76   CXXFLAGS="$folly_save_CXXFLAGS"])
  77 AC_MSG_RESULT([$folly_cv_cxx_shadow_local_support])
  78 if test "$folly_cv_cxx_shadow_local_support" = yes; then
  79   AC_DEFINE([HAVE_SHADOW_LOCAL_WARNINGS], [1],
  80   [Define if both -Wshadow-local and -Wshadow-compatible-local are supported.])
  81 fi
  82
  83 # Checks for glog and gflags
  84 # There are no symbols with C linkage, so we do a try-run
  85 AC_HAVE_LIBRARY([gflags],[],[AC_MSG_ERROR(
  86                 [Please install google-gflags library])])
  87 AC_CACHE_CHECK(
  88   [for gflags viability],
  89   [folly_cv_prog_cc_gflags],
  90   [AC_RUN_IFELSE(
  91     [AC_LANG_SOURCE[
  92       #include <gflags/gflags.h>
  93       DEFINE_bool(folly_truthy, true, "Sample truthy flag");
  94       DEFINE_bool(folly_falsey, false, "Sample falsey flag");
  95       int main(int argc, char** argv) {
  96         return (FLAGS_folly_truthy && !FLAGS_folly_falsey) ? 0 : 1;
  97       }
  98     ]],
  99     [folly_cv_prog_cc_gflags=yes],
 100     [folly_cv_prog_cc_gflags=no]
 101   )]
 102 )
 103
 104 if test "$folly_cv_prog_cc_gflags" != "yes"; then
 105   AC_MSG_ERROR(["gflags invalid, see config.log for details"])
 106 fi
 107 FB_CHECK_PKG_CONFIG([GFLAGS], [gflags])
 108
 109 AC_HAVE_LIBRARY([glog],[],[AC_MSG_ERROR(
 110                 [Please install google-glog library])])
 111 AC_CACHE_CHECK(
 112   [for glog viability],
 113   [folly_cv_prog_cc_glog],
 114   [AC_RUN_IFELSE(
 115     [AC_LANG_SOURCE[
 116       #include <glog/logging.h>
 117       int main(int argc, char** argv) {
 118         google::InitGoogleLogging(argv[0]);
 119         google::ShutdownGoogleLogging();
 120         return 0;
 121       }
 122     ]],
 123     [folly_cv_prog_cc_glog=yes],
 124     [folly_cv_prog_cc_glog=no]
 125   )]
 126 )
 127
 128 if test "$folly_cv_prog_cc_glog" != "yes"; then
 129   AC_MSG_ERROR(["libglog invalid, see config.log for details"])
 130 fi
 131 FB_CHECK_PKG_CONFIG([GLOG], [libglog])
 132
 133 AS_IF(
 134   [test "x$OPENSSL_INCLUDES" = "x"],
 135   [
 136     AX_CHECK_OPENSSL([], [AC_MSG_ERROR(["Error: libssl required"])])
 137   ],
 138   [
 139     # AX_CHECK_OPENSSL doesn't seem to play nice with builds started
 140     # via build/bootstrap-osx-homebrew.sh
 141     AC_MSG_WARN(["Using existing OpenSSL flags from environment."])
 142     PKG_CXXFLAGS="$PKG_CXXFLAGS $OPENSSL_INCLUDES"
 143   ]
 144 )
 145 FB_CHECK_PKG_CONFIG([OPENSSL], [openssl])
 146
 147 # check for boost libs
 148 AX_BOOST_BASE([1.51.0], [], [AC_MSG_ERROR(
 149               [Please install boost >= 1.51.0 (context, thread, program_options, regex, system and chrono)])])
 150 AX_BOOST_CONTEXT
 151 AX_BOOST_PROGRAM_OPTIONS
 152 AX_BOOST_THREAD
 153 AX_BOOST_REGEX
 154 AX_BOOST_SYSTEM
 155 AX_BOOST_FILESYSTEM
 156 AX_BOOST_CHRONO
 157
 158 # Check for python interpreter
 159 AM_PATH_PYTHON
 160
 161 # Checks for header files.
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([features.h malloc.h bits/functexcept.h bits/c++config.h])
 164
 165 AC_CHECK_HEADER(double-conversion/double-conversion.h, [], [AC_MSG_ERROR(
 166                 [Couldn't find double-conversion.h, please download from \
 167                  https://github.com/google/double-conversion/])], [])
 168 AC_CHECK_LIB([double-conversion],[ceil],[],[AC_MSG_ERROR(
 169              [Please install double-conversion library])])
 170
 171 AC_CHECK_LIB([event], [event_set], [], [AC_MSG_ERROR([Unable to find libevent])])
 172 FB_CHECK_PKG_CONFIG([EVENT], [libevent])
 173
 174 AC_ARG_WITH([jemalloc], [
 175   --with-jemalloc     Whether to make folly jemalloc aware
 176 ],[
 177   AC_CHECK_LIB([jemalloc], [xallocx],[
 178     AC_DEFINE([USE_JEMALLOC], [1], [Enable jemalloc])
 179   ],[
 180     AC_MSG_ERROR([--with-jemalloc requested, but jemalloc not found])
 181   ])
 182 ])
 183
 184 # Checks for typedefs, structures, and compiler characteristics.
 185 AC_C_CONST
 186 AC_C_INLINE
 187 AC_TYPE_SIZE_T
 188 AC_HEADER_TIME
 189 AC_C_VOLATILE
 190 AC_CHECK_TYPE([__int128], [folly_cv_prog_cc_int128=yes],
 191     [folly_cv_prog_cc_int128=no])
 192 if test "$folly_cv_prog_cc_int128" = "yes"; then
 193   AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128])
 194   AC_CACHE_CHECK(
 195     [for __int128 type traits],
 196     [folly_cv_prog_cc_int128traits],
 197     [AC_COMPILE_IFELSE(
 198       [AC_LANG_SOURCE([[
 199 #include <type_traits>
 200 static_assert(
 201   ::std::is_same<::std::make_signed<unsigned __int128>::type, __int128>::value,
 202   "signed form of \`unsigned __uint128\` must be \`__int128\`.");
 203       ]])],
 204       [folly_cv_prog_cc_int128traits=yes],
 205       [folly_cv_prog_cc_int128traits=no])
 206     ])
 207   if test "$folly_cv_prog_cc_int128traits" = "no"; then
 208     AC_DEFINE([SUPPLY_MISSING_INT128_TRAITS], [1], [Define if we need the standard integer traits defined for the type `__int128'.])
 209   fi
 210 fi
 211
 212 AC_CHECK_TYPES([pthread_spinlock_t])
 213
 214 AC_CACHE_CHECK(
 215   [for ifunc support],
 216   [folly_cv_prog_cc_ifunc],
 217   [AC_COMPILE_IFELSE(
 218     [AC_LANG_SOURCE[
 219       #pragma GCC diagnostic error "-Wattributes"
 220       extern "C" void (*test_ifunc(void))() { return 0; }
 221       void func() __attribute__((ifunc("test_ifunc")));]
 222     ],
 223     [folly_cv_prog_cc_ifunc=yes],
 224     [folly_cv_prog_cc_ifunc=no])])
 225
 226 if test "$folly_cv_prog_cc_ifunc" = "yes"; then
 227   AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
 228 fi
 229
 230 AC_CACHE_CHECK(
 231   [for final and override support],
 232   [folly_cv_c_final_override],
 233   [AC_COMPILE_IFELSE(
 234     [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
 235                     class D : public C { virtual void g() override {} };]],
 236     [folly_cv_c_final_override=yes],
 237     [folly_cv_c_final_override=no])])
 238
 239 if test "$folly_cv_c_final_override" = "yes"; then
 240   final_val=final
 241   override_val=override
 242 else
 243   final_val=
 244   override_val=
 245 fi
 246
 247 AC_DEFINE_UNQUOTED(
 248   [FINAL], [$final_val],
 249   [Define to "final" if the compiler supports C++11 "final"])
 250 AC_DEFINE_UNQUOTED(
 251   [OVERRIDE], [$override_val],
 252   [Define to "override" if the compiler supports C++11 "override"])
 253
 254 AC_CACHE_CHECK(
 255   [for libc++],
 256   [folly_cv_lib_libcpp],
 257   [AC_COMPILE_IFELSE(
 258     [AC_LANG_SOURCE[
 259       #include <type_traits>
 260       #if !_LIBCPP_VERSION
 261       #error No libc++
 262       #endif
 263       void func() {}]
 264     ],
 265     [folly_cv_lib_libcpp=yes],
 266     [folly_cv_lib_libcpp=no])])
 267
 268 if test "$folly_cv_lib_libcpp" = yes; then
 269   AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
 270 fi
 271
 272 AC_CACHE_CHECK(
 273   [for c++11 atomic support without GNU Atomic library],
 274   [folly_cv_lib_libatomic],
 275   [AC_LINK_IFELSE(
 276     [AC_LANG_SOURCE[
 277       #include <atomic>
 278       int main() {
 279         struct Test { int val; };
 280         std::atomic<Test> s;
 281         s.is_lock_free();
 282       }
 283     ]],
 284     [folly_cv_lib_libatomic=yes],
 285     [folly_cv_lib_libatomic=no])])
 286
 287 if test "$folly_cv_lib_libatomic" = no; then
 288   AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
 289                   [Please install the GNU Atomic library])])
 290 fi
 291
 292 AC_CACHE_CHECK(
 293   [for liblinux-vdso support],
 294   [folly_cv_lib_liblinux_vdso],
 295   [AC_RUN_IFELSE(
 296     [AC_LANG_PROGRAM[
 297       #include <dlfcn.h>
 298       int main() {
 299         void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
 300         if (h == nullptr) {
 301           return -1;
 302         }
 303         dlclose(h);
 304         return 0;
 305       }
 306     ]],
 307     [folly_cv_lib_liblinux_vdso=yes],
 308     [folly_cv_lib_liblinux_vdso=no])])
 309
 310 if test "$folly_cv_lib_liblinux_vdso" = yes; then
 311   AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
 312 fi
 313
 314 AC_DEFINE([HAVE_PTHREAD], [1], [Define to 1 if pthread is avaliable])
 315
 316 AC_CACHE_CHECK(
 317   [for usable std::is_trivially_copyable],
 318   [folly_cv_decl_std_is_trivially_copyable],
 319   [AC_COMPILE_IFELSE(
 320     [AC_LANG_SOURCE[
 321       #include <type_traits>
 322       const bool val = std::is_trivially_copyable<bool>::value;]
 323     ],
 324     [folly_cv_decl_std_is_trivially_copyable=yes],
 325     [folly_cv_decl_std_is_trivially_copyable=no])])
 326
 327 if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
 328   AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
 329             [Define to 1 if we have a usable std::is_trivially_copyable<T>
 330              implementation.])
 331 fi
 332
 333 AC_CACHE_CHECK(
 334   [gflags namespace],
 335   [folly_cv_decl_gflags_namespace],
 336   [AC_COMPILE_IFELSE(
 337     [AC_LANG_SOURCE[
 338       #include <gflags/gflags.h>
 339       void foo() { gflags::GetArgv(); }]
 340     ],
 341     [folly_cv_decl_gflags_namespace=gflags],
 342     [AC_COMPILE_IFELSE(
 343       [AC_LANG_SOURCE[
 344         #include <gflags/gflags.h>
 345         void foo() { google::GetArgv(); }]
 346       ],
 347       [folly_cv_decl_gflags_namespace=google],
 348       [folly_cv_decl_gflags_namespace=error])])])
 349
 350 if test "$folly_cv_decl_gflags_namespace" = error; then
 351   AC_MSG_ERROR([Cannot determine gflags namespace])
 352 else
 353   AC_DEFINE_UNQUOTED(
 354     [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
 355     [Define to gflags namespace (usually "google" or "gflags")])
 356   if test "$folly_cv_decl_gflags_namespace" != gflags; then
 357      AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
 358                [Define to 1 if the gflags namespace is not "gflags"])
 359   fi
 360 fi
 361
 362 # Figure out if we support weak symbols. If not, we will link in some null
 363 # stubs for functions that would otherwise be weak.
 364 AC_CACHE_CHECK(
 365   [for weak symbol support],
 366   [folly_cv_prog_cc_weak_symbols],
 367   [AC_LINK_IFELSE(
 368     [AC_LANG_SOURCE[
 369       extern "C" void configure_link_extern_weak_test() __attribute__((weak));
 370       int main(int argc, char** argv) {
 371           return configure_link_extern_weak_test == nullptr;
 372       }]],
 373     [folly_cv_prog_cc_weak_symbols="yes"],
 374     [folly_cv_prog_cc_weak_symbols="no"])])
 375
 376 if test "$folly_cv_prog_cc_weak_symbols" = yes; then
 377   AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
 378             [Define to 1 if the linker supports weak symbols.])
 379 fi
 380
 381
 382 # Figure out if we support wchar well
 383 AC_CACHE_CHECK(
 384   [for wchar support],
 385   [folly_cv_prog_cc_wchar_support],
 386   [AC_RUN_IFELSE(
 387     [AC_LANG_SOURCE[
 388       #include <cstddef>
 389       #include <cwchar>
 390
 391       int main(int argc, char** argv) {
 392         return wcstol(L"01", nullptr, 10) == 1 ? 0 : 1;
 393       }
 394     ]],
 395     [folly_cv_prog_cc_wchar_support=yes],
 396     [folly_cv_prog_cc_wchar_support=no])])
 397
 398 if test "$folly_cv_prog_cc_wchar_support" = "yes"; then
 399   AC_DEFINE([HAVE_WCHAR_SUPPORT], [1], [Define to 1 if the libc supports wchar well])
 400 fi
 401
 402 # Figure out whether the architecture supports unaligned accesses
 403 AC_CACHE_CHECK(
 404   [for unaligned access support],
 405   [folly_cv_prog_cc_unaligned_access],
 406   [AC_RUN_IFELSE(
 407     [AC_LANG_SOURCE[
 408       int main(int argc, char** argv) {
 409         char buf[64] = {0};
 410         unsigned long *ptr = (unsigned long *)(buf + 1);
 411         *ptr = 0xdeadbeef;
 412         return (*ptr & 0xff) == 0xef ? 0 : 1;
 413       }
 414     ]],
 415     [folly_cv_prog_cc_unaligned_access=yes],
 416     [folly_cv_prog_cc_unaligned_access=no])])
 417
 418 if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
 419   AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
 420 fi
 421
 422 AC_CACHE_CHECK(
 423   [for vsnprintf reporting bad format strings],
 424   [folly_cv_prog_vsnprintf_bad_format],
 425   [AC_RUN_IFELSE(
 426     [AC_LANG_SOURCE[
 427       #include <stdio.h>
 428
 429       int main(int argc, char** argv) {
 430           char buf[256];
 431           return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
 432       }]],
 433     [folly_cv_prog_vsnprintf_bad_format="yes"],
 434     [folly_cv_prog_vsnprintf_bad_format="no"])])
 435
 436 if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
 437   AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
 438             [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
 439 fi
 440
 441 AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
 442 if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
 443   AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
 444             [Define to 1 if we have cplus_demangle_v3_callback.])
 445 fi
 446
 447 # Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
 448 # want to link with librt if necessary.
 449 AC_SEARCH_LIBS([clock_gettime], [rt],
 450   AC_DEFINE(
 451     [HAVE_CLOCK_GETTIME],
 452     [1],
 453     [Define to 1 if we support clock_gettime(2).]),
 454   [])
 455
 456 # Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
 457 # want to include pthread.h if necessary.
 458 AC_CACHE_CHECK(
 459   [for pthread_atfork support],
 460   [folly_cv_prog_cc_pthread_atfork],
 461   [AC_COMPILE_IFELSE(
 462     [AC_LANG_SOURCE[
 463       #include <pthread.h>
 464       void func() {pthread_atfork(NULL, NULL, NULL);}]
 465     ],
 466     [folly_cv_prog_cc_pthread_atfork=yes],
 467     [folly_cv_prog_cc_pthread_atfork=no])])
 468
 469 if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
 470   AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
 471 fi
 472
 473 # Check for XSI-compatible strerror_r as default implementation
 474 AC_CACHE_CHECK(
 475   [for XSI style strerror_r support],
 476   [folly_cv_prog_cc_xsi_strerror_r],
 477   [AC_RUN_IFELSE(
 478     [AC_LANG_SOURCE[
 479       #include <string.h>
 480       #include <errno.h>
 481       int main(int argc, char** argv) {
 482         char buf[1024];
 483         buf[0] = 0;
 484         int ret = strerror_r(ENOMEM, buf, sizeof(buf));
 485         return ret;
 486       }
 487     ]],
 488     [folly_cv_prog_cc_xsi_strerror_r=yes],
 489     [folly_cv_prog_cc_xsi_strerror_r=no])])
 490
 491 if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
 492   AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
 493 fi
 494
 495 AC_CACHE_CHECK(
 496   [for ext/random and __gnu_cxx::sfmt19937],
 497   [folly_cv_prog_cc_have_extrandom_sfmt19937],
 498   [AC_COMPILE_IFELSE(
 499     [AC_LANG_SOURCE[
 500       #include <ext/random>
 501       int main(int argc, char** argv) {
 502         __gnu_cxx::sfmt19937 rng;
 503         return 0;
 504       }
 505     ]],
 506     [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
 507     [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
 508
 509 AC_CACHE_CHECK(
 510   [for VLA (variable-length array) support],
 511   [folly_cv_prog_cc_have_vla],
 512   [AC_COMPILE_IFELSE(
 513     [AC_LANG_SOURCE[
 514       int main(int argc, char** argv) {
 515         unsigned size = argc;
 516         char data[size];
 517         return 0;
 518       }
 519     ]],
 520     [folly_cv_prog_cc_have_vla=yes],
 521     [folly_cv_prog_cc_have_vla=no])])
 522
 523 test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
 524 AC_DEFINE_UNQUOTED(
 525   [HAVE_VLA],
 526   [$have_vla],
 527   [Define to 1 if the compiler has VLA (variable-length array) support,
 528    otherwise define to 0])
 529
 530 # Checks for library functions.
 531 AC_CHECK_FUNCS([malloc_size \
 532                 malloc_usable_size \
 533                 memrchr \
 534                 pipe2 \
 535                 preadv \
 536                 pwritev \
 537               ])
 538
 539 AC_CHECK_HEADER([lz4.h], AC_CHECK_LIB([lz4], [LZ4_decompress_safe]))
 540 AC_CHECK_HEADER([snappy.h], AC_CHECK_LIB([snappy], [main]))
 541 AC_CHECK_HEADER([zlib.h], AC_CHECK_LIB([z], [main]))
 542 AC_CHECK_HEADER([lzma.h], AC_CHECK_LIB([lzma], [main]))
 543 AC_CHECK_HEADER([zstd.h], AC_CHECK_LIB([zstd], [ZSTD_compressStream]))
 544 AC_CHECK_HEADER([bzlib.h], AC_CHECK_LIB([bz2], [main]))
 545 AC_CHECK_HEADER([linux/membarrier.h], AC_DEFINE([HAVE_LINUX_MEMBARRIER_H], [1], [Define to 1 if membarrier.h is available]))
 546
 547 AC_ARG_ENABLE([follytestmain],
 548    AS_HELP_STRING([--enable-follytestmain], [enables using main function from folly for tests]),
 549    [use_follytestmain=${enableval}], [use_follytestmain=yes])
 550
 551 # libdwarf used to install in /usr/include, now installs in /usr/include/libdwarf.
 552 AC_CHECK_HEADERS([libdwarf/dwarf.h dwarf.h], [break])
 553 # Check whether we have both the library and the header
 554 have_libdwarf=no
 555 AS_IF([test "x${ac_cv_header_libdwarf_dwarf_h}" = xyes], [have_libdwarf=yes])
 556 AS_IF([test "x${ac_cv_header_dwarf_h}" = xyes], [have_libdwarf=yes])
 557
 558
 559 AC_ARG_ENABLE([mobile],
 560    AS_HELP_STRING([--enable-mobile],
 561                   [enables using main function from folly for tests]),
 562                   [mobile=${enableval}], [mobile=no])
 563 AS_IF([test "x${mobile}" = "xyes"], [
 564     AC_DEFINE([MOBILE], [1],
 565               [Define to 1 for compiler guards for mobile targets.])
 566 ])
 567
 568 AC_ARG_ENABLE([exception-tracer],
 569     AS_HELP_STRING([--enable-exception-tracer], [enables building exception tracer]),
 570     [build_exception_tracer=${enableval}], [build_exception_tracer=no])
 571
 572 # Include directory that contains "folly" so #include <folly/Foo.h> works
 573 AM_CPPFLAGS='-I$(top_srcdir)/..'
 574 AM_CPPFLAGS="$AM_CPPFLAGS $BOOST_CPPFLAGS $OPENSSL_INCLUDES"
 575 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CONTEXT_LIB $BOOST_PROGRAM_OPTIONS_LIB"
 576 AM_LDFLAGS="$AM_LDFLAGS $BOOST_THREAD_LIB $BOOST_FILESYSTEM_LIB"
 577 AM_LDFLAGS="$AM_LDFLAGS $BOOST_SYSTEM_LIB $BOOST_REGEX_LIB -lpthread"
 578 AM_LDFLAGS="$AM_LDFLAGS $BOOST_CHRONO_LIB"
 579
 580 AM_LDFLAGS="$AM_LDFLAGS $OPENSSL_LDFLAGS $OPENSSL_LIBS"
 581
 582 AC_SUBST([AM_CPPFLAGS])
 583 AC_SUBST([AM_LDFLAGS])
 584
 585 AM_CONDITIONAL([HAVE_STD_THREAD], [test "$ac_cv_header_features" = "yes"])
 586 AM_CONDITIONAL([HAVE_X86_64], [test "$build_cpu" = "x86_64"])
 587 AM_CONDITIONAL([HAVE_PPC64], [test "$build_cpu" = "powerpc64le"])
 588 AM_CONDITIONAL([RUN_ARCH_SPECIFIC_TESTS], [test "$build_cpu" = "x86_64" || test "$build_cpu" = "powerpc64le"])
 589 AM_CONDITIONAL([HAVE_LINUX], [test "$build_os" == "linux-gnu"])
 590 AM_CONDITIONAL([HAVE_WEAK_SYMBOLS],
 591                [test "$folly_cv_prog_cc_weak_symbols" = "yes"])
 592 AM_CONDITIONAL([HAVE_BITS_FUNCTEXCEPT_H], [test "$ac_cv_header_bits_functexcept_h" = "yes"])
 593 AM_CONDITIONAL([HAVE_EXTRANDOM_SFMT19937],
 594                [test "$folly_cv_prog_cc_have_extrandom_sfmt19937" = "yes"])
 595 AM_CONDITIONAL([FOLLY_TESTMAIN], [test "x${use_follytestmain}" = "xyes"])
 596 AM_CONDITIONAL([HAVE_LIBDWARF], [test "x${have_libdwarf}" = "xyes"])
 597 AM_CONDITIONAL([HAVE_BOOST_CONTEXT], [test "x${ax_cv_boost_context}" = "xyes"])
 598 AM_CONDITIONAL([EXCEPTION_TRACER], [test "x${build_exception_tracer}" = "xyes"])
 599
 600 # remove pkg-config deps from dependent libraries
 601 # (at least for pkg-config file purposes)
 602 FB_FILTER_PKG_LIBS([$AM_LDFLAGS $LIBS])
 603
 604 # Output
 605 AC_CONFIG_FILES([Makefile
 606                  io/test/Makefile
 607                  libfolly.pc
 608                  test/Makefile
 609                  test/function_benchmark/Makefile
 610                  experimental/Makefile
 611                  experimental/io/test/Makefile
 612                  experimental/symbolizer/Makefile
 613                  init/Makefile])
 614
 615 AM_COND_IF([EXCEPTION_TRACER],
 616            [AC_CONFIG_FILES([experimental/exception_tracer/Makefile])])
 617 AC_OUTPUT