Make folly::getCurrentThreadId() return a thread ID on OSX
[folly.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
2
3 # Unfortunately, CMake doesn't easily provide us a way to merge static
4 # libraries, which is what we want to do to generate the main folly library, so
5 # we do a bit of a workaround here to inject a property into the generated
6 # project files that will only get enabled for the folly target. Ugly, but
7 # the alternatives are far, far worse.
8 if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio 15( 2017)? Win64")
9   set(CMAKE_GENERATOR_TOOLSET "v141</PlatformToolset></PropertyGroup><ItemDefinitionGroup Condition=\"'$(ProjectName)'=='folly'\"><ProjectReference><LinkLibraryDependencies>true</LinkLibraryDependencies></ProjectReference></ItemDefinitionGroup><PropertyGroup><PlatformToolset>v141")
10 elseif ("${CMAKE_GENERATOR}" STREQUAL "Visual Studio 14 2015 Win64")
11   set(CMAKE_GENERATOR_TOOLSET "v140</PlatformToolset></PropertyGroup><ItemDefinitionGroup Condition=\"'$(ProjectName)'=='folly'\"><ProjectReference><LinkLibraryDependencies>true</LinkLibraryDependencies></ProjectReference></ItemDefinitionGroup><PropertyGroup><PlatformToolset>v140")
12 else()
13   message(FATAL_ERROR "This build script only supports building Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
14 endif()
15
16 # includes
17 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
18 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
19
20 # package information
21 set(PACKAGE_NAME      "folly")
22 set(PACKAGE_VERSION   "0.58.0-dev")
23 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
24 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
25 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
26
27 # 150+ tests in the root folder anyone? No? I didn't think so.
28 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
29
30 project(${PACKAGE_NAME} CXX)
31
32 # Check architecture OS
33 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
34   message(FATAL_ERROR "Folly requires a 64bit OS")
35 endif()
36 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
37   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
38 endif()
39
40 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
41
42 # Generate a few tables and create the main config file.
43 find_package(PythonInterp REQUIRED)
44 add_custom_command(
45   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
46   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
47   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
48   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
49   COMMENT "Generating the escape tables..." VERBATIM
50 )
51 add_custom_command(
52   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
53   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
54   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
55   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
56   COMMENT "Generating the format tables..." VERBATIM
57 )
58 add_custom_command(
59   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
60   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
61   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
62   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
63   COMMENT "Generating the group varint tables..." VERBATIM
64 )
65
66 include(folly-deps) # Find the required packages
67 if (LIBPTHREAD_FOUND)
68   set(FOLLY_HAVE_PTHREAD ON)
69 endif()
70 configure_file(
71   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
72   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
73 )
74
75 include(FollyCompiler)
76 include(FollyFunctions)
77
78 # Main folly library files
79 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
80 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
81
82 # No need for tests or benchmarks, and we can't build most experimental stuff.
83 REMOVE_MATCHES_FROM_LISTS(files hfiles
84   MATCHES
85     "/build/"
86     "/experimental/exception_tracer/"
87     "/experimental/hazptr/example/"
88     "/experimental/symbolizer/"
89     "/futures/exercises/"
90     "/test/"
91     "Benchmark.cpp$"
92     "Test.cpp$"
93   IGNORE_MATCHES
94     "/Benchmark.cpp$"
95 )
96 list(REMOVE_ITEM files
97   ${FOLLY_DIR}/Subprocess.cpp
98   ${FOLLY_DIR}/SingletonStackTrace.cpp
99   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
100   ${FOLLY_DIR}/experimental/RCUUtils.cpp
101   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
102   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
103   ${FOLLY_DIR}/futures/test/Benchmark.cpp
104 )
105 list(REMOVE_ITEM hfiles
106   ${FOLLY_DIR}/Fingerprint.h
107   ${FOLLY_DIR}/detail/SlowFingerprint.h
108   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
109   ${FOLLY_DIR}/experimental/RCURefCount.h
110   ${FOLLY_DIR}/experimental/RCUUtils.h
111   ${FOLLY_DIR}/experimental/io/AsyncIO.h
112 )
113
114 add_library(folly_base STATIC
115   ${files} ${hfiles}
116   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
117   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
118   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
119   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
120 )
121 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
122 apply_folly_compile_options_to_target(folly_base)
123 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
124 # Add the generated files to the correct source group.
125 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
126 source_group("folly\\build" FILES
127   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
128   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
129   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
130   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
131 )
132
133 target_include_directories(folly_base
134   PUBLIC
135     ${DOUBLE_CONVERSION_INCLUDE_DIR}
136     ${LIBGFLAGS_INCLUDE_DIR}
137     ${LIBGLOG_INCLUDE_DIR}
138     ${LIBEVENT_INCLUDE_DIR}
139 )
140 target_link_libraries(folly_base
141   PUBLIC
142     Boost::chrono
143     Boost::context
144     Boost::date_time
145     Boost::filesystem
146     Boost::program_options
147     Boost::regex
148     Boost::system
149     ${DOUBLE_CONVERSION_LIBRARY}
150     ${LIBEVENT_LIB}
151     ${LIBGFLAGS_LIBRARY}
152     ${LIBGLOG_LIBRARY}
153     OpenSSL::SSL
154     OpenSSL::Crypto
155     Ws2_32.lib
156 )
157 if (FOLLY_HAVE_PTHREAD)
158   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
159   target_link_libraries(folly_base PUBLIC ${LIBPTHREAD_LIBRARIES})
160 endif()
161
162 # Now to generate the fingerprint tables
163 add_executable(GenerateFingerprintTables
164   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
165 )
166 apply_folly_compile_options_to_target(GenerateFingerprintTables)
167 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
168 target_link_libraries(GenerateFingerprintTables PRIVATE folly_base)
169 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
170
171 # Compile the fingerprint tables.
172 add_custom_command(
173   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
174   COMMAND GenerateFingerprintTables
175   DEPENDS GenerateFingerprintTables
176   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
177   COMMENT "Generating the fingerprint tables..."
178 )
179 add_library(folly_fingerprint STATIC
180   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
181   ${FOLLY_DIR}/Fingerprint.h
182   ${FOLLY_DIR}/detail/SlowFingerprint.h
183   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
184 )
185 apply_folly_compile_options_to_target(folly_fingerprint)
186 target_link_libraries(folly_fingerprint PRIVATE folly_base)
187
188 # We want to generate a single library and target for folly, but we needed a
189 # two-stage compile for the fingerprint tables, so we create a phony source
190 # file that we modify whenever the base libraries change, causing folly to be
191 # re-linked, making things happy.
192 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
193   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
194   DEPENDS folly_base folly_fingerprint
195 )
196 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
197 apply_folly_compile_options_to_target(folly)
198 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
199
200 # Rather than list the dependencies in two places, we apply them directly on
201 # the folly_base target and then copy them over to the folly target.
202 get_target_property(FOLLY_LINK_LIBRARIES folly_base INTERFACE_LINK_LIBRARIES)
203 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
204 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
205
206 install(TARGETS folly
207   EXPORT folly
208   RUNTIME DESTINATION bin
209   LIBRARY DESTINATION lib
210   ARCHIVE DESTINATION lib)
211 auto_install_files(folly ${FOLLY_DIR}
212   ${hfiles}
213   ${FOLLY_DIR}/Fingerprint.h
214   ${FOLLY_DIR}/detail/SlowFingerprint.h
215   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
216 )
217 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
218 install(
219   EXPORT folly
220   DESTINATION share/folly
221   NAMESPACE Folly::
222   FILE folly-targets.cmake
223 )
224
225 # We need a wrapper config file to do the find_package calls to ensure
226 # that all our dependencies are available to link against.
227 file(
228   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
229   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
230 )
231 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
232 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
233
234 option(BUILD_TESTS "If enabled, compile the tests." OFF)
235 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
236 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
237 if (BUILD_TESTS)
238   find_package(GMock MODULE REQUIRED)
239
240   add_library(folly_test_support
241     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
242     ${FOLLY_DIR}/test/DeterministicSchedule.h
243     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
244     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
245     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
246     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
247     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
248     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
249     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
250     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
251     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
252     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
253     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
254     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
255     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
256     ${FOLLY_DIR}/io/async/test/SocketPair.h
257     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
258     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
259     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
260     ${FOLLY_DIR}/io/async/test/TimeUtil.h
261     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
262     ${FOLLY_DIR}/io/async/test/Util.h
263   )
264   target_include_directories(folly_test_support
265     PUBLIC
266       ${LIBGMOCK_INCLUDE_DIR}
267   )
268   target_link_libraries(folly_test_support
269     PUBLIC
270       Boost::thread
271       folly
272       ${LIBGMOCK_LIBRARY}
273   )
274   apply_folly_compile_options_to_target(folly_test_support)
275
276   folly_define_tests(
277     DIRECTORY experimental/test/
278       TEST autotimer_test SOURCES AutoTimerTest.cpp
279       TEST bits_test_2 SOURCES BitsTest.cpp
280       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
281       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
282       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
283       TEST event_count_test SOURCES EventCountTest.cpp
284       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
285       TEST future_dag_test SOURCES FutureDAGTest.cpp
286       TEST json_schema_test SOURCES JSONSchemaTest.cpp
287       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
288       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
289       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
290       # Depends on liburcu
291       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
292       #TEST ref_count_test SOURCES RefCountTest.cpp
293       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
294       TEST test_util_test SOURCES TestUtilTest.cpp
295       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
296
297     DIRECTORY experimental/io/test/
298       # Depends on libaio
299       #TEST async_io_test SOURCES AsyncIOTest.cpp
300       TEST fs_util_test SOURCES FsUtilTest.cpp
301
302     DIRECTORY fibers/test/
303       TEST fibers_test SOURCES FibersTest.cpp
304
305     DIRECTORY futures/test/
306       TEST futures-test
307         HEADERS
308           ThenCompileTest.h
309         SOURCES
310           BarrierTest.cpp
311           CollectTest.cpp
312           ContextTest.cpp
313           CoreTest.cpp
314           EnsureTest.cpp
315           ExecutorTest.cpp
316           FSMTest.cpp
317           FilterTest.cpp
318           # MSVC SFINAE bug
319           #FutureTest.cpp
320           HeaderCompileTest.cpp
321           InterruptTest.cpp
322           MapTest.cpp
323           NonCopyableLambdaTest.cpp
324           PollTest.cpp
325           PromiseTest.cpp
326           ReduceTest.cpp
327           # MSVC SFINAE bug
328           #RetryingTest.cpp
329           SelfDestructTest.cpp
330           SharedPromiseTest.cpp
331           ThenCompileTest.cpp
332           ThenTest.cpp
333           TimekeeperTest.cpp
334           TimesTest.cpp
335           UnwrapTest.cpp
336           ViaTest.cpp
337           WaitTest.cpp
338           WhenTest.cpp
339           WhileDoTest.cpp
340           WillEqualTest.cpp
341           WindowTest.cpp
342
343     DIRECTORY gen/test/
344       # MSVC bug can't resolve initializer_list constructor properly
345       #TEST base_test SOURCES BaseTest.cpp
346       TEST combine_test SOURCES CombineTest.cpp
347       TEST parallel_map_test SOURCES ParallelMapTest.cpp
348       TEST parallel_test SOURCES ParallelTest.cpp
349
350     DIRECTORY io/test/
351       TEST compression_test SOURCES CompressionTest.cpp
352       TEST iobuf_test SOURCES IOBufTest.cpp
353       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
354       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
355       TEST record_io_test SOURCES RecordIOTest.cpp
356       TEST ShutdownSocketSetTest HANGING
357         SOURCES ShutdownSocketSetTest.cpp
358
359     DIRECTORY io/async/test/
360       TEST async_test
361         CONTENT_DIR certs/
362         HEADERS
363           AsyncSocketTest.h
364           AsyncSSLSocketTest.h
365         SOURCES
366           AsyncPipeTest.cpp
367           AsyncSocketExceptionTest.cpp
368           AsyncSocketTest.cpp
369           AsyncSocketTest2.cpp
370           AsyncSSLSocketTest.cpp
371           AsyncSSLSocketTest2.cpp
372           AsyncSSLSocketWriteTest.cpp
373           AsyncTransportTest.cpp
374           # This is disabled because it depends on things that don't exist
375           # on Windows.
376           #EventHandlerTest.cpp
377       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
378       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
379       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
380       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
381       TEST EventBaseTest SOURCES EventBaseTest.cpp
382       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
383       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
384       TEST HHWheelTimerSlowTests SLOW
385         SOURCES HHWheelTimerSlowTests.cpp
386       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
387       TEST RequestContextTest SOURCES RequestContextTest.cpp
388       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
389       TEST ssl_session_test SOURCES SSLSessionTest.cpp
390       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
391
392     DIRECTORY io/async/ssl/test/
393       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
394
395     DIRECTORY portability/test/
396       TEST constexpr_test SOURCES ConstexprTest.cpp
397       TEST libgen-test SOURCES LibgenTest.cpp
398       TEST time-test SOURCES TimeTest.cpp
399
400     DIRECTORY ssl/test/
401       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
402
403     DIRECTORY test/
404       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
405       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
406       TEST arena_test SOURCES ArenaTest.cpp
407       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
408       TEST array_test SOURCES ArrayTest.cpp
409       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
410       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
411       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
412       TEST atomic_hash_map_test HANGING
413         SOURCES AtomicHashMapTest.cpp
414       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
415       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
416       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
417       TEST baton_test SOURCES BatonTest.cpp
418       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
419       TEST bits_test SOURCES BitsTest.cpp
420       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
421       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
422       TEST call_once_test SOURCES CallOnceTest.cpp
423       TEST checksum_test SOURCES ChecksumTest.cpp
424       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
425       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
426       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
427       TEST conv_test SOURCES ConvTest.cpp
428       TEST cpu_id_test SOURCES CpuIdTest.cpp
429       TEST demangle_test SOURCES DemangleTest.cpp
430       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
431       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
432       TEST dynamic_test SOURCES DynamicTest.cpp
433       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
434       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
435       TEST endian_test SOURCES EndianTest.cpp
436       TEST enumerate_test SOURCES EnumerateTest.cpp
437       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
438       TEST exception_test SOURCES ExceptionTest.cpp
439       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
440       TEST expected_test SOURCES ExpectedTest.cpp
441       TEST fbvector_test SOURCES FBVectorTest.cpp
442       TEST file_test SOURCES FileTest.cpp
443       #TEST file_lock_test SOURCES FileLockTest.cpp
444       TEST file_util_test HANGING
445         SOURCES FileUtilTest.cpp
446       TEST fingerprint_test SOURCES FingerprintTest.cpp
447       TEST foreach_test SOURCES ForeachTest.cpp
448       TEST format_other_test SOURCES FormatOtherTest.cpp
449       TEST format_test SOURCES FormatTest.cpp
450       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
451       TEST function_test SOURCES FunctionTest.cpp
452       TEST function_ref_test SOURCES FunctionRefTest.cpp
453       TEST futex_test SOURCES FutexTest.cpp
454       TEST group_varint_test SOURCES GroupVarintTest.cpp
455       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
456       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
457       TEST hash_test SOURCES HashTest.cpp
458       TEST histogram_test SOURCES HistogramTest.cpp
459       TEST indestructible_test SOURCES IndestructibleTest.cpp
460       TEST indexed_mem_pool_test SOURCES IndexedMemPoolTest.cpp
461       # MSVC Preprocessor stringizing raw string literals bug
462       #TEST json_test SOURCES JsonTest.cpp
463       TEST json_other_test
464         CONTENT_DIR json_test_data/
465         SOURCES
466           JsonOtherTest.cpp
467       TEST lazy_test SOURCES LazyTest.cpp
468       TEST lifosem_test SOURCES LifoSemTests.cpp
469       TEST lock_traits_test SOURCES LockTraitsTest.cpp
470       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
471       TEST logging_test SOURCES LoggingTest.cpp
472       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
473       TEST math_test SOURCES MathTest.cpp
474       TEST map_util_test SOURCES MapUtilTest.cpp
475       TEST memcpy_test SOURCES MemcpyTest.cpp
476       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
477       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
478       TEST memory_test SOURCES MemoryTest.cpp
479       TEST merge SOURCES MergeTest.cpp
480       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
481       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
482       TEST mpmc_queue_test SLOW
483         SOURCES MPMCQueueTest.cpp
484       TEST network_address_test HANGING
485         SOURCES
486           IPAddressTest.cpp
487           MacAddressTest.cpp
488           SocketAddressTest.cpp
489       TEST optional_test SOURCES OptionalTest.cpp
490       TEST packed_sync_ptr_test HANGING
491         SOURCES PackedSyncPtrTest.cpp
492       TEST padded_test SOURCES PaddedTest.cpp
493       TEST partial_test SOURCES PartialTest.cpp
494       TEST portability_test SOURCES PortabilityTest.cpp
495       TEST producer_consumer_queue_test SLOW
496         SOURCES ProducerConsumerQueueTest.cpp
497       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
498       TEST random_test SOURCES RandomTest.cpp
499       TEST range_test SOURCES RangeTest.cpp
500       TEST safe_assert_test SOURCES SafeAssertTest.cpp
501       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
502       # Heavily dependent on drand and srand48
503       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
504       TEST shell_test SOURCES ShellTest.cpp
505       TEST singleton_test SOURCES SingletonTest.cpp
506       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
507       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
508       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
509       TEST small_vector_test SOURCES small_vector_test.cpp
510       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
511       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
512       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
513       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
514       TEST string_test SOURCES StringTest.cpp
515       #TEST subprocess_test SOURCES SubprocessTest.cpp
516       TEST synchronized_test SOURCES SynchronizedTest.cpp
517       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
518       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
519       TEST thread_local_test SOURCES ThreadLocalTest.cpp
520       TEST thread_name_test SOURCES ThreadNameTest.cpp
521       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
522       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
523       TEST timeseries_test SOURCES TimeseriesTest.cpp
524       TEST token_bucket_test SOURCES TokenBucketTest.cpp
525       TEST traits_test SOURCES TraitsTest.cpp
526       TEST try_test SOURCES TryTest.cpp
527       TEST unit_test SOURCES UnitTest.cpp
528       TEST uri_test SOURCES UriTest.cpp
529       TEST varint_test SOURCES VarintTest.cpp
530   )
531 endif()