-AC_CHECK_TYPE([__int128],
- [AC_DEFINE([HAVE_INT128_T], [1], [Define if __int128 exists])],
- [AC_DEFINE([HAVE_INT128_T], [0], [Define if __int128 does not exist])])
-AC_CHECK_TYPES([ptrdiff_t])
-AC_COMPILE_IFELSE(
- [AC_LANG_SOURCE[
- #pragma GCC diagnostic error "-Wattributes"
- extern "C" void (*test_ifunc(void))() { return 0; }
- void func() __attribute__((ifunc("test_ifunc")));]
- ],
- [AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])],
- [AC_DEFINE([HAVE_IFUNC], [0], [Define to 0 if the compiler doesn't support ifunc])]
-)
-AC_COMPILE_IFELSE(
- [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
- class D : public C { virtual void g() override {} };]],
- [AC_DEFINE([FINAL], [final],
- [Define to "final" if the compiler supports C++11 "final"])
- AC_DEFINE([OVERRIDE], [override],
- [Define to "override" if the compiler supports C++11 "override"])],
- [AC_DEFINE([FINAL], [],
- [Define to "final" if the compiler supports C++11 "final"])
- AC_DEFINE([OVERRIDE], [],
- [Define to "override" if the compiler supports C++11 "override"])]
-)
+AC_CHECK_TYPE([__int128], AC_DEFINE([HAVE_INT128_T], [1], [Define if we have __int128]))
+AC_CHECK_TYPES([ptrdiff_t, pthread_spinlock_t])
+
+AC_CACHE_CHECK(
+ [for ifunc support],
+ [folly_cv_prog_cc_ifunc],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #pragma GCC diagnostic error "-Wattributes"
+ extern "C" void (*test_ifunc(void))() { return 0; }
+ void func() __attribute__((ifunc("test_ifunc")));]
+ ],
+ [folly_cv_prog_cc_ifunc=yes],
+ [folly_cv_prog_cc_ifunc=no])])
+
+if test "$folly_cv_prog_cc_ifunc" = "yes"; then
+ AC_DEFINE([HAVE_IFUNC], [1], [Define to 1 if the compiler supports ifunc])
+fi
+
+AC_CACHE_CHECK(
+ [for final and override support],
+ [folly_cv_c_final_override],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[class C { virtual void f() final {} virtual void g() {} };
+ class D : public C { virtual void g() override {} };]],
+ [folly_cv_c_final_override=yes],
+ [folly_cv_c_final_override=no])])
+
+if test "$folly_cv_c_final_override" = "yes"; then
+ final_val=final
+ override_val=override
+else
+ final_val=
+ override_val=
+fi
+
+AC_DEFINE_UNQUOTED(
+ [FINAL], [$final_val],
+ [Define to "final" if the compiler supports C++11 "final"])
+AC_DEFINE_UNQUOTED(
+ [OVERRIDE], [$override_val],
+ [Define to "override" if the compiler supports C++11 "override"])
+
+AC_CACHE_CHECK(
+ [for std::this_thread::sleep_for],
+ [folly_cv_func_this_thread_sleep_for],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <thread>
+ #include <chrono>
+ void func() { std::this_thread::sleep_for(std::chrono::seconds(1)); }]],
+ [folly_cv_func_this_thread_sleep_for=yes],
+ [folly_cv_func_this_thread_sleep_for=no])])
+
+if test "$folly_cv_func_this_thread_sleep_for" = yes; then
+ AC_DEFINE([HAVE_STD__THIS_THREAD__SLEEP_FOR], [1],
+ [Define to 1 if std::this_thread::sleep_for() is defined.])
+fi
+
+AC_CACHE_CHECK(
+ [for constexpr strlen],
+ [folly_cv_func_constexpr_strlen],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <cstring>
+ static constexpr int val = strlen("foo");]],
+ [folly_cv_func_constexpr_strlen=yes],
+ [folly_cv_func_constexpr_strlen=no])])
+
+if test "$folly_cv_func_constexpr_strlen" = yes; then
+ AC_DEFINE([HAVE_CONSTEXPR_STRLEN], [1],
+ [Define to 1 if strlen(3) is constexpr.])
+fi
+
+AC_CACHE_CHECK(
+ [for libc++],
+ [folly_cv_lib_libcpp],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_SOURCE[
+ #include <type_traits>
+ #if !_LIBCPP_VERSION
+ #error No libc++
+ #endif
+ void func() {}]
+ ],
+ [folly_cv_lib_libcpp=yes],
+ [folly_cv_lib_libcpp=no])])
+
+if test "$folly_cv_lib_libcpp" = yes; then
+ AC_DEFINE([USE_LIBCPP], [1], [Define to 1 if we are using libc++.])
+fi