CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
   2
   3 # includes
   4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
   5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   6
   7 # package information
   8 set(PACKAGE_NAME      "folly")
   9 set(PACKAGE_VERSION   "0.58.0-dev")
  10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
  13
  14 # 150+ tests in the root folder anyone? No? I didn't think so.
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 project(${PACKAGE_NAME} CXX)
  18
  19 if (MSVC_VERSION GREATER_EQUAL 1910 AND MSVC_VERSION LESS 1920)
  20   set(MSVC_IS_2017 ON)
  21 elseif (MSVC_VERSION EQUAL 1900)
  22   set(MSVC_IS_2017 OFF)
  23 else()
  24   message(FATAL_ERROR "This build script only supports building Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017. MSVC version '${MSVC_VERSION}' is not supported.")
  25 endif()
  26
  27 # Check architecture OS
  28 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
  29   message(FATAL_ERROR "Folly requires a 64bit OS")
  30 endif()
  31 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  32   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
  33 endif()
  34
  35 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
  36
  37 # Generate a few tables and create the main config file.
  38 find_package(PythonInterp REQUIRED)
  39 add_custom_command(
  40   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
  41   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
  42   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
  43   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  44   COMMENT "Generating the escape tables..." VERBATIM
  45 )
  46 add_custom_command(
  47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
  48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
  49   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
  50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  51   COMMENT "Generating the format tables..." VERBATIM
  52 )
  53 add_custom_command(
  54   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
  55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
  56   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
  57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  58   COMMENT "Generating the group varint tables..." VERBATIM
  59 )
  60
  61 include(folly-deps) # Find the required packages
  62 if (LIBPTHREAD_FOUND)
  63   set(FOLLY_HAVE_PTHREAD ON)
  64 endif()
  65 configure_file(
  66   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
  67   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
  68 )
  69
  70 include(FollyCompiler)
  71 include(FollyFunctions)
  72
  73 # Main folly library files
  74 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
  75 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
  76
  77 # No need for tests or benchmarks, and we can't build most experimental stuff.
  78 REMOVE_MATCHES_FROM_LISTS(files hfiles
  79   MATCHES
  80     "/build/"
  81     "/experimental/exception_tracer/"
  82     "/experimental/hazptr/bench/"
  83     "/experimental/hazptr/example/"
  84     "/experimental/logging/example/"
  85     "/experimental/symbolizer/"
  86     "/futures/exercises/"
  87     "/test/"
  88     "/tools/"
  89     "Benchmark.cpp$"
  90     "Test.cpp$"
  91   IGNORE_MATCHES
  92     "/Benchmark.cpp$"
  93 )
  94 list(REMOVE_ITEM files
  95   ${FOLLY_DIR}/Poly.cpp
  96   ${FOLLY_DIR}/Subprocess.cpp
  97   ${FOLLY_DIR}/SingletonStackTrace.cpp
  98   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
  99   ${FOLLY_DIR}/experimental/RCUUtils.cpp
 100   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
 101   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
 102   ${FOLLY_DIR}/futures/test/Benchmark.cpp
 103 )
 104 list(REMOVE_ITEM hfiles
 105   ${FOLLY_DIR}/Fingerprint.h
 106   ${FOLLY_DIR}/Poly.h
 107   ${FOLLY_DIR}/Poly-inl.h
 108   ${FOLLY_DIR}/detail/PolyDetail.h
 109   ${FOLLY_DIR}/detail/TypeList.h
 110   ${FOLLY_DIR}/detail/SlowFingerprint.h
 111   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 112   ${FOLLY_DIR}/experimental/RCURefCount.h
 113   ${FOLLY_DIR}/experimental/RCUUtils.h
 114   ${FOLLY_DIR}/experimental/io/AsyncIO.h
 115   ${FOLLY_DIR}/poly/Nullable.h
 116   ${FOLLY_DIR}/poly/Regular.h
 117 )
 118
 119 add_library(folly_base OBJECT
 120   ${files} ${hfiles}
 121   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
 122   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 123   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 125 )
 126 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
 127 apply_folly_compile_options_to_target(folly_base)
 128 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
 129 # Add the generated files to the correct source group.
 130 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
 131 source_group("folly\\build" FILES
 132   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 133   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 134   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 135   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 136 )
 137
 138 set(FOLLY_SHINY_DEPENDENCIES
 139   Boost::chrono
 140   Boost::context
 141   Boost::date_time
 142   Boost::filesystem
 143   Boost::program_options
 144   Boost::regex
 145   Boost::system
 146   OpenSSL::SSL
 147   OpenSSL::Crypto
 148 )
 149
 150 set(FOLLY_LINK_LIBRARIES
 151   ${DOUBLE_CONVERSION_LIBRARY}
 152   ${LIBEVENT_LIB}
 153   ${LIBGFLAGS_LIBRARY}
 154   ${LIBGLOG_LIBRARY}
 155   Iphlpapi.lib
 156   Ws2_32.lib
 157
 158   ${FOLLY_SHINY_DEPENDENCIES}
 159 )
 160
 161 target_include_directories(folly_base
 162   PUBLIC
 163     ${DOUBLE_CONVERSION_INCLUDE_DIR}
 164     ${LIBGFLAGS_INCLUDE_DIR}
 165     ${LIBGLOG_INCLUDE_DIR}
 166     ${LIBEVENT_INCLUDE_DIR}
 167     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
 168 )
 169
 170 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
 171   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
 172 endforeach()
 173
 174 if (FOLLY_HAVE_PTHREAD)
 175   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
 176   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
 177 endif()
 178
 179 # Now to generate the fingerprint tables
 180 add_executable(GenerateFingerprintTables
 181   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
 182   $<TARGET_OBJECTS:folly_base>
 183 )
 184 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
 185 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 186 add_dependencies(GenerateFingerprintTables folly_base)
 187 apply_folly_compile_options_to_target(GenerateFingerprintTables)
 188 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
 189 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
 190
 191 # Compile the fingerprint tables.
 192 add_custom_command(
 193   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 194   COMMAND GenerateFingerprintTables
 195   DEPENDS GenerateFingerprintTables
 196   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
 197   COMMENT "Generating the fingerprint tables..."
 198 )
 199 add_library(folly_fingerprint STATIC
 200   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 201   ${FOLLY_DIR}/Fingerprint.h
 202   ${FOLLY_DIR}/detail/SlowFingerprint.h
 203   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 204   $<TARGET_OBJECTS:folly_base>
 205 )
 206 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
 207 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 208 add_dependencies(folly_fingerprint folly_base)
 209 apply_folly_compile_options_to_target(folly_fingerprint)
 210
 211 # We want to generate a single library and target for folly, but we needed a
 212 # two-stage compile for the fingerprint tables, so we create a phony source
 213 # file that we modify whenever the base libraries change, causing folly to be
 214 # re-linked, making things happy.
 215 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 216   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 217   DEPENDS folly_base folly_fingerprint
 218 )
 219 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
 220 apply_folly_compile_options_to_target(folly)
 221 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
 222
 223 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
 224 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 225
 226 install(TARGETS folly
 227   EXPORT folly
 228   RUNTIME DESTINATION bin
 229   LIBRARY DESTINATION lib
 230   ARCHIVE DESTINATION lib)
 231 auto_install_files(folly ${FOLLY_DIR}
 232   ${hfiles}
 233   ${FOLLY_DIR}/Fingerprint.h
 234   ${FOLLY_DIR}/detail/SlowFingerprint.h
 235   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 236 )
 237 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
 238 install(
 239   EXPORT folly
 240   DESTINATION share/folly
 241   NAMESPACE Folly::
 242   FILE folly-targets.cmake
 243 )
 244
 245 # We need a wrapper config file to do the find_package calls to ensure
 246 # that all our dependencies are available to link against.
 247 file(
 248   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
 249   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
 250 )
 251 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
 252 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
 253
 254 option(BUILD_TESTS "If enabled, compile the tests." OFF)
 255 option(BUILD_BROKEN_TESTS "If enabled, compile tests that are known to be broken." OFF)
 256 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
 257 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
 258 if (BUILD_TESTS)
 259   find_package(GMock MODULE REQUIRED)
 260
 261   add_library(folly_test_support
 262     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
 263     ${FOLLY_DIR}/test/DeterministicSchedule.h
 264     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
 265     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
 266     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
 267     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
 268     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
 269     ${FOLLY_DIR}/futures/test/TestExecutor.h
 270     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
 271     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
 272     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
 273     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
 274     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
 275     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
 276     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
 277     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
 278     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
 279     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
 280     ${FOLLY_DIR}/io/async/test/SocketPair.h
 281     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
 282     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
 283     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
 284     ${FOLLY_DIR}/io/async/test/TimeUtil.h
 285     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
 286     ${FOLLY_DIR}/io/async/test/Util.h
 287   )
 288   target_compile_definitions(folly_test_support
 289     PUBLIC
 290       ${LIBGMOCK_DEFINES}
 291   )
 292   target_include_directories(folly_test_support
 293     PUBLIC
 294       ${LIBGMOCK_INCLUDE_DIR}
 295   )
 296   target_link_libraries(folly_test_support
 297     PUBLIC
 298       Boost::thread
 299       folly
 300       ${LIBGMOCK_LIBRARY}
 301   )
 302   apply_folly_compile_options_to_target(folly_test_support)
 303
 304   folly_define_tests(
 305     DIRECTORY compression/test/
 306       TEST compression_test SOURCES CompressionTest.cpp
 307
 308     DIRECTORY container/test/
 309       TEST array_test SOURCES ArrayTest.cpp
 310       TEST enumerate_test SOURCES EnumerateTest.cpp
 311       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
 312       TEST foreach_test SOURCES ForeachTest.cpp
 313       TEST merge_test SOURCES MergeTest.cpp
 314       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
 315
 316     DIRECTORY concurrency/test/
 317       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
 318
 319     DIRECTORY executors/test/
 320       TEST async_helpers_test SOURCES AsyncTest.cpp
 321       TEST codel_test SOURCES CodelTest.cpp
 322       TEST executor_test SOURCES ExecutorTest.cpp
 323       TEST fiber_io_executor_test SOURCES FiberIOExecutorTest.cpp
 324       TEST global_executor_test SOURCES GlobalExecutorTest.cpp
 325       TEST serial_executor_test SOURCES SerialExecutorTest.cpp
 326       TEST thread_pool_executor_test SOURCES ThreadPoolExecutorTest.cpp
 327       TEST threaded_executor_test SOURCES ThreadedExecutorTest.cpp
 328
 329     DIRECTORY executors/task_queue/test/
 330       TEST unbounded_blocking_queue_test SOURCES UnboundedBlockingQueueTest.cpp
 331
 332     DIRECTORY experimental/test/
 333       TEST autotimer_test SOURCES AutoTimerTest.cpp
 334       TEST bits_test_2 SOURCES BitsTest.cpp
 335       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
 336       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
 337       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
 338       TEST event_count_test SOURCES EventCountTest.cpp
 339       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
 340       TEST future_dag_test SOURCES FutureDAGTest.cpp
 341       TEST json_schema_test SOURCES JSONSchemaTest.cpp
 342       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
 343       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
 344       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
 345       # Depends on liburcu
 346       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
 347       #TEST ref_count_test SOURCES RefCountTest.cpp
 348       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
 349       TEST test_util_test SOURCES TestUtilTest.cpp
 350       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
 351
 352     DIRECTORY experimental/io/test/
 353       # Depends on libaio
 354       #TEST async_io_test SOURCES AsyncIOTest.cpp
 355       TEST fs_util_test SOURCES FsUtilTest.cpp
 356
 357     DIRECTORY experimental/logging/test/
 358       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
 359       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
 360       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
 361       TEST log_category_test SOURCES LogCategoryTest.cpp
 362       TEST logger_db_test SOURCES LoggerDBTest.cpp
 363       TEST logger_test SOURCES LoggerTest.cpp
 364       TEST log_level_test SOURCES LogLevelTest.cpp
 365       TEST log_message_test SOURCES LogMessageTest.cpp
 366       TEST log_name_test SOURCES LogNameTest.cpp
 367       TEST log_stream_test SOURCES LogStreamTest.cpp
 368       TEST printf_test SOURCES PrintfTest.cpp
 369       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
 370       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
 371       TEST xlog_test
 372         HEADERS
 373           XlogHeader1.h
 374           XlogHeader2.h
 375         SOURCES
 376           XlogFile1.cpp
 377           XlogFile2.cpp
 378           XlogTest.cpp
 379
 380     DIRECTORY fibers/test/
 381       TEST fibers_test SOURCES FibersTest.cpp
 382
 383     DIRECTORY functional/test/
 384       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
 385       TEST partial_test SOURCES PartialTest.cpp
 386
 387     DIRECTORY futures/test/
 388       TEST barrier_test SOURCES BarrierTest.cpp
 389       TEST callback_lifetime_test SOURCES CallbackLifetimeTest.cpp
 390       TEST collect_test SOURCES CollectTest.cpp
 391       TEST context_test SOURCES ContextTest.cpp
 392       TEST core_test SOURCES CoreTest.cpp
 393       TEST ensure_test SOURCES EnsureTest.cpp
 394       TEST fsm_test SOURCES FSMTest.cpp
 395       TEST filter_test SOURCES FilterTest.cpp
 396       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
 397       # MSVC SFINAE bug
 398       #TEST future_test SOURCES FutureTest.cpp
 399       TEST header_compile_test SOURCES HeaderCompileTest.cpp
 400       TEST interrupt_test SOURCES InterruptTest.cpp
 401       TEST map_test SOURCES MapTest.cpp
 402       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
 403       TEST poll_test SOURCES PollTest.cpp
 404       TEST promise_test SOURCES PromiseTest.cpp
 405       TEST reduce_test SOURCES ReduceTest.cpp
 406       # MSVC SFINAE bug
 407       #TEST retrying_test SOURCES RetryingTest.cpp
 408       TEST self_destruct_test SOURCES SelfDestructTest.cpp
 409       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
 410       TEST test_executor_test SOURCES TestExecutorTest.cpp
 411       TEST then_compile_test
 412         HEADERS
 413           ThenCompileTest.h
 414         SOURCES
 415           ThenCompileTest.cpp
 416       TEST then_test SOURCES ThenTest.cpp
 417       TEST timekeeper_test SOURCES TimekeeperTest.cpp
 418       TEST times_test SOURCES TimesTest.cpp
 419       TEST unwrap_test SOURCES UnwrapTest.cpp
 420       TEST via_test SOURCES ViaTest.cpp
 421       TEST wait_test SOURCES WaitTest.cpp
 422       TEST when_test SOURCES WhenTest.cpp
 423       TEST while_do_test SOURCES WhileDoTest.cpp
 424       TEST will_equal_test SOURCES WillEqualTest.cpp
 425       TEST window_test SOURCES WindowTest.cpp
 426
 427     DIRECTORY gen/test/
 428       # MSVC bug can't resolve initializer_list constructor properly
 429       #TEST base_test SOURCES BaseTest.cpp
 430       TEST combine_test SOURCES CombineTest.cpp
 431       TEST parallel_map_test SOURCES ParallelMapTest.cpp
 432       TEST parallel_test SOURCES ParallelTest.cpp
 433
 434     DIRECTORY hash/test/
 435       TEST checksum_test SOURCES ChecksumTest.cpp
 436       TEST hash_test SOURCES HashTest.cpp
 437       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
 438       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
 439
 440     DIRECTORY io/test/
 441       TEST iobuf_test SOURCES IOBufTest.cpp
 442       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
 443       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
 444       TEST record_io_test SOURCES RecordIOTest.cpp
 445       TEST ShutdownSocketSetTest HANGING
 446         SOURCES ShutdownSocketSetTest.cpp
 447
 448     DIRECTORY io/async/test/
 449       TEST async_test
 450         CONTENT_DIR certs/
 451         HEADERS
 452           AsyncSocketTest.h
 453           AsyncSSLSocketTest.h
 454         SOURCES
 455           AsyncPipeTest.cpp
 456           AsyncSocketExceptionTest.cpp
 457           AsyncSocketTest.cpp
 458           AsyncSocketTest2.cpp
 459           AsyncSSLSocketTest.cpp
 460           AsyncSSLSocketTest2.cpp
 461           AsyncSSLSocketWriteTest.cpp
 462           AsyncTransportTest.cpp
 463           # This is disabled because it depends on things that don't exist
 464           # on Windows.
 465           #EventHandlerTest.cpp
 466           # The async signal handler is not supported on Windows.
 467           #AsyncSignalHandlerTest.cpp
 468       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
 469       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
 470       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
 471       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
 472       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
 473       TEST EventBaseTest SOURCES EventBaseTest.cpp
 474       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
 475       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
 476       TEST HHWheelTimerSlowTests SLOW
 477         SOURCES HHWheelTimerSlowTests.cpp
 478       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
 479       TEST RequestContextTest SOURCES RequestContextTest.cpp
 480       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
 481       TEST ssl_session_test SOURCES SSLSessionTest.cpp
 482       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
 483
 484     DIRECTORY io/async/ssl/test/
 485       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
 486
 487     DIRECTORY memory/test/
 488       TEST arena_test SOURCES ArenaTest.cpp
 489       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
 490       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
 491
 492     DIRECTORY portability/test/
 493       TEST constexpr_test SOURCES ConstexprTest.cpp
 494       TEST libgen-test SOURCES LibgenTest.cpp
 495       TEST openssl_portability_test SOURCES OpenSSLPortabilityTest.cpp
 496       TEST time-test SOURCES TimeTest.cpp
 497
 498     DIRECTORY ssl/test/
 499       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
 500
 501     DIRECTORY stats/test/
 502       TEST histogram_test SOURCES HistogramTest.cpp
 503       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
 504       TEST timeseries_test SOURCES TimeseriesTest.cpp
 505
 506     DIRECTORY synchronization/test/
 507       TEST call_once_test SOURCES CallOnceTest.cpp
 508
 509     DIRECTORY system/test/
 510       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
 511       TEST shell_test SOURCES ShellTest.cpp
 512       #TEST subprocess_test SOURCES SubprocessTest.cpp
 513       TEST thread_id_test SOURCES ThreadIdTest.cpp
 514       TEST thread_name_test SOURCES ThreadNameTest.cpp
 515
 516     DIRECTORY test/
 517       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
 518       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
 519       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
 520       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
 521       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
 522       TEST atomic_hash_map_test HANGING
 523         SOURCES AtomicHashMapTest.cpp
 524       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
 525       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
 526       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
 527       TEST baton_test SOURCES BatonTest.cpp
 528       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
 529       TEST bits_test SOURCES BitsTest.cpp
 530       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
 531       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
 532       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
 533       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
 534       TEST conv_test SOURCES ConvTest.cpp
 535       TEST cpu_id_test SOURCES CpuIdTest.cpp
 536       TEST demangle_test SOURCES DemangleTest.cpp
 537       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
 538       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
 539       TEST dynamic_test SOURCES DynamicTest.cpp
 540       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
 541       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
 542       TEST endian_test SOURCES EndianTest.cpp
 543       TEST exception_test SOURCES ExceptionTest.cpp
 544       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
 545       TEST expected_test SOURCES ExpectedTest.cpp
 546       TEST fbvector_test SOURCES FBVectorTest.cpp
 547       TEST file_test SOURCES FileTest.cpp
 548       #TEST file_lock_test SOURCES FileLockTest.cpp
 549       TEST file_util_test HANGING
 550         SOURCES FileUtilTest.cpp
 551       TEST fingerprint_test SOURCES FingerprintTest.cpp
 552       TEST format_other_test SOURCES FormatOtherTest.cpp
 553       TEST format_test SOURCES FormatTest.cpp
 554       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
 555       TEST function_test BROKEN
 556         SOURCES FunctionTest.cpp
 557       TEST function_ref_test SOURCES FunctionRefTest.cpp
 558       TEST futex_test SOURCES FutexTest.cpp
 559       TEST group_varint_test SOURCES GroupVarintTest.cpp
 560       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
 561       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
 562       TEST indestructible_test SOURCES IndestructibleTest.cpp
 563       TEST indexed_mem_pool_test BROKEN
 564         SOURCES IndexedMemPoolTest.cpp
 565       # MSVC Preprocessor stringizing raw string literals bug
 566       #TEST json_test SOURCES JsonTest.cpp
 567       TEST json_other_test
 568         CONTENT_DIR json_test_data/
 569         SOURCES
 570           JsonOtherTest.cpp
 571       TEST lazy_test SOURCES LazyTest.cpp
 572       TEST lifosem_test SOURCES LifoSemTests.cpp
 573       TEST lock_traits_test SOURCES LockTraitsTest.cpp
 574       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
 575       TEST logging_test SOURCES LoggingTest.cpp
 576       TEST math_test SOURCES MathTest.cpp
 577       TEST map_util_test SOURCES MapUtilTest.cpp
 578       TEST memcpy_test SOURCES MemcpyTest.cpp
 579       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
 580       TEST memory_test SOURCES MemoryTest.cpp
 581       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
 582       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
 583       TEST mpmc_queue_test SLOW
 584         SOURCES MPMCQueueTest.cpp
 585       TEST network_address_test HANGING
 586         SOURCES
 587           IPAddressTest.cpp
 588           MacAddressTest.cpp
 589           SocketAddressTest.cpp
 590       TEST optional_test SOURCES OptionalTest.cpp
 591       TEST packed_sync_ptr_test HANGING
 592         SOURCES PackedSyncPtrTest.cpp
 593       TEST padded_test SOURCES PaddedTest.cpp
 594       #TEST poly_test SOURCES PolyTest.cpp
 595       TEST portability_test SOURCES PortabilityTest.cpp
 596       TEST producer_consumer_queue_test SLOW
 597         SOURCES ProducerConsumerQueueTest.cpp
 598       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
 599       TEST random_test SOURCES RandomTest.cpp
 600       TEST range_test SOURCES RangeTest.cpp
 601       TEST safe_assert_test SOURCES SafeAssertTest.cpp
 602       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
 603       # Heavily dependent on drand and srand48
 604       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
 605       TEST singleton_test SOURCES SingletonTest.cpp
 606       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
 607       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
 608       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
 609       TEST small_vector_test SOURCES small_vector_test.cpp
 610       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
 611       TEST string_test SOURCES StringTest.cpp
 612       TEST synchronized_test SOURCES SynchronizedTest.cpp
 613       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
 614       TEST thread_local_test SOURCES ThreadLocalTest.cpp
 615       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
 616       TEST token_bucket_test SOURCES TokenBucketTest.cpp
 617       TEST traits_test SOURCES TraitsTest.cpp
 618       TEST try_test SOURCES TryTest.cpp
 619       TEST unit_test SOURCES UnitTest.cpp
 620       TEST uri_test SOURCES UriTest.cpp
 621       TEST varint_test SOURCES VarintTest.cpp
 622   )
 623 endif()