Clarify in the docs what belongs in portability/
[folly.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
2
3 # Unfortunately, CMake doesn't easily provide us a way to merge static
4 # libraries, which is what we want to do to generate the main folly library, so
5 # we do a bit of a workaround here to inject a property into the generated
6 # project files that will only get enabled for the folly target. Ugly, but
7 # the alternatives are far, far worse.
8 if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio 15( 2017)? Win64")
9   set(CMAKE_GENERATOR_TOOLSET "v141</PlatformToolset></PropertyGroup><ItemDefinitionGroup Condition=\"'$(ProjectName)'=='folly'\"><ProjectReference><LinkLibraryDependencies>true</LinkLibraryDependencies></ProjectReference></ItemDefinitionGroup><PropertyGroup><PlatformToolset>v141")
10   set(MSVC_IS_2017 ON)
11 elseif ("${CMAKE_GENERATOR}" STREQUAL "Visual Studio 14 2015 Win64")
12   set(CMAKE_GENERATOR_TOOLSET "v140</PlatformToolset></PropertyGroup><ItemDefinitionGroup Condition=\"'$(ProjectName)'=='folly'\"><ProjectReference><LinkLibraryDependencies>true</LinkLibraryDependencies></ProjectReference></ItemDefinitionGroup><PropertyGroup><PlatformToolset>v140")
13   set(MSVC_IS_2017 OFF)
14 elseif ("${CMAKE_GENERATOR}" STREQUAL "Ninja")
15   message("Folly is being built with Ninja, so assuming VS 2017 is being used.")
16   set(MSVC_IS_2017 ON)
17 else()
18   message(FATAL_ERROR "This build script only supports building Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
19 endif()
20
21 # includes
22 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
23 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
24
25 # package information
26 set(PACKAGE_NAME      "folly")
27 set(PACKAGE_VERSION   "0.58.0-dev")
28 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
29 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
30 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
31
32 # 150+ tests in the root folder anyone? No? I didn't think so.
33 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
34
35 project(${PACKAGE_NAME} CXX)
36
37 # Check architecture OS
38 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
39   message(FATAL_ERROR "Folly requires a 64bit OS")
40 endif()
41 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
42   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
43 endif()
44
45 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
46
47 # Generate a few tables and create the main config file.
48 find_package(PythonInterp REQUIRED)
49 add_custom_command(
50   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
51   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
52   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
53   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
54   COMMENT "Generating the escape tables..." VERBATIM
55 )
56 add_custom_command(
57   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
58   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
59   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
60   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
61   COMMENT "Generating the format tables..." VERBATIM
62 )
63 add_custom_command(
64   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
65   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
66   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
67   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
68   COMMENT "Generating the group varint tables..." VERBATIM
69 )
70
71 include(folly-deps) # Find the required packages
72 if (LIBPTHREAD_FOUND)
73   set(FOLLY_HAVE_PTHREAD ON)
74 endif()
75 configure_file(
76   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
77   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
78 )
79
80 include(FollyCompiler)
81 include(FollyFunctions)
82
83 # Main folly library files
84 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
85 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
86
87 # No need for tests or benchmarks, and we can't build most experimental stuff.
88 REMOVE_MATCHES_FROM_LISTS(files hfiles
89   MATCHES
90     "/build/"
91     "/experimental/exception_tracer/"
92     "/experimental/hazptr/example/"
93     "/experimental/symbolizer/"
94     "/futures/exercises/"
95     "/test/"
96     "Benchmark.cpp$"
97     "Test.cpp$"
98   IGNORE_MATCHES
99     "/Benchmark.cpp$"
100 )
101 list(REMOVE_ITEM files
102   ${FOLLY_DIR}/Subprocess.cpp
103   ${FOLLY_DIR}/SingletonStackTrace.cpp
104   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
105   ${FOLLY_DIR}/experimental/RCUUtils.cpp
106   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
107   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
108   ${FOLLY_DIR}/futures/test/Benchmark.cpp
109 )
110 list(REMOVE_ITEM hfiles
111   ${FOLLY_DIR}/Fingerprint.h
112   ${FOLLY_DIR}/detail/SlowFingerprint.h
113   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
114   ${FOLLY_DIR}/experimental/RCURefCount.h
115   ${FOLLY_DIR}/experimental/RCUUtils.h
116   ${FOLLY_DIR}/experimental/io/AsyncIO.h
117 )
118
119 add_library(folly_base STATIC
120   ${files} ${hfiles}
121   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
122   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
123   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
125 )
126 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
127 apply_folly_compile_options_to_target(folly_base)
128 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
129 # Add the generated files to the correct source group.
130 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
131 source_group("folly\\build" FILES
132   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
133   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
134   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
135   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
136 )
137
138 target_include_directories(folly_base
139   PUBLIC
140     ${DOUBLE_CONVERSION_INCLUDE_DIR}
141     ${LIBGFLAGS_INCLUDE_DIR}
142     ${LIBGLOG_INCLUDE_DIR}
143     ${LIBEVENT_INCLUDE_DIR}
144 )
145 target_link_libraries(folly_base
146   PUBLIC
147     Boost::chrono
148     Boost::context
149     Boost::date_time
150     Boost::filesystem
151     Boost::program_options
152     Boost::regex
153     Boost::system
154     ${DOUBLE_CONVERSION_LIBRARY}
155     ${LIBEVENT_LIB}
156     ${LIBGFLAGS_LIBRARY}
157     ${LIBGLOG_LIBRARY}
158     OpenSSL::SSL
159     OpenSSL::Crypto
160     Ws2_32.lib
161 )
162 if (FOLLY_HAVE_PTHREAD)
163   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
164   target_link_libraries(folly_base PUBLIC ${LIBPTHREAD_LIBRARIES})
165 endif()
166
167 # Now to generate the fingerprint tables
168 add_executable(GenerateFingerprintTables
169   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
170 )
171 apply_folly_compile_options_to_target(GenerateFingerprintTables)
172 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
173 target_link_libraries(GenerateFingerprintTables PRIVATE folly_base)
174 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
175
176 # Compile the fingerprint tables.
177 add_custom_command(
178   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
179   COMMAND GenerateFingerprintTables
180   DEPENDS GenerateFingerprintTables
181   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
182   COMMENT "Generating the fingerprint tables..."
183 )
184 add_library(folly_fingerprint STATIC
185   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
186   ${FOLLY_DIR}/Fingerprint.h
187   ${FOLLY_DIR}/detail/SlowFingerprint.h
188   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
189 )
190 apply_folly_compile_options_to_target(folly_fingerprint)
191 target_link_libraries(folly_fingerprint PRIVATE folly_base)
192
193 # We want to generate a single library and target for folly, but we needed a
194 # two-stage compile for the fingerprint tables, so we create a phony source
195 # file that we modify whenever the base libraries change, causing folly to be
196 # re-linked, making things happy.
197 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
198   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
199   DEPENDS folly_base folly_fingerprint
200 )
201 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
202 apply_folly_compile_options_to_target(folly)
203 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
204
205 # Rather than list the dependencies in two places, we apply them directly on
206 # the folly_base target and then copy them over to the folly target.
207 get_target_property(FOLLY_LINK_LIBRARIES folly_base INTERFACE_LINK_LIBRARIES)
208 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
209 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
210
211 install(TARGETS folly
212   EXPORT folly
213   RUNTIME DESTINATION bin
214   LIBRARY DESTINATION lib
215   ARCHIVE DESTINATION lib)
216 auto_install_files(folly ${FOLLY_DIR}
217   ${hfiles}
218   ${FOLLY_DIR}/Fingerprint.h
219   ${FOLLY_DIR}/detail/SlowFingerprint.h
220   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
221 )
222 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
223 install(
224   EXPORT folly
225   DESTINATION share/folly
226   NAMESPACE Folly::
227   FILE folly-targets.cmake
228 )
229
230 # We need a wrapper config file to do the find_package calls to ensure
231 # that all our dependencies are available to link against.
232 file(
233   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
234   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
235 )
236 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
237 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
238
239 option(BUILD_TESTS "If enabled, compile the tests." OFF)
240 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
241 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
242 if (BUILD_TESTS)
243   find_package(GMock MODULE REQUIRED)
244
245   add_library(folly_test_support
246     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
247     ${FOLLY_DIR}/test/DeterministicSchedule.h
248     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
249     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
250     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
251     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
252     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
253     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
254     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
255     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
256     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
257     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
258     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
259     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
260     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
261     ${FOLLY_DIR}/io/async/test/SocketPair.h
262     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
263     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
264     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
265     ${FOLLY_DIR}/io/async/test/TimeUtil.h
266     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
267     ${FOLLY_DIR}/io/async/test/Util.h
268   )
269   target_compile_definitions(folly_test_support
270     PUBLIC
271       ${LIBGMOCK_DEFINES}
272   )
273   target_include_directories(folly_test_support
274     PUBLIC
275       ${LIBGMOCK_INCLUDE_DIR}
276   )
277   target_link_libraries(folly_test_support
278     PUBLIC
279       Boost::thread
280       folly
281       ${LIBGMOCK_LIBRARY}
282   )
283   apply_folly_compile_options_to_target(folly_test_support)
284
285   folly_define_tests(
286     DIRECTORY experimental/test/
287       TEST autotimer_test SOURCES AutoTimerTest.cpp
288       TEST bits_test_2 SOURCES BitsTest.cpp
289       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
290       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
291       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
292       TEST event_count_test SOURCES EventCountTest.cpp
293       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
294       TEST future_dag_test SOURCES FutureDAGTest.cpp
295       TEST json_schema_test SOURCES JSONSchemaTest.cpp
296       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
297       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
298       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
299       # Depends on liburcu
300       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
301       #TEST ref_count_test SOURCES RefCountTest.cpp
302       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
303       TEST test_util_test SOURCES TestUtilTest.cpp
304       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
305
306     DIRECTORY experimental/io/test/
307       # Depends on libaio
308       #TEST async_io_test SOURCES AsyncIOTest.cpp
309       TEST fs_util_test SOURCES FsUtilTest.cpp
310
311     DIRECTORY fibers/test/
312       TEST fibers_test SOURCES FibersTest.cpp
313
314     DIRECTORY futures/test/
315       TEST futures-test
316         HEADERS
317           ThenCompileTest.h
318         SOURCES
319           BarrierTest.cpp
320           CollectTest.cpp
321           ContextTest.cpp
322           CoreTest.cpp
323           EnsureTest.cpp
324           ExecutorTest.cpp
325           FSMTest.cpp
326           FilterTest.cpp
327           # MSVC SFINAE bug
328           #FutureTest.cpp
329           HeaderCompileTest.cpp
330           InterruptTest.cpp
331           MapTest.cpp
332           NonCopyableLambdaTest.cpp
333           PollTest.cpp
334           PromiseTest.cpp
335           ReduceTest.cpp
336           # MSVC SFINAE bug
337           #RetryingTest.cpp
338           SelfDestructTest.cpp
339           SharedPromiseTest.cpp
340           ThenCompileTest.cpp
341           ThenTest.cpp
342           TimekeeperTest.cpp
343           TimesTest.cpp
344           UnwrapTest.cpp
345           ViaTest.cpp
346           WaitTest.cpp
347           WhenTest.cpp
348           WhileDoTest.cpp
349           WillEqualTest.cpp
350           WindowTest.cpp
351
352     DIRECTORY gen/test/
353       # MSVC bug can't resolve initializer_list constructor properly
354       #TEST base_test SOURCES BaseTest.cpp
355       TEST combine_test SOURCES CombineTest.cpp
356       TEST parallel_map_test SOURCES ParallelMapTest.cpp
357       TEST parallel_test SOURCES ParallelTest.cpp
358
359     DIRECTORY io/test/
360       TEST compression_test SOURCES CompressionTest.cpp
361       TEST iobuf_test SOURCES IOBufTest.cpp
362       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
363       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
364       TEST record_io_test SOURCES RecordIOTest.cpp
365       TEST ShutdownSocketSetTest HANGING
366         SOURCES ShutdownSocketSetTest.cpp
367
368     DIRECTORY io/async/test/
369       TEST async_test
370         CONTENT_DIR certs/
371         HEADERS
372           AsyncSocketTest.h
373           AsyncSSLSocketTest.h
374         SOURCES
375           AsyncPipeTest.cpp
376           AsyncSocketExceptionTest.cpp
377           AsyncSocketTest.cpp
378           AsyncSocketTest2.cpp
379           AsyncSSLSocketTest.cpp
380           AsyncSSLSocketTest2.cpp
381           AsyncSSLSocketWriteTest.cpp
382           AsyncTransportTest.cpp
383           # This is disabled because it depends on things that don't exist
384           # on Windows.
385           #EventHandlerTest.cpp
386       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
387       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
388       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
389       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
390       TEST EventBaseTest SOURCES EventBaseTest.cpp
391       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
392       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
393       TEST HHWheelTimerSlowTests SLOW
394         SOURCES HHWheelTimerSlowTests.cpp
395       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
396       TEST RequestContextTest SOURCES RequestContextTest.cpp
397       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
398       TEST ssl_session_test SOURCES SSLSessionTest.cpp
399       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
400
401     DIRECTORY io/async/ssl/test/
402       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
403
404     DIRECTORY portability/test/
405       TEST constexpr_test SOURCES ConstexprTest.cpp
406       TEST libgen-test SOURCES LibgenTest.cpp
407       TEST time-test SOURCES TimeTest.cpp
408
409     DIRECTORY ssl/test/
410       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
411
412     DIRECTORY test/
413       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
414       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
415       TEST arena_test SOURCES ArenaTest.cpp
416       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
417       TEST array_test SOURCES ArrayTest.cpp
418       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
419       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
420       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
421       TEST atomic_hash_map_test HANGING
422         SOURCES AtomicHashMapTest.cpp
423       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
424       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
425       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
426       TEST baton_test SOURCES BatonTest.cpp
427       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
428       TEST bits_test SOURCES BitsTest.cpp
429       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
430       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
431       TEST call_once_test SOURCES CallOnceTest.cpp
432       TEST checksum_test SOURCES ChecksumTest.cpp
433       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
434       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
435       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
436       TEST conv_test SOURCES ConvTest.cpp
437       TEST cpu_id_test SOURCES CpuIdTest.cpp
438       TEST demangle_test SOURCES DemangleTest.cpp
439       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
440       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
441       TEST dynamic_test SOURCES DynamicTest.cpp
442       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
443       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
444       TEST endian_test SOURCES EndianTest.cpp
445       TEST enumerate_test SOURCES EnumerateTest.cpp
446       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
447       TEST exception_test SOURCES ExceptionTest.cpp
448       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
449       TEST expected_test SOURCES ExpectedTest.cpp
450       TEST fbvector_test SOURCES FBVectorTest.cpp
451       TEST file_test SOURCES FileTest.cpp
452       #TEST file_lock_test SOURCES FileLockTest.cpp
453       TEST file_util_test HANGING
454         SOURCES FileUtilTest.cpp
455       TEST fingerprint_test SOURCES FingerprintTest.cpp
456       TEST foreach_test SOURCES ForeachTest.cpp
457       TEST format_other_test SOURCES FormatOtherTest.cpp
458       TEST format_test SOURCES FormatTest.cpp
459       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
460       TEST function_test SOURCES FunctionTest.cpp
461       TEST function_ref_test SOURCES FunctionRefTest.cpp
462       TEST futex_test SOURCES FutexTest.cpp
463       TEST group_varint_test SOURCES GroupVarintTest.cpp
464       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
465       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
466       TEST hash_test SOURCES HashTest.cpp
467       TEST histogram_test SOURCES HistogramTest.cpp
468       TEST indestructible_test SOURCES IndestructibleTest.cpp
469       TEST indexed_mem_pool_test SOURCES IndexedMemPoolTest.cpp
470       # MSVC Preprocessor stringizing raw string literals bug
471       #TEST json_test SOURCES JsonTest.cpp
472       TEST json_other_test
473         CONTENT_DIR json_test_data/
474         SOURCES
475           JsonOtherTest.cpp
476       TEST lazy_test SOURCES LazyTest.cpp
477       TEST lifosem_test SOURCES LifoSemTests.cpp
478       TEST lock_traits_test SOURCES LockTraitsTest.cpp
479       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
480       TEST logging_test SOURCES LoggingTest.cpp
481       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
482       TEST math_test SOURCES MathTest.cpp
483       TEST map_util_test SOURCES MapUtilTest.cpp
484       TEST memcpy_test SOURCES MemcpyTest.cpp
485       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
486       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
487       TEST memory_test SOURCES MemoryTest.cpp
488       TEST merge SOURCES MergeTest.cpp
489       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
490       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
491       TEST mpmc_queue_test SLOW
492         SOURCES MPMCQueueTest.cpp
493       TEST network_address_test HANGING
494         SOURCES
495           IPAddressTest.cpp
496           MacAddressTest.cpp
497           SocketAddressTest.cpp
498       TEST optional_test SOURCES OptionalTest.cpp
499       TEST packed_sync_ptr_test HANGING
500         SOURCES PackedSyncPtrTest.cpp
501       TEST padded_test SOURCES PaddedTest.cpp
502       TEST partial_test SOURCES PartialTest.cpp
503       TEST portability_test SOURCES PortabilityTest.cpp
504       TEST producer_consumer_queue_test SLOW
505         SOURCES ProducerConsumerQueueTest.cpp
506       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
507       TEST random_test SOURCES RandomTest.cpp
508       TEST range_test SOURCES RangeTest.cpp
509       TEST safe_assert_test SOURCES SafeAssertTest.cpp
510       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
511       # Heavily dependent on drand and srand48
512       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
513       TEST shell_test SOURCES ShellTest.cpp
514       TEST singleton_test SOURCES SingletonTest.cpp
515       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
516       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
517       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
518       TEST small_vector_test SOURCES small_vector_test.cpp
519       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
520       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
521       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
522       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
523       TEST string_test SOURCES StringTest.cpp
524       #TEST subprocess_test SOURCES SubprocessTest.cpp
525       TEST synchronized_test SOURCES SynchronizedTest.cpp
526       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
527       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
528       TEST thread_local_test SOURCES ThreadLocalTest.cpp
529       TEST thread_name_test SOURCES ThreadNameTest.cpp
530       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
531       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
532       TEST timeseries_test SOURCES TimeseriesTest.cpp
533       TEST token_bucket_test SOURCES TokenBucketTest.cpp
534       TEST traits_test SOURCES TraitsTest.cpp
535       TEST try_test SOURCES TryTest.cpp
536       TEST unit_test SOURCES UnitTest.cpp
537       TEST uri_test SOURCES UriTest.cpp
538       TEST varint_test SOURCES VarintTest.cpp
539   )
540 endif()