test/Transforms/ObjCARC/retain-block.ll

   1 ; RUN: opt -objc-arc -S < %s | FileCheck %s
   2
   3 target datalayout = "e-p:64:64:64"
   4
   5 !0 = metadata !{}
   6
   7 declare i8* @objc_retain(i8*)
   8 declare void @callee(i8)
   9 declare void @use_pointer(i8*)
  10 declare void @objc_release(i8*)
  11 declare i8* @objc_retainBlock(i8*)
  12 declare i8* @objc_autorelease(i8*)
  13
  14 ; Basic retainBlock+release elimination.
  15
  16 ; CHECK-LABEL: define void @test0(i8* %tmp) {
  17 ; CHECK-NOT: @objc
  18 ; CHECK: }
  19 define void @test0(i8* %tmp) {
  20 entry:
  21   %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) nounwind, !clang.arc.copy_on_escape !0
  22   tail call void @use_pointer(i8* %tmp2)
  23   tail call void @objc_release(i8* %tmp2) nounwind, !clang.imprecise_release !0
  24   ret void
  25 }
  26
  27 ; Same as test0, but there's no copy_on_escape metadata, so there's no
  28 ; optimization possible.
  29
  30 ; CHECK-LABEL: define void @test0_no_metadata(i8* %tmp) {
  31 ; CHECK: %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) [[NUW:#[0-9]+]]
  32 ; CHECK: tail call void @objc_release(i8* %tmp2) [[NUW]], !clang.imprecise_release !0
  33 ; CHECK: }
  34 define void @test0_no_metadata(i8* %tmp) {
  35 entry:
  36   %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) nounwind
  37   tail call void @use_pointer(i8* %tmp2)
  38   tail call void @objc_release(i8* %tmp2) nounwind, !clang.imprecise_release !0
  39   ret void
  40 }
  41
  42 ; Same as test0, but the pointer escapes, so there's no
  43 ; optimization possible.
  44
  45 ; CHECK-LABEL: define void @test0_escape(i8* %tmp, i8** %z) {
  46 ; CHECK: %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) [[NUW]], !clang.arc.copy_on_escape !0
  47 ; CHECK: tail call void @objc_release(i8* %tmp2) [[NUW]], !clang.imprecise_release !0
  48 ; CHECK: }
  49 define void @test0_escape(i8* %tmp, i8** %z) {
  50 entry:
  51   %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) nounwind, !clang.arc.copy_on_escape !0
  52   store i8* %tmp2, i8** %z
  53   tail call void @use_pointer(i8* %tmp2)
  54   tail call void @objc_release(i8* %tmp2) nounwind, !clang.imprecise_release !0
  55   ret void
  56 }
  57
  58 ; Same as test0_escape, but there's no intervening call.
  59
  60 ; CHECK-LABEL: define void @test0_just_escape(i8* %tmp, i8** %z) {
  61 ; CHECK: %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) [[NUW]], !clang.arc.copy_on_escape !0
  62 ; CHECK: tail call void @objc_release(i8* %tmp2) [[NUW]], !clang.imprecise_release !0
  63 ; CHECK: }
  64 define void @test0_just_escape(i8* %tmp, i8** %z) {
  65 entry:
  66   %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) nounwind, !clang.arc.copy_on_escape !0
  67   store i8* %tmp2, i8** %z
  68   tail call void @objc_release(i8* %tmp2) nounwind, !clang.imprecise_release !0
  69   ret void
  70 }
  71
  72 ; Basic nested retainBlock+release elimination.
  73
  74 ; CHECK: define void @test1(i8* %tmp) {
  75 ; CHECK-NOT: @objc
  76 ; CHECK: tail call i8* @objc_retain(i8* %tmp) [[NUW]]
  77 ; CHECK-NOT: @objc
  78 ; CHECK: tail call void @objc_release(i8* %tmp) [[NUW]], !clang.imprecise_release !0
  79 ; CHECK-NOT: @objc
  80 ; CHECK: }
  81 define void @test1(i8* %tmp) {
  82 entry:
  83   %tmp1 = tail call i8* @objc_retain(i8* %tmp) nounwind
  84   %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) nounwind, !clang.arc.copy_on_escape !0
  85   tail call void @use_pointer(i8* %tmp2)
  86   tail call void @use_pointer(i8* %tmp2)
  87   tail call void @objc_release(i8* %tmp2) nounwind, !clang.imprecise_release !0
  88   tail call void @objc_release(i8* %tmp) nounwind, !clang.imprecise_release !0
  89   ret void
  90 }
  91
  92 ; Same as test1, but there's no copy_on_escape metadata, so there's no
  93 ; retainBlock+release optimization possible. But we can still eliminate
  94 ; the outer retain+release.
  95
  96 ; CHECK-LABEL: define void @test1_no_metadata(i8* %tmp) {
  97 ; CHECK-NEXT: entry:
  98 ; CHECK-NEXT: tail call i8* @objc_retainBlock(i8* %tmp) [[NUW]]
  99 ; CHECK-NEXT: @use_pointer(i8* %tmp2)
 100 ; CHECK-NEXT: @use_pointer(i8* %tmp2)
 101 ; CHECK-NEXT: tail call void @objc_release(i8* %tmp2) [[NUW]], !clang.imprecise_release !0
 102 ; CHECK-NOT: @objc
 103 ; CHECK: }
 104 define void @test1_no_metadata(i8* %tmp) {
 105 entry:
 106   %tmp1 = tail call i8* @objc_retain(i8* %tmp) nounwind
 107   %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) nounwind
 108   tail call void @use_pointer(i8* %tmp2)
 109   tail call void @use_pointer(i8* %tmp2)
 110   tail call void @objc_release(i8* %tmp2) nounwind, !clang.imprecise_release !0
 111   tail call void @objc_release(i8* %tmp) nounwind, !clang.imprecise_release !0
 112   ret void
 113 }
 114
 115 ; Same as test1, but the pointer escapes, so there's no
 116 ; retainBlock+release optimization possible. But we can still eliminate
 117 ; the outer retain+release
 118
 119 ; CHECK: define void @test1_escape(i8* %tmp, i8** %z) {
 120 ; CHECK-NEXT: entry:
 121 ; CHECK-NEXT: %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) [[NUW]], !clang.arc.copy_on_escape !0
 122 ; CHECK-NEXT: store i8* %tmp2, i8** %z
 123 ; CHECK-NEXT: @use_pointer(i8* %tmp2)
 124 ; CHECK-NEXT: @use_pointer(i8* %tmp2)
 125 ; CHECK-NEXT: tail call void @objc_release(i8* %tmp2) [[NUW]], !clang.imprecise_release !0
 126 ; CHECK-NOT: @objc
 127 ; CHECK: }
 128 define void @test1_escape(i8* %tmp, i8** %z) {
 129 entry:
 130   %tmp1 = tail call i8* @objc_retain(i8* %tmp) nounwind
 131   %tmp2 = tail call i8* @objc_retainBlock(i8* %tmp) nounwind, !clang.arc.copy_on_escape !0
 132   store i8* %tmp2, i8** %z
 133   tail call void @use_pointer(i8* %tmp2)
 134   tail call void @use_pointer(i8* %tmp2)
 135   tail call void @objc_release(i8* %tmp2) nounwind, !clang.imprecise_release !0
 136   tail call void @objc_release(i8* %tmp) nounwind, !clang.imprecise_release !0
 137   ret void
 138 }
 139
 140 ; Optimize objc_retainBlock.
 141
 142 ; CHECK-LABEL: define void @test23(
 143 ; CHECK-NOT: @objc_
 144 ; CHECK: }
 145 %block0 = type { i64, i64, i8*, i8* }
 146 %block1 = type { i8**, i32, i32, i32 (%struct.__block_literal_1*)*, %block0* }
 147 %struct.__block_descriptor = type { i64, i64 }
 148 %struct.__block_literal_1 = type { i8**, i32, i32, i8**, %struct.__block_descriptor* }
 149 @__block_holder_tmp_1 = external constant %block1
 150 define void @test23() {
 151 entry:
 152   %0 = call i8* @objc_retainBlock(i8* bitcast (%block1* @__block_holder_tmp_1 to i8*)) nounwind, !clang.arc.copy_on_escape !0
 153   call void @bar(i32 ()* bitcast (%block1* @__block_holder_tmp_1 to i32 ()*))
 154   call void @bar(i32 ()* bitcast (%block1* @__block_holder_tmp_1 to i32 ()*))
 155   call void @objc_release(i8* bitcast (%block1* @__block_holder_tmp_1 to i8*)) nounwind
 156   ret void
 157 }
 158
 159 ; Don't optimize objc_retainBlock, but do strength reduce it.
 160
 161 ; CHECK-LABEL: define void @test3a(i8* %p) {
 162 ; CHECK: @objc_retain
 163 ; CHECK: @objc_release
 164 ; CHECK: }
 165 define void @test3a(i8* %p) {
 166 entry:
 167   %0 = call i8* @objc_retainBlock(i8* %p) nounwind, !clang.arc.copy_on_escape !0
 168   call void @callee()
 169   call void @use_pointer(i8* %p)
 170   call void @objc_release(i8* %p) nounwind
 171   ret void
 172 }
 173
 174 ; Don't optimize objc_retainBlock, because there's no copy_on_escape metadata.
 175
 176 ; CHECK-LABEL: define void @test3b(
 177 ; CHECK: @objc_retainBlock
 178 ; CHECK: @objc_release
 179 ; CHECK: }
 180 define void @test3b() {
 181 entry:
 182   %0 = call i8* @objc_retainBlock(i8* bitcast (%block1* @__block_holder_tmp_1 to i8*)) nounwind
 183   call void @bar(i32 ()* bitcast (%block1* @__block_holder_tmp_1 to i32 ()*))
 184   call void @bar(i32 ()* bitcast (%block1* @__block_holder_tmp_1 to i32 ()*))
 185   call void @objc_release(i8* bitcast (%block1* @__block_holder_tmp_1 to i8*)) nounwind
 186   ret void
 187 }
 188
 189 ; CHECK: attributes [[NUW]] = { nounwind }