CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
   2
   3 # includes
   4 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake" ${CMAKE_MODULE_PATH})
   5 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   6
   7 # package information
   8 set(PACKAGE_NAME      "folly")
   9 set(PACKAGE_VERSION   "0.58.0-dev")
  10 set(PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  11 set(PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  12 set(PACKAGE_BUGREPORT "https://github.com/facebook/folly/issues")
  13
  14 # 150+ tests in the root folder anyone? No? I didn't think so.
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 project(${PACKAGE_NAME} CXX)
  18
  19 if (MSVC_VERSION EQUAL 1910 OR MSVC_VERSION EQUAL 1911)
  20   set(MSVC_IS_2017 ON)
  21 elseif (MSVC_VERSION EQUAL 1900)
  22   set(MSVC_IS_2017 OFF)
  23 else()
  24   message(FATAL_ERROR "This build script only supports building '${MSVC_VERSION}' Folly on 64-bit Windows with Visual Studio 2015 or Visual Studio 2017.")
  25 endif()
  26
  27 # Check architecture OS
  28 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
  29   message(FATAL_ERROR "Folly requires a 64bit OS")
  30 endif()
  31 if(NOT "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  32   message(FATAL_ERROR "You should only be using CMake to build Folly if you are on Windows!")
  33 endif()
  34
  35 set(FOLLY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/folly")
  36
  37 # Generate a few tables and create the main config file.
  38 find_package(PythonInterp REQUIRED)
  39 add_custom_command(
  40   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
  41   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_escape_tables.py"
  42   DEPENDS ${FOLLY_DIR}/build/generate_escape_tables.py
  43   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  44   COMMENT "Generating the escape tables..." VERBATIM
  45 )
  46 add_custom_command(
  47   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
  48   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_format_tables.py"
  49   DEPENDS ${FOLLY_DIR}/build/generate_format_tables.py
  50   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  51   COMMENT "Generating the format tables..." VERBATIM
  52 )
  53 add_custom_command(
  54   OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp"
  55   COMMAND ${PYTHON_EXECUTABLE} "${FOLLY_DIR}/build/generate_varint_tables.py"
  56   DEPENDS ${FOLLY_DIR}/build/generate_varint_tables.py
  57   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
  58   COMMENT "Generating the group varint tables..." VERBATIM
  59 )
  60
  61 include(folly-deps) # Find the required packages
  62 if (LIBPTHREAD_FOUND)
  63   set(FOLLY_HAVE_PTHREAD ON)
  64 endif()
  65 configure_file(
  66   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-config.h.cmake
  67   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
  68 )
  69
  70 include(FollyCompiler)
  71 include(FollyFunctions)
  72
  73 # Main folly library files
  74 auto_sources(files "*.cpp" "RECURSE" "${FOLLY_DIR}")
  75 auto_sources(hfiles "*.h" "RECURSE" "${FOLLY_DIR}")
  76
  77 # No need for tests or benchmarks, and we can't build most experimental stuff.
  78 REMOVE_MATCHES_FROM_LISTS(files hfiles
  79   MATCHES
  80     "/build/"
  81     "/experimental/exception_tracer/"
  82     "/experimental/hazptr/bench/"
  83     "/experimental/hazptr/example/"
  84     "/experimental/logging/example/"
  85     "/experimental/symbolizer/"
  86     "/futures/exercises/"
  87     "/test/"
  88     "Benchmark.cpp$"
  89     "Test.cpp$"
  90   IGNORE_MATCHES
  91     "/Benchmark.cpp$"
  92 )
  93 list(REMOVE_ITEM files
  94   ${FOLLY_DIR}/Subprocess.cpp
  95   ${FOLLY_DIR}/SingletonStackTrace.cpp
  96   ${FOLLY_DIR}/experimental/JSONSchemaTester.cpp
  97   ${FOLLY_DIR}/experimental/RCUUtils.cpp
  98   ${FOLLY_DIR}/experimental/io/AsyncIO.cpp
  99   ${FOLLY_DIR}/experimental/io/HugePageUtil.cpp
 100   ${FOLLY_DIR}/futures/test/Benchmark.cpp
 101 )
 102 list(REMOVE_ITEM hfiles
 103   ${FOLLY_DIR}/Fingerprint.h
 104   ${FOLLY_DIR}/detail/SlowFingerprint.h
 105   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 106   ${FOLLY_DIR}/experimental/RCURefCount.h
 107   ${FOLLY_DIR}/experimental/RCUUtils.h
 108   ${FOLLY_DIR}/experimental/io/AsyncIO.h
 109 )
 110
 111 add_library(folly_base OBJECT
 112   ${files} ${hfiles}
 113   ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h
 114   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 115   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 116   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 117 )
 118 auto_source_group(folly ${FOLLY_DIR} ${files} ${hfiles})
 119 apply_folly_compile_options_to_target(folly_base)
 120 target_include_directories(folly_base PUBLIC ${CMAKE_CURRENT_BINARY_DIR})
 121 # Add the generated files to the correct source group.
 122 source_group("folly" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h)
 123 source_group("folly\\build" FILES
 124   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/EscapeTables.cpp
 125   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 126   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FormatTables.cpp
 127   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/GroupVarintTables.cpp
 128 )
 129
 130 set(FOLLY_SHINY_DEPENDENCIES
 131   Boost::chrono
 132   Boost::context
 133   Boost::date_time
 134   Boost::filesystem
 135   Boost::program_options
 136   Boost::regex
 137   Boost::system
 138   OpenSSL::SSL
 139   OpenSSL::Crypto
 140 )
 141
 142 set(FOLLY_LINK_LIBRARIES
 143   ${DOUBLE_CONVERSION_LIBRARY}
 144   ${LIBEVENT_LIB}
 145   ${LIBGFLAGS_LIBRARY}
 146   ${LIBGLOG_LIBRARY}
 147   Ws2_32.lib
 148
 149   ${FOLLY_SHINY_DEPENDENCIES}
 150 )
 151
 152 target_include_directories(folly_base
 153   PUBLIC
 154     ${DOUBLE_CONVERSION_INCLUDE_DIR}
 155     ${LIBGFLAGS_INCLUDE_DIR}
 156     ${LIBGLOG_INCLUDE_DIR}
 157     ${LIBEVENT_INCLUDE_DIR}
 158     $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
 159 )
 160
 161 foreach (LIB ${FOLLY_SHINY_DEPENDENCIES})
 162   target_include_directories(folly_base PUBLIC $<TARGET_PROPERTY:${LIB},INCLUDE_DIRECTORIES>)
 163 endforeach()
 164
 165 if (FOLLY_HAVE_PTHREAD)
 166   target_include_directories(folly_base PUBLIC ${LIBPTHREAD_INCLUDE_DIRS})
 167   list(APPEND FOLLY_LINK_LIBRARIES ${LIBPTHREAD_LIBRARIES})
 168 endif()
 169
 170 # Now to generate the fingerprint tables
 171 add_executable(GenerateFingerprintTables
 172   ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp
 173   $<TARGET_OBJECTS:folly_base>
 174 )
 175 target_link_libraries(GenerateFingerprintTables PRIVATE ${FOLLY_LINK_LIBRARIES})
 176 target_include_directories(GenerateFingerprintTables PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 177 add_dependencies(GenerateFingerprintTables folly_base)
 178 apply_folly_compile_options_to_target(GenerateFingerprintTables)
 179 set_property(TARGET GenerateFingerprintTables PROPERTY FOLDER "Build")
 180 source_group("" FILES ${FOLLY_DIR}/build/GenerateFingerprintTables.cpp)
 181
 182 # Compile the fingerprint tables.
 183 add_custom_command(
 184   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 185   COMMAND GenerateFingerprintTables
 186   DEPENDS GenerateFingerprintTables
 187   WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/folly/build/
 188   COMMENT "Generating the fingerprint tables..."
 189 )
 190 add_library(folly_fingerprint STATIC
 191   ${CMAKE_CURRENT_BINARY_DIR}/folly/build/FingerprintTables.cpp
 192   ${FOLLY_DIR}/Fingerprint.h
 193   ${FOLLY_DIR}/detail/SlowFingerprint.h
 194   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 195   $<TARGET_OBJECTS:folly_base>
 196 )
 197 target_link_libraries(folly_fingerprint PRIVATE ${FOLLY_LINK_LIBRARIES})
 198 target_include_directories(folly_fingerprint PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 199 add_dependencies(folly_fingerprint folly_base)
 200 apply_folly_compile_options_to_target(folly_fingerprint)
 201
 202 # We want to generate a single library and target for folly, but we needed a
 203 # two-stage compile for the fingerprint tables, so we create a phony source
 204 # file that we modify whenever the base libraries change, causing folly to be
 205 # re-linked, making things happy.
 206 add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 207   COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp
 208   DEPENDS folly_base folly_fingerprint
 209 )
 210 add_library(folly ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp $<TARGET_OBJECTS:folly_base>)
 211 apply_folly_compile_options_to_target(folly)
 212 source_group("" FILES ${CMAKE_CURRENT_BINARY_DIR}/folly_dep.cpp)
 213
 214 target_link_libraries(folly PUBLIC ${FOLLY_LINK_LIBRARIES})
 215 target_include_directories(folly PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
 216
 217 install(TARGETS folly
 218   EXPORT folly
 219   RUNTIME DESTINATION bin
 220   LIBRARY DESTINATION lib
 221   ARCHIVE DESTINATION lib)
 222 auto_install_files(folly ${FOLLY_DIR}
 223   ${hfiles}
 224   ${FOLLY_DIR}/Fingerprint.h
 225   ${FOLLY_DIR}/detail/SlowFingerprint.h
 226   ${FOLLY_DIR}/detail/FingerprintPolynomial.h
 227 )
 228 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly/folly-config.h DESTINATION include/folly)
 229 install(
 230   EXPORT folly
 231   DESTINATION share/folly
 232   NAMESPACE Folly::
 233   FILE folly-targets.cmake
 234 )
 235
 236 # We need a wrapper config file to do the find_package calls to ensure
 237 # that all our dependencies are available to link against.
 238 file(
 239   COPY ${CMAKE_CURRENT_SOURCE_DIR}/CMake/folly-deps.cmake
 240   DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
 241 )
 242 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake "\ninclude(folly-targets.cmake)\n")
 243 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/folly-deps.cmake DESTINATION share/folly RENAME folly-config.cmake)
 244
 245 option(BUILD_TESTS "If enabled, compile the tests." OFF)
 246 option(BUILD_HANGING_TESTS "If enabled, compile tests that are known to hang." OFF)
 247 option(BUILD_SLOW_TESTS "If enabled, compile tests that take a while to run in debug mode." OFF)
 248 if (BUILD_TESTS)
 249   find_package(GMock MODULE REQUIRED)
 250
 251   add_library(folly_test_support
 252     ${FOLLY_DIR}/test/DeterministicSchedule.cpp
 253     ${FOLLY_DIR}/test/DeterministicSchedule.h
 254     ${FOLLY_DIR}/test/SingletonTestStructs.cpp
 255     ${FOLLY_DIR}/test/SocketAddressTestHelper.cpp
 256     ${FOLLY_DIR}/test/SocketAddressTestHelper.h
 257     ${FOLLY_DIR}/experimental/logging/test/TestLogHandler.h
 258     ${FOLLY_DIR}/futures/test/TestExecutor.cpp
 259     ${FOLLY_DIR}/futures/test/TestExecutor.h
 260     ${FOLLY_DIR}/io/async/test/BlockingSocket.h
 261     ${FOLLY_DIR}/io/async/test/MockAsyncServerSocket.h
 262     ${FOLLY_DIR}/io/async/test/MockAsyncSocket.h
 263     ${FOLLY_DIR}/io/async/test/MockAsyncSSLSocket.h
 264     ${FOLLY_DIR}/io/async/test/MockAsyncTransport.h
 265     ${FOLLY_DIR}/io/async/test/MockAsyncUDPSocket.h
 266     ${FOLLY_DIR}/io/async/test/MockTimeoutManager.h
 267     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.cpp
 268     ${FOLLY_DIR}/io/async/test/ScopedBoundPort.h
 269     ${FOLLY_DIR}/io/async/test/SocketPair.cpp
 270     ${FOLLY_DIR}/io/async/test/SocketPair.h
 271     ${FOLLY_DIR}/io/async/test/TestSSLServer.cpp
 272     ${FOLLY_DIR}/io/async/test/TestSSLServer.h
 273     ${FOLLY_DIR}/io/async/test/TimeUtil.cpp
 274     ${FOLLY_DIR}/io/async/test/TimeUtil.h
 275     ${FOLLY_DIR}/io/async/test/UndelayedDestruction.h
 276     ${FOLLY_DIR}/io/async/test/Util.h
 277   )
 278   target_compile_definitions(folly_test_support
 279     PUBLIC
 280       ${LIBGMOCK_DEFINES}
 281   )
 282   target_include_directories(folly_test_support
 283     PUBLIC
 284       ${LIBGMOCK_INCLUDE_DIR}
 285   )
 286   target_link_libraries(folly_test_support
 287     PUBLIC
 288       Boost::thread
 289       folly
 290       ${LIBGMOCK_LIBRARY}
 291   )
 292   apply_folly_compile_options_to_target(folly_test_support)
 293
 294   folly_define_tests(
 295     DIRECTORY experimental/test/
 296       TEST autotimer_test SOURCES AutoTimerTest.cpp
 297       TEST bits_test_2 SOURCES BitsTest.cpp
 298       TEST bitvector_test SOURCES BitVectorCodingTest.cpp
 299       TEST dynamic_parser_test SOURCES DynamicParserTest.cpp
 300       TEST eliasfano_test SOURCES EliasFanoCodingTest.cpp
 301       TEST event_count_test SOURCES EventCountTest.cpp
 302       TEST function_scheduler_test_2 SOURCES FunctionSchedulerTest.cpp
 303       TEST future_dag_test SOURCES FutureDAGTest.cpp
 304       TEST json_schema_test SOURCES JSONSchemaTest.cpp
 305       TEST lock_free_ring_buffer_test SOURCES LockFreeRingBufferTest.cpp
 306       #TEST nested_command_line_app_test SOURCES NestedCommandLineAppTest.cpp
 307       #TEST program_options_test SOURCES ProgramOptionsTest.cpp
 308       # Depends on liburcu
 309       #TEST read_mostly_shared_ptr_test SOURCES ReadMostlySharedPtrTest.cpp
 310       #TEST ref_count_test SOURCES RefCountTest.cpp
 311       TEST stringkeyed_test SOURCES StringKeyedTest.cpp
 312       TEST test_util_test SOURCES TestUtilTest.cpp
 313       TEST tuple_ops_test SOURCES TupleOpsTest.cpp
 314
 315     DIRECTORY experimental/io/test/
 316       # Depends on libaio
 317       #TEST async_io_test SOURCES AsyncIOTest.cpp
 318       TEST fs_util_test SOURCES FsUtilTest.cpp
 319
 320     DIRECTORY experimental/logging/test/
 321       TEST async_file_writer_test SOURCES AsyncFileWriterTest.cpp
 322       TEST glog_formatter_test SOURCES GlogFormatterTest.cpp
 323       TEST immediate_file_writer_test SOURCES ImmediateFileWriterTest.cpp
 324       TEST log_category_test SOURCES LogCategoryTest.cpp
 325       TEST logger_db_test SOURCES LoggerDBTest.cpp
 326       TEST logger_test SOURCES LoggerTest.cpp
 327       TEST log_level_test SOURCES LogLevelTest.cpp
 328       TEST log_message_test SOURCES LogMessageTest.cpp
 329       TEST log_name_test SOURCES LogNameTest.cpp
 330       TEST log_stream_test SOURCES LogStreamTest.cpp
 331       TEST printf_test SOURCES PrintfTest.cpp
 332       TEST rate_limiter_test SOURCES RateLimiterTest.cpp
 333       TEST standard_log_handler_test SOURCES StandardLogHandlerTest.cpp
 334       TEST xlog_test
 335         HEADERS
 336           XlogHeader1.h
 337           XlogHeader2.h
 338         SOURCES
 339           XlogFile1.cpp
 340           XlogFile2.cpp
 341           XlogTest.cpp
 342
 343     DIRECTORY fibers/test/
 344       TEST fibers_test SOURCES FibersTest.cpp
 345
 346     DIRECTORY futures/test/
 347       TEST barrier_test SOURCES BarrierTest.cpp
 348       TEST collect_test SOURCES CollectTest.cpp
 349       TEST context_test SOURCES ContextTest.cpp
 350       TEST core_test SOURCES CoreTest.cpp
 351       TEST ensure_test SOURCES EnsureTest.cpp
 352       TEST executor_test SOURCES ExecutorTest.cpp
 353       TEST fsm_test SOURCES FSMTest.cpp
 354       TEST filter_test SOURCES FilterTest.cpp
 355       TEST future_splitter_test SOURCES FutureSplitterTest.cpp
 356       # MSVC SFINAE bug
 357       #TEST future_test SOURCES FutureTest.cpp
 358       TEST header_compile_test SOURCES HeaderCompileTest.cpp
 359       TEST interrupt_test SOURCES InterruptTest.cpp
 360       TEST map_test SOURCES MapTest.cpp
 361       TEST non_copyable_lambda_test SOURCES NonCopyableLambdaTest.cpp
 362       TEST poll_test SOURCES PollTest.cpp
 363       TEST promise_test SOURCES PromiseTest.cpp
 364       TEST reduce_test SOURCES ReduceTest.cpp
 365       # MSVC SFINAE bug
 366       #TEST retrying_test SOURCES RetryingTest.cpp
 367       TEST self_destruct_test SOURCES SelfDestructTest.cpp
 368       TEST shared_promise_test SOURCES SharedPromiseTest.cpp
 369       TEST test_executor_test SOURCES TestExecutorTest.cpp
 370       TEST then_compile_test
 371         HEADERS
 372           ThenCompileTest.h
 373         SOURCES
 374           ThenCompileTest.cpp
 375       TEST then_test SOURCES ThenTest.cpp
 376       TEST timekeeper_test SOURCES TimekeeperTest.cpp
 377       TEST times_test SOURCES TimesTest.cpp
 378       TEST unwrap_test SOURCES UnwrapTest.cpp
 379       TEST via_test SOURCES ViaTest.cpp
 380       TEST wait_test SOURCES WaitTest.cpp
 381       TEST when_test SOURCES WhenTest.cpp
 382       TEST while_do_test SOURCES WhileDoTest.cpp
 383       TEST will_equal_test SOURCES WillEqualTest.cpp
 384       TEST window_test SOURCES WindowTest.cpp
 385
 386     DIRECTORY gen/test/
 387       # MSVC bug can't resolve initializer_list constructor properly
 388       #TEST base_test SOURCES BaseTest.cpp
 389       TEST combine_test SOURCES CombineTest.cpp
 390       TEST parallel_map_test SOURCES ParallelMapTest.cpp
 391       TEST parallel_test SOURCES ParallelTest.cpp
 392
 393     DIRECTORY io/test/
 394       TEST compression_test SOURCES CompressionTest.cpp
 395       TEST iobuf_test SOURCES IOBufTest.cpp
 396       TEST iobuf_cursor_test SOURCES IOBufCursorTest.cpp
 397       TEST iobuf_queue_test SOURCES IOBufQueueTest.cpp
 398       TEST record_io_test SOURCES RecordIOTest.cpp
 399       TEST ShutdownSocketSetTest HANGING
 400         SOURCES ShutdownSocketSetTest.cpp
 401
 402     DIRECTORY io/async/test/
 403       TEST async_test
 404         CONTENT_DIR certs/
 405         HEADERS
 406           AsyncSocketTest.h
 407           AsyncSSLSocketTest.h
 408         SOURCES
 409           AsyncPipeTest.cpp
 410           AsyncSocketExceptionTest.cpp
 411           AsyncSocketTest.cpp
 412           AsyncSocketTest2.cpp
 413           AsyncSSLSocketTest.cpp
 414           AsyncSSLSocketTest2.cpp
 415           AsyncSSLSocketWriteTest.cpp
 416           AsyncTransportTest.cpp
 417           # This is disabled because it depends on things that don't exist
 418           # on Windows.
 419           #EventHandlerTest.cpp
 420       TEST async_timeout_test SOURCES AsyncTimeoutTest.cpp
 421       TEST AsyncUDPSocketTest SOURCES AsyncUDPSocketTest.cpp
 422       TEST DelayedDestructionTest SOURCES DelayedDestructionTest.cpp
 423       TEST DelayedDestructionBaseTest SOURCES DelayedDestructionBaseTest.cpp
 424       TEST DestructorCheckTest SOURCES DestructorCheckTest.cpp
 425       TEST EventBaseTest SOURCES EventBaseTest.cpp
 426       TEST EventBaseLocalTest SOURCES EventBaseLocalTest.cpp
 427       TEST HHWheelTimerTest SOURCES HHWheelTimerTest.cpp
 428       TEST HHWheelTimerSlowTests SLOW
 429         SOURCES HHWheelTimerSlowTests.cpp
 430       TEST NotificationQueueTest SOURCES NotificationQueueTest.cpp
 431       TEST RequestContextTest SOURCES RequestContextTest.cpp
 432       TEST ScopedEventBaseThreadTest SOURCES ScopedEventBaseThreadTest.cpp
 433       TEST ssl_session_test SOURCES SSLSessionTest.cpp
 434       TEST writechain_test SOURCES WriteChainAsyncTransportWrapperTest.cpp
 435
 436     DIRECTORY io/async/ssl/test/
 437       TEST ssl_errors_test SOURCES SSLErrorsTest.cpp
 438
 439     DIRECTORY portability/test/
 440       TEST constexpr_test SOURCES ConstexprTest.cpp
 441       TEST libgen-test SOURCES LibgenTest.cpp
 442       TEST time-test SOURCES TimeTest.cpp
 443
 444     DIRECTORY ssl/test/
 445       TEST openssl_hash_test SOURCES OpenSSLHashTest.cpp
 446
 447     DIRECTORY stats/test/
 448       TEST histogram_test SOURCES HistogramTest.cpp
 449       TEST timeseries_histogram_test SOURCES TimeseriesHistogramTest.cpp
 450       TEST timeseries_test SOURCES TimeseriesTest.cpp
 451
 452     DIRECTORY test/
 453       TEST ahm_int_stress_test SOURCES AHMIntStressTest.cpp
 454       TEST apply_tuple_test SOURCES ApplyTupleTest.cpp
 455       TEST arena_test SOURCES ArenaTest.cpp
 456       TEST arena_smartptr_test SOURCES ArenaSmartPtrTest.cpp
 457       TEST array_test SOURCES ArrayTest.cpp
 458       TEST ascii_check_test SOURCES AsciiCaseInsensitiveTest.cpp
 459       TEST atomic_bit_set_test SOURCES AtomicBitSetTest.cpp
 460       TEST atomic_hash_array_test SOURCES AtomicHashArrayTest.cpp
 461       TEST atomic_hash_map_test HANGING
 462         SOURCES AtomicHashMapTest.cpp
 463       TEST atomic_linked_list_test SOURCES AtomicLinkedListTest.cpp
 464       TEST atomic_struct_test SOURCES AtomicStructTest.cpp
 465       TEST atomic_unordered_map_test SOURCES AtomicUnorderedMapTest.cpp
 466       TEST baton_test SOURCES BatonTest.cpp
 467       TEST bit_iterator_test SOURCES BitIteratorTest.cpp
 468       TEST bits_test SOURCES BitsTest.cpp
 469       TEST cache_locality_test SOURCES CacheLocalityTest.cpp
 470       TEST cacheline_padded_test SOURCES CachelinePaddedTest.cpp
 471       TEST call_once_test SOURCES CallOnceTest.cpp
 472       TEST checksum_test SOURCES ChecksumTest.cpp
 473       TEST clock_gettime_wrappers_test SOURCES ClockGettimeWrappersTest.cpp
 474       TEST concurrent_skip_list_test SOURCES ConcurrentSkipListTest.cpp
 475       TEST container_traits_test SOURCES ContainerTraitsTest.cpp
 476       TEST conv_test SOURCES ConvTest.cpp
 477       TEST cpu_id_test SOURCES CpuIdTest.cpp
 478       TEST demangle_test SOURCES DemangleTest.cpp
 479       TEST deterministic_schedule_test SOURCES DeterministicScheduleTest.cpp
 480       TEST discriminated_ptr_test SOURCES DiscriminatedPtrTest.cpp
 481       TEST dynamic_test SOURCES DynamicTest.cpp
 482       TEST dynamic_converter_test SOURCES DynamicConverterTest.cpp
 483       TEST dynamic_other_test SOURCES DynamicOtherTest.cpp
 484       TEST endian_test SOURCES EndianTest.cpp
 485       TEST enumerate_test SOURCES EnumerateTest.cpp
 486       TEST evicting_cache_map_test SOURCES EvictingCacheMapTest.cpp
 487       TEST exception_test SOURCES ExceptionTest.cpp
 488       TEST exception_wrapper_test SOURCES ExceptionWrapperTest.cpp
 489       TEST expected_test SOURCES ExpectedTest.cpp
 490       TEST fbvector_test SOURCES FBVectorTest.cpp
 491       TEST file_test SOURCES FileTest.cpp
 492       #TEST file_lock_test SOURCES FileLockTest.cpp
 493       TEST file_util_test HANGING
 494         SOURCES FileUtilTest.cpp
 495       TEST fingerprint_test SOURCES FingerprintTest.cpp
 496       TEST foreach_test SOURCES ForeachTest.cpp
 497       TEST format_other_test SOURCES FormatOtherTest.cpp
 498       TEST format_test SOURCES FormatTest.cpp
 499       TEST function_scheduler_test SOURCES FunctionSchedulerTest.cpp
 500       TEST function_test SOURCES FunctionTest.cpp
 501       TEST function_ref_test SOURCES FunctionRefTest.cpp
 502       TEST futex_test SOURCES FutexTest.cpp
 503       TEST group_varint_test SOURCES GroupVarintTest.cpp
 504       TEST group_varint_test_ssse3 SOURCES GroupVarintTest.cpp
 505       TEST has_member_fn_traits_test SOURCES HasMemberFnTraitsTest.cpp
 506       TEST hash_test SOURCES HashTest.cpp
 507       TEST indestructible_test SOURCES IndestructibleTest.cpp
 508       TEST indexed_mem_pool_test SOURCES IndexedMemPoolTest.cpp
 509       # MSVC Preprocessor stringizing raw string literals bug
 510       #TEST json_test SOURCES JsonTest.cpp
 511       TEST json_other_test
 512         CONTENT_DIR json_test_data/
 513         SOURCES
 514           JsonOtherTest.cpp
 515       TEST lazy_test SOURCES LazyTest.cpp
 516       TEST lifosem_test SOURCES LifoSemTests.cpp
 517       TEST lock_traits_test SOURCES LockTraitsTest.cpp
 518       TEST locks_test SOURCES SmallLocksTest.cpp SpinLockTest.cpp
 519       TEST logging_test SOURCES LoggingTest.cpp
 520       TEST mallctl_helper_test SOURCES MallctlHelperTest.cpp
 521       TEST math_test SOURCES MathTest.cpp
 522       TEST map_util_test SOURCES MapUtilTest.cpp
 523       TEST memcpy_test SOURCES MemcpyTest.cpp
 524       TEST memory_idler_test SOURCES MemoryIdlerTest.cpp
 525       TEST memory_mapping_test SOURCES MemoryMappingTest.cpp
 526       TEST memory_test SOURCES MemoryTest.cpp
 527       TEST merge SOURCES MergeTest.cpp
 528       TEST move_wrapper_test SOURCES MoveWrapperTest.cpp
 529       TEST mpmc_pipeline_test SOURCES MPMCPipelineTest.cpp
 530       TEST mpmc_queue_test SLOW
 531         SOURCES MPMCQueueTest.cpp
 532       TEST network_address_test HANGING
 533         SOURCES
 534           IPAddressTest.cpp
 535           MacAddressTest.cpp
 536           SocketAddressTest.cpp
 537       TEST optional_test SOURCES OptionalTest.cpp
 538       TEST packed_sync_ptr_test HANGING
 539         SOURCES PackedSyncPtrTest.cpp
 540       TEST padded_test SOURCES PaddedTest.cpp
 541       TEST partial_test SOURCES PartialTest.cpp
 542       TEST portability_test SOURCES PortabilityTest.cpp
 543       TEST producer_consumer_queue_test SLOW
 544         SOURCES ProducerConsumerQueueTest.cpp
 545       TEST r_w_spin_lock_test SOURCES RWSpinLockTest.cpp
 546       TEST random_test SOURCES RandomTest.cpp
 547       TEST range_test SOURCES RangeTest.cpp
 548       TEST safe_assert_test SOURCES SafeAssertTest.cpp
 549       TEST scope_guard_test SOURCES ScopeGuardTest.cpp
 550       # Heavily dependent on drand and srand48
 551       #TEST shared_mutex_test SOURCES SharedMutexTest.cpp
 552       TEST shell_test SOURCES ShellTest.cpp
 553       TEST singleton_test SOURCES SingletonTest.cpp
 554       TEST singleton_test_global SOURCES SingletonTestGlobal.cpp
 555       TEST singleton_thread_local_test SOURCES SingletonThreadLocalTest.cpp
 556       TEST singletonvault_c_test SOURCES SingletonVaultCTest.cpp
 557       TEST small_vector_test SOURCES small_vector_test.cpp
 558       TEST sorted_vector_types_test SOURCES sorted_vector_test.cpp
 559       TEST sparse_byte_set_test SOURCES SparseByteSetTest.cpp
 560       TEST spooky_hash_v1_test SOURCES SpookyHashV1Test.cpp
 561       TEST spooky_hash_v2_test SOURCES SpookyHashV2Test.cpp
 562       TEST string_test SOURCES StringTest.cpp
 563       #TEST subprocess_test SOURCES SubprocessTest.cpp
 564       TEST synchronized_test SOURCES SynchronizedTest.cpp
 565       TEST thread_cached_arena_test SOURCES ThreadCachedArenaTest.cpp
 566       TEST thread_cached_int_test SOURCES ThreadCachedIntTest.cpp
 567       TEST thread_id_test SOURCES ThreadIdTest.cpp
 568       TEST thread_local_test SOURCES ThreadLocalTest.cpp
 569       TEST thread_name_test SOURCES ThreadNameTest.cpp
 570       TEST timeout_queue_test SOURCES TimeoutQueueTest.cpp
 571       TEST token_bucket_test SOURCES TokenBucketTest.cpp
 572       TEST traits_test SOURCES TraitsTest.cpp
 573       TEST try_test SOURCES TryTest.cpp
 574       TEST unit_test SOURCES UnitTest.cpp
 575       TEST uri_test SOURCES UriTest.cpp
 576       TEST varint_test SOURCES VarintTest.cpp
 577   )
 578 endif()