CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
   2
   3 # includes
   4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
   5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   6
   7 # package information
   8 set(PACKAGE_NAME      "folly")
   9 set(PACKAGE_VERSION   "0.58.0-dev")
  10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
  13
  14 # 150+ tests in the root folder anyone? No? I didn't think so.
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 project(${PACKAGE_NAME} CXX)
  18
  19 if (MSVC_VERSION EQUAL 1910 OR MSVC_VERSION EQUAL 1911)
  20   set(MSVC_IS_2017 ON)
  21 elseif (MSVC_VERSION EQUAL 1900)
  22   set(MSVC_IS_2017 OFF)
  23 else()
  24   message(FATAL_ERROR "This build script only supports building '${MSVC_VERSION}' Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
  25 endif()
  26
  27 # Check architecture OS
  28 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
  29   message(FATAL_ERROR "Folly requires a 64bit OS")
  30 endif()
  31 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  32   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
  33 endif()
  34
  35 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
  36
  37 # Generate a few tables and create the main config file.
  38 find_package(PythonInterp REQUIRED)
  39 add_custom_command(
  40   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
  41   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
  42   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
  43   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  44   COMMENT "Generating the escape tables..." VERBATIM
  45 )
  46 add_custom_command(
  47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
  48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
  49   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
  50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  51   COMMENT "Generating the format tables..." VERBATIM
  52 )
  53 add_custom_command(
  54   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
  55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
  56   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
  57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  58   COMMENT "Generating the group varint tables..." VERBATIM
  59 )
  60
  61 include(folly-deps) # Find the required packages
  62 if (LIBPTHREAD_FOUND)
  63   set(FOLLY_HAVE_PTHREAD ON)
  64 endif()
  65 configure_file(
  66   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
  67   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
  68 )
  69
  70 include(FollyCompiler)
  71 include(FollyFunctions)
  72
  73 # Main folly library files
  74 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
  75 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
  76
  77 # No need for tests or benchmarks, and we can't build most experimental stuff.
  78 REMOVE_MATCHES_FROM_LISTS(files hfiles
  79   MATCHES
  80     "/build/"
  81     "/experimental/exception_tracer/"
  82     "/experimental/hazptr/bench/"
  83     "/experimental/hazptr/example/"
  84     "/experimental/logging/example/"
  85     "/experimental/symbolizer/"
  86     "/futures/exercises/"
  87     "/test/"
  88     "Benchmark.cpp$"
  89     "Test.cpp$"
  90   IGNORE_MATCHES
  91     "/Benchmark.cpp$"
  92 )
  93 list(REMOVE_ITEM files
  94   ${FOLLY_DIR}/Subprocess.cpp
  95   ${FOLLY_DIR}/SingletonStackTrace.cpp
  96   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
  97   ${FOLLY_DIR}/experimental/RCUUtils.cpp
  98   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
  99   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
 100   ${FOLLY_DIR}/futures/test/Benchmark.cpp
 101 )
 102 list(REMOVE_ITEM hfiles
 103   ${FOLLY_DIR}/Fingerprint.h
 104   ${FOLLY_DIR}/detail/SlowFingerprint.h
 105   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 106   ${FOLLY_DIR}/experimental/RCURefCount.h
 107   ${FOLLY_DIR}/experimental/RCUUtils.h
 108   ${FOLLY_DIR}/experimental/io/AsyncIO.h
 109 )
 110
 111 add_library(folly_base OBJECT
 112   ${files} ${hfiles}
 113   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
 114   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 115   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 116   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 117 )
 118 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
 119 apply_folly_compile_options_to_target(folly_base)
 120 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
 121 # Add the generated files to the correct source group.
 122 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
 123 source_group("folly\\build" FILES
 124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 125   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 126   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 127   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 128 )
 129
 130 set(FOLLY_SHINY_DEPENDENCIES
 131   Boost::chrono
 132   Boost::context
 133   Boost::date_time
 134   Boost::filesystem
 135   Boost::program_options
 136   Boost::regex
 137   Boost::system
 138   OpenSSL::SSL
 139   OpenSSL::Crypto
 140 )
 141
 142 set(FOLLY_LINK_LIBRARIES
 143   ${DOUBLE_CONVERSION_LIBRARY}
 144   ${LIBEVENT_LIB}
 145   ${LIBGFLAGS_LIBRARY}
 146   ${LIBGLOG_LIBRARY}
 147   Iphlpapi.lib
 148   Ws2_32.lib
 149
 150   ${FOLLY_SHINY_DEPENDENCIES}
 151 )
 152
 153 target_include_directories(folly_base
 154   PUBLIC
 155     ${DOUBLE_CONVERSION_INCLUDE_DIR}
 156     ${LIBGFLAGS_INCLUDE_DIR}
 157     ${LIBGLOG_INCLUDE_DIR}
 158     ${LIBEVENT_INCLUDE_DIR}
 159     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
 160 )
 161
 162 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
 163   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
 164 endforeach()
 165
 166 if (FOLLY_HAVE_PTHREAD)
 167   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
 168   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
 169 endif()
 170
 171 # Now to generate the fingerprint tables
 172 add_executable(GenerateFingerprintTables
 173   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
 174   $<TARGET_OBJECTS:folly_base>
 175 )
 176 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
 177 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 178 add_dependencies(GenerateFingerprintTables folly_base)
 179 apply_folly_compile_options_to_target(GenerateFingerprintTables)
 180 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
 181 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
 182
 183 # Compile the fingerprint tables.
 184 add_custom_command(
 185   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 186   COMMAND GenerateFingerprintTables
 187   DEPENDS GenerateFingerprintTables
 188   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
 189   COMMENT "Generating the fingerprint tables..."
 190 )
 191 add_library(folly_fingerprint STATIC
 192   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 193   ${FOLLY_DIR}/Fingerprint.h
 194   ${FOLLY_DIR}/detail/SlowFingerprint.h
 195   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 196   $<TARGET_OBJECTS:folly_base>
 197 )
 198 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
 199 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 200 add_dependencies(folly_fingerprint folly_base)
 201 apply_folly_compile_options_to_target(folly_fingerprint)
 202
 203 # We want to generate a single library and target for folly, but we needed a
 204 # two-stage compile for the fingerprint tables, so we create a phony source
 205 # file that we modify whenever the base libraries change, causing folly to be
 206 # re-linked, making things happy.
 207 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 208   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 209   DEPENDS folly_base folly_fingerprint
 210 )
 211 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
 212 apply_folly_compile_options_to_target(folly)
 213 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
 214
 215 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
 216 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 217
 218 install(TARGETS folly
 219   EXPORT folly
 220   RUNTIME DESTINATION bin
 221   LIBRARY DESTINATION lib
 222   ARCHIVE DESTINATION lib)
 223 auto_install_files(folly ${FOLLY_DIR}
 224   ${hfiles}
 225   ${FOLLY_DIR}/Fingerprint.h
 226   ${FOLLY_DIR}/detail/SlowFingerprint.h
 227   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 228 )
 229 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
 230 install(
 231   EXPORT folly
 232   DESTINATION share/folly
 233   NAMESPACE Folly::
 234   FILE folly-targets.cmake
 235 )
 236
 237 # We need a wrapper config file to do the find_package calls to ensure
 238 # that all our dependencies are available to link against.
 239 file(
 240   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
 241   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
 242 )
 243 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
 244 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
 245
 246 option(BUILD_TESTS "If enabled, compile the tests." OFF)
 247 option(BUILD_BROKEN_TESTS "If enabled, compile tests that are known to be broken." OFF)
 248 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
 249 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
 250 if (BUILD_TESTS)
 251   find_package(GMock MODULE REQUIRED)
 252
 253   add_library(folly_test_support
 254     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
 255     ${FOLLY_DIR}/test/DeterministicSchedule.h
 256     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
 257     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
 258     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
 259     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
 260     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
 261     ${FOLLY_DIR}/futures/test/TestExecutor.h
 262     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
 263     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
 264     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
 265     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
 266     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
 267     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
 268     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
 269     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
 270     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
 271     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
 272     ${FOLLY_DIR}/io/async/test/SocketPair.h
 273     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
 274     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
 275     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
 276     ${FOLLY_DIR}/io/async/test/TimeUtil.h
 277     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
 278     ${FOLLY_DIR}/io/async/test/Util.h
 279   )
 280   target_compile_definitions(folly_test_support
 281     PUBLIC
 282       ${LIBGMOCK_DEFINES}
 283   )
 284   target_include_directories(folly_test_support
 285     PUBLIC
 286       ${LIBGMOCK_INCLUDE_DIR}
 287   )
 288   target_link_libraries(folly_test_support
 289     PUBLIC
 290       Boost::thread
 291       folly
 292       ${LIBGMOCK_LIBRARY}
 293   )
 294   apply_folly_compile_options_to_target(folly_test_support)
 295
 296   folly_define_tests(
 297     DIRECTORY compression/test/
 298       TEST compression_test SOURCES CompressionTest.cpp
 299
 300     DIRECTORY concurrency/test/
 301       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
 302
 303     DIRECTORY executors/test/
 304       TEST async_helpers_test SOURCES AsyncTest.cpp
 305       TEST codel_test SOURCES CodelTest.cpp
 306       TEST executor_test SOURCES ExecutorTest.cpp
 307       TEST fiber_io_executor_test SOURCES FiberIOExecutorTest.cpp
 308       TEST global_executor_test SOURCES GlobalExecutorTest.cpp
 309       TEST serial_executor_test SOURCES SerialExecutorTest.cpp
 310       TEST thread_pool_executor_test SOURCES ThreadPoolExecutorTest.cpp
 311       TEST threaded_executor_test SOURCES ThreadedExecutorTest.cpp
 312       TEST unbounded_blocking_queue_test SOURCES UnboundedBlockingQueueTest.cpp
 313
 314     DIRECTORY container/test/
 315       TEST enumerate_test SOURCES EnumerateTest.cpp
 316       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
 317       TEST foreach_test SOURCES ForeachTest.cpp
 318       TEST merge_test SOURCES MergeTest.cpp
 319       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
 320
 321     DIRECTORY experimental/test/
 322       TEST autotimer_test SOURCES AutoTimerTest.cpp
 323       TEST bits_test_2 SOURCES BitsTest.cpp
 324       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
 325       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
 326       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
 327       TEST event_count_test SOURCES EventCountTest.cpp
 328       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
 329       TEST future_dag_test SOURCES FutureDAGTest.cpp
 330       TEST json_schema_test SOURCES JSONSchemaTest.cpp
 331       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
 332       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
 333       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
 334       # Depends on liburcu
 335       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
 336       #TEST ref_count_test SOURCES RefCountTest.cpp
 337       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
 338       TEST test_util_test SOURCES TestUtilTest.cpp
 339       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
 340
 341     DIRECTORY experimental/io/test/
 342       # Depends on libaio
 343       #TEST async_io_test SOURCES AsyncIOTest.cpp
 344       TEST fs_util_test SOURCES FsUtilTest.cpp
 345
 346     DIRECTORY experimental/logging/test/
 347       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
 348       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
 349       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
 350       TEST log_category_test SOURCES LogCategoryTest.cpp
 351       TEST logger_db_test SOURCES LoggerDBTest.cpp
 352       TEST logger_test SOURCES LoggerTest.cpp
 353       TEST log_level_test SOURCES LogLevelTest.cpp
 354       TEST log_message_test SOURCES LogMessageTest.cpp
 355       TEST log_name_test SOURCES LogNameTest.cpp
 356       TEST log_stream_test SOURCES LogStreamTest.cpp
 357       TEST printf_test SOURCES PrintfTest.cpp
 358       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
 359       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
 360       TEST xlog_test
 361         HEADERS
 362           XlogHeader1.h
 363           XlogHeader2.h
 364         SOURCES
 365           XlogFile1.cpp
 366           XlogFile2.cpp
 367           XlogTest.cpp
 368
 369     DIRECTORY fibers/test/
 370       TEST fibers_test SOURCES FibersTest.cpp
 371
 372     DIRECTORY functional/test/
 373       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
 374
 375     DIRECTORY futures/test/
 376       TEST barrier_test SOURCES BarrierTest.cpp
 377       TEST callback_lifetime_test SOURCES CallbackLifetimeTest.cpp
 378       TEST collect_test SOURCES CollectTest.cpp
 379       TEST context_test SOURCES ContextTest.cpp
 380       TEST core_test SOURCES CoreTest.cpp
 381       TEST ensure_test SOURCES EnsureTest.cpp
 382       TEST fsm_test SOURCES FSMTest.cpp
 383       TEST filter_test SOURCES FilterTest.cpp
 384       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
 385       # MSVC SFINAE bug
 386       #TEST future_test SOURCES FutureTest.cpp
 387       TEST header_compile_test SOURCES HeaderCompileTest.cpp
 388       TEST interrupt_test SOURCES InterruptTest.cpp
 389       TEST map_test SOURCES MapTest.cpp
 390       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
 391       TEST poll_test SOURCES PollTest.cpp
 392       TEST promise_test SOURCES PromiseTest.cpp
 393       TEST reduce_test SOURCES ReduceTest.cpp
 394       # MSVC SFINAE bug
 395       #TEST retrying_test SOURCES RetryingTest.cpp
 396       TEST self_destruct_test SOURCES SelfDestructTest.cpp
 397       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
 398       TEST test_executor_test SOURCES TestExecutorTest.cpp
 399       TEST then_compile_test
 400         HEADERS
 401           ThenCompileTest.h
 402         SOURCES
 403           ThenCompileTest.cpp
 404       TEST then_test SOURCES ThenTest.cpp
 405       TEST timekeeper_test SOURCES TimekeeperTest.cpp
 406       TEST times_test SOURCES TimesTest.cpp
 407       TEST unwrap_test SOURCES UnwrapTest.cpp
 408       TEST via_test SOURCES ViaTest.cpp
 409       TEST wait_test SOURCES WaitTest.cpp
 410       TEST when_test SOURCES WhenTest.cpp
 411       TEST while_do_test SOURCES WhileDoTest.cpp
 412       TEST will_equal_test SOURCES WillEqualTest.cpp
 413       TEST window_test SOURCES WindowTest.cpp
 414
 415     DIRECTORY gen/test/
 416       # MSVC bug can't resolve initializer_list constructor properly
 417       #TEST base_test SOURCES BaseTest.cpp
 418       TEST combine_test SOURCES CombineTest.cpp
 419       TEST parallel_map_test SOURCES ParallelMapTest.cpp
 420       TEST parallel_test SOURCES ParallelTest.cpp
 421
 422     DIRECTORY hash/test/
 423       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
 424       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
 425
 426     DIRECTORY io/test/
 427       TEST iobuf_test SOURCES IOBufTest.cpp
 428       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
 429       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
 430       TEST record_io_test SOURCES RecordIOTest.cpp
 431       TEST ShutdownSocketSetTest HANGING
 432         SOURCES ShutdownSocketSetTest.cpp
 433
 434     DIRECTORY io/async/test/
 435       TEST async_test
 436         CONTENT_DIR certs/
 437         HEADERS
 438           AsyncSocketTest.h
 439           AsyncSSLSocketTest.h
 440         SOURCES
 441           AsyncPipeTest.cpp
 442           AsyncSocketExceptionTest.cpp
 443           AsyncSocketTest.cpp
 444           AsyncSocketTest2.cpp
 445           AsyncSSLSocketTest.cpp
 446           AsyncSSLSocketTest2.cpp
 447           AsyncSSLSocketWriteTest.cpp
 448           AsyncTransportTest.cpp
 449           # This is disabled because it depends on things that don't exist
 450           # on Windows.
 451           #EventHandlerTest.cpp
 452           # The async signal handler is not supported on Windows.
 453           #AsyncSignalHandlerTest.cpp
 454       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
 455       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
 456       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
 457       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
 458       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
 459       TEST EventBaseTest SOURCES EventBaseTest.cpp
 460       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
 461       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
 462       TEST HHWheelTimerSlowTests SLOW
 463         SOURCES HHWheelTimerSlowTests.cpp
 464       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
 465       TEST RequestContextTest SOURCES RequestContextTest.cpp
 466       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
 467       TEST ssl_session_test SOURCES SSLSessionTest.cpp
 468       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
 469
 470     DIRECTORY io/async/ssl/test/
 471       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
 472
 473     DIRECTORY memory/test/
 474       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
 475       TEST arena_test SOURCES ArenaTest.cpp
 476
 477     DIRECTORY portability/test/
 478       TEST constexpr_test SOURCES ConstexprTest.cpp
 479       TEST libgen-test SOURCES LibgenTest.cpp
 480       TEST time-test SOURCES TimeTest.cpp
 481       TEST openssl_portability_test SOURCES OpenSSLPortabilityTest.cpp
 482
 483     DIRECTORY ssl/test/
 484       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
 485
 486     DIRECTORY stats/test/
 487       TEST histogram_test SOURCES HistogramTest.cpp
 488       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
 489       TEST timeseries_test SOURCES TimeseriesTest.cpp
 490
 491     DIRECTORY synchronization/test/
 492       TEST call_once_test SOURCES CallOnceTest.cpp
 493
 494     DIRECTORY system/test/
 495       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
 496       TEST shell_test SOURCES ShellTest.cpp
 497       #TEST subprocess_test SOURCES SubprocessTest.cpp
 498       TEST thread_id_test SOURCES ThreadIdTest.cpp
 499       TEST thread_name_test SOURCES ThreadNameTest.cpp
 500
 501     DIRECTORY test/
 502       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
 503       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
 504       TEST array_test SOURCES ArrayTest.cpp
 505       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
 506       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
 507       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
 508       TEST atomic_hash_map_test HANGING
 509         SOURCES AtomicHashMapTest.cpp
 510       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
 511       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
 512       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
 513       TEST baton_test SOURCES BatonTest.cpp
 514       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
 515       TEST bits_test SOURCES BitsTest.cpp
 516       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
 517       TEST checksum_test SOURCES ChecksumTest.cpp
 518       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
 519       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
 520       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
 521       TEST conv_test SOURCES ConvTest.cpp
 522       TEST cpu_id_test SOURCES CpuIdTest.cpp
 523       TEST demangle_test SOURCES DemangleTest.cpp
 524       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
 525       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
 526       TEST dynamic_test SOURCES DynamicTest.cpp
 527       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
 528       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
 529       TEST endian_test SOURCES EndianTest.cpp
 530       TEST exception_test SOURCES ExceptionTest.cpp
 531       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
 532       TEST expected_test SOURCES ExpectedTest.cpp
 533       TEST fbvector_test SOURCES FBVectorTest.cpp
 534       TEST file_test SOURCES FileTest.cpp
 535       #TEST file_lock_test SOURCES FileLockTest.cpp
 536       TEST file_util_test HANGING
 537         SOURCES FileUtilTest.cpp
 538       TEST fingerprint_test SOURCES FingerprintTest.cpp
 539       TEST format_other_test SOURCES FormatOtherTest.cpp
 540       TEST format_test SOURCES FormatTest.cpp
 541       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
 542       TEST function_test BROKEN
 543         SOURCES FunctionTest.cpp
 544       TEST function_ref_test SOURCES FunctionRefTest.cpp
 545       TEST futex_test SOURCES FutexTest.cpp
 546       TEST group_varint_test SOURCES GroupVarintTest.cpp
 547       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
 548       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
 549       TEST hash_test SOURCES HashTest.cpp
 550       TEST indestructible_test SOURCES IndestructibleTest.cpp
 551       TEST indexed_mem_pool_test BROKEN
 552         SOURCES IndexedMemPoolTest.cpp
 553       # MSVC Preprocessor stringizing raw string literals bug
 554       #TEST json_test SOURCES JsonTest.cpp
 555       TEST json_other_test
 556         CONTENT_DIR json_test_data/
 557         SOURCES
 558           JsonOtherTest.cpp
 559       TEST lazy_test SOURCES LazyTest.cpp
 560       TEST lifosem_test SOURCES LifoSemTests.cpp
 561       TEST lock_traits_test SOURCES LockTraitsTest.cpp
 562       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
 563       TEST logging_test SOURCES LoggingTest.cpp
 564       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
 565       TEST math_test SOURCES MathTest.cpp
 566       TEST map_util_test SOURCES MapUtilTest.cpp
 567       TEST memcpy_test SOURCES MemcpyTest.cpp
 568       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
 569       TEST memory_test SOURCES MemoryTest.cpp
 570       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
 571       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
 572       TEST mpmc_queue_test SLOW
 573         SOURCES MPMCQueueTest.cpp
 574       TEST network_address_test HANGING
 575         SOURCES
 576           IPAddressTest.cpp
 577           MacAddressTest.cpp
 578           SocketAddressTest.cpp
 579       TEST optional_test SOURCES OptionalTest.cpp
 580       TEST packed_sync_ptr_test HANGING
 581         SOURCES PackedSyncPtrTest.cpp
 582       TEST padded_test SOURCES PaddedTest.cpp
 583       TEST partial_test SOURCES PartialTest.cpp
 584       TEST portability_test SOURCES PortabilityTest.cpp
 585       TEST producer_consumer_queue_test SLOW
 586         SOURCES ProducerConsumerQueueTest.cpp
 587       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
 588       TEST random_test SOURCES RandomTest.cpp
 589       TEST range_test SOURCES RangeTest.cpp
 590       TEST safe_assert_test SOURCES SafeAssertTest.cpp
 591       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
 592       # Heavily dependent on drand and srand48
 593       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
 594       TEST singleton_test SOURCES SingletonTest.cpp
 595       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
 596       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
 597       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
 598       TEST small_vector_test SOURCES small_vector_test.cpp
 599       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
 600       TEST string_test SOURCES StringTest.cpp
 601       TEST synchronized_test SOURCES SynchronizedTest.cpp
 602       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
 603       TEST thread_local_test SOURCES ThreadLocalTest.cpp
 604       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
 605       TEST token_bucket_test SOURCES TokenBucketTest.cpp
 606       TEST traits_test SOURCES TraitsTest.cpp
 607       TEST try_test SOURCES TryTest.cpp
 608       TEST unit_test SOURCES UnitTest.cpp
 609       TEST uri_test SOURCES UriTest.cpp
 610       TEST varint_test SOURCES VarintTest.cpp
 611   )
 612 endif()