Fix reliance on the sign of char in fnv32 and fnv64
[folly.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
2
3 # Unfortunately, CMake doesn't easily provide us a way to merge static
4 # libraries, which is what we want to do to generate the main folly library, so
5 # we do a bit of a workaround here to inject a property into the generated
6 # project files that will only get enabled for the folly target. Ugly, but
7 # the alternatives are far, far worse.
8 if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio 15( 2017)? Win64")
9   set(CMAKE_GENERATOR_TOOLSET "v141</PlatformToolset></PropertyGroup><ItemDefinitionGroup Condition=\"'$(ProjectName)'=='folly'\"><ProjectReference><LinkLibraryDependencies>true</LinkLibraryDependencies></ProjectReference></ItemDefinitionGroup><PropertyGroup><PlatformToolset>v141")
10   set(MSVC_IS_2017 ON)
11 elseif ("${CMAKE_GENERATOR}" STREQUAL "Visual Studio 14 2015 Win64")
12   set(CMAKE_GENERATOR_TOOLSET "v140</PlatformToolset></PropertyGroup><ItemDefinitionGroup Condition=\"'$(ProjectName)'=='folly'\"><ProjectReference><LinkLibraryDependencies>true</LinkLibraryDependencies></ProjectReference></ItemDefinitionGroup><PropertyGroup><PlatformToolset>v140")
13   set(MSVC_IS_2017 OFF)
14 else()
15   message(FATAL_ERROR "This build script only supports building Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
16 endif()
17
18 # includes
19 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
20 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
21
22 # package information
23 set(PACKAGE_NAME      "folly")
24 set(PACKAGE_VERSION   "0.58.0-dev")
25 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
26 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
27 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
28
29 # 150+ tests in the root folder anyone? No? I didn't think so.
30 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
31
32 project(${PACKAGE_NAME} CXX)
33
34 # Check architecture OS
35 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
36   message(FATAL_ERROR "Folly requires a 64bit OS")
37 endif()
38 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
39   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
40 endif()
41
42 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
43
44 # Generate a few tables and create the main config file.
45 find_package(PythonInterp REQUIRED)
46 add_custom_command(
47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
49   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
51   COMMENT "Generating the escape tables..." VERBATIM
52 )
53 add_custom_command(
54   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
56   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
58   COMMENT "Generating the format tables..." VERBATIM
59 )
60 add_custom_command(
61   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
62   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
63   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
64   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
65   COMMENT "Generating the group varint tables..." VERBATIM
66 )
67
68 include(folly-deps) # Find the required packages
69 if (LIBPTHREAD_FOUND)
70   set(FOLLY_HAVE_PTHREAD ON)
71 endif()
72 configure_file(
73   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
74   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
75 )
76
77 include(FollyCompiler)
78 include(FollyFunctions)
79
80 # Main folly library files
81 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
82 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
83
84 # No need for tests or benchmarks, and we can't build most experimental stuff.
85 REMOVE_MATCHES_FROM_LISTS(files hfiles
86   MATCHES
87     "/build/"
88     "/experimental/exception_tracer/"
89     "/experimental/hazptr/example/"
90     "/experimental/symbolizer/"
91     "/futures/exercises/"
92     "/test/"
93     "Benchmark.cpp$"
94     "Test.cpp$"
95   IGNORE_MATCHES
96     "/Benchmark.cpp$"
97 )
98 list(REMOVE_ITEM files
99   ${FOLLY_DIR}/Subprocess.cpp
100   ${FOLLY_DIR}/SingletonStackTrace.cpp
101   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
102   ${FOLLY_DIR}/experimental/RCUUtils.cpp
103   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
104   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
105   ${FOLLY_DIR}/futures/test/Benchmark.cpp
106 )
107 list(REMOVE_ITEM hfiles
108   ${FOLLY_DIR}/Fingerprint.h
109   ${FOLLY_DIR}/detail/SlowFingerprint.h
110   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
111   ${FOLLY_DIR}/experimental/RCURefCount.h
112   ${FOLLY_DIR}/experimental/RCUUtils.h
113   ${FOLLY_DIR}/experimental/io/AsyncIO.h
114 )
115
116 add_library(folly_base STATIC
117   ${files} ${hfiles}
118   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
119   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
120   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
121   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
122 )
123 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
124 apply_folly_compile_options_to_target(folly_base)
125 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
126 # Add the generated files to the correct source group.
127 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
128 source_group("folly\\build" FILES
129   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
130   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
131   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
132   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
133 )
134
135 target_include_directories(folly_base
136   PUBLIC
137     ${DOUBLE_CONVERSION_INCLUDE_DIR}
138     ${LIBGFLAGS_INCLUDE_DIR}
139     ${LIBGLOG_INCLUDE_DIR}
140     ${LIBEVENT_INCLUDE_DIR}
141 )
142 target_link_libraries(folly_base
143   PUBLIC
144     Boost::chrono
145     Boost::context
146     Boost::date_time
147     Boost::filesystem
148     Boost::program_options
149     Boost::regex
150     Boost::system
151     ${DOUBLE_CONVERSION_LIBRARY}
152     ${LIBEVENT_LIB}
153     ${LIBGFLAGS_LIBRARY}
154     ${LIBGLOG_LIBRARY}
155     OpenSSL::SSL
156     OpenSSL::Crypto
157     Ws2_32.lib
158 )
159 if (FOLLY_HAVE_PTHREAD)
160   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
161   target_link_libraries(folly_base PUBLIC ${LIBPTHREAD_LIBRARIES})
162 endif()
163
164 # Now to generate the fingerprint tables
165 add_executable(GenerateFingerprintTables
166   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
167 )
168 apply_folly_compile_options_to_target(GenerateFingerprintTables)
169 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
170 target_link_libraries(GenerateFingerprintTables PRIVATE folly_base)
171 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
172
173 # Compile the fingerprint tables.
174 add_custom_command(
175   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
176   COMMAND GenerateFingerprintTables
177   DEPENDS GenerateFingerprintTables
178   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
179   COMMENT "Generating the fingerprint tables..."
180 )
181 add_library(folly_fingerprint STATIC
182   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
183   ${FOLLY_DIR}/Fingerprint.h
184   ${FOLLY_DIR}/detail/SlowFingerprint.h
185   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
186 )
187 apply_folly_compile_options_to_target(folly_fingerprint)
188 target_link_libraries(folly_fingerprint PRIVATE folly_base)
189
190 # We want to generate a single library and target for folly, but we needed a
191 # two-stage compile for the fingerprint tables, so we create a phony source
192 # file that we modify whenever the base libraries change, causing folly to be
193 # re-linked, making things happy.
194 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
195   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
196   DEPENDS folly_base folly_fingerprint
197 )
198 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
199 apply_folly_compile_options_to_target(folly)
200 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
201
202 # Rather than list the dependencies in two places, we apply them directly on
203 # the folly_base target and then copy them over to the folly target.
204 get_target_property(FOLLY_LINK_LIBRARIES folly_base INTERFACE_LINK_LIBRARIES)
205 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
206 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
207
208 install(TARGETS folly
209   EXPORT folly
210   RUNTIME DESTINATION bin
211   LIBRARY DESTINATION lib
212   ARCHIVE DESTINATION lib)
213 auto_install_files(folly ${FOLLY_DIR}
214   ${hfiles}
215   ${FOLLY_DIR}/Fingerprint.h
216   ${FOLLY_DIR}/detail/SlowFingerprint.h
217   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
218 )
219 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
220 install(
221   EXPORT folly
222   DESTINATION share/folly
223   NAMESPACE Folly::
224   FILE folly-targets.cmake
225 )
226
227 # We need a wrapper config file to do the find_package calls to ensure
228 # that all our dependencies are available to link against.
229 file(
230   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
231   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
232 )
233 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
234 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
235
236 option(BUILD_TESTS "If enabled, compile the tests." OFF)
237 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
238 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
239 if (BUILD_TESTS)
240   find_package(GMock MODULE REQUIRED)
241
242   add_library(folly_test_support
243     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
244     ${FOLLY_DIR}/test/DeterministicSchedule.h
245     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
246     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
247     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
248     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
249     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
250     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
251     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
252     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
253     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
254     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
255     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
256     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
257     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
258     ${FOLLY_DIR}/io/async/test/SocketPair.h
259     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
260     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
261     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
262     ${FOLLY_DIR}/io/async/test/TimeUtil.h
263     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
264     ${FOLLY_DIR}/io/async/test/Util.h
265   )
266   target_compile_definitions(folly_test_support
267     PUBLIC
268       ${LIBGMOCK_DEFINES}
269   )
270   target_include_directories(folly_test_support
271     PUBLIC
272       ${LIBGMOCK_INCLUDE_DIR}
273   )
274   target_link_libraries(folly_test_support
275     PUBLIC
276       Boost::thread
277       folly
278       ${LIBGMOCK_LIBRARY}
279   )
280   apply_folly_compile_options_to_target(folly_test_support)
281
282   folly_define_tests(
283     DIRECTORY experimental/test/
284       TEST autotimer_test SOURCES AutoTimerTest.cpp
285       TEST bits_test_2 SOURCES BitsTest.cpp
286       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
287       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
288       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
289       TEST event_count_test SOURCES EventCountTest.cpp
290       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
291       TEST future_dag_test SOURCES FutureDAGTest.cpp
292       TEST json_schema_test SOURCES JSONSchemaTest.cpp
293       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
294       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
295       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
296       # Depends on liburcu
297       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
298       #TEST ref_count_test SOURCES RefCountTest.cpp
299       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
300       TEST test_util_test SOURCES TestUtilTest.cpp
301       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
302
303     DIRECTORY experimental/io/test/
304       # Depends on libaio
305       #TEST async_io_test SOURCES AsyncIOTest.cpp
306       TEST fs_util_test SOURCES FsUtilTest.cpp
307
308     DIRECTORY fibers/test/
309       TEST fibers_test SOURCES FibersTest.cpp
310
311     DIRECTORY futures/test/
312       TEST futures-test
313         HEADERS
314           ThenCompileTest.h
315         SOURCES
316           BarrierTest.cpp
317           CollectTest.cpp
318           ContextTest.cpp
319           CoreTest.cpp
320           EnsureTest.cpp
321           ExecutorTest.cpp
322           FSMTest.cpp
323           FilterTest.cpp
324           # MSVC SFINAE bug
325           #FutureTest.cpp
326           HeaderCompileTest.cpp
327           InterruptTest.cpp
328           MapTest.cpp
329           NonCopyableLambdaTest.cpp
330           PollTest.cpp
331           PromiseTest.cpp
332           ReduceTest.cpp
333           # MSVC SFINAE bug
334           #RetryingTest.cpp
335           SelfDestructTest.cpp
336           SharedPromiseTest.cpp
337           ThenCompileTest.cpp
338           ThenTest.cpp
339           TimekeeperTest.cpp
340           TimesTest.cpp
341           UnwrapTest.cpp
342           ViaTest.cpp
343           WaitTest.cpp
344           WhenTest.cpp
345           WhileDoTest.cpp
346           WillEqualTest.cpp
347           WindowTest.cpp
348
349     DIRECTORY gen/test/
350       # MSVC bug can't resolve initializer_list constructor properly
351       #TEST base_test SOURCES BaseTest.cpp
352       TEST combine_test SOURCES CombineTest.cpp
353       TEST parallel_map_test SOURCES ParallelMapTest.cpp
354       TEST parallel_test SOURCES ParallelTest.cpp
355
356     DIRECTORY io/test/
357       TEST compression_test SOURCES CompressionTest.cpp
358       TEST iobuf_test SOURCES IOBufTest.cpp
359       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
360       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
361       TEST record_io_test SOURCES RecordIOTest.cpp
362       TEST ShutdownSocketSetTest HANGING
363         SOURCES ShutdownSocketSetTest.cpp
364
365     DIRECTORY io/async/test/
366       TEST async_test
367         CONTENT_DIR certs/
368         HEADERS
369           AsyncSocketTest.h
370           AsyncSSLSocketTest.h
371         SOURCES
372           AsyncPipeTest.cpp
373           AsyncSocketExceptionTest.cpp
374           AsyncSocketTest.cpp
375           AsyncSocketTest2.cpp
376           AsyncSSLSocketTest.cpp
377           AsyncSSLSocketTest2.cpp
378           AsyncSSLSocketWriteTest.cpp
379           AsyncTransportTest.cpp
380           # This is disabled because it depends on things that don't exist
381           # on Windows.
382           #EventHandlerTest.cpp
383       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
384       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
385       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
386       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
387       TEST EventBaseTest SOURCES EventBaseTest.cpp
388       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
389       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
390       TEST HHWheelTimerSlowTests SLOW
391         SOURCES HHWheelTimerSlowTests.cpp
392       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
393       TEST RequestContextTest SOURCES RequestContextTest.cpp
394       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
395       TEST ssl_session_test SOURCES SSLSessionTest.cpp
396       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
397
398     DIRECTORY io/async/ssl/test/
399       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
400
401     DIRECTORY portability/test/
402       TEST constexpr_test SOURCES ConstexprTest.cpp
403       TEST libgen-test SOURCES LibgenTest.cpp
404       TEST time-test SOURCES TimeTest.cpp
405
406     DIRECTORY ssl/test/
407       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
408
409     DIRECTORY test/
410       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
411       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
412       TEST arena_test SOURCES ArenaTest.cpp
413       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
414       TEST array_test SOURCES ArrayTest.cpp
415       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
416       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
417       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
418       TEST atomic_hash_map_test HANGING
419         SOURCES AtomicHashMapTest.cpp
420       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
421       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
422       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
423       TEST baton_test SOURCES BatonTest.cpp
424       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
425       TEST bits_test SOURCES BitsTest.cpp
426       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
427       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
428       TEST call_once_test SOURCES CallOnceTest.cpp
429       TEST checksum_test SOURCES ChecksumTest.cpp
430       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
431       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
432       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
433       TEST conv_test SOURCES ConvTest.cpp
434       TEST cpu_id_test SOURCES CpuIdTest.cpp
435       TEST demangle_test SOURCES DemangleTest.cpp
436       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
437       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
438       TEST dynamic_test SOURCES DynamicTest.cpp
439       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
440       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
441       TEST endian_test SOURCES EndianTest.cpp
442       TEST enumerate_test SOURCES EnumerateTest.cpp
443       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
444       TEST exception_test SOURCES ExceptionTest.cpp
445       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
446       TEST expected_test SOURCES ExpectedTest.cpp
447       TEST fbvector_test SOURCES FBVectorTest.cpp
448       TEST file_test SOURCES FileTest.cpp
449       #TEST file_lock_test SOURCES FileLockTest.cpp
450       TEST file_util_test HANGING
451         SOURCES FileUtilTest.cpp
452       TEST fingerprint_test SOURCES FingerprintTest.cpp
453       TEST foreach_test SOURCES ForeachTest.cpp
454       TEST format_other_test SOURCES FormatOtherTest.cpp
455       TEST format_test SOURCES FormatTest.cpp
456       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
457       TEST function_test SOURCES FunctionTest.cpp
458       TEST function_ref_test SOURCES FunctionRefTest.cpp
459       TEST futex_test SOURCES FutexTest.cpp
460       TEST group_varint_test SOURCES GroupVarintTest.cpp
461       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
462       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
463       TEST hash_test SOURCES HashTest.cpp
464       TEST histogram_test SOURCES HistogramTest.cpp
465       TEST indestructible_test SOURCES IndestructibleTest.cpp
466       TEST indexed_mem_pool_test SOURCES IndexedMemPoolTest.cpp
467       # MSVC Preprocessor stringizing raw string literals bug
468       #TEST json_test SOURCES JsonTest.cpp
469       TEST json_other_test
470         CONTENT_DIR json_test_data/
471         SOURCES
472           JsonOtherTest.cpp
473       TEST lazy_test SOURCES LazyTest.cpp
474       TEST lifosem_test SOURCES LifoSemTests.cpp
475       TEST lock_traits_test SOURCES LockTraitsTest.cpp
476       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
477       TEST logging_test SOURCES LoggingTest.cpp
478       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
479       TEST math_test SOURCES MathTest.cpp
480       TEST map_util_test SOURCES MapUtilTest.cpp
481       TEST memcpy_test SOURCES MemcpyTest.cpp
482       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
483       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
484       TEST memory_test SOURCES MemoryTest.cpp
485       TEST merge SOURCES MergeTest.cpp
486       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
487       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
488       TEST mpmc_queue_test SLOW
489         SOURCES MPMCQueueTest.cpp
490       TEST network_address_test HANGING
491         SOURCES
492           IPAddressTest.cpp
493           MacAddressTest.cpp
494           SocketAddressTest.cpp
495       TEST optional_test SOURCES OptionalTest.cpp
496       TEST packed_sync_ptr_test HANGING
497         SOURCES PackedSyncPtrTest.cpp
498       TEST padded_test SOURCES PaddedTest.cpp
499       TEST partial_test SOURCES PartialTest.cpp
500       TEST portability_test SOURCES PortabilityTest.cpp
501       TEST producer_consumer_queue_test SLOW
502         SOURCES ProducerConsumerQueueTest.cpp
503       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
504       TEST random_test SOURCES RandomTest.cpp
505       TEST range_test SOURCES RangeTest.cpp
506       TEST safe_assert_test SOURCES SafeAssertTest.cpp
507       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
508       # Heavily dependent on drand and srand48
509       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
510       TEST shell_test SOURCES ShellTest.cpp
511       TEST singleton_test SOURCES SingletonTest.cpp
512       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
513       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
514       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
515       TEST small_vector_test SOURCES small_vector_test.cpp
516       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
517       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
518       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
519       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
520       TEST string_test SOURCES StringTest.cpp
521       #TEST subprocess_test SOURCES SubprocessTest.cpp
522       TEST synchronized_test SOURCES SynchronizedTest.cpp
523       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
524       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
525       TEST thread_local_test SOURCES ThreadLocalTest.cpp
526       TEST thread_name_test SOURCES ThreadNameTest.cpp
527       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
528       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
529       TEST timeseries_test SOURCES TimeseriesTest.cpp
530       TEST token_bucket_test SOURCES TokenBucketTest.cpp
531       TEST traits_test SOURCES TraitsTest.cpp
532       TEST try_test SOURCES TryTest.cpp
533       TEST unit_test SOURCES UnitTest.cpp
534       TEST uri_test SOURCES UriTest.cpp
535       TEST varint_test SOURCES VarintTest.cpp
536   )
537 endif()