a5dcf63c2242f57572d67d4f6395d10dfac27f0d
[folly.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
2
3 # includes
4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
6
7 # package information
8 set(PACKAGE_NAME      "folly")
9 set(PACKAGE_VERSION   "0.58.0-dev")
10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
13
14 # 150+ tests in the root folder anyone? No? I didn't think so.
15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
16
17 project(${PACKAGE_NAME} CXX)
18
19 # Check target architecture
20 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
21   message(FATAL_ERROR "Folly requires a 64bit target architecture.")
22 endif()
23
24 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
25   if (MSVC_VERSION GREATER_EQUAL 1910 AND MSVC_VERSION LESS 1920)
26     set(MSVC_IS_2017 ON)
27   elseif (MSVC_VERSION EQUAL 1900)
28     set(MSVC_IS_2017 OFF)
29   else()
30     message(
31       FATAL_ERROR
32       "This build script only supports building Folly on 64-bit Windows with "
33       "Visual Studio 2015 or Visual Studio 2017. "
34       "MSVC version '${MSVC_VERSION}' is not supported."
35     )
36   endif()
37 else()
38   message(
39     FATAL_ERROR
40     "The CMake build should only be used on Windows. "
41     "For every other platform, use autoconf."
42   )
43 endif()
44
45 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
46
47 # Generate a few tables and create the main config file.
48 find_package(PythonInterp REQUIRED)
49 add_custom_command(
50   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
51   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
52   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
53   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
54   COMMENT "Generating the escape tables..." VERBATIM
55 )
56 add_custom_command(
57   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
58   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
59   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
60   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
61   COMMENT "Generating the format tables..." VERBATIM
62 )
63 add_custom_command(
64   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
65   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
66   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
67   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
68   COMMENT "Generating the group varint tables..." VERBATIM
69 )
70
71 include(folly-deps) # Find the required packages
72 if (LIBPTHREAD_FOUND)
73   set(FOLLY_HAVE_PTHREAD ON)
74 endif()
75 configure_file(
76   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
77   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
78 )
79
80 include(FollyCompiler)
81 include(FollyFunctions)
82
83 # Main folly library files
84 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
85 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
86
87 # No need for tests or benchmarks, and we can't build most experimental stuff.
88 REMOVE_MATCHES_FROM_LISTS(files hfiles
89   MATCHES
90     "/build/"
91     "/experimental/exception_tracer/"
92     "/experimental/hazptr/bench/"
93     "/experimental/hazptr/example/"
94     "/experimental/logging/example/"
95     "/experimental/symbolizer/"
96     "/futures/exercises/"
97     "/test/"
98     "/tools/"
99     "Benchmark.cpp$"
100     "Test.cpp$"
101   IGNORE_MATCHES
102     "/Benchmark.cpp$"
103 )
104 list(REMOVE_ITEM files
105   ${FOLLY_DIR}/Poly.cpp
106   ${FOLLY_DIR}/Subprocess.cpp
107   ${FOLLY_DIR}/SingletonStackTrace.cpp
108   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
109   ${FOLLY_DIR}/experimental/RCUUtils.cpp
110   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
111   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
112   ${FOLLY_DIR}/futures/test/Benchmark.cpp
113 )
114 list(REMOVE_ITEM hfiles
115   ${FOLLY_DIR}/Fingerprint.h
116   ${FOLLY_DIR}/Poly.h
117   ${FOLLY_DIR}/Poly-inl.h
118   ${FOLLY_DIR}/detail/PolyDetail.h
119   ${FOLLY_DIR}/detail/TypeList.h
120   ${FOLLY_DIR}/detail/SlowFingerprint.h
121   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
122   ${FOLLY_DIR}/experimental/RCURefCount.h
123   ${FOLLY_DIR}/experimental/RCUUtils.h
124   ${FOLLY_DIR}/experimental/io/AsyncIO.h
125   ${FOLLY_DIR}/poly/Nullable.h
126   ${FOLLY_DIR}/poly/Regular.h
127 )
128
129 add_library(folly_base OBJECT
130   ${files} ${hfiles}
131   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
132   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
133   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
134   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
135 )
136 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
137 apply_folly_compile_options_to_target(folly_base)
138 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
139 # Add the generated files to the correct source group.
140 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
141 source_group("folly\\build" FILES
142   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
143   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
144   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
145   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
146 )
147
148 set(FOLLY_SHINY_DEPENDENCIES
149   Boost::chrono
150   Boost::context
151   Boost::date_time
152   Boost::filesystem
153   Boost::program_options
154   Boost::regex
155   Boost::system
156   OpenSSL::SSL
157   OpenSSL::Crypto
158 )
159
160 set(FOLLY_LINK_LIBRARIES
161   ${DOUBLE_CONVERSION_LIBRARY}
162 )
163
164 set(FOLLY_INCLUDE_DIRECTORIES
165   ${DOUBLE_CONVERSION_INCLUDE_DIR}
166 )
167
168 if(TARGET gflags)
169   set(FOLLY_SHINY_DEPENDENCIES ${FOLLY_SHINY_DEPENDENCIES} gflags)
170 else()
171   set(FOLLY_LINK_LIBRARIES ${FOLLY_LINK_LIBRARIES} ${LIBGFLAGS_LIBRARY})
172   set(FOLLY_INCLUDE_DIRECTORIES ${FOLLY_INCLUDE_DIRECTORIES} ${LIBGFLAGS_INCLUDE_DIR})
173 endif()
174
175 if(TARGET glog::glog)
176   set(FOLLY_SHINY_DEPENDENCIES ${FOLLY_SHINY_DEPENDENCIES} glog::glog)
177 else()
178   set(FOLLY_LINK_LIBRARIES ${FOLLY_LINK_LIBRARIES} ${LIBGLOG_LIBRARY})
179   set(FOLLY_INCLUDE_DIRECTORIES ${FOLLY_INCLUDE_DIRECTORIES} ${LIBGLOG_INCLUDE_DIR})
180 endif()
181
182 if(TARGET event)
183   set(FOLLY_SHINY_DEPENDENCIES ${FOLLY_SHINY_DEPENDENCIES} event)
184 else()
185   set(FOLLY_LINK_LIBRARIES ${FOLLY_LINK_LIBRARIES} ${LIBEVENT_LIB})
186   set(FOLLY_INCLUDE_DIRECTORIES ${FOLLY_INCLUDE_DIRECTORIES} ${LIBEVENT_INCLUDE_DIR})
187 endif()
188
189
190 set(FOLLY_LINK_LIBRARIES
191   ${FOLLY_LINK_LIBRARIES}
192   Iphlpapi.lib
193   Ws2_32.lib
194
195   ${FOLLY_SHINY_DEPENDENCIES}
196 )
197
198 target_include_directories(folly_base
199   PUBLIC
200     ${FOLLY_INCLUDE_DIRECTORIES}
201     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
202 )
203
204 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
205   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
206   target_compile_definitions(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INTERFACE_COMPILE_DEFINITIONS>)
207 endforeach()
208
209 if (FOLLY_HAVE_PTHREAD)
210   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
211   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
212 endif()
213
214 # Now to generate the fingerprint tables
215 add_executable(GenerateFingerprintTables
216   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
217   $<TARGET_OBJECTS:folly_base>
218 )
219 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
220 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
221 add_dependencies(GenerateFingerprintTables folly_base)
222 apply_folly_compile_options_to_target(GenerateFingerprintTables)
223 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
224 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
225
226 # Compile the fingerprint tables.
227 add_custom_command(
228   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
229   COMMAND GenerateFingerprintTables
230   DEPENDS GenerateFingerprintTables
231   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
232   COMMENT "Generating the fingerprint tables..."
233 )
234 add_library(folly_fingerprint STATIC
235   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
236   ${FOLLY_DIR}/Fingerprint.h
237   ${FOLLY_DIR}/detail/SlowFingerprint.h
238   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
239   $<TARGET_OBJECTS:folly_base>
240 )
241 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
242 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
243 add_dependencies(folly_fingerprint folly_base)
244 apply_folly_compile_options_to_target(folly_fingerprint)
245
246 # We want to generate a single library and target for folly, but we needed a
247 # two-stage compile for the fingerprint tables, so we create a phony source
248 # file that we modify whenever the base libraries change, causing folly to be
249 # re-linked, making things happy.
250 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
251   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
252   DEPENDS folly_base folly_fingerprint
253 )
254 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
255 apply_folly_compile_options_to_target(folly)
256 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
257
258 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
259 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
260
261 install(TARGETS folly
262   EXPORT folly
263   RUNTIME DESTINATION bin
264   LIBRARY DESTINATION lib
265   ARCHIVE DESTINATION lib)
266 auto_install_files(folly ${FOLLY_DIR}
267   ${hfiles}
268   ${FOLLY_DIR}/Fingerprint.h
269   ${FOLLY_DIR}/detail/SlowFingerprint.h
270   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
271 )
272 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
273 install(
274   EXPORT folly
275   DESTINATION share/folly
276   NAMESPACE Folly::
277   FILE folly-targets.cmake
278 )
279
280 # We need a wrapper config file to do the find_package calls to ensure
281 # that all our dependencies are available to link against.
282 file(
283   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
284   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
285 )
286 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
287 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
288
289 option(BUILD_TESTS "If enabled, compile the tests." OFF)
290 option(BUILD_BROKEN_TESTS "If enabled, compile tests that are known to be broken." OFF)
291 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
292 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
293 if (BUILD_TESTS)
294   find_package(GMock MODULE REQUIRED)
295
296   add_library(folly_test_support
297     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
298     ${FOLLY_DIR}/test/DeterministicSchedule.h
299     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
300     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
301     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
302     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.cpp
303     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
304     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
305     ${FOLLY_DIR}/futures/test/TestExecutor.h
306     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
307     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
308     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
309     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
310     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
311     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
312     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
313     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
314     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
315     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
316     ${FOLLY_DIR}/io/async/test/SocketPair.h
317     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
318     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
319     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
320     ${FOLLY_DIR}/io/async/test/TimeUtil.h
321     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
322     ${FOLLY_DIR}/io/async/test/Util.h
323   )
324   target_compile_definitions(folly_test_support
325     PUBLIC
326       ${LIBGMOCK_DEFINES}
327   )
328   target_include_directories(folly_test_support
329     PUBLIC
330       ${LIBGMOCK_INCLUDE_DIR}
331   )
332   target_link_libraries(folly_test_support
333     PUBLIC
334       Boost::thread
335       folly
336       ${LIBGMOCK_LIBRARY}
337   )
338   apply_folly_compile_options_to_target(folly_test_support)
339
340   folly_define_tests(
341     DIRECTORY chrono/test/
342       TEST chrono_conv_test SOURCES ConvTest.cpp
343
344     DIRECTORY compression/test/
345       TEST compression_test SOURCES CompressionTest.cpp
346
347     DIRECTORY container/test/
348       TEST access_test SOURCES AccessTest.cpp
349       TEST array_test SOURCES ArrayTest.cpp
350       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
351       TEST enumerate_test SOURCES EnumerateTest.cpp
352       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
353       TEST foreach_test SOURCES ForeachTest.cpp
354       TEST merge_test SOURCES MergeTest.cpp
355       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
356
357     DIRECTORY concurrency/test/
358       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
359
360     DIRECTORY executors/test/
361       TEST async_helpers_test SOURCES AsyncTest.cpp
362       TEST codel_test SOURCES CodelTest.cpp
363       TEST executor_test SOURCES ExecutorTest.cpp
364       TEST fiber_io_executor_test SOURCES FiberIOExecutorTest.cpp
365       TEST global_executor_test SOURCES GlobalExecutorTest.cpp
366       TEST serial_executor_test SOURCES SerialExecutorTest.cpp
367       TEST thread_pool_executor_test SOURCES ThreadPoolExecutorTest.cpp
368       TEST threaded_executor_test SOURCES ThreadedExecutorTest.cpp
369
370     DIRECTORY executors/task_queue/test/
371       TEST unbounded_blocking_queue_test SOURCES UnboundedBlockingQueueTest.cpp
372
373     DIRECTORY experimental/test/
374       TEST autotimer_test SOURCES AutoTimerTest.cpp
375       TEST bits_test_2 SOURCES BitsTest.cpp
376       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
377       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
378       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
379       TEST event_count_test SOURCES EventCountTest.cpp
380       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
381       TEST future_dag_test SOURCES FutureDAGTest.cpp
382       TEST json_schema_test SOURCES JSONSchemaTest.cpp
383       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
384       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
385       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
386       # Depends on liburcu
387       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
388       #TEST ref_count_test SOURCES RefCountTest.cpp
389       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
390       TEST test_util_test SOURCES TestUtilTest.cpp
391       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
392
393     DIRECTORY experimental/io/test/
394       # Depends on libaio
395       #TEST async_io_test SOURCES AsyncIOTest.cpp
396       TEST fs_util_test SOURCES FsUtilTest.cpp
397
398     DIRECTORY experimental/logging/test/
399       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
400       TEST config_parser_test SOURCES ConfigParserTest.cpp
401       TEST config_update_test SOURCES ConfigUpdateTest.cpp
402       TEST file_handler_factory_test SOURCES FileHandlerFactoryTest.cpp
403       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
404       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
405       TEST log_category_test SOURCES LogCategoryTest.cpp
406       TEST logger_db_test SOURCES LoggerDBTest.cpp
407       TEST logger_test SOURCES LoggerTest.cpp
408       TEST log_level_test SOURCES LogLevelTest.cpp
409       TEST log_message_test SOURCES LogMessageTest.cpp
410       TEST log_name_test SOURCES LogNameTest.cpp
411       TEST log_stream_test SOURCES LogStreamTest.cpp
412       TEST printf_test SOURCES PrintfTest.cpp
413       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
414       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
415       TEST xlog_test
416         HEADERS
417           XlogHeader1.h
418           XlogHeader2.h
419         SOURCES
420           XlogFile1.cpp
421           XlogFile2.cpp
422           XlogTest.cpp
423
424     DIRECTORY fibers/test/
425       TEST fibers_test SOURCES FibersTest.cpp
426
427     DIRECTORY functional/test/
428       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
429       TEST partial_test SOURCES PartialTest.cpp
430
431     DIRECTORY futures/test/
432       TEST barrier_test SOURCES BarrierTest.cpp
433       TEST callback_lifetime_test SOURCES CallbackLifetimeTest.cpp
434       TEST collect_test SOURCES CollectTest.cpp
435       TEST context_test SOURCES ContextTest.cpp
436       TEST core_test SOURCES CoreTest.cpp
437       TEST ensure_test SOURCES EnsureTest.cpp
438       TEST fsm_test SOURCES FSMTest.cpp
439       TEST filter_test SOURCES FilterTest.cpp
440       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
441       # MSVC SFINAE bug
442       #TEST future_test SOURCES FutureTest.cpp
443       TEST header_compile_test SOURCES HeaderCompileTest.cpp
444       TEST interrupt_test SOURCES InterruptTest.cpp
445       TEST map_test SOURCES MapTest.cpp
446       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
447       TEST poll_test SOURCES PollTest.cpp
448       TEST promise_test SOURCES PromiseTest.cpp
449       TEST reduce_test SOURCES ReduceTest.cpp
450       # MSVC SFINAE bug
451       #TEST retrying_test SOURCES RetryingTest.cpp
452       TEST self_destruct_test SOURCES SelfDestructTest.cpp
453       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
454       TEST test_executor_test SOURCES TestExecutorTest.cpp
455       TEST then_compile_test
456         HEADERS
457           ThenCompileTest.h
458         SOURCES
459           ThenCompileTest.cpp
460       TEST then_test SOURCES ThenTest.cpp
461       TEST timekeeper_test SOURCES TimekeeperTest.cpp
462       TEST times_test SOURCES TimesTest.cpp
463       TEST unwrap_test SOURCES UnwrapTest.cpp
464       TEST via_test SOURCES ViaTest.cpp
465       TEST wait_test SOURCES WaitTest.cpp
466       TEST when_test SOURCES WhenTest.cpp
467       TEST while_do_test SOURCES WhileDoTest.cpp
468       TEST will_equal_test SOURCES WillEqualTest.cpp
469       TEST window_test SOURCES WindowTest.cpp
470
471     DIRECTORY gen/test/
472       # MSVC bug can't resolve initializer_list constructor properly
473       #TEST base_test SOURCES BaseTest.cpp
474       TEST combine_test SOURCES CombineTest.cpp
475       TEST parallel_map_test SOURCES ParallelMapTest.cpp
476       TEST parallel_test SOURCES ParallelTest.cpp
477
478     DIRECTORY hash/test/
479       TEST checksum_test SOURCES ChecksumTest.cpp
480       TEST hash_test SOURCES HashTest.cpp
481       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
482       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
483
484     DIRECTORY io/test/
485       TEST iobuf_test SOURCES IOBufTest.cpp
486       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
487       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
488       TEST record_io_test SOURCES RecordIOTest.cpp
489       TEST ShutdownSocketSetTest HANGING
490         SOURCES ShutdownSocketSetTest.cpp
491
492     DIRECTORY io/async/test/
493       TEST async_test
494         CONTENT_DIR certs/
495         HEADERS
496           AsyncSocketTest.h
497           AsyncSSLSocketTest.h
498         SOURCES
499           AsyncPipeTest.cpp
500           AsyncSocketExceptionTest.cpp
501           AsyncSocketTest.cpp
502           AsyncSocketTest2.cpp
503           AsyncSSLSocketTest.cpp
504           AsyncSSLSocketTest2.cpp
505           AsyncSSLSocketWriteTest.cpp
506           AsyncTransportTest.cpp
507           # This is disabled because it depends on things that don't exist
508           # on Windows.
509           #EventHandlerTest.cpp
510           # The async signal handler is not supported on Windows.
511           #AsyncSignalHandlerTest.cpp
512       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
513       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
514       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
515       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
516       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
517       TEST EventBaseTest SOURCES EventBaseTest.cpp
518       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
519       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
520       TEST HHWheelTimerSlowTests SLOW
521         SOURCES HHWheelTimerSlowTests.cpp
522       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
523       TEST RequestContextTest SOURCES RequestContextTest.cpp
524       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
525       TEST ssl_session_test SOURCES SSLSessionTest.cpp
526       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
527
528     DIRECTORY io/async/ssl/test/
529       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
530
531     DIRECTORY lang/test/
532       TEST bits_test SOURCES BitsTest.cpp
533       TEST cold_class_test SOURCES ColdClassTest.cpp
534
535     DIRECTORY memory/test/
536       TEST arena_test SOURCES ArenaTest.cpp
537       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
538       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
539
540     DIRECTORY portability/test/
541       TEST constexpr_test SOURCES ConstexprTest.cpp
542       TEST libgen-test SOURCES LibgenTest.cpp
543       TEST openssl_portability_test SOURCES OpenSSLPortabilityTest.cpp
544       TEST time-test SOURCES TimeTest.cpp
545
546     DIRECTORY ssl/test/
547       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
548
549     DIRECTORY stats/test/
550       TEST histogram_test SOURCES HistogramTest.cpp
551       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
552       TEST timeseries_test SOURCES TimeseriesTest.cpp
553
554     DIRECTORY synchronization/test/
555       TEST baton_test SOURCES BatonTest.cpp
556       TEST call_once_test SOURCES CallOnceTest.cpp
557       TEST lifo_sem_test SOURCES LifoSemTests.cpp
558       TEST rw_spin_lock_test SOURCES RWSpinLockTest.cpp
559
560     DIRECTORY system/test/
561       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
562       TEST shell_test SOURCES ShellTest.cpp
563       #TEST subprocess_test SOURCES SubprocessTest.cpp
564       TEST thread_id_test SOURCES ThreadIdTest.cpp
565       TEST thread_name_test SOURCES ThreadNameTest.cpp
566
567     DIRECTORY test/
568       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
569       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
570       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
571       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
572       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
573       TEST atomic_hash_map_test HANGING
574         SOURCES AtomicHashMapTest.cpp
575       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
576       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
577       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
578       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
579       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
580       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
581       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
582       TEST conv_test SOURCES ConvTest.cpp
583       TEST cpu_id_test SOURCES CpuIdTest.cpp
584       TEST demangle_test SOURCES DemangleTest.cpp
585       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
586       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
587       TEST dynamic_test SOURCES DynamicTest.cpp
588       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
589       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
590       TEST endian_test SOURCES EndianTest.cpp
591       TEST exception_test SOURCES ExceptionTest.cpp
592       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
593       TEST expected_test SOURCES ExpectedTest.cpp
594       TEST fbvector_test SOURCES FBVectorTest.cpp
595       TEST file_test SOURCES FileTest.cpp
596       #TEST file_lock_test SOURCES FileLockTest.cpp
597       TEST file_util_test HANGING
598         SOURCES FileUtilTest.cpp
599       TEST fingerprint_test SOURCES FingerprintTest.cpp
600       TEST format_other_test SOURCES FormatOtherTest.cpp
601       TEST format_test SOURCES FormatTest.cpp
602       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
603       TEST function_test BROKEN
604         SOURCES FunctionTest.cpp
605       TEST function_ref_test SOURCES FunctionRefTest.cpp
606       TEST futex_test SOURCES FutexTest.cpp
607       TEST group_varint_test SOURCES GroupVarintTest.cpp
608       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
609       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
610       TEST indestructible_test SOURCES IndestructibleTest.cpp
611       TEST indexed_mem_pool_test BROKEN
612         SOURCES IndexedMemPoolTest.cpp
613       # MSVC Preprocessor stringizing raw string literals bug
614       #TEST json_test SOURCES JsonTest.cpp
615       TEST json_other_test
616         CONTENT_DIR json_test_data/
617         SOURCES
618           JsonOtherTest.cpp
619       TEST lazy_test SOURCES LazyTest.cpp
620       TEST lock_traits_test SOURCES LockTraitsTest.cpp
621       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
622       TEST logging_test SOURCES LoggingTest.cpp
623       TEST math_test SOURCES MathTest.cpp
624       TEST map_util_test SOURCES MapUtilTest.cpp
625       TEST memcpy_test SOURCES MemcpyTest.cpp
626       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
627       TEST memory_test SOURCES MemoryTest.cpp
628       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
629       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
630       TEST mpmc_queue_test SLOW
631         SOURCES MPMCQueueTest.cpp
632       TEST network_address_test HANGING
633         SOURCES
634           IPAddressTest.cpp
635           MacAddressTest.cpp
636           SocketAddressTest.cpp
637       TEST optional_test SOURCES OptionalTest.cpp
638       TEST packed_sync_ptr_test HANGING
639         SOURCES PackedSyncPtrTest.cpp
640       TEST padded_test SOURCES PaddedTest.cpp
641       #TEST poly_test SOURCES PolyTest.cpp
642       TEST portability_test SOURCES PortabilityTest.cpp
643       TEST producer_consumer_queue_test SLOW
644         SOURCES ProducerConsumerQueueTest.cpp
645       TEST random_test SOURCES RandomTest.cpp
646       TEST range_test SOURCES RangeTest.cpp
647       TEST safe_assert_test SOURCES SafeAssertTest.cpp
648       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
649       # Heavily dependent on drand and srand48
650       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
651       TEST singleton_test SOURCES SingletonTest.cpp
652       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
653       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
654       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
655       TEST small_vector_test SOURCES small_vector_test.cpp
656       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
657       TEST string_test SOURCES StringTest.cpp
658       TEST synchronized_test SOURCES SynchronizedTest.cpp
659       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
660       TEST thread_local_test SOURCES ThreadLocalTest.cpp
661       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
662       TEST token_bucket_test SOURCES TokenBucketTest.cpp
663       TEST traits_test SOURCES TraitsTest.cpp
664       TEST try_test SOURCES TryTest.cpp
665       TEST unit_test SOURCES UnitTest.cpp
666       TEST uri_test SOURCES UriTest.cpp
667       TEST varint_test SOURCES VarintTest.cpp
668   )
669 endif()