+AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
+AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
+
+AC_CACHE_CHECK(
+ [for ifunc support],
+ [folly_cv_prog_cc_ifunc],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #pragma GCC diagnostic error "-Wattributes"
+ extern "C" void (*test_ifunc(void))() { return 0; }
+ void func() __attribute__((ifunc("test_ifunc")));]
+ ],
+ [folly_cv_prog_cc_ifunc=yes],
+ [folly_cv_prog_cc_ifunc=no])])
+
+if test "$folly_cv_prog_cc_ifunc" = "yes"; then
+ AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
+fi
+
+AC_CACHE_CHECK(
+ [for final and override support],
+ [folly_cv_c_final_override],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
+ class D : public C { virtual void g() override {} };]],
+ [folly_cv_c_final_override=yes],
+ [folly_cv_c_final_override=no])])
+
+if test "$folly_cv_c_final_override" = "yes"; then
+ final_val=final
+ override_val=override
+else
+ final_val=
+ override_val=
+fi
+
+AC_DEFINE_UNQUOTED(
+ [FINAL], [$final_val],
+ [Define to "final" if the compiler supports C++11 "final"])
+AC_DEFINE_UNQUOTED(
+ [OVERRIDE], [$override_val],
+ [Define to "override" if the compiler supports C++11 "override"])
+
+AC_CACHE_CHECK(
+ [for std::this_thread::sleep_for],
+ [folly_cv_func_this_thread_sleep_for],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <thread>
+ #include <chrono>
+ void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
+ [folly_cv_func_this_thread_sleep_for=yes],
+ [folly_cv_func_this_thread_sleep_for=no])])
+
+if test "$folly_cv_func_this_thread_sleep_for" = yes; then
+ AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
+ [Define to 1 if std::this_thread::sleep_for() is defined.])
+fi
+
+AC_CACHE_CHECK(
+ [for constexpr strlen],
+ [folly_cv_func_constexpr_strlen],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <cstring>
+ static constexpr int val = strlen("foo");]],
+ [folly_cv_func_constexpr_strlen=yes],
+ [folly_cv_func_constexpr_strlen=no])])
+
+if test "$folly_cv_func_constexpr_strlen" = yes; then
+ AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
+ [Define to 1 if strlen(3) is constexpr.])
+fi
+
+AC_CACHE_CHECK(
+ [for libc++],
+ [folly_cv_lib_libcpp],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <type_traits>
+ #if !_LIBCPP_VERSION
+ #error No libc++
+ #endif
+ void func() {}]
+ ],
+ [folly_cv_lib_libcpp=yes],
+ [folly_cv_lib_libcpp=no])])
+
+if test "$folly_cv_lib_libcpp" = yes; then
+ AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
+fi
+
+AC_CACHE_CHECK(
+ [for c++11 atomic support without GNU Atomic library],
+ [folly_cv_lib_libatomic],
+ [AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM[
+ #include <atomic>
+ int main() {
+ struct Test { int val; };
+ std::atomic<Test> s;
+ s.is_lock_free();
+ }
+ ]],
+ [folly_cv_lib_libatomic=yes],
+ [folly_cv_lib_libatomic=no])])
+
+if test "$folly_cv_lib_libatomic" = no; then
+ AC_HAVE_LIBRARY([atomic],[],[AC_MSG_ERROR(
+ [Please install the GNU Atomic library])])
+fi
+
+AC_CACHE_CHECK(
+ [for liblinux-vdso support],
+ [folly_cv_lib_liblinux_vdso],
+ [AC_RUN_IFELSE(
+ [AC_LANG_PROGRAM[
+ #include <dlfcn.h>
+ int main() {
+ void *h = dlopen("linux-vdso.so.1", RTLD_LAZY | RTLD_LOCAL | RTLD_NOLOAD);
+ if (h == nullptr) {
+ return -1;
+ }
+ dlclose(h);
+ return 0;
+ }
+ ]],
+ [folly_cv_lib_liblinux_vdso=yes],
+ [folly_cv_lib_liblinux_vdso=no])])
+
+if test "$folly_cv_lib_liblinux_vdso" = yes; then
+ AC_DEFINE([HAVE_LINUX_VDSO], [1], [Define to 1 if liblinux-vdso is available])
+fi
+
+AC_CACHE_CHECK(
+ [for usable std::is_trivially_copyable],
+ [folly_cv_decl_std_is_trivially_copyable],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <type_traits>
+ const bool val = std::is_trivially_copyable<bool>::value;]
+ ],
+ [folly_cv_decl_std_is_trivially_copyable=yes],
+ [folly_cv_decl_std_is_trivially_copyable=no])])
+
+if test "$folly_cv_decl_std_is_trivially_copyable" = yes; then
+ AC_DEFINE([HAVE_STD__IS_TRIVIALLY_COPYABLE], [1],
+ [Define to 1 if we have a usable std::is_trivially_copyable<T>
+ implementation.])
+fi
+
+AC_CACHE_CHECK(
+ [gflags namespace],
+ [folly_cv_decl_gflags_namespace],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <gflags/gflags.h>
+ void foo() { gflags::GetArgv(); }]
+ ],
+ [folly_cv_decl_gflags_namespace=gflags],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <gflags/gflags.h>
+ void foo() { google::GetArgv(); }]
+ ],
+ [folly_cv_decl_gflags_namespace=google],
+ [folly_cv_decl_gflags_namespace=error])])])
+
+if test "$folly_cv_decl_gflags_namespace" = error; then
+ AC_MSG_ERROR([Cannot determine gflags namespace])
+else
+ AC_DEFINE_UNQUOTED(
+ [GFLAGS_NAMESPACE], [$folly_cv_decl_gflags_namespace],
+ [Define to gflags namespace (usually "google" or "gflags")])
+ if test "$folly_cv_decl_gflags_namespace" != gflags; then
+ AC_DEFINE([UNUSUAL_GFLAGS_NAMESPACE], [1],
+ [Define to 1 if the gflags namespace is not "gflags"])
+ fi
+fi
+
+# Figure out if we support weak symbols. If not, we will link in some null
+# stubs for functions that would otherwise be weak.
+AC_CACHE_CHECK(
+ [for weak symbol support],
+ [folly_cv_prog_cc_weak_symbols],
+ [AC_LINK_IFELSE(
+ [AC_LANG_SOURCE[
+ extern "C" void configure_link_extern_weak_test() __attribute__((weak));
+ int main(int argc, char** argv) {
+ return configure_link_extern_weak_test == nullptr;
+ }]],
+ [folly_cv_prog_cc_weak_symbols="yes"],
+ [folly_cv_prog_cc_weak_symbols="no"])])
+
+if test "$folly_cv_prog_cc_weak_symbols" = yes; then
+ AC_DEFINE([HAVE_WEAK_SYMBOLS], [1],
+ [Define to 1 if the linker supports weak symbols.])
+fi
+
+# Figure out whether the architecture supports unaligned accesses
+AC_CACHE_CHECK(
+ [for unaligned access support],
+ [folly_cv_prog_cc_unaligned_access],
+ [AC_RUN_IFELSE(
+ [AC_LANG_SOURCE[
+ int main(int argc, char** argv) {
+ char buf[64] = {0};
+ unsigned long *ptr = (unsigned long *)(buf + 1);
+ *ptr = 0xdeadbeef;
+ return (*ptr & 0xff) == 0xef ? 0 : 1;
+ }
+ ]],
+ [folly_cv_prog_cc_unaligned_access=yes],
+ [folly_cv_prog_cc_unaligned_access=no])])
+
+if test "$folly_cv_prog_cc_unaligned_access" = "yes"; then
+ AC_DEFINE([HAVE_UNALIGNED_ACCESS], [1], [Define to 1 if the architecture allows unaligned accesses])
+fi
+
+AC_CACHE_CHECK(
+ [for vsnprintf reporting bad format strings],
+ [folly_cv_prog_vsnprintf_bad_format],
+ [AC_RUN_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <stdio.h>
+
+ int main(int argc, char** argv) {
+ char buf[256];
+ return vsnprintf(buf, sizeof(buf), "%", 1) < 0 ? 0 : 1;
+ }]],
+ [folly_cv_prog_vsnprintf_bad_format="yes"],
+ [folly_cv_prog_vsnprintf_bad_format="no"])])
+
+if test "$folly_cv_prog_vsnprintf_bad_format" = yes; then
+ AC_DEFINE([HAVE_VSNPRINTF_ERRORS], [1],
+ [Define to 1 if the vsnprintf supports returning errors on bad format strings.])
+fi
+
+AC_SEARCH_LIBS([cplus_demangle_v3_callback], [iberty_pic iberty])
+if test "$ac_cv_search_cplus_demangle_v3_callback" != "no" ; then
+ AC_DEFINE([HAVE_CPLUS_DEMANGLE_V3_CALLBACK], [1],
+ [Define to 1 if we have cplus_demangle_v3_callback.])
+fi
+
+# Check for clock_gettime(2). This is not in an AC_CHECK_FUNCS() because we
+# want to link with librt if necessary.
+AC_SEARCH_LIBS([clock_gettime], [rt],
+ AC_DEFINE(
+ [HAVE_CLOCK_GETTIME],
+ [1],
+ [Define to 1 if we support clock_gettime(2).]),
+ [])
+
+# Check for pthread_atfork(3). This is not in an AC_CHECK_FUNCS() because we
+# want to include pthread.h if necessary.
+AC_CACHE_CHECK(
+ [for pthread_atfork support],
+ [folly_cv_prog_cc_pthread_atfork],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <pthread.h>
+ void func() {pthread_atfork(NULL, NULL, NULL);}]
+ ],
+ [folly_cv_prog_cc_pthread_atfork=yes],
+ [folly_cv_prog_cc_pthread_atfork=no])])
+
+if test "$folly_cv_prog_cc_pthread_atfork" = "yes"; then
+ AC_DEFINE([HAVE_PTHREAD_ATFORK], [1], [Define to 1 if the compiler supports pthread_atfork])
+fi
+
+# Check for XSI-compatible strerror_r as default implementation
+AC_CACHE_CHECK(
+ [for XSI style strerror_r support],
+ [folly_cv_prog_cc_xsi_strerror_r],
+ [AC_RUN_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <string.h>
+ #include <errno.h>
+ int main(int argc, char** argv) {
+ char buf[1024];
+ buf[0] = 0;
+ int ret = strerror_r(ENOMEM, buf, sizeof(buf));
+ return ret;
+ }
+ ]],
+ [folly_cv_prog_cc_xsi_strerror_r=yes],
+ [folly_cv_prog_cc_xsi_strerror_r=no])])
+
+if test "$folly_cv_prog_cc_xsi_strerror_r" = "yes"; then
+ AC_DEFINE([HAVE_XSI_STRERROR_R], [1], [Define to 1 if the runtime supports XSI-style strerror_r])
+fi
+
+AC_CACHE_CHECK(
+ [for ext/random and __gnu_cxx::sfmt19937],
+ [folly_cv_prog_cc_have_extrandom_sfmt19937],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <ext/random>
+ int main(int argc, char** argv) {
+ __gnu_cxx::sfmt19937 rng;
+ return 0;
+ }
+ ]],
+ [folly_cv_prog_cc_have_extrandom_sfmt19937=yes],
+ [folly_cv_prog_cc_have_extrandom_sfmt19937=no])])
+
+AC_CACHE_CHECK(
+ [for VLA (variable-length array) support],
+ [folly_cv_prog_cc_have_vla],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ int main(int argc, char** argv) {
+ unsigned size = argc;
+ char data[size];
+ return 0;
+ }
+ ]],
+ [folly_cv_prog_cc_have_vla=yes],
+ [folly_cv_prog_cc_have_vla=no])])
+
+test "$folly_cv_prog_cc_have_vla" = yes && have_vla=1 || have_vla=0
+AC_DEFINE_UNQUOTED(
+ [HAVE_VLA],
+ [$have_vla],
+ [Define to 1 if the compiler has VLA (variable-length array) support,
+ otherwise define to 0])