lib/Target/X86/X86InstrInfo.td

   1 //===-- X86InstrInfo.td - Main X86 Instruction Definition --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 instruction set, defining the instructions, and
  11 // properties of the instructions which are needed for code generation, machine
  12 // code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // X86 specific DAG Nodes.
  18 //
  19
  20 def SDTIntShiftDOp: SDTypeProfile<1, 3,
  21                                   [SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>,
  22                                    SDTCisInt<0>, SDTCisInt<3>]>;
  23
  24 def SDTX86CmpTest : SDTypeProfile<1, 2, [SDTCisVT<0, i32>, SDTCisSameAs<1, 2>]>;
  25
  26 def SDTX86Cmps : SDTypeProfile<1, 3, [SDTCisFP<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
  27 //def SDTX86Cmpss : SDTypeProfile<1, 3, [SDTCisVT<0, f32>, SDTCisSameAs<1, 2>, SDTCisVT<3, i8>]>;
  28
  29 def SDTX86Cmov    : SDTypeProfile<1, 4,
  30                                   [SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>,
  31                                    SDTCisVT<3, i8>, SDTCisVT<4, i32>]>;
  32
  33 // Unary and binary operator instructions that set EFLAGS as a side-effect.
  34 def SDTUnaryArithWithFlags : SDTypeProfile<2, 1,
  35                                            [SDTCisInt<0>, SDTCisVT<1, i32>]>;
  36
  37 def SDTBinaryArithWithFlags : SDTypeProfile<2, 2,
  38                                             [SDTCisSameAs<0, 2>,
  39                                              SDTCisSameAs<0, 3>,
  40                                              SDTCisInt<0>, SDTCisVT<1, i32>]>;
  41
  42 // SDTBinaryArithWithFlagsInOut - RES1, EFLAGS = op LHS, RHS, EFLAGS
  43 def SDTBinaryArithWithFlagsInOut : SDTypeProfile<2, 3,
  44                                             [SDTCisSameAs<0, 2>,
  45                                              SDTCisSameAs<0, 3>,
  46                                              SDTCisInt<0>,
  47                                              SDTCisVT<1, i32>,
  48                                              SDTCisVT<4, i32>]>;
  49 // RES1, RES2, FLAGS = op LHS, RHS
  50 def SDT2ResultBinaryArithWithFlags : SDTypeProfile<3, 2,
  51                                             [SDTCisSameAs<0, 1>,
  52                                              SDTCisSameAs<0, 2>,
  53                                              SDTCisSameAs<0, 3>,
  54                                              SDTCisInt<0>, SDTCisVT<1, i32>]>;
  55 def SDTX86BrCond  : SDTypeProfile<0, 3,
  56                                   [SDTCisVT<0, OtherVT>,
  57                                    SDTCisVT<1, i8>, SDTCisVT<2, i32>]>;
  58
  59 def SDTX86SetCC   : SDTypeProfile<1, 2,
  60                                   [SDTCisVT<0, i8>,
  61                                    SDTCisVT<1, i8>, SDTCisVT<2, i32>]>;
  62 def SDTX86SetCC_C : SDTypeProfile<1, 2,
  63                                   [SDTCisInt<0>,
  64                                    SDTCisVT<1, i8>, SDTCisVT<2, i32>]>;
  65
  66 def SDTX86sahf : SDTypeProfile<1, 1, [SDTCisVT<0, i32>, SDTCisVT<1, i8>]>;
  67
  68 def SDTX86rdrand : SDTypeProfile<2, 0, [SDTCisInt<0>, SDTCisVT<1, i32>]>;
  69
  70 def SDTX86cas : SDTypeProfile<0, 3, [SDTCisPtrTy<0>, SDTCisInt<1>,
  71                                      SDTCisVT<2, i8>]>;
  72 def SDTX86caspair : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  73
  74 def SDTX86atomicBinary : SDTypeProfile<2, 3, [SDTCisInt<0>, SDTCisInt<1>,
  75                                 SDTCisPtrTy<2>, SDTCisInt<3>,SDTCisInt<4>]>;
  76 def SDTX86Ret     : SDTypeProfile<0, -1, [SDTCisVT<0, i16>]>;
  77
  78 def SDT_X86CallSeqStart : SDCallSeqStart<[SDTCisVT<0, i32>]>;
  79 def SDT_X86CallSeqEnd   : SDCallSeqEnd<[SDTCisVT<0, i32>,
  80                                         SDTCisVT<1, i32>]>;
  81
  82 def SDT_X86Call   : SDTypeProfile<0, -1, [SDTCisVT<0, iPTR>]>;
  83
  84 def SDT_X86VASTART_SAVE_XMM_REGS : SDTypeProfile<0, -1, [SDTCisVT<0, i8>,
  85                                                          SDTCisVT<1, iPTR>,
  86                                                          SDTCisVT<2, iPTR>]>;
  87
  88 def SDT_X86VAARG_64 : SDTypeProfile<1, -1, [SDTCisPtrTy<0>,
  89                                             SDTCisPtrTy<1>,
  90                                             SDTCisVT<2, i32>,
  91                                             SDTCisVT<3, i8>,
  92                                             SDTCisVT<4, i32>]>;
  93
  94 def SDTX86RepStr  : SDTypeProfile<0, 1, [SDTCisVT<0, OtherVT>]>;
  95
  96 def SDTX86Void    : SDTypeProfile<0, 0, []>;
  97
  98 def SDTX86Wrapper : SDTypeProfile<1, 1, [SDTCisSameAs<0, 1>, SDTCisPtrTy<0>]>;
  99
 100 def SDT_X86TLSADDR : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 101
 102 def SDT_X86TLSBASEADDR : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 103
 104 def SDT_X86TLSCALL : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 105
 106 def SDT_X86SEG_ALLOCA : SDTypeProfile<1, 1, [SDTCisVT<0, iPTR>, SDTCisVT<1, iPTR>]>;
 107
 108 def SDT_X86WIN_FTOL : SDTypeProfile<0, 1, [SDTCisFP<0>]>;
 109
 110 def SDT_X86EHRET : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 111
 112 def SDT_X86TCRET : SDTypeProfile<0, 2, [SDTCisPtrTy<0>, SDTCisVT<1, i32>]>;
 113
 114 def SDT_X86MEMBARRIER : SDTypeProfile<0, 0, []>;
 115
 116 def X86MemBarrier : SDNode<"X86ISD::MEMBARRIER", SDT_X86MEMBARRIER,
 117                             [SDNPHasChain,SDNPSideEffect]>;
 118 def X86MFence : SDNode<"X86ISD::MFENCE", SDT_X86MEMBARRIER,
 119                         [SDNPHasChain]>;
 120 def X86SFence : SDNode<"X86ISD::SFENCE", SDT_X86MEMBARRIER,
 121                         [SDNPHasChain]>;
 122 def X86LFence : SDNode<"X86ISD::LFENCE", SDT_X86MEMBARRIER,
 123                         [SDNPHasChain]>;
 124
 125
 126 def X86bsf     : SDNode<"X86ISD::BSF",      SDTUnaryArithWithFlags>;
 127 def X86bsr     : SDNode<"X86ISD::BSR",      SDTUnaryArithWithFlags>;
 128 def X86shld    : SDNode<"X86ISD::SHLD",     SDTIntShiftDOp>;
 129 def X86shrd    : SDNode<"X86ISD::SHRD",     SDTIntShiftDOp>;
 130
 131 def X86cmp     : SDNode<"X86ISD::CMP" ,     SDTX86CmpTest>;
 132 def X86bt      : SDNode<"X86ISD::BT",       SDTX86CmpTest>;
 133
 134 def X86cmov    : SDNode<"X86ISD::CMOV",     SDTX86Cmov>;
 135 def X86brcond  : SDNode<"X86ISD::BRCOND",   SDTX86BrCond,
 136                         [SDNPHasChain]>;
 137 def X86setcc   : SDNode<"X86ISD::SETCC",    SDTX86SetCC>;
 138 def X86setcc_c : SDNode<"X86ISD::SETCC_CARRY", SDTX86SetCC_C>;
 139
 140 def X86sahf    : SDNode<"X86ISD::SAHF",     SDTX86sahf>;
 141
 142 def X86rdrand  : SDNode<"X86ISD::RDRAND",   SDTX86rdrand,
 143                         [SDNPHasChain, SDNPSideEffect]>;
 144
 145 def X86rdseed  : SDNode<"X86ISD::RDSEED",   SDTX86rdrand,
 146                         [SDNPHasChain, SDNPSideEffect]>;
 147
 148 def X86cas : SDNode<"X86ISD::LCMPXCHG_DAG", SDTX86cas,
 149                         [SDNPHasChain, SDNPInGlue, SDNPOutGlue, SDNPMayStore,
 150                          SDNPMayLoad, SDNPMemOperand]>;
 151 def X86cas8 : SDNode<"X86ISD::LCMPXCHG8_DAG", SDTX86caspair,
 152                         [SDNPHasChain, SDNPInGlue, SDNPOutGlue, SDNPMayStore,
 153                          SDNPMayLoad, SDNPMemOperand]>;
 154 def X86cas16 : SDNode<"X86ISD::LCMPXCHG16_DAG", SDTX86caspair,
 155                         [SDNPHasChain, SDNPInGlue, SDNPOutGlue, SDNPMayStore,
 156                          SDNPMayLoad, SDNPMemOperand]>;
 157
 158 def X86AtomAdd64 : SDNode<"X86ISD::ATOMADD64_DAG", SDTX86atomicBinary,
 159                         [SDNPHasChain, SDNPMayStore,
 160                          SDNPMayLoad, SDNPMemOperand]>;
 161 def X86AtomSub64 : SDNode<"X86ISD::ATOMSUB64_DAG", SDTX86atomicBinary,
 162                         [SDNPHasChain, SDNPMayStore,
 163                          SDNPMayLoad, SDNPMemOperand]>;
 164 def X86AtomOr64 : SDNode<"X86ISD::ATOMOR64_DAG", SDTX86atomicBinary,
 165                         [SDNPHasChain, SDNPMayStore,
 166                          SDNPMayLoad, SDNPMemOperand]>;
 167 def X86AtomXor64 : SDNode<"X86ISD::ATOMXOR64_DAG", SDTX86atomicBinary,
 168                         [SDNPHasChain, SDNPMayStore,
 169                          SDNPMayLoad, SDNPMemOperand]>;
 170 def X86AtomAnd64 : SDNode<"X86ISD::ATOMAND64_DAG", SDTX86atomicBinary,
 171                         [SDNPHasChain, SDNPMayStore,
 172                          SDNPMayLoad, SDNPMemOperand]>;
 173 def X86AtomNand64 : SDNode<"X86ISD::ATOMNAND64_DAG", SDTX86atomicBinary,
 174                         [SDNPHasChain, SDNPMayStore,
 175                          SDNPMayLoad, SDNPMemOperand]>;
 176 def X86AtomSwap64 : SDNode<"X86ISD::ATOMSWAP64_DAG", SDTX86atomicBinary,
 177                         [SDNPHasChain, SDNPMayStore,
 178                          SDNPMayLoad, SDNPMemOperand]>;
 179 def X86retflag : SDNode<"X86ISD::RET_FLAG", SDTX86Ret,
 180                         [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
 181
 182 def X86vastart_save_xmm_regs :
 183                  SDNode<"X86ISD::VASTART_SAVE_XMM_REGS",
 184                         SDT_X86VASTART_SAVE_XMM_REGS,
 185                         [SDNPHasChain, SDNPVariadic]>;
 186 def X86vaarg64 :
 187                  SDNode<"X86ISD::VAARG_64", SDT_X86VAARG_64,
 188                         [SDNPHasChain, SDNPMayLoad, SDNPMayStore,
 189                          SDNPMemOperand]>;
 190 def X86callseq_start :
 191                  SDNode<"ISD::CALLSEQ_START", SDT_X86CallSeqStart,
 192                         [SDNPHasChain, SDNPOutGlue]>;
 193 def X86callseq_end :
 194                  SDNode<"ISD::CALLSEQ_END",   SDT_X86CallSeqEnd,
 195                         [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 196
 197 def X86call    : SDNode<"X86ISD::CALL",     SDT_X86Call,
 198                         [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
 199                          SDNPVariadic]>;
 200
 201 def X86rep_stos: SDNode<"X86ISD::REP_STOS", SDTX86RepStr,
 202                         [SDNPHasChain, SDNPInGlue, SDNPOutGlue, SDNPMayStore]>;
 203 def X86rep_movs: SDNode<"X86ISD::REP_MOVS", SDTX86RepStr,
 204                         [SDNPHasChain, SDNPInGlue, SDNPOutGlue, SDNPMayStore,
 205                          SDNPMayLoad]>;
 206
 207 def X86rdtsc   : SDNode<"X86ISD::RDTSC_DAG", SDTX86Void,
 208                         [SDNPHasChain, SDNPOutGlue, SDNPSideEffect]>;
 209
 210 def X86Wrapper    : SDNode<"X86ISD::Wrapper",     SDTX86Wrapper>;
 211 def X86WrapperRIP : SDNode<"X86ISD::WrapperRIP",  SDTX86Wrapper>;
 212
 213 def X86tlsaddr : SDNode<"X86ISD::TLSADDR", SDT_X86TLSADDR,
 214                         [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 215
 216 def X86tlsbaseaddr : SDNode<"X86ISD::TLSBASEADDR", SDT_X86TLSBASEADDR,
 217                         [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 218
 219 def X86ehret : SDNode<"X86ISD::EH_RETURN", SDT_X86EHRET,
 220                         [SDNPHasChain]>;
 221
 222 def X86eh_sjlj_setjmp  : SDNode<"X86ISD::EH_SJLJ_SETJMP",
 223                                 SDTypeProfile<1, 1, [SDTCisInt<0>,
 224                                                      SDTCisPtrTy<1>]>,
 225                                 [SDNPHasChain, SDNPSideEffect]>;
 226 def X86eh_sjlj_longjmp : SDNode<"X86ISD::EH_SJLJ_LONGJMP",
 227                                 SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>,
 228                                 [SDNPHasChain, SDNPSideEffect]>;
 229
 230 def X86tcret : SDNode<"X86ISD::TC_RETURN", SDT_X86TCRET,
 231                         [SDNPHasChain,  SDNPOptInGlue, SDNPVariadic]>;
 232
 233 def X86add_flag  : SDNode<"X86ISD::ADD",  SDTBinaryArithWithFlags,
 234                           [SDNPCommutative]>;
 235 def X86sub_flag  : SDNode<"X86ISD::SUB",  SDTBinaryArithWithFlags>;
 236 def X86smul_flag : SDNode<"X86ISD::SMUL", SDTBinaryArithWithFlags,
 237                           [SDNPCommutative]>;
 238 def X86umul_flag : SDNode<"X86ISD::UMUL", SDT2ResultBinaryArithWithFlags,
 239                           [SDNPCommutative]>;
 240 def X86adc_flag  : SDNode<"X86ISD::ADC",  SDTBinaryArithWithFlagsInOut>;
 241 def X86sbb_flag  : SDNode<"X86ISD::SBB",  SDTBinaryArithWithFlagsInOut>;
 242
 243 def X86inc_flag  : SDNode<"X86ISD::INC",  SDTUnaryArithWithFlags>;
 244 def X86dec_flag  : SDNode<"X86ISD::DEC",  SDTUnaryArithWithFlags>;
 245 def X86or_flag   : SDNode<"X86ISD::OR",   SDTBinaryArithWithFlags,
 246                           [SDNPCommutative]>;
 247 def X86xor_flag  : SDNode<"X86ISD::XOR",  SDTBinaryArithWithFlags,
 248                           [SDNPCommutative]>;
 249 def X86and_flag  : SDNode<"X86ISD::AND",  SDTBinaryArithWithFlags,
 250                           [SDNPCommutative]>;
 251
 252 def X86blsi   : SDNode<"X86ISD::BLSI",   SDTIntUnaryOp>;
 253 def X86blsmsk : SDNode<"X86ISD::BLSMSK", SDTIntUnaryOp>;
 254 def X86blsr   : SDNode<"X86ISD::BLSR",   SDTIntUnaryOp>;
 255 def X86bzhi   : SDNode<"X86ISD::BZHI",   SDTIntShiftOp>;
 256 def X86bextr  : SDNode<"X86ISD::BEXTR",  SDTIntBinOp>;
 257
 258 def X86mul_imm : SDNode<"X86ISD::MUL_IMM", SDTIntBinOp>;
 259
 260 def X86WinAlloca : SDNode<"X86ISD::WIN_ALLOCA", SDTX86Void,
 261                           [SDNPHasChain, SDNPInGlue, SDNPOutGlue]>;
 262
 263 def X86SegAlloca : SDNode<"X86ISD::SEG_ALLOCA", SDT_X86SEG_ALLOCA,
 264                           [SDNPHasChain]>;
 265
 266 def X86TLSCall : SDNode<"X86ISD::TLSCALL", SDT_X86TLSCALL,
 267                         [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 268
 269 def X86WinFTOL : SDNode<"X86ISD::WIN_FTOL", SDT_X86WIN_FTOL,
 270                         [SDNPHasChain, SDNPOutGlue]>;
 271
 272 //===----------------------------------------------------------------------===//
 273 // X86 Operand Definitions.
 274 //
 275
 276 // A version of ptr_rc which excludes SP, ESP, and RSP. This is used for
 277 // the index operand of an address, to conform to x86 encoding restrictions.
 278 def ptr_rc_nosp : PointerLikeRegClass<1>;
 279
 280 // *mem - Operand definitions for the funky X86 addressing mode operands.
 281 //
 282 def X86MemAsmOperand : AsmOperandClass {
 283  let Name = "Mem";
 284 }
 285 def X86Mem8AsmOperand : AsmOperandClass {
 286   let Name = "Mem8"; let RenderMethod = "addMemOperands";
 287 }
 288 def X86Mem16AsmOperand : AsmOperandClass {
 289   let Name = "Mem16"; let RenderMethod = "addMemOperands";
 290 }
 291 def X86Mem32AsmOperand : AsmOperandClass {
 292   let Name = "Mem32"; let RenderMethod = "addMemOperands";
 293 }
 294 def X86Mem64AsmOperand : AsmOperandClass {
 295   let Name = "Mem64"; let RenderMethod = "addMemOperands";
 296 }
 297 def X86Mem80AsmOperand : AsmOperandClass {
 298   let Name = "Mem80"; let RenderMethod = "addMemOperands";
 299 }
 300 def X86Mem128AsmOperand : AsmOperandClass {
 301   let Name = "Mem128"; let RenderMethod = "addMemOperands";
 302 }
 303 def X86Mem256AsmOperand : AsmOperandClass {
 304   let Name = "Mem256"; let RenderMethod = "addMemOperands";
 305 }
 306 def X86Mem512AsmOperand : AsmOperandClass {
 307   let Name = "Mem512"; let RenderMethod = "addMemOperands";
 308 }
 309
 310 // Gather mem operands
 311 def X86MemVX32Operand : AsmOperandClass {
 312   let Name = "MemVX32"; let RenderMethod = "addMemOperands";
 313 }
 314 def X86MemVY32Operand : AsmOperandClass {
 315   let Name = "MemVY32"; let RenderMethod = "addMemOperands";
 316 }
 317 def X86MemVZ32Operand : AsmOperandClass {
 318   let Name = "MemVZ32"; let RenderMethod = "addMemOperands";
 319 }
 320 def X86MemVX64Operand : AsmOperandClass {
 321   let Name = "MemVX64"; let RenderMethod = "addMemOperands";
 322 }
 323 def X86MemVY64Operand : AsmOperandClass {
 324   let Name = "MemVY64"; let RenderMethod = "addMemOperands";
 325 }
 326 def X86MemVZ64Operand : AsmOperandClass {
 327   let Name = "MemVZ64"; let RenderMethod = "addMemOperands";
 328 }
 329
 330 def X86AbsMemAsmOperand : AsmOperandClass {
 331   let Name = "AbsMem";
 332   let SuperClasses = [X86MemAsmOperand];
 333 }
 334 class X86MemOperand<string printMethod> : Operand<iPTR> {
 335   let PrintMethod = printMethod;
 336   let MIOperandInfo = (ops ptr_rc, i8imm, ptr_rc_nosp, i32imm, i8imm);
 337   let ParserMatchClass = X86MemAsmOperand;
 338 }
 339
 340 let OperandType = "OPERAND_MEMORY" in {
 341 def opaque32mem : X86MemOperand<"printopaquemem">;
 342 def opaque48mem : X86MemOperand<"printopaquemem">;
 343 def opaque80mem : X86MemOperand<"printopaquemem">;
 344 def opaque512mem : X86MemOperand<"printopaquemem">;
 345
 346 def i8mem   : X86MemOperand<"printi8mem"> {
 347   let ParserMatchClass = X86Mem8AsmOperand; }
 348 def i16mem  : X86MemOperand<"printi16mem"> {
 349   let ParserMatchClass = X86Mem16AsmOperand; }
 350 def i32mem  : X86MemOperand<"printi32mem"> {
 351   let ParserMatchClass = X86Mem32AsmOperand; }
 352 def i64mem  : X86MemOperand<"printi64mem"> {
 353   let ParserMatchClass = X86Mem64AsmOperand; }
 354 def i128mem : X86MemOperand<"printi128mem"> {
 355   let ParserMatchClass = X86Mem128AsmOperand; }
 356 def i256mem : X86MemOperand<"printi256mem"> {
 357   let ParserMatchClass = X86Mem256AsmOperand; }
 358 def i512mem : X86MemOperand<"printi512mem"> {
 359   let ParserMatchClass = X86Mem512AsmOperand; }
 360 def f32mem  : X86MemOperand<"printf32mem"> {
 361   let ParserMatchClass = X86Mem32AsmOperand; }
 362 def f64mem  : X86MemOperand<"printf64mem"> {
 363   let ParserMatchClass = X86Mem64AsmOperand; }
 364 def f80mem  : X86MemOperand<"printf80mem"> {
 365   let ParserMatchClass = X86Mem80AsmOperand; }
 366 def f128mem : X86MemOperand<"printf128mem"> {
 367   let ParserMatchClass = X86Mem128AsmOperand; }
 368 def f256mem : X86MemOperand<"printf256mem">{
 369   let ParserMatchClass = X86Mem256AsmOperand; }
 370 def f512mem : X86MemOperand<"printf512mem">{
 371   let ParserMatchClass = X86Mem512AsmOperand; }
 372 def v512mem : Operand<iPTR> {
 373   let PrintMethod = "printf512mem";
 374   let MIOperandInfo = (ops ptr_rc, i8imm, VR512, i32imm, i8imm);
 375   let ParserMatchClass = X86Mem512AsmOperand; }
 376
 377 // Gather mem operands
 378 def vx32mem : X86MemOperand<"printi32mem">{
 379   let MIOperandInfo = (ops ptr_rc, i8imm, VR128, i32imm, i8imm);
 380   let ParserMatchClass = X86MemVX32Operand; }
 381 def vy32mem : X86MemOperand<"printi32mem">{
 382   let MIOperandInfo = (ops ptr_rc, i8imm, VR256, i32imm, i8imm);
 383   let ParserMatchClass = X86MemVY32Operand; }
 384 def vx64mem : X86MemOperand<"printi64mem">{
 385   let MIOperandInfo = (ops ptr_rc, i8imm, VR128, i32imm, i8imm);
 386   let ParserMatchClass = X86MemVX64Operand; }
 387 def vy64mem : X86MemOperand<"printi64mem">{
 388   let MIOperandInfo = (ops ptr_rc, i8imm, VR256, i32imm, i8imm);
 389   let ParserMatchClass = X86MemVY64Operand; }
 390 def vy64xmem : X86MemOperand<"printi64mem">{
 391   let MIOperandInfo = (ops ptr_rc, i8imm, VR256X, i32imm, i8imm);
 392   let ParserMatchClass = X86MemVY64Operand; }
 393 def vz32mem : X86MemOperand<"printi32mem">{
 394   let MIOperandInfo = (ops ptr_rc, i16imm, VR512, i32imm, i8imm);
 395   let ParserMatchClass = X86MemVZ32Operand; }
 396 def vz64mem : X86MemOperand<"printi64mem">{
 397   let MIOperandInfo = (ops ptr_rc, i8imm, VR512, i32imm, i8imm);
 398   let ParserMatchClass = X86MemVZ64Operand; }
 399 }
 400
 401 // A version of i8mem for use on x86-64 that uses GR64_NOREX instead of
 402 // plain GR64, so that it doesn't potentially require a REX prefix.
 403 def i8mem_NOREX : Operand<i64> {
 404   let PrintMethod = "printi8mem";
 405   let MIOperandInfo = (ops GR64_NOREX, i8imm, GR64_NOREX_NOSP, i32imm, i8imm);
 406   let ParserMatchClass = X86Mem8AsmOperand;
 407   let OperandType = "OPERAND_MEMORY";
 408 }
 409
 410 // GPRs available for tailcall.
 411 // It represents GR32_TC, GR64_TC or GR64_TCW64.
 412 def ptr_rc_tailcall : PointerLikeRegClass<2>;
 413
 414 // Special i32mem for addresses of load folding tail calls. These are not
 415 // allowed to use callee-saved registers since they must be scheduled
 416 // after callee-saved register are popped.
 417 def i32mem_TC : Operand<i32> {
 418   let PrintMethod = "printi32mem";
 419   let MIOperandInfo = (ops ptr_rc_tailcall, i8imm, ptr_rc_tailcall,
 420                        i32imm, i8imm);
 421   let ParserMatchClass = X86Mem32AsmOperand;
 422   let OperandType = "OPERAND_MEMORY";
 423 }
 424
 425 // Special i64mem for addresses of load folding tail calls. These are not
 426 // allowed to use callee-saved registers since they must be scheduled
 427 // after callee-saved register are popped.
 428 def i64mem_TC : Operand<i64> {
 429   let PrintMethod = "printi64mem";
 430   let MIOperandInfo = (ops ptr_rc_tailcall, i8imm,
 431                        ptr_rc_tailcall, i32imm, i8imm);
 432   let ParserMatchClass = X86Mem64AsmOperand;
 433   let OperandType = "OPERAND_MEMORY";
 434 }
 435
 436 let OperandType = "OPERAND_PCREL",
 437     ParserMatchClass = X86AbsMemAsmOperand,
 438     PrintMethod = "printPCRelImm" in {
 439 def i32imm_pcrel : Operand<i32>;
 440 def i16imm_pcrel : Operand<i16>;
 441
 442 // Branch targets have OtherVT type and print as pc-relative values.
 443 def brtarget : Operand<OtherVT>;
 444 def brtarget8 : Operand<OtherVT>;
 445
 446 }
 447
 448 def X86MemOffs8AsmOperand : AsmOperandClass {
 449   let Name = "MemOffs8";
 450   let RenderMethod = "addMemOffsOperands";
 451   let SuperClasses = [X86Mem8AsmOperand];
 452 }
 453 def X86MemOffs16AsmOperand : AsmOperandClass {
 454   let Name = "MemOffs16";
 455   let RenderMethod = "addMemOffsOperands";
 456   let SuperClasses = [X86Mem16AsmOperand];
 457 }
 458 def X86MemOffs32AsmOperand : AsmOperandClass {
 459   let Name = "MemOffs32";
 460   let RenderMethod = "addMemOffsOperands";
 461   let SuperClasses = [X86Mem32AsmOperand];
 462 }
 463 def X86MemOffs64AsmOperand : AsmOperandClass {
 464   let Name = "MemOffs64";
 465   let RenderMethod = "addMemOffsOperands";
 466   let SuperClasses = [X86Mem64AsmOperand];
 467 }
 468
 469 let OperandType = "OPERAND_MEMORY" in {
 470 def offset8 : Operand<i64> {
 471   let ParserMatchClass = X86MemOffs8AsmOperand;
 472   let PrintMethod = "printMemOffs8"; }
 473 def offset16 : Operand<i64> {
 474   let ParserMatchClass = X86MemOffs16AsmOperand;
 475   let PrintMethod = "printMemOffs16"; }
 476 def offset32 : Operand<i64> {
 477   let ParserMatchClass = X86MemOffs32AsmOperand;
 478   let PrintMethod = "printMemOffs32"; }
 479 def offset64 : Operand<i64> {
 480   let ParserMatchClass = X86MemOffs64AsmOperand;
 481   let PrintMethod = "printMemOffs64"; }
 482 }
 483
 484
 485 def SSECC : Operand<i8> {
 486   let PrintMethod = "printSSECC";
 487   let OperandType = "OPERAND_IMMEDIATE";
 488 }
 489
 490 def AVXCC : Operand<i8> {
 491   let PrintMethod = "printAVXCC";
 492   let OperandType = "OPERAND_IMMEDIATE";
 493 }
 494
 495 class ImmSExtAsmOperandClass : AsmOperandClass {
 496   let SuperClasses = [ImmAsmOperand];
 497   let RenderMethod = "addImmOperands";
 498 }
 499
 500 class ImmZExtAsmOperandClass : AsmOperandClass {
 501   let SuperClasses = [ImmAsmOperand];
 502   let RenderMethod = "addImmOperands";
 503 }
 504
 505 def X86GR32orGR64AsmOperand : AsmOperandClass {
 506   let Name = "GR32orGR64";
 507 }
 508
 509 def GR32orGR64 : RegisterOperand<GR32> {
 510   let ParserMatchClass = X86GR32orGR64AsmOperand;
 511 }
 512
 513 def AVX512RC : Operand<i32> {
 514   let PrintMethod = "printRoundingControl";
 515   let OperandType = "OPERAND_IMMEDIATE";
 516 }
 517 // Sign-extended immediate classes. We don't need to define the full lattice
 518 // here because there is no instruction with an ambiguity between ImmSExti64i32
 519 // and ImmSExti32i8.
 520 //
 521 // The strange ranges come from the fact that the assembler always works with
 522 // 64-bit immediates, but for a 16-bit target value we want to accept both "-1"
 523 // (which will be a -1ULL), and "0xFF" (-1 in 16-bits).
 524
 525 // [0, 0x7FFFFFFF]                                            |
 526 //   [0xFFFFFFFF80000000, 0xFFFFFFFFFFFFFFFF]
 527 def ImmSExti64i32AsmOperand : ImmSExtAsmOperandClass {
 528   let Name = "ImmSExti64i32";
 529 }
 530
 531 // [0, 0x0000007F] | [0x000000000000FF80, 0x000000000000FFFF] |
 532 //   [0xFFFFFFFFFFFFFF80, 0xFFFFFFFFFFFFFFFF]
 533 def ImmSExti16i8AsmOperand : ImmSExtAsmOperandClass {
 534   let Name = "ImmSExti16i8";
 535   let SuperClasses = [ImmSExti64i32AsmOperand];
 536 }
 537
 538 // [0, 0x0000007F] | [0x00000000FFFFFF80, 0x00000000FFFFFFFF] |
 539 //   [0xFFFFFFFFFFFFFF80, 0xFFFFFFFFFFFFFFFF]
 540 def ImmSExti32i8AsmOperand : ImmSExtAsmOperandClass {
 541   let Name = "ImmSExti32i8";
 542 }
 543
 544 // [0, 0x000000FF]
 545 def ImmZExtu32u8AsmOperand : ImmZExtAsmOperandClass {
 546   let Name = "ImmZExtu32u8";
 547 }
 548
 549
 550 // [0, 0x0000007F]                                            |
 551 //   [0xFFFFFFFFFFFFFF80, 0xFFFFFFFFFFFFFFFF]
 552 def ImmSExti64i8AsmOperand : ImmSExtAsmOperandClass {
 553   let Name = "ImmSExti64i8";
 554   let SuperClasses = [ImmSExti16i8AsmOperand, ImmSExti32i8AsmOperand,
 555                       ImmSExti64i32AsmOperand];
 556 }
 557
 558 // A couple of more descriptive operand definitions.
 559 // 16-bits but only 8 bits are significant.
 560 def i16i8imm  : Operand<i16> {
 561   let ParserMatchClass = ImmSExti16i8AsmOperand;
 562   let OperandType = "OPERAND_IMMEDIATE";
 563 }
 564 // 32-bits but only 8 bits are significant.
 565 def i32i8imm  : Operand<i32> {
 566   let ParserMatchClass = ImmSExti32i8AsmOperand;
 567   let OperandType = "OPERAND_IMMEDIATE";
 568 }
 569 // 32-bits but only 8 bits are significant, and those 8 bits are unsigned.
 570 def u32u8imm  : Operand<i32> {
 571   let ParserMatchClass = ImmZExtu32u8AsmOperand;
 572   let OperandType = "OPERAND_IMMEDIATE";
 573 }
 574
 575 // 64-bits but only 32 bits are significant.
 576 def i64i32imm  : Operand<i64> {
 577   let ParserMatchClass = ImmSExti64i32AsmOperand;
 578   let OperandType = "OPERAND_IMMEDIATE";
 579 }
 580
 581 // 64-bits but only 32 bits are significant, and those bits are treated as being
 582 // pc relative.
 583 def i64i32imm_pcrel : Operand<i64> {
 584   let PrintMethod = "printPCRelImm";
 585   let ParserMatchClass = X86AbsMemAsmOperand;
 586   let OperandType = "OPERAND_PCREL";
 587 }
 588
 589 // 64-bits but only 8 bits are significant.
 590 def i64i8imm   : Operand<i64> {
 591   let ParserMatchClass = ImmSExti64i8AsmOperand;
 592   let OperandType = "OPERAND_IMMEDIATE";
 593 }
 594
 595 def lea64_32mem : Operand<i32> {
 596   let PrintMethod = "printi32mem";
 597   let MIOperandInfo = (ops GR64, i8imm, GR64_NOSP, i32imm, i8imm);
 598   let ParserMatchClass = X86MemAsmOperand;
 599 }
 600
 601 // Memory operands that use 64-bit pointers in both ILP32 and LP64.
 602 def lea64mem : Operand<i64> {
 603   let PrintMethod = "printi64mem";
 604   let MIOperandInfo = (ops GR64, i8imm, GR64_NOSP, i32imm, i8imm);
 605   let ParserMatchClass = X86MemAsmOperand;
 606 }
 607
 608
 609 //===----------------------------------------------------------------------===//
 610 // X86 Complex Pattern Definitions.
 611 //
 612
 613 // Define X86 specific addressing mode.
 614 def addr      : ComplexPattern<iPTR, 5, "SelectAddr", [], [SDNPWantParent]>;
 615 def lea32addr : ComplexPattern<i32, 5, "SelectLEAAddr",
 616                                [add, sub, mul, X86mul_imm, shl, or, frameindex],
 617                                []>;
 618 // In 64-bit mode 32-bit LEAs can use RIP-relative addressing.
 619 def lea64_32addr : ComplexPattern<i32, 5, "SelectLEA64_32Addr",
 620                                   [add, sub, mul, X86mul_imm, shl, or,
 621                                    frameindex, X86WrapperRIP],
 622                                   []>;
 623
 624 def tls32addr : ComplexPattern<i32, 5, "SelectTLSADDRAddr",
 625                                [tglobaltlsaddr], []>;
 626
 627 def tls32baseaddr : ComplexPattern<i32, 5, "SelectTLSADDRAddr",
 628                                [tglobaltlsaddr], []>;
 629
 630 def lea64addr : ComplexPattern<i64, 5, "SelectLEAAddr",
 631                         [add, sub, mul, X86mul_imm, shl, or, frameindex,
 632                          X86WrapperRIP], []>;
 633
 634 def tls64addr : ComplexPattern<i64, 5, "SelectTLSADDRAddr",
 635                                [tglobaltlsaddr], []>;
 636
 637 def tls64baseaddr : ComplexPattern<i64, 5, "SelectTLSADDRAddr",
 638                                [tglobaltlsaddr], []>;
 639
 640 //===----------------------------------------------------------------------===//
 641 // X86 Instruction Predicate Definitions.
 642 def HasCMov      : Predicate<"Subtarget->hasCMov()">;
 643 def NoCMov       : Predicate<"!Subtarget->hasCMov()">;
 644
 645 def HasMMX       : Predicate<"Subtarget->hasMMX()">;
 646 def Has3DNow     : Predicate<"Subtarget->has3DNow()">;
 647 def Has3DNowA    : Predicate<"Subtarget->has3DNowA()">;
 648 def HasSSE1      : Predicate<"Subtarget->hasSSE1()">;
 649 def UseSSE1      : Predicate<"Subtarget->hasSSE1() && !Subtarget->hasAVX()">;
 650 def HasSSE2      : Predicate<"Subtarget->hasSSE2()">;
 651 def UseSSE2      : Predicate<"Subtarget->hasSSE2() && !Subtarget->hasAVX()">;
 652 def HasSSE3      : Predicate<"Subtarget->hasSSE3()">;
 653 def UseSSE3      : Predicate<"Subtarget->hasSSE3() && !Subtarget->hasAVX()">;
 654 def HasSSSE3     : Predicate<"Subtarget->hasSSSE3()">;
 655 def UseSSSE3     : Predicate<"Subtarget->hasSSSE3() && !Subtarget->hasAVX()">;
 656 def HasSSE41     : Predicate<"Subtarget->hasSSE41()">;
 657 def UseSSE41     : Predicate<"Subtarget->hasSSE41() && !Subtarget->hasAVX()">;
 658 def HasSSE42     : Predicate<"Subtarget->hasSSE42()">;
 659 def UseSSE42     : Predicate<"Subtarget->hasSSE42() && !Subtarget->hasAVX()">;
 660 def HasSSE4A     : Predicate<"Subtarget->hasSSE4A()">;
 661 def HasAVX       : Predicate<"Subtarget->hasAVX()">;
 662 def HasAVX2      : Predicate<"Subtarget->hasAVX2()">;
 663 def HasAVX1Only  : Predicate<"Subtarget->hasAVX() && !Subtarget->hasAVX2()">;
 664 def HasAVX512    : Predicate<"Subtarget->hasAVX512()">,
 665                      AssemblerPredicate<"FeatureAVX512", "AVX-512 ISA">;
 666 def UseAVX       : Predicate<"Subtarget->hasAVX() && !Subtarget->hasAVX512()">;
 667 def UseAVX2      : Predicate<"Subtarget->hasAVX2() && !Subtarget->hasAVX512()">;
 668 def NoAVX512       : Predicate<"!Subtarget->hasAVX512()">;
 669 def HasCDI       : Predicate<"Subtarget->hasCDI()">;
 670 def HasPFI       : Predicate<"Subtarget->hasPFI()">;
 671 def HasERI       : Predicate<"Subtarget->hasERI()">;
 672
 673 def HasPOPCNT    : Predicate<"Subtarget->hasPOPCNT()">;
 674 def HasAES       : Predicate<"Subtarget->hasAES()">;
 675 def HasPCLMUL    : Predicate<"Subtarget->hasPCLMUL()">;
 676 def HasFMA       : Predicate<"Subtarget->hasFMA()">;
 677 def UseFMAOnAVX  : Predicate<"Subtarget->hasFMA() && !Subtarget->hasAVX512()">;
 678 def HasFMA4      : Predicate<"Subtarget->hasFMA4()">;
 679 def HasXOP       : Predicate<"Subtarget->hasXOP()">;
 680 def HasTBM       : Predicate<"Subtarget->hasTBM()">;
 681 def HasMOVBE     : Predicate<"Subtarget->hasMOVBE()">;
 682 def HasRDRAND    : Predicate<"Subtarget->hasRDRAND()">;
 683 def HasF16C      : Predicate<"Subtarget->hasF16C()">;
 684 def HasFSGSBase  : Predicate<"Subtarget->hasFSGSBase()">;
 685 def HasLZCNT     : Predicate<"Subtarget->hasLZCNT()">;
 686 def HasBMI       : Predicate<"Subtarget->hasBMI()">;
 687 def HasBMI2      : Predicate<"Subtarget->hasBMI2()">;
 688 def HasRTM       : Predicate<"Subtarget->hasRTM()">;
 689 def HasHLE       : Predicate<"Subtarget->hasHLE()">;
 690 def HasTSX       : Predicate<"Subtarget->hasRTM() || Subtarget->hasHLE()">;
 691 def HasADX       : Predicate<"Subtarget->hasADX()">;
 692 def HasSHA       : Predicate<"Subtarget->hasSHA()">;
 693 def HasPRFCHW    : Predicate<"Subtarget->hasPRFCHW()">;
 694 def HasRDSEED    : Predicate<"Subtarget->hasRDSEED()">;
 695 def HasPrefetchW : Predicate<"Subtarget->hasPRFCHW()">;
 696 def FPStackf32   : Predicate<"!Subtarget->hasSSE1()">;
 697 def FPStackf64   : Predicate<"!Subtarget->hasSSE2()">;
 698 def HasCmpxchg16b: Predicate<"Subtarget->hasCmpxchg16b()">;
 699 def Not64BitMode : Predicate<"!Subtarget->is64Bit()">,
 700                              AssemblerPredicate<"!Mode64Bit", "Not 64-bit mode">;
 701 def In64BitMode  : Predicate<"Subtarget->is64Bit()">,
 702                              AssemblerPredicate<"Mode64Bit", "64-bit mode">;
 703 def IsWin64      : Predicate<"Subtarget->isTargetWin64()">;
 704 def IsNaCl       : Predicate<"Subtarget->isTargetNaCl()">;
 705 def NotNaCl      : Predicate<"!Subtarget->isTargetNaCl()">;
 706 def SmallCode    : Predicate<"TM.getCodeModel() == CodeModel::Small">;
 707 def KernelCode   : Predicate<"TM.getCodeModel() == CodeModel::Kernel">;
 708 def FarData      : Predicate<"TM.getCodeModel() != CodeModel::Small &&"
 709                              "TM.getCodeModel() != CodeModel::Kernel">;
 710 def NearData     : Predicate<"TM.getCodeModel() == CodeModel::Small ||"
 711                              "TM.getCodeModel() == CodeModel::Kernel">;
 712 def IsStatic     : Predicate<"TM.getRelocationModel() == Reloc::Static">;
 713 def IsNotPIC     : Predicate<"TM.getRelocationModel() != Reloc::PIC_">;
 714 def OptForSize   : Predicate<"OptForSize">;
 715 def OptForSpeed  : Predicate<"!OptForSize">;
 716 def FastBTMem    : Predicate<"!Subtarget->isBTMemSlow()">;
 717 def CallImmAddr  : Predicate<"Subtarget->IsLegalToCallImmediateAddr(TM)">;
 718 def FavorMemIndirectCall  : Predicate<"!Subtarget->callRegIndirect()">;
 719
 720 //===----------------------------------------------------------------------===//
 721 // X86 Instruction Format Definitions.
 722 //
 723
 724 include "X86InstrFormats.td"
 725
 726 //===----------------------------------------------------------------------===//
 727 // Pattern fragments.
 728 //
 729
 730 // X86 specific condition code. These correspond to CondCode in
 731 // X86InstrInfo.h. They must be kept in synch.
 732 def X86_COND_A   : PatLeaf<(i8 0)>;  // alt. COND_NBE
 733 def X86_COND_AE  : PatLeaf<(i8 1)>;  // alt. COND_NC
 734 def X86_COND_B   : PatLeaf<(i8 2)>;  // alt. COND_C
 735 def X86_COND_BE  : PatLeaf<(i8 3)>;  // alt. COND_NA
 736 def X86_COND_E   : PatLeaf<(i8 4)>;  // alt. COND_Z
 737 def X86_COND_G   : PatLeaf<(i8 5)>;  // alt. COND_NLE
 738 def X86_COND_GE  : PatLeaf<(i8 6)>;  // alt. COND_NL
 739 def X86_COND_L   : PatLeaf<(i8 7)>;  // alt. COND_NGE
 740 def X86_COND_LE  : PatLeaf<(i8 8)>;  // alt. COND_NG
 741 def X86_COND_NE  : PatLeaf<(i8 9)>;  // alt. COND_NZ
 742 def X86_COND_NO  : PatLeaf<(i8 10)>;
 743 def X86_COND_NP  : PatLeaf<(i8 11)>; // alt. COND_PO
 744 def X86_COND_NS  : PatLeaf<(i8 12)>;
 745 def X86_COND_O   : PatLeaf<(i8 13)>;
 746 def X86_COND_P   : PatLeaf<(i8 14)>; // alt. COND_PE
 747 def X86_COND_S   : PatLeaf<(i8 15)>;
 748
 749 let FastIselShouldIgnore = 1 in { // FastIsel should ignore all simm8 instrs.
 750   def i16immSExt8  : ImmLeaf<i16, [{ return Imm == (int8_t)Imm; }]>;
 751   def i32immSExt8  : ImmLeaf<i32, [{ return Imm == (int8_t)Imm; }]>;
 752   def i64immSExt8  : ImmLeaf<i64, [{ return Imm == (int8_t)Imm; }]>;
 753 }
 754
 755 def i64immSExt32 : ImmLeaf<i64, [{ return Imm == (int32_t)Imm; }]>;
 756
 757
 758 // i64immZExt32 predicate - True if the 64-bit immediate fits in a 32-bit
 759 // unsigned field.
 760 def i64immZExt32 : ImmLeaf<i64, [{ return (uint64_t)Imm == (uint32_t)Imm; }]>;
 761
 762 def i64immZExt32SExt8 : ImmLeaf<i64, [{
 763   return (uint64_t)Imm == (uint32_t)Imm && (int32_t)Imm == (int8_t)Imm;
 764 }]>;
 765
 766 // Helper fragments for loads.
 767 // It's always safe to treat a anyext i16 load as a i32 load if the i16 is
 768 // known to be 32-bit aligned or better. Ditto for i8 to i16.
 769 def loadi16 : PatFrag<(ops node:$ptr), (i16 (unindexedload node:$ptr)), [{
 770   LoadSDNode *LD = cast<LoadSDNode>(N);
 771   ISD::LoadExtType ExtType = LD->getExtensionType();
 772   if (ExtType == ISD::NON_EXTLOAD)
 773     return true;
 774   if (ExtType == ISD::EXTLOAD)
 775     return LD->getAlignment() >= 2 && !LD->isVolatile();
 776   return false;
 777 }]>;
 778
 779 def loadi16_anyext : PatFrag<(ops node:$ptr), (i32 (unindexedload node:$ptr)),[{
 780   LoadSDNode *LD = cast<LoadSDNode>(N);
 781   ISD::LoadExtType ExtType = LD->getExtensionType();
 782   if (ExtType == ISD::EXTLOAD)
 783     return LD->getAlignment() >= 2 && !LD->isVolatile();
 784   return false;
 785 }]>;
 786
 787 def loadi32 : PatFrag<(ops node:$ptr), (i32 (unindexedload node:$ptr)), [{
 788   LoadSDNode *LD = cast<LoadSDNode>(N);
 789   ISD::LoadExtType ExtType = LD->getExtensionType();
 790   if (ExtType == ISD::NON_EXTLOAD)
 791     return true;
 792   if (ExtType == ISD::EXTLOAD)
 793     return LD->getAlignment() >= 4 && !LD->isVolatile();
 794   return false;
 795 }]>;
 796
 797 def loadi8  : PatFrag<(ops node:$ptr), (i8  (load node:$ptr))>;
 798 def loadi64 : PatFrag<(ops node:$ptr), (i64 (load node:$ptr))>;
 799 def loadf32 : PatFrag<(ops node:$ptr), (f32 (load node:$ptr))>;
 800 def loadf64 : PatFrag<(ops node:$ptr), (f64 (load node:$ptr))>;
 801 def loadf80 : PatFrag<(ops node:$ptr), (f80 (load node:$ptr))>;
 802
 803 def sextloadi16i8  : PatFrag<(ops node:$ptr), (i16 (sextloadi8 node:$ptr))>;
 804 def sextloadi32i8  : PatFrag<(ops node:$ptr), (i32 (sextloadi8 node:$ptr))>;
 805 def sextloadi32i16 : PatFrag<(ops node:$ptr), (i32 (sextloadi16 node:$ptr))>;
 806 def sextloadi64i8  : PatFrag<(ops node:$ptr), (i64 (sextloadi8 node:$ptr))>;
 807 def sextloadi64i16 : PatFrag<(ops node:$ptr), (i64 (sextloadi16 node:$ptr))>;
 808 def sextloadi64i32 : PatFrag<(ops node:$ptr), (i64 (sextloadi32 node:$ptr))>;
 809
 810 def zextloadi8i1   : PatFrag<(ops node:$ptr), (i8  (zextloadi1 node:$ptr))>;
 811 def zextloadi16i1  : PatFrag<(ops node:$ptr), (i16 (zextloadi1 node:$ptr))>;
 812 def zextloadi32i1  : PatFrag<(ops node:$ptr), (i32 (zextloadi1 node:$ptr))>;
 813 def zextloadi16i8  : PatFrag<(ops node:$ptr), (i16 (zextloadi8 node:$ptr))>;
 814 def zextloadi32i8  : PatFrag<(ops node:$ptr), (i32 (zextloadi8 node:$ptr))>;
 815 def zextloadi32i16 : PatFrag<(ops node:$ptr), (i32 (zextloadi16 node:$ptr))>;
 816 def zextloadi64i1  : PatFrag<(ops node:$ptr), (i64 (zextloadi1 node:$ptr))>;
 817 def zextloadi64i8  : PatFrag<(ops node:$ptr), (i64 (zextloadi8 node:$ptr))>;
 818 def zextloadi64i16 : PatFrag<(ops node:$ptr), (i64 (zextloadi16 node:$ptr))>;
 819 def zextloadi64i32 : PatFrag<(ops node:$ptr), (i64 (zextloadi32 node:$ptr))>;
 820
 821 def extloadi8i1    : PatFrag<(ops node:$ptr), (i8  (extloadi1 node:$ptr))>;
 822 def extloadi16i1   : PatFrag<(ops node:$ptr), (i16 (extloadi1 node:$ptr))>;
 823 def extloadi32i1   : PatFrag<(ops node:$ptr), (i32 (extloadi1 node:$ptr))>;
 824 def extloadi16i8   : PatFrag<(ops node:$ptr), (i16 (extloadi8 node:$ptr))>;
 825 def extloadi32i8   : PatFrag<(ops node:$ptr), (i32 (extloadi8 node:$ptr))>;
 826 def extloadi32i16  : PatFrag<(ops node:$ptr), (i32 (extloadi16 node:$ptr))>;
 827 def extloadi64i1   : PatFrag<(ops node:$ptr), (i64 (extloadi1 node:$ptr))>;
 828 def extloadi64i8   : PatFrag<(ops node:$ptr), (i64 (extloadi8 node:$ptr))>;
 829 def extloadi64i16  : PatFrag<(ops node:$ptr), (i64 (extloadi16 node:$ptr))>;
 830 def extloadi64i32  : PatFrag<(ops node:$ptr), (i64 (extloadi32 node:$ptr))>;
 831
 832
 833 // An 'and' node with a single use.
 834 def and_su : PatFrag<(ops node:$lhs, node:$rhs), (and node:$lhs, node:$rhs), [{
 835   return N->hasOneUse();
 836 }]>;
 837 // An 'srl' node with a single use.
 838 def srl_su : PatFrag<(ops node:$lhs, node:$rhs), (srl node:$lhs, node:$rhs), [{
 839   return N->hasOneUse();
 840 }]>;
 841 // An 'trunc' node with a single use.
 842 def trunc_su : PatFrag<(ops node:$src), (trunc node:$src), [{
 843   return N->hasOneUse();
 844 }]>;
 845
 846 //===----------------------------------------------------------------------===//
 847 // Instruction list.
 848 //
 849
 850 // Nop
 851 let neverHasSideEffects = 1, SchedRW = [WriteZero] in {
 852   def NOOP : I<0x90, RawFrm, (outs), (ins), "nop", [], IIC_NOP>;
 853   def NOOPW : I<0x1f, MRM0m, (outs), (ins i16mem:$zero),
 854                 "nop{w}\t$zero", [], IIC_NOP>, TB, OpSize;
 855   def NOOPL : I<0x1f, MRM0m, (outs), (ins i32mem:$zero),
 856                 "nop{l}\t$zero", [], IIC_NOP>, TB;
 857 }
 858
 859
 860 // Constructing a stack frame.
 861 def ENTER : Ii16<0xC8, RawFrmImm8, (outs), (ins i16imm:$len, i8imm:$lvl),
 862                  "enter\t$len, $lvl", [], IIC_ENTER>, Sched<[WriteMicrocoded]>;
 863
 864 let SchedRW = [WriteALU] in {
 865 let Defs = [EBP, ESP], Uses = [EBP, ESP], mayLoad = 1, neverHasSideEffects=1 in
 866 def LEAVE    : I<0xC9, RawFrm,
 867                  (outs), (ins), "leave", [], IIC_LEAVE>,
 868                  Requires<[Not64BitMode]>;
 869
 870 let Defs = [RBP,RSP], Uses = [RBP,RSP], mayLoad = 1, neverHasSideEffects = 1 in
 871 def LEAVE64  : I<0xC9, RawFrm,
 872                  (outs), (ins), "leave", [], IIC_LEAVE>,
 873                  Requires<[In64BitMode]>;
 874 } // SchedRW
 875
 876 //===----------------------------------------------------------------------===//
 877 //  Miscellaneous Instructions.
 878 //
 879
 880 let Defs = [ESP], Uses = [ESP], neverHasSideEffects=1 in {
 881 let mayLoad = 1, SchedRW = [WriteLoad] in {
 882 def POP16r  : I<0x58, AddRegFrm, (outs GR16:$reg), (ins), "pop{w}\t$reg", [],
 883                 IIC_POP_REG16>, OpSize;
 884 def POP32r  : I<0x58, AddRegFrm, (outs GR32:$reg), (ins), "pop{l}\t$reg", [],
 885                 IIC_POP_REG>;
 886 def POP16rmr: I<0x8F, MRM0r, (outs GR16:$reg), (ins), "pop{w}\t$reg", [],
 887                 IIC_POP_REG>, OpSize;
 888 def POP16rmm: I<0x8F, MRM0m, (outs), (ins i16mem:$dst), "pop{w}\t$dst", [],
 889                 IIC_POP_MEM>, OpSize;
 890 def POP32rmr: I<0x8F, MRM0r, (outs GR32:$reg), (ins), "pop{l}\t$reg", [],
 891                 IIC_POP_REG>;
 892 def POP32rmm: I<0x8F, MRM0m, (outs), (ins i32mem:$dst), "pop{l}\t$dst", [],
 893                 IIC_POP_MEM>;
 894
 895 def POPF16   : I<0x9D, RawFrm, (outs), (ins), "popf{w}", [], IIC_POP_F>, OpSize;
 896 def POPF32   : I<0x9D, RawFrm, (outs), (ins), "popf{l|d}", [], IIC_POP_FD>,
 897                Requires<[Not64BitMode]>;
 898 } // mayLoad, SchedRW
 899
 900 let mayStore = 1, SchedRW = [WriteStore] in {
 901 def PUSH16r  : I<0x50, AddRegFrm, (outs), (ins GR16:$reg), "push{w}\t$reg",[],
 902                  IIC_PUSH_REG>, OpSize;
 903 def PUSH32r  : I<0x50, AddRegFrm, (outs), (ins GR32:$reg), "push{l}\t$reg",[],
 904                  IIC_PUSH_REG>;
 905 def PUSH16rmr: I<0xFF, MRM6r, (outs), (ins GR16:$reg), "push{w}\t$reg",[],
 906                  IIC_PUSH_REG>, OpSize;
 907 def PUSH16rmm: I<0xFF, MRM6m, (outs), (ins i16mem:$src), "push{w}\t$src",[],
 908                  IIC_PUSH_MEM>,
 909   OpSize;
 910 def PUSH32rmr: I<0xFF, MRM6r, (outs), (ins GR32:$reg), "push{l}\t$reg",[],
 911                  IIC_PUSH_REG>;
 912 def PUSH32rmm: I<0xFF, MRM6m, (outs), (ins i32mem:$src), "push{l}\t$src",[],
 913                  IIC_PUSH_MEM>;
 914
 915 def PUSHi8   : Ii8<0x6a, RawFrm, (outs), (ins i32i8imm:$imm),
 916                       "push{l}\t$imm", [], IIC_PUSH_IMM>;
 917 def PUSHi16  : Ii16<0x68, RawFrm, (outs), (ins i16imm:$imm),
 918                       "push{w}\t$imm", [], IIC_PUSH_IMM>, OpSize;
 919 def PUSHi32  : Ii32<0x68, RawFrm, (outs), (ins i32imm:$imm),
 920                       "push{l}\t$imm", [], IIC_PUSH_IMM>;
 921
 922 def PUSHF16  : I<0x9C, RawFrm, (outs), (ins), "pushf{w}", [], IIC_PUSH_F>,
 923                  OpSize;
 924 def PUSHF32  : I<0x9C, RawFrm, (outs), (ins), "pushf{l|d}", [], IIC_PUSH_F>,
 925                Requires<[Not64BitMode]>;
 926
 927 } // mayStore, SchedRW
 928 }
 929
 930 let Defs = [RSP], Uses = [RSP], neverHasSideEffects=1 in {
 931 let mayLoad = 1, SchedRW = [WriteLoad] in {
 932 def POP64r   : I<0x58, AddRegFrm,
 933                  (outs GR64:$reg), (ins), "pop{q}\t$reg", [], IIC_POP_REG>;
 934 def POP64rmr: I<0x8F, MRM0r, (outs GR64:$reg), (ins), "pop{q}\t$reg", [],
 935                 IIC_POP_REG>;
 936 def POP64rmm: I<0x8F, MRM0m, (outs), (ins i64mem:$dst), "pop{q}\t$dst", [],
 937                 IIC_POP_MEM>;
 938 } // mayLoad, SchedRW
 939 let mayStore = 1, SchedRW = [WriteStore] in {
 940 def PUSH64r  : I<0x50, AddRegFrm,
 941                  (outs), (ins GR64:$reg), "push{q}\t$reg", [], IIC_PUSH_REG>;
 942 def PUSH64rmr: I<0xFF, MRM6r, (outs), (ins GR64:$reg), "push{q}\t$reg", [],
 943                  IIC_PUSH_REG>;
 944 def PUSH64rmm: I<0xFF, MRM6m, (outs), (ins i64mem:$src), "push{q}\t$src", [],
 945                  IIC_PUSH_MEM>;
 946 } // mayStore, SchedRW
 947 }
 948
 949 let Defs = [RSP], Uses = [RSP], neverHasSideEffects = 1, mayStore = 1,
 950     SchedRW = [WriteStore] in {
 951 def PUSH64i8   : Ii8<0x6a, RawFrm, (outs), (ins i64i8imm:$imm),
 952                      "push{q}\t$imm", [], IIC_PUSH_IMM>;
 953 def PUSH64i16  : Ii16<0x68, RawFrm, (outs), (ins i16imm:$imm),
 954                       "push{q}\t$imm", [], IIC_PUSH_IMM>;
 955 def PUSH64i32  : Ii32<0x68, RawFrm, (outs), (ins i64i32imm:$imm),
 956                       "push{q}\t$imm", [], IIC_PUSH_IMM>;
 957 }
 958
 959 let Defs = [RSP, EFLAGS], Uses = [RSP], mayLoad = 1, neverHasSideEffects=1 in
 960 def POPF64   : I<0x9D, RawFrm, (outs), (ins), "popfq", [], IIC_POP_FD>,
 961                Requires<[In64BitMode]>, Sched<[WriteLoad]>;
 962 let Defs = [RSP], Uses = [RSP, EFLAGS], mayStore = 1, neverHasSideEffects=1 in
 963 def PUSHF64    : I<0x9C, RawFrm, (outs), (ins), "pushfq", [], IIC_PUSH_F>,
 964                  Requires<[In64BitMode]>, Sched<[WriteStore]>;
 965
 966 let Defs = [EDI, ESI, EBP, EBX, EDX, ECX, EAX, ESP], Uses = [ESP],
 967     mayLoad = 1, neverHasSideEffects = 1, SchedRW = [WriteLoad] in {
 968 def POPA32   : I<0x61, RawFrm, (outs), (ins), "popa{l}", [], IIC_POP_A>,
 969                Requires<[Not64BitMode]>;
 970 }
 971 let Defs = [ESP], Uses = [EDI, ESI, EBP, EBX, EDX, ECX, EAX, ESP],
 972     mayStore = 1, neverHasSideEffects = 1, SchedRW = [WriteStore] in {
 973 def PUSHA32  : I<0x60, RawFrm, (outs), (ins), "pusha{l}", [], IIC_PUSH_A>,
 974                Requires<[Not64BitMode]>;
 975 }
 976
 977 let Constraints = "$src = $dst", SchedRW = [WriteALU] in {
 978 // GR32 = bswap GR32
 979 def BSWAP32r : I<0xC8, AddRegFrm,
 980                  (outs GR32:$dst), (ins GR32:$src),
 981                  "bswap{l}\t$dst",
 982                  [(set GR32:$dst, (bswap GR32:$src))], IIC_BSWAP>, TB;
 983
 984 def BSWAP64r : RI<0xC8, AddRegFrm, (outs GR64:$dst), (ins GR64:$src),
 985                   "bswap{q}\t$dst",
 986                   [(set GR64:$dst, (bswap GR64:$src))], IIC_BSWAP>, TB;
 987 } // Constraints = "$src = $dst", SchedRW
 988
 989 // Bit scan instructions.
 990 let Defs = [EFLAGS] in {
 991 def BSF16rr  : I<0xBC, MRMSrcReg, (outs GR16:$dst), (ins GR16:$src),
 992                  "bsf{w}\t{$src, $dst|$dst, $src}",
 993                  [(set GR16:$dst, EFLAGS, (X86bsf GR16:$src))],
 994                   IIC_BIT_SCAN_REG>, TB, OpSize, Sched<[WriteShift]>;
 995 def BSF16rm  : I<0xBC, MRMSrcMem, (outs GR16:$dst), (ins i16mem:$src),
 996                  "bsf{w}\t{$src, $dst|$dst, $src}",
 997                  [(set GR16:$dst, EFLAGS, (X86bsf (loadi16 addr:$src)))],
 998                   IIC_BIT_SCAN_MEM>, TB, OpSize, Sched<[WriteShiftLd]>;
 999 def BSF32rr  : I<0xBC, MRMSrcReg, (outs GR32:$dst), (ins GR32:$src),
1000                  "bsf{l}\t{$src, $dst|$dst, $src}",
1001                  [(set GR32:$dst, EFLAGS, (X86bsf GR32:$src))],
1002                  IIC_BIT_SCAN_REG>, TB,
1003                Sched<[WriteShift]>;
1004 def BSF32rm  : I<0xBC, MRMSrcMem, (outs GR32:$dst), (ins i32mem:$src),
1005                  "bsf{l}\t{$src, $dst|$dst, $src}",
1006                  [(set GR32:$dst, EFLAGS, (X86bsf (loadi32 addr:$src)))],
1007                  IIC_BIT_SCAN_MEM>, TB, Sched<[WriteShiftLd]>;
1008 def BSF64rr  : RI<0xBC, MRMSrcReg, (outs GR64:$dst), (ins GR64:$src),
1009                   "bsf{q}\t{$src, $dst|$dst, $src}",
1010                   [(set GR64:$dst, EFLAGS, (X86bsf GR64:$src))],
1011                   IIC_BIT_SCAN_REG>, TB, Sched<[WriteShift]>;
1012 def BSF64rm  : RI<0xBC, MRMSrcMem, (outs GR64:$dst), (ins i64mem:$src),
1013                   "bsf{q}\t{$src, $dst|$dst, $src}",
1014                   [(set GR64:$dst, EFLAGS, (X86bsf (loadi64 addr:$src)))],
1015                   IIC_BIT_SCAN_MEM>, TB, Sched<[WriteShiftLd]>;
1016
1017 def BSR16rr  : I<0xBD, MRMSrcReg, (outs GR16:$dst), (ins GR16:$src),
1018                  "bsr{w}\t{$src, $dst|$dst, $src}",
1019                  [(set GR16:$dst, EFLAGS, (X86bsr GR16:$src))],
1020                  IIC_BIT_SCAN_REG>,
1021                  TB, OpSize, Sched<[WriteShift]>;
1022 def BSR16rm  : I<0xBD, MRMSrcMem, (outs GR16:$dst), (ins i16mem:$src),
1023                  "bsr{w}\t{$src, $dst|$dst, $src}",
1024                  [(set GR16:$dst, EFLAGS, (X86bsr (loadi16 addr:$src)))],
1025                  IIC_BIT_SCAN_MEM>, TB,
1026                  OpSize, Sched<[WriteShiftLd]>;
1027 def BSR32rr  : I<0xBD, MRMSrcReg, (outs GR32:$dst), (ins GR32:$src),
1028                  "bsr{l}\t{$src, $dst|$dst, $src}",
1029                  [(set GR32:$dst, EFLAGS, (X86bsr GR32:$src))],
1030                  IIC_BIT_SCAN_REG>, TB,
1031                Sched<[WriteShift]>;
1032 def BSR32rm  : I<0xBD, MRMSrcMem, (outs GR32:$dst), (ins i32mem:$src),
1033                  "bsr{l}\t{$src, $dst|$dst, $src}",
1034                  [(set GR32:$dst, EFLAGS, (X86bsr (loadi32 addr:$src)))],
1035                  IIC_BIT_SCAN_MEM>, TB, Sched<[WriteShiftLd]>;
1036 def BSR64rr  : RI<0xBD, MRMSrcReg, (outs GR64:$dst), (ins GR64:$src),
1037                   "bsr{q}\t{$src, $dst|$dst, $src}",
1038                   [(set GR64:$dst, EFLAGS, (X86bsr GR64:$src))], IIC_BIT_SCAN_REG>, TB,
1039                Sched<[WriteShift]>;
1040 def BSR64rm  : RI<0xBD, MRMSrcMem, (outs GR64:$dst), (ins i64mem:$src),
1041                   "bsr{q}\t{$src, $dst|$dst, $src}",
1042                   [(set GR64:$dst, EFLAGS, (X86bsr (loadi64 addr:$src)))],
1043                   IIC_BIT_SCAN_MEM>, TB, Sched<[WriteShiftLd]>;
1044 } // Defs = [EFLAGS]
1045
1046 let SchedRW = [WriteMicrocoded] in {
1047 // These uses the DF flag in the EFLAGS register to inc or dec EDI and ESI
1048 let Defs = [EDI,ESI], Uses = [EDI,ESI,EFLAGS] in {
1049 def MOVSB : I<0xA4, RawFrm, (outs), (ins), "movsb", [], IIC_MOVS>;
1050 def MOVSW : I<0xA5, RawFrm, (outs), (ins), "movsw", [], IIC_MOVS>, OpSize;
1051 def MOVSD : I<0xA5, RawFrm, (outs), (ins), "movs{l|d}", [], IIC_MOVS>;
1052 def MOVSQ : RI<0xA5, RawFrm, (outs), (ins), "movsq", [], IIC_MOVS>;
1053 }
1054
1055 // These uses the DF flag in the EFLAGS register to inc or dec EDI and ESI
1056 let Defs = [EDI], Uses = [AL,EDI,EFLAGS] in
1057 def STOSB : I<0xAA, RawFrm, (outs), (ins), "stosb", [], IIC_STOS>;
1058 let Defs = [EDI], Uses = [AX,EDI,EFLAGS] in
1059 def STOSW : I<0xAB, RawFrm, (outs), (ins), "stosw", [], IIC_STOS>, OpSize;
1060 let Defs = [EDI], Uses = [EAX,EDI,EFLAGS] in
1061 def STOSD : I<0xAB, RawFrm, (outs), (ins), "stos{l|d}", [], IIC_STOS>;
1062 let Defs = [RCX,RDI], Uses = [RAX,RCX,RDI,EFLAGS] in
1063 def STOSQ : RI<0xAB, RawFrm, (outs), (ins), "stosq", [], IIC_STOS>;
1064
1065 def SCAS8 : I<0xAE, RawFrm, (outs), (ins), "scasb", [], IIC_SCAS>;
1066 def SCAS16 : I<0xAF, RawFrm, (outs), (ins), "scasw", [], IIC_SCAS>, OpSize;
1067 def SCAS32 : I<0xAF, RawFrm, (outs), (ins), "scas{l|d}", [], IIC_SCAS>;
1068 def SCAS64 : RI<0xAF, RawFrm, (outs), (ins), "scasq", [], IIC_SCAS>;
1069
1070 def CMPS8 : I<0xA6, RawFrm, (outs), (ins), "cmpsb", [], IIC_CMPS>;
1071 def CMPS16 : I<0xA7, RawFrm, (outs), (ins), "cmpsw", [], IIC_CMPS>, OpSize;
1072 def CMPS32 : I<0xA7, RawFrm, (outs), (ins), "cmps{l|d}", [], IIC_CMPS>;
1073 def CMPS64 : RI<0xA7, RawFrm, (outs), (ins), "cmpsq", [], IIC_CMPS>;
1074 } // SchedRW
1075
1076 //===----------------------------------------------------------------------===//
1077 //  Move Instructions.
1078 //
1079 let SchedRW = [WriteMove] in {
1080 let neverHasSideEffects = 1 in {
1081 def MOV8rr  : I<0x88, MRMDestReg, (outs GR8 :$dst), (ins GR8 :$src),
1082                 "mov{b}\t{$src, $dst|$dst, $src}", [], IIC_MOV>;
1083 def MOV16rr : I<0x89, MRMDestReg, (outs GR16:$dst), (ins GR16:$src),
1084                 "mov{w}\t{$src, $dst|$dst, $src}", [], IIC_MOV>, OpSize;
1085 def MOV32rr : I<0x89, MRMDestReg, (outs GR32:$dst), (ins GR32:$src),
1086                 "mov{l}\t{$src, $dst|$dst, $src}", [], IIC_MOV>;
1087 def MOV64rr : RI<0x89, MRMDestReg, (outs GR64:$dst), (ins GR64:$src),
1088                  "mov{q}\t{$src, $dst|$dst, $src}", [], IIC_MOV>;
1089 }
1090
1091 let isReMaterializable = 1, isAsCheapAsAMove = 1 in {
1092 def MOV8ri  : Ii8 <0xB0, AddRegFrm, (outs GR8 :$dst), (ins i8imm :$src),
1093                    "mov{b}\t{$src, $dst|$dst, $src}",
1094                    [(set GR8:$dst, imm:$src)], IIC_MOV>;
1095 def MOV16ri : Ii16<0xB8, AddRegFrm, (outs GR16:$dst), (ins i16imm:$src),
1096                    "mov{w}\t{$src, $dst|$dst, $src}",
1097                    [(set GR16:$dst, imm:$src)], IIC_MOV>, OpSize;
1098 def MOV32ri : Ii32<0xB8, AddRegFrm, (outs GR32:$dst), (ins i32imm:$src),
1099                    "mov{l}\t{$src, $dst|$dst, $src}",
1100                    [(set GR32:$dst, imm:$src)], IIC_MOV>;
1101 def MOV64ri : RIi64<0xB8, AddRegFrm, (outs GR64:$dst), (ins i64imm:$src),
1102                     "movabs{q}\t{$src, $dst|$dst, $src}",
1103                     [(set GR64:$dst, imm:$src)], IIC_MOV>;
1104 def MOV64ri32 : RIi32<0xC7, MRM0r, (outs GR64:$dst), (ins i64i32imm:$src),
1105                       "mov{q}\t{$src, $dst|$dst, $src}",
1106                       [(set GR64:$dst, i64immSExt32:$src)], IIC_MOV>;
1107 }
1108 } // SchedRW
1109
1110 let SchedRW = [WriteStore] in {
1111 def MOV8mi  : Ii8 <0xC6, MRM0m, (outs), (ins i8mem :$dst, i8imm :$src),
1112                    "mov{b}\t{$src, $dst|$dst, $src}",
1113                    [(store (i8 imm:$src), addr:$dst)], IIC_MOV_MEM>;
1114 def MOV16mi : Ii16<0xC7, MRM0m, (outs), (ins i16mem:$dst, i16imm:$src),
1115                    "mov{w}\t{$src, $dst|$dst, $src}",
1116                    [(store (i16 imm:$src), addr:$dst)], IIC_MOV_MEM>, OpSize;
1117 def MOV32mi : Ii32<0xC7, MRM0m, (outs), (ins i32mem:$dst, i32imm:$src),
1118                    "mov{l}\t{$src, $dst|$dst, $src}",
1119                    [(store (i32 imm:$src), addr:$dst)], IIC_MOV_MEM>;
1120 def MOV64mi32 : RIi32<0xC7, MRM0m, (outs), (ins i64mem:$dst, i64i32imm:$src),
1121                       "mov{q}\t{$src, $dst|$dst, $src}",
1122                       [(store i64immSExt32:$src, addr:$dst)], IIC_MOV_MEM>;
1123 } // SchedRW
1124
1125 let hasSideEffects = 0 in {
1126
1127 /// moffs8, moffs16 and moffs32 versions of moves.  The immediate is a
1128 /// 32-bit offset from the PC.  These are only valid in x86-32 mode.
1129 let SchedRW = [WriteALU] in {
1130 let mayLoad = 1 in {
1131 def MOV8o8a : Ii32 <0xA0, RawFrm, (outs), (ins offset8:$src),
1132                    "mov{b}\t{$src, %al|al, $src}", [], IIC_MOV_MEM>,
1133                    Requires<[Not64BitMode]>;
1134 def MOV16o16a : Ii32 <0xA1, RawFrm, (outs), (ins offset16:$src),
1135                       "mov{w}\t{$src, %ax|ax, $src}", [], IIC_MOV_MEM>, OpSize,
1136                      Requires<[Not64BitMode]>;
1137 def MOV32o32a : Ii32 <0xA1, RawFrm, (outs), (ins offset32:$src),
1138                       "mov{l}\t{$src, %eax|eax, $src}", [], IIC_MOV_MEM>,
1139                      Requires<[Not64BitMode]>;
1140 }
1141 let mayStore = 1 in {
1142 def MOV8ao8 : Ii32 <0xA2, RawFrm, (outs offset8:$dst), (ins),
1143                    "mov{b}\t{%al, $dst|$dst, al}", [], IIC_MOV_MEM>,
1144                   Requires<[Not64BitMode]>;
1145 def MOV16ao16 : Ii32 <0xA3, RawFrm, (outs offset16:$dst), (ins),
1146                       "mov{w}\t{%ax, $dst|$dst, ax}", [], IIC_MOV_MEM>, OpSize,
1147                      Requires<[Not64BitMode]>;
1148 def MOV32ao32 : Ii32 <0xA3, RawFrm, (outs offset32:$dst), (ins),
1149                       "mov{l}\t{%eax, $dst|$dst, eax}", [], IIC_MOV_MEM>,
1150                      Requires<[Not64BitMode]>;
1151 }
1152 }
1153
1154 // These forms all have full 64-bit absolute addresses in their instructions
1155 // and use the movabs mnemonic to indicate this specific form.
1156 let mayLoad = 1 in {
1157 def MOV64o8a : RIi64_NOREX<0xA0, RawFrm, (outs), (ins offset8:$src),
1158                      "movabs{b}\t{$src, %al|al, $src}", []>,
1159                      Requires<[In64BitMode]>;
1160 def MOV64o16a : RIi64_NOREX<0xA1, RawFrm, (outs), (ins offset16:$src),
1161                      "movabs{w}\t{$src, %ax|ax, $src}", []>, OpSize,
1162                      Requires<[In64BitMode]>;
1163 def MOV64o32a : RIi64_NOREX<0xA1, RawFrm, (outs), (ins offset32:$src),
1164                      "movabs{l}\t{$src, %eax|eax, $src}", []>,
1165                      Requires<[In64BitMode]>;
1166 def MOV64o64a : RIi64<0xA1, RawFrm, (outs), (ins offset64:$src),
1167                      "movabs{q}\t{$src, %rax|rax, $src}", []>,
1168                      Requires<[In64BitMode]>;
1169 }
1170
1171 let mayStore = 1 in {
1172 def MOV64ao8 : RIi64_NOREX<0xA2, RawFrm, (outs offset8:$dst), (ins),
1173                      "movabs{b}\t{%al, $dst|$dst, al}", []>,
1174                      Requires<[In64BitMode]>;
1175 def MOV64ao16 : RIi64_NOREX<0xA3, RawFrm, (outs offset16:$dst), (ins),
1176                      "movabs{w}\t{%ax, $dst|$dst, ax}", []>, OpSize,
1177                      Requires<[In64BitMode]>;
1178 def MOV64ao32 : RIi64_NOREX<0xA3, RawFrm, (outs offset32:$dst), (ins),
1179                      "movabs{l}\t{%eax, $dst|$dst, eax}", []>,
1180                      Requires<[In64BitMode]>;
1181 def MOV64ao64 : RIi64<0xA3, RawFrm, (outs offset64:$dst), (ins),
1182                      "movabs{q}\t{%rax, $dst|$dst, rax}", []>,
1183                      Requires<[In64BitMode]>;
1184 }
1185 } // hasSideEffects = 0
1186
1187 let isCodeGenOnly = 1, hasSideEffects = 0, SchedRW = [WriteMove] in {
1188 def MOV8rr_REV : I<0x8A, MRMSrcReg, (outs GR8:$dst), (ins GR8:$src),
1189                    "mov{b}\t{$src, $dst|$dst, $src}", [], IIC_MOV>;
1190 def MOV16rr_REV : I<0x8B, MRMSrcReg, (outs GR16:$dst), (ins GR16:$src),
1191                     "mov{w}\t{$src, $dst|$dst, $src}", [], IIC_MOV>, OpSize;
1192 def MOV32rr_REV : I<0x8B, MRMSrcReg, (outs GR32:$dst), (ins GR32:$src),
1193                     "mov{l}\t{$src, $dst|$dst, $src}", [], IIC_MOV>;
1194 def MOV64rr_REV : RI<0x8B, MRMSrcReg, (outs GR64:$dst), (ins GR64:$src),
1195                      "mov{q}\t{$src, $dst|$dst, $src}", [], IIC_MOV>;
1196 }
1197
1198 let canFoldAsLoad = 1, isReMaterializable = 1, SchedRW = [WriteLoad] in {
1199 def MOV8rm  : I<0x8A, MRMSrcMem, (outs GR8 :$dst), (ins i8mem :$src),
1200                 "mov{b}\t{$src, $dst|$dst, $src}",
1201                 [(set GR8:$dst, (loadi8 addr:$src))], IIC_MOV_MEM>;
1202 def MOV16rm : I<0x8B, MRMSrcMem, (outs GR16:$dst), (ins i16mem:$src),
1203                 "mov{w}\t{$src, $dst|$dst, $src}",
1204                 [(set GR16:$dst, (loadi16 addr:$src))], IIC_MOV_MEM>, OpSize;
1205 def MOV32rm : I<0x8B, MRMSrcMem, (outs GR32:$dst), (ins i32mem:$src),
1206                 "mov{l}\t{$src, $dst|$dst, $src}",
1207                 [(set GR32:$dst, (loadi32 addr:$src))], IIC_MOV_MEM>;
1208 def MOV64rm : RI<0x8B, MRMSrcMem, (outs GR64:$dst), (ins i64mem:$src),
1209                  "mov{q}\t{$src, $dst|$dst, $src}",
1210                  [(set GR64:$dst, (load addr:$src))], IIC_MOV_MEM>;
1211 }
1212
1213 let SchedRW = [WriteStore] in {
1214 def MOV8mr  : I<0x88, MRMDestMem, (outs), (ins i8mem :$dst, GR8 :$src),
1215                 "mov{b}\t{$src, $dst|$dst, $src}",
1216                 [(store GR8:$src, addr:$dst)], IIC_MOV_MEM>;
1217 def MOV16mr : I<0x89, MRMDestMem, (outs), (ins i16mem:$dst, GR16:$src),
1218                 "mov{w}\t{$src, $dst|$dst, $src}",
1219                 [(store GR16:$src, addr:$dst)], IIC_MOV_MEM>, OpSize;
1220 def MOV32mr : I<0x89, MRMDestMem, (outs), (ins i32mem:$dst, GR32:$src),
1221                 "mov{l}\t{$src, $dst|$dst, $src}",
1222                 [(store GR32:$src, addr:$dst)], IIC_MOV_MEM>;
1223 def MOV64mr : RI<0x89, MRMDestMem, (outs), (ins i64mem:$dst, GR64:$src),
1224                  "mov{q}\t{$src, $dst|$dst, $src}",
1225                  [(store GR64:$src, addr:$dst)], IIC_MOV_MEM>;
1226 } // SchedRW
1227
1228 // Versions of MOV8rr, MOV8mr, and MOV8rm that use i8mem_NOREX and GR8_NOREX so
1229 // that they can be used for copying and storing h registers, which can't be
1230 // encoded when a REX prefix is present.
1231 let isCodeGenOnly = 1 in {
1232 let neverHasSideEffects = 1 in
1233 def MOV8rr_NOREX : I<0x88, MRMDestReg,
1234                      (outs GR8_NOREX:$dst), (ins GR8_NOREX:$src),
1235                      "mov{b}\t{$src, $dst|$dst, $src}  # NOREX", [], IIC_MOV>,
1236                    Sched<[WriteMove]>;
1237 let mayStore = 1, neverHasSideEffects = 1 in
1238 def MOV8mr_NOREX : I<0x88, MRMDestMem,
1239                      (outs), (ins i8mem_NOREX:$dst, GR8_NOREX:$src),
1240                      "mov{b}\t{$src, $dst|$dst, $src}  # NOREX", [],
1241                      IIC_MOV_MEM>, Sched<[WriteStore]>;
1242 let mayLoad = 1, neverHasSideEffects = 1,
1243     canFoldAsLoad = 1, isReMaterializable = 1 in
1244 def MOV8rm_NOREX : I<0x8A, MRMSrcMem,
1245                      (outs GR8_NOREX:$dst), (ins i8mem_NOREX:$src),
1246                      "mov{b}\t{$src, $dst|$dst, $src}  # NOREX", [],
1247                      IIC_MOV_MEM>, Sched<[WriteLoad]>;
1248 }
1249
1250
1251 // Condition code ops, incl. set if equal/not equal/...
1252 let SchedRW = [WriteALU] in {
1253 let Defs = [EFLAGS], Uses = [AH] in
1254 def SAHF     : I<0x9E, RawFrm, (outs),  (ins), "sahf",
1255                  [(set EFLAGS, (X86sahf AH))], IIC_AHF>;
1256 let Defs = [AH], Uses = [EFLAGS], neverHasSideEffects = 1 in
1257 def LAHF     : I<0x9F, RawFrm, (outs),  (ins), "lahf", [],
1258                 IIC_AHF>;  // AH = flags
1259 } // SchedRW
1260
1261 //===----------------------------------------------------------------------===//
1262 // Bit tests instructions: BT, BTS, BTR, BTC.
1263
1264 let Defs = [EFLAGS] in {
1265 let SchedRW = [WriteALU] in {
1266 def BT16rr : I<0xA3, MRMDestReg, (outs), (ins GR16:$src1, GR16:$src2),
1267                "bt{w}\t{$src2, $src1|$src1, $src2}",
1268                [(set EFLAGS, (X86bt GR16:$src1, GR16:$src2))], IIC_BT_RR>,
1269                OpSize, TB;
1270 def BT32rr : I<0xA3, MRMDestReg, (outs), (ins GR32:$src1, GR32:$src2),
1271                "bt{l}\t{$src2, $src1|$src1, $src2}",
1272                [(set EFLAGS, (X86bt GR32:$src1, GR32:$src2))], IIC_BT_RR>, TB;
1273 def BT64rr : RI<0xA3, MRMDestReg, (outs), (ins GR64:$src1, GR64:$src2),
1274                "bt{q}\t{$src2, $src1|$src1, $src2}",
1275                [(set EFLAGS, (X86bt GR64:$src1, GR64:$src2))], IIC_BT_RR>, TB;
1276 } // SchedRW
1277
1278 // Unlike with the register+register form, the memory+register form of the
1279 // bt instruction does not ignore the high bits of the index. From ISel's
1280 // perspective, this is pretty bizarre. Make these instructions disassembly
1281 // only for now.
1282
1283 let mayLoad = 1, hasSideEffects = 0, SchedRW = [WriteALULd] in {
1284   def BT16mr : I<0xA3, MRMDestMem, (outs), (ins i16mem:$src1, GR16:$src2),
1285                  "bt{w}\t{$src2, $src1|$src1, $src2}",
1286   //               [(X86bt (loadi16 addr:$src1), GR16:$src2),
1287   //                (implicit EFLAGS)]
1288                  [], IIC_BT_MR
1289                  >, OpSize, TB, Requires<[FastBTMem]>;
1290   def BT32mr : I<0xA3, MRMDestMem, (outs), (ins i32mem:$src1, GR32:$src2),
1291                  "bt{l}\t{$src2, $src1|$src1, $src2}",
1292   //               [(X86bt (loadi32 addr:$src1), GR32:$src2),
1293   //                (implicit EFLAGS)]
1294                  [], IIC_BT_MR
1295                  >, TB, Requires<[FastBTMem]>;
1296   def BT64mr : RI<0xA3, MRMDestMem, (outs), (ins i64mem:$src1, GR64:$src2),
1297                  "bt{q}\t{$src2, $src1|$src1, $src2}",
1298   //               [(X86bt (loadi64 addr:$src1), GR64:$src2),
1299   //                (implicit EFLAGS)]
1300                   [], IIC_BT_MR
1301                   >, TB;
1302 }
1303
1304 let SchedRW = [WriteALU] in {
1305 def BT16ri8 : Ii8<0xBA, MRM4r, (outs), (ins GR16:$src1, i16i8imm:$src2),
1306                 "bt{w}\t{$src2, $src1|$src1, $src2}",
1307                 [(set EFLAGS, (X86bt GR16:$src1, i16immSExt8:$src2))],
1308                 IIC_BT_RI>, OpSize, TB;
1309 def BT32ri8 : Ii8<0xBA, MRM4r, (outs), (ins GR32:$src1, i32i8imm:$src2),
1310                 "bt{l}\t{$src2, $src1|$src1, $src2}",
1311                 [(set EFLAGS, (X86bt GR32:$src1, i32immSExt8:$src2))],
1312                 IIC_BT_RI>, TB;
1313 def BT64ri8 : RIi8<0xBA, MRM4r, (outs), (ins GR64:$src1, i64i8imm:$src2),
1314                 "bt{q}\t{$src2, $src1|$src1, $src2}",
1315                 [(set EFLAGS, (X86bt GR64:$src1, i64immSExt8:$src2))],
1316                 IIC_BT_RI>, TB;
1317 } // SchedRW
1318
1319 // Note that these instructions don't need FastBTMem because that
1320 // only applies when the other operand is in a register. When it's
1321 // an immediate, bt is still fast.
1322 let SchedRW = [WriteALU] in {
1323 def BT16mi8 : Ii8<0xBA, MRM4m, (outs), (ins i16mem:$src1, i16i8imm:$src2),
1324                 "bt{w}\t{$src2, $src1|$src1, $src2}",
1325                 [(set EFLAGS, (X86bt (loadi16 addr:$src1), i16immSExt8:$src2))
1326                  ], IIC_BT_MI>, OpSize, TB;
1327 def BT32mi8 : Ii8<0xBA, MRM4m, (outs), (ins i32mem:$src1, i32i8imm:$src2),
1328                 "bt{l}\t{$src2, $src1|$src1, $src2}",
1329                 [(set EFLAGS, (X86bt (loadi32 addr:$src1), i32immSExt8:$src2))
1330                  ], IIC_BT_MI>, TB;
1331 def BT64mi8 : RIi8<0xBA, MRM4m, (outs), (ins i64mem:$src1, i64i8imm:$src2),
1332                 "bt{q}\t{$src2, $src1|$src1, $src2}",
1333                 [(set EFLAGS, (X86bt (loadi64 addr:$src1),
1334                                      i64immSExt8:$src2))], IIC_BT_MI>, TB;
1335 } // SchedRW
1336
1337 let hasSideEffects = 0 in {
1338 let SchedRW = [WriteALU] in {
1339 def BTC16rr : I<0xBB, MRMDestReg, (outs), (ins GR16:$src1, GR16:$src2),
1340                 "btc{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>,
1341                 OpSize, TB;
1342 def BTC32rr : I<0xBB, MRMDestReg, (outs), (ins GR32:$src1, GR32:$src2),
1343                 "btc{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>, TB;
1344 def BTC64rr : RI<0xBB, MRMDestReg, (outs), (ins GR64:$src1, GR64:$src2),
1345                  "btc{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>, TB;
1346 } // SchedRW
1347
1348 let mayLoad = 1, mayStore = 1, SchedRW = [WriteALULd, WriteRMW] in {
1349 def BTC16mr : I<0xBB, MRMDestMem, (outs), (ins i16mem:$src1, GR16:$src2),
1350                 "btc{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>,
1351                 OpSize, TB;
1352 def BTC32mr : I<0xBB, MRMDestMem, (outs), (ins i32mem:$src1, GR32:$src2),
1353                 "btc{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>, TB;
1354 def BTC64mr : RI<0xBB, MRMDestMem, (outs), (ins i64mem:$src1, GR64:$src2),
1355                  "btc{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>, TB;
1356 }
1357
1358 let SchedRW = [WriteALU] in {
1359 def BTC16ri8 : Ii8<0xBA, MRM7r, (outs), (ins GR16:$src1, i16i8imm:$src2),
1360                     "btc{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>,
1361                     OpSize, TB;
1362 def BTC32ri8 : Ii8<0xBA, MRM7r, (outs), (ins GR32:$src1, i32i8imm:$src2),
1363                     "btc{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>, TB;
1364 def BTC64ri8 : RIi8<0xBA, MRM7r, (outs), (ins GR64:$src1, i64i8imm:$src2),
1365                     "btc{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>, TB;
1366 } // SchedRW
1367
1368 let mayLoad = 1, mayStore = 1, SchedRW = [WriteALULd, WriteRMW] in {
1369 def BTC16mi8 : Ii8<0xBA, MRM7m, (outs), (ins i16mem:$src1, i16i8imm:$src2),
1370                     "btc{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>,
1371                     OpSize, TB;
1372 def BTC32mi8 : Ii8<0xBA, MRM7m, (outs), (ins i32mem:$src1, i32i8imm:$src2),
1373                     "btc{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>, TB;
1374 def BTC64mi8 : RIi8<0xBA, MRM7m, (outs), (ins i64mem:$src1, i64i8imm:$src2),
1375                     "btc{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>, TB;
1376 }
1377
1378 let SchedRW = [WriteALU] in {
1379 def BTR16rr : I<0xB3, MRMDestReg, (outs), (ins GR16:$src1, GR16:$src2),
1380                 "btr{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>,
1381                 OpSize, TB;
1382 def BTR32rr : I<0xB3, MRMDestReg, (outs), (ins GR32:$src1, GR32:$src2),
1383                 "btr{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>, TB;
1384 def BTR64rr : RI<0xB3, MRMDestReg, (outs), (ins GR64:$src1, GR64:$src2),
1385                  "btr{q}\t{$src2, $src1|$src1, $src2}", []>, TB;
1386 } // SchedRW
1387
1388 let mayLoad = 1, mayStore = 1, SchedRW = [WriteALULd, WriteRMW] in {
1389 def BTR16mr : I<0xB3, MRMDestMem, (outs), (ins i16mem:$src1, GR16:$src2),
1390                 "btr{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>,
1391                 OpSize, TB;
1392 def BTR32mr : I<0xB3, MRMDestMem, (outs), (ins i32mem:$src1, GR32:$src2),
1393                 "btr{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>, TB;
1394 def BTR64mr : RI<0xB3, MRMDestMem, (outs), (ins i64mem:$src1, GR64:$src2),
1395                  "btr{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>, TB;
1396 }
1397
1398 let SchedRW = [WriteALU] in {
1399 def BTR16ri8 : Ii8<0xBA, MRM6r, (outs), (ins GR16:$src1, i16i8imm:$src2),
1400                     "btr{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>,
1401                     OpSize, TB;
1402 def BTR32ri8 : Ii8<0xBA, MRM6r, (outs), (ins GR32:$src1, i32i8imm:$src2),
1403                     "btr{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>, TB;
1404 def BTR64ri8 : RIi8<0xBA, MRM6r, (outs), (ins GR64:$src1, i64i8imm:$src2),
1405                     "btr{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>, TB;
1406 } // SchedRW
1407
1408 let mayLoad = 1, mayStore = 1, SchedRW = [WriteALULd, WriteRMW] in {
1409 def BTR16mi8 : Ii8<0xBA, MRM6m, (outs), (ins i16mem:$src1, i16i8imm:$src2),
1410                     "btr{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>,
1411                     OpSize, TB;
1412 def BTR32mi8 : Ii8<0xBA, MRM6m, (outs), (ins i32mem:$src1, i32i8imm:$src2),
1413                     "btr{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>, TB;
1414 def BTR64mi8 : RIi8<0xBA, MRM6m, (outs), (ins i64mem:$src1, i64i8imm:$src2),
1415                     "btr{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>, TB;
1416 }
1417
1418 let SchedRW = [WriteALU] in {
1419 def BTS16rr : I<0xAB, MRMDestReg, (outs), (ins GR16:$src1, GR16:$src2),
1420                 "bts{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>,
1421                 OpSize, TB;
1422 def BTS32rr : I<0xAB, MRMDestReg, (outs), (ins GR32:$src1, GR32:$src2),
1423                 "bts{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>, TB;
1424 def BTS64rr : RI<0xAB, MRMDestReg, (outs), (ins GR64:$src1, GR64:$src2),
1425                  "bts{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RR>, TB;
1426 } // SchedRW
1427
1428 let mayLoad = 1, mayStore = 1, SchedRW = [WriteALULd, WriteRMW] in {
1429 def BTS16mr : I<0xAB, MRMDestMem, (outs), (ins i16mem:$src1, GR16:$src2),
1430                 "bts{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>,
1431                 OpSize, TB;
1432 def BTS32mr : I<0xAB, MRMDestMem, (outs), (ins i32mem:$src1, GR32:$src2),
1433                 "bts{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>, TB;
1434 def BTS64mr : RI<0xAB, MRMDestMem, (outs), (ins i64mem:$src1, GR64:$src2),
1435                  "bts{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MR>, TB;
1436 }
1437
1438 let SchedRW = [WriteALU] in {
1439 def BTS16ri8 : Ii8<0xBA, MRM5r, (outs), (ins GR16:$src1, i16i8imm:$src2),
1440                     "bts{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>,
1441                     OpSize, TB;
1442 def BTS32ri8 : Ii8<0xBA, MRM5r, (outs), (ins GR32:$src1, i32i8imm:$src2),
1443                     "bts{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>, TB;
1444 def BTS64ri8 : RIi8<0xBA, MRM5r, (outs), (ins GR64:$src1, i64i8imm:$src2),
1445                     "bts{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_RI>, TB;
1446 } // SchedRW
1447
1448 let mayLoad = 1, mayStore = 1, SchedRW = [WriteALULd, WriteRMW] in {
1449 def BTS16mi8 : Ii8<0xBA, MRM5m, (outs), (ins i16mem:$src1, i16i8imm:$src2),
1450                     "bts{w}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>,
1451                     OpSize, TB;
1452 def BTS32mi8 : Ii8<0xBA, MRM5m, (outs), (ins i32mem:$src1, i32i8imm:$src2),
1453                     "bts{l}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>, TB;
1454 def BTS64mi8 : RIi8<0xBA, MRM5m, (outs), (ins i64mem:$src1, i64i8imm:$src2),
1455                     "bts{q}\t{$src2, $src1|$src1, $src2}", [], IIC_BTX_MI>, TB;
1456 }
1457 } // hasSideEffects = 0
1458 } // Defs = [EFLAGS]
1459
1460
1461 //===----------------------------------------------------------------------===//
1462 // Atomic support
1463 //
1464
1465 // Atomic swap. These are just normal xchg instructions. But since a memory
1466 // operand is referenced, the atomicity is ensured.
1467 multiclass ATOMIC_SWAP<bits<8> opc8, bits<8> opc, string mnemonic, string frag,
1468                        InstrItinClass itin> {
1469   let Constraints = "$val = $dst", SchedRW = [WriteALULd, WriteRMW] in {
1470     def NAME#8rm  : I<opc8, MRMSrcMem, (outs GR8:$dst),
1471                       (ins GR8:$val, i8mem:$ptr),
1472                       !strconcat(mnemonic, "{b}\t{$val, $ptr|$ptr, $val}"),
1473                       [(set
1474                          GR8:$dst,
1475                          (!cast<PatFrag>(frag # "_8") addr:$ptr, GR8:$val))],
1476                       itin>;
1477     def NAME#16rm : I<opc, MRMSrcMem, (outs GR16:$dst),
1478                       (ins GR16:$val, i16mem:$ptr),
1479                       !strconcat(mnemonic, "{w}\t{$val, $ptr|$ptr, $val}"),
1480                       [(set
1481                          GR16:$dst,
1482                          (!cast<PatFrag>(frag # "_16") addr:$ptr, GR16:$val))],
1483                       itin>, OpSize;
1484     def NAME#32rm : I<opc, MRMSrcMem, (outs GR32:$dst),
1485                       (ins GR32:$val, i32mem:$ptr),
1486                       !strconcat(mnemonic, "{l}\t{$val, $ptr|$ptr, $val}"),
1487                       [(set
1488                          GR32:$dst,
1489                          (!cast<PatFrag>(frag # "_32") addr:$ptr, GR32:$val))],
1490                       itin>;
1491     def NAME#64rm : RI<opc, MRMSrcMem, (outs GR64:$dst),
1492                        (ins GR64:$val, i64mem:$ptr),
1493                        !strconcat(mnemonic, "{q}\t{$val, $ptr|$ptr, $val}"),
1494                        [(set
1495                          GR64:$dst,
1496                          (!cast<PatFrag>(frag # "_64") addr:$ptr, GR64:$val))],
1497                        itin>;
1498   }
1499 }
1500
1501 defm XCHG    : ATOMIC_SWAP<0x86, 0x87, "xchg", "atomic_swap", IIC_XCHG_MEM>;
1502
1503 // Swap between registers.
1504 let SchedRW = [WriteALU] in {
1505 let Constraints = "$val = $dst" in {
1506 def XCHG8rr : I<0x86, MRMSrcReg, (outs GR8:$dst), (ins GR8:$val, GR8:$src),
1507                 "xchg{b}\t{$val, $src|$src, $val}", [], IIC_XCHG_REG>;
1508 def XCHG16rr : I<0x87, MRMSrcReg, (outs GR16:$dst), (ins GR16:$val, GR16:$src),
1509                  "xchg{w}\t{$val, $src|$src, $val}", [], IIC_XCHG_REG>, OpSize;
1510 def XCHG32rr : I<0x87, MRMSrcReg, (outs GR32:$dst), (ins GR32:$val, GR32:$src),
1511                  "xchg{l}\t{$val, $src|$src, $val}", [], IIC_XCHG_REG>;
1512 def XCHG64rr : RI<0x87, MRMSrcReg, (outs GR64:$dst), (ins GR64:$val,GR64:$src),
1513                   "xchg{q}\t{$val, $src|$src, $val}", [], IIC_XCHG_REG>;
1514 }
1515
1516 // Swap between EAX and other registers.
1517 def XCHG16ar : I<0x90, AddRegFrm, (outs), (ins GR16:$src),
1518                   "xchg{w}\t{$src, %ax|ax, $src}", [], IIC_XCHG_REG>, OpSize;
1519 def XCHG32ar : I<0x90, AddRegFrm, (outs), (ins GR32:$src),
1520                   "xchg{l}\t{$src, %eax|eax, $src}", [], IIC_XCHG_REG>,
1521                   Requires<[Not64BitMode]>;
1522 // Uses GR32_NOAX in 64-bit mode to prevent encoding using the 0x90 NOP encoding.
1523 // xchg %eax, %eax needs to clear upper 32-bits of RAX so is not a NOP.
1524 def XCHG32ar64 : I<0x90, AddRegFrm, (outs), (ins GR32_NOAX:$src),
1525                    "xchg{l}\t{$src, %eax|eax, $src}", [], IIC_XCHG_REG>,
1526                    Requires<[In64BitMode]>;
1527 def XCHG64ar : RI<0x90, AddRegFrm, (outs), (ins GR64:$src),
1528                   "xchg{q}\t{$src, %rax|rax, $src}", [], IIC_XCHG_REG>;
1529 } // SchedRW
1530
1531 let SchedRW = [WriteALU] in {
1532 def XADD8rr : I<0xC0, MRMDestReg, (outs GR8:$dst), (ins GR8:$src),
1533                 "xadd{b}\t{$src, $dst|$dst, $src}", [], IIC_XADD_REG>, TB;
1534 def XADD16rr : I<0xC1, MRMDestReg, (outs GR16:$dst), (ins GR16:$src),
1535                  "xadd{w}\t{$src, $dst|$dst, $src}", [], IIC_XADD_REG>, TB,
1536                  OpSize;
1537 def XADD32rr  : I<0xC1, MRMDestReg, (outs GR32:$dst), (ins GR32:$src),
1538                  "xadd{l}\t{$src, $dst|$dst, $src}", [], IIC_XADD_REG>, TB;
1539 def XADD64rr  : RI<0xC1, MRMDestReg, (outs GR64:$dst), (ins GR64:$src),
1540                    "xadd{q}\t{$src, $dst|$dst, $src}", [], IIC_XADD_REG>, TB;
1541 } // SchedRW
1542
1543 let mayLoad = 1, mayStore = 1, SchedRW = [WriteALULd, WriteRMW] in {
1544 def XADD8rm   : I<0xC0, MRMDestMem, (outs), (ins i8mem:$dst, GR8:$src),
1545                  "xadd{b}\t{$src, $dst|$dst, $src}", [], IIC_XADD_MEM>, TB;
1546 def XADD16rm  : I<0xC1, MRMDestMem, (outs), (ins i16mem:$dst, GR16:$src),
1547                  "xadd{w}\t{$src, $dst|$dst, $src}", [], IIC_XADD_MEM>, TB,
1548                  OpSize;
1549 def XADD32rm  : I<0xC1, MRMDestMem, (outs), (ins i32mem:$dst, GR32:$src),
1550                  "xadd{l}\t{$src, $dst|$dst, $src}", [], IIC_XADD_MEM>, TB;
1551 def XADD64rm  : RI<0xC1, MRMDestMem, (outs), (ins i64mem:$dst, GR64:$src),
1552                    "xadd{q}\t{$src, $dst|$dst, $src}", [], IIC_XADD_MEM>, TB;
1553
1554 }
1555
1556 let SchedRW = [WriteALU] in {
1557 def CMPXCHG8rr : I<0xB0, MRMDestReg, (outs GR8:$dst), (ins GR8:$src),
1558                    "cmpxchg{b}\t{$src, $dst|$dst, $src}", [],
1559                    IIC_CMPXCHG_REG8>, TB;
1560 def CMPXCHG16rr : I<0xB1, MRMDestReg, (outs GR16:$dst), (ins GR16:$src),
1561                     "cmpxchg{w}\t{$src, $dst|$dst, $src}", [],
1562                     IIC_CMPXCHG_REG>, TB, OpSize;
1563 def CMPXCHG32rr  : I<0xB1, MRMDestReg, (outs GR32:$dst), (ins GR32:$src),
1564                      "cmpxchg{l}\t{$src, $dst|$dst, $src}", [],
1565                      IIC_CMPXCHG_REG>, TB;
1566 def CMPXCHG64rr  : RI<0xB1, MRMDestReg, (outs GR64:$dst), (ins GR64:$src),
1567                       "cmpxchg{q}\t{$src, $dst|$dst, $src}", [],
1568                       IIC_CMPXCHG_REG>, TB;
1569 } // SchedRW
1570
1571 let SchedRW = [WriteALULd, WriteRMW] in {
1572 let mayLoad = 1, mayStore = 1 in {
1573 def CMPXCHG8rm   : I<0xB0, MRMDestMem, (outs), (ins i8mem:$dst, GR8:$src),
1574                      "cmpxchg{b}\t{$src, $dst|$dst, $src}", [],
1575                      IIC_CMPXCHG_MEM8>, TB;
1576 def CMPXCHG16rm  : I<0xB1, MRMDestMem, (outs), (ins i16mem:$dst, GR16:$src),
1577                      "cmpxchg{w}\t{$src, $dst|$dst, $src}", [],
1578                      IIC_CMPXCHG_MEM>, TB, OpSize;
1579 def CMPXCHG32rm  : I<0xB1, MRMDestMem, (outs), (ins i32mem:$dst, GR32:$src),
1580                      "cmpxchg{l}\t{$src, $dst|$dst, $src}", [],
1581                      IIC_CMPXCHG_MEM>, TB;
1582 def CMPXCHG64rm  : RI<0xB1, MRMDestMem, (outs), (ins i64mem:$dst, GR64:$src),
1583                       "cmpxchg{q}\t{$src, $dst|$dst, $src}", [],
1584                       IIC_CMPXCHG_MEM>, TB;
1585 }
1586
1587 let Defs = [EAX, EDX, EFLAGS], Uses = [EAX, EBX, ECX, EDX] in
1588 def CMPXCHG8B : I<0xC7, MRM1m, (outs), (ins i64mem:$dst),
1589                   "cmpxchg8b\t$dst", [], IIC_CMPXCHG_8B>, TB;
1590
1591 let Defs = [RAX, RDX, EFLAGS], Uses = [RAX, RBX, RCX, RDX] in
1592 def CMPXCHG16B : RI<0xC7, MRM1m, (outs), (ins i128mem:$dst),
1593                     "cmpxchg16b\t$dst", [], IIC_CMPXCHG_16B>,
1594                     TB, Requires<[HasCmpxchg16b]>;
1595 } // SchedRW
1596
1597
1598 // Lock instruction prefix
1599 def LOCK_PREFIX : I<0xF0, RawFrm, (outs),  (ins), "lock", []>;
1600
1601 // Rex64 instruction prefix
1602 def REX64_PREFIX : I<0x48, RawFrm, (outs),  (ins), "rex64", []>,
1603                      Requires<[In64BitMode]>;
1604
1605 // Data16 instruction prefix
1606 def DATA16_PREFIX : I<0x66, RawFrm, (outs),  (ins), "data16", []>;
1607
1608 // Repeat string operation instruction prefixes
1609 // These uses the DF flag in the EFLAGS register to inc or dec ECX
1610 let Defs = [ECX], Uses = [ECX,EFLAGS] in {
1611 // Repeat (used with INS, OUTS, MOVS, LODS and STOS)
1612 def REP_PREFIX : I<0xF3, RawFrm, (outs),  (ins), "rep", []>;
1613 // Repeat while not equal (used with CMPS and SCAS)
1614 def REPNE_PREFIX : I<0xF2, RawFrm, (outs),  (ins), "repne", []>;
1615 }
1616
1617
1618 // String manipulation instructions
1619 let SchedRW = [WriteMicrocoded] in {
1620 def LODSB : I<0xAC, RawFrm, (outs), (ins), "lodsb", [], IIC_LODS>;
1621 def LODSW : I<0xAD, RawFrm, (outs), (ins), "lodsw", [], IIC_LODS>, OpSize;
1622 def LODSD : I<0xAD, RawFrm, (outs), (ins), "lods{l|d}", [], IIC_LODS>;
1623 def LODSQ : RI<0xAD, RawFrm, (outs), (ins), "lodsq", [], IIC_LODS>;
1624 }
1625
1626 let SchedRW = [WriteSystem] in {
1627 def OUTSB : I<0x6E, RawFrm, (outs), (ins), "outsb", [], IIC_OUTS>;
1628 def OUTSW : I<0x6F, RawFrm, (outs), (ins), "outsw", [], IIC_OUTS>, OpSize;
1629 def OUTSD : I<0x6F, RawFrm, (outs), (ins), "outs{l|d}", [], IIC_OUTS>;
1630 }
1631
1632 // Flag instructions
1633 let SchedRW = [WriteALU] in {
1634 def CLC : I<0xF8, RawFrm, (outs), (ins), "clc", [], IIC_CLC>;
1635 def STC : I<0xF9, RawFrm, (outs), (ins), "stc", [], IIC_STC>;
1636 def CLI : I<0xFA, RawFrm, (outs), (ins), "cli", [], IIC_CLI>;
1637 def STI : I<0xFB, RawFrm, (outs), (ins), "sti", [], IIC_STI>;
1638 def CLD : I<0xFC, RawFrm, (outs), (ins), "cld", [], IIC_CLD>;
1639 def STD : I<0xFD, RawFrm, (outs), (ins), "std", [], IIC_STD>;
1640 def CMC : I<0xF5, RawFrm, (outs), (ins), "cmc", [], IIC_CMC>;
1641
1642 def CLTS : I<0x06, RawFrm, (outs), (ins), "clts", [], IIC_CLTS>, TB;
1643 }
1644
1645 // Table lookup instructions
1646 def XLAT : I<0xD7, RawFrm, (outs), (ins), "xlatb", [], IIC_XLAT>,
1647            Sched<[WriteLoad]>;
1648
1649 let SchedRW = [WriteMicrocoded] in {
1650 // ASCII Adjust After Addition
1651 // sets AL, AH and CF and AF of EFLAGS and uses AL and AF of EFLAGS
1652 def AAA : I<0x37, RawFrm, (outs), (ins), "aaa", [], IIC_AAA>,
1653             Requires<[Not64BitMode]>;
1654
1655 // ASCII Adjust AX Before Division
1656 // sets AL, AH and EFLAGS and uses AL and AH
1657 def AAD8i8 : Ii8<0xD5, RawFrm, (outs), (ins i8imm:$src),
1658                  "aad\t$src", [], IIC_AAD>, Requires<[Not64BitMode]>;
1659
1660 // ASCII Adjust AX After Multiply
1661 // sets AL, AH and EFLAGS and uses AL
1662 def AAM8i8 : Ii8<0xD4, RawFrm, (outs), (ins i8imm:$src),
1663                  "aam\t$src", [], IIC_AAM>, Requires<[Not64BitMode]>;
1664
1665 // ASCII Adjust AL After Subtraction - sets
1666 // sets AL, AH and CF and AF of EFLAGS and uses AL and AF of EFLAGS
1667 def AAS : I<0x3F, RawFrm, (outs), (ins), "aas", [], IIC_AAS>,
1668             Requires<[Not64BitMode]>;
1669
1670 // Decimal Adjust AL after Addition
1671 // sets AL, CF and AF of EFLAGS and uses AL, CF and AF of EFLAGS
1672 def DAA : I<0x27, RawFrm, (outs), (ins), "daa", [], IIC_DAA>,
1673             Requires<[Not64BitMode]>;
1674
1675 // Decimal Adjust AL after Subtraction
1676 // sets AL, CF and AF of EFLAGS and uses AL, CF and AF of EFLAGS
1677 def DAS : I<0x2F, RawFrm, (outs), (ins), "das", [], IIC_DAS>,
1678             Requires<[Not64BitMode]>;
1679 } // SchedRW
1680
1681 let SchedRW = [WriteSystem] in {
1682 // Check Array Index Against Bounds
1683 def BOUNDS16rm : I<0x62, MRMSrcMem, (outs GR16:$dst), (ins i16mem:$src),
1684                    "bound\t{$src, $dst|$dst, $src}", [], IIC_BOUND>, OpSize,
1685                    Requires<[Not64BitMode]>;
1686 def BOUNDS32rm : I<0x62, MRMSrcMem, (outs GR32:$dst), (ins i32mem:$src),
1687                    "bound\t{$src, $dst|$dst, $src}", [], IIC_BOUND>,
1688                    Requires<[Not64BitMode]>;
1689
1690 // Adjust RPL Field of Segment Selector
1691 def ARPL16rr : I<0x63, MRMDestReg, (outs GR16:$dst), (ins GR16:$src),
1692                  "arpl\t{$src, $dst|$dst, $src}", [], IIC_ARPL_REG>,
1693                  Requires<[Not64BitMode]>;
1694 def ARPL16mr : I<0x63, MRMDestMem, (outs), (ins i16mem:$dst, GR16:$src),
1695                  "arpl\t{$src, $dst|$dst, $src}", [], IIC_ARPL_MEM>,
1696                  Requires<[Not64BitMode]>;
1697 } // SchedRW
1698
1699 //===----------------------------------------------------------------------===//
1700 // MOVBE Instructions
1701 //
1702 let Predicates = [HasMOVBE] in {
1703   let SchedRW = [WriteALULd] in {
1704   def MOVBE16rm : I<0xF0, MRMSrcMem, (outs GR16:$dst), (ins i16mem:$src),
1705                     "movbe{w}\t{$src, $dst|$dst, $src}",
1706                     [(set GR16:$dst, (bswap (loadi16 addr:$src)))], IIC_MOVBE>,
1707                     OpSize, T8;
1708   def MOVBE32rm : I<0xF0, MRMSrcMem, (outs GR32:$dst), (ins i32mem:$src),
1709                     "movbe{l}\t{$src, $dst|$dst, $src}",
1710                     [(set GR32:$dst, (bswap (loadi32 addr:$src)))], IIC_MOVBE>,
1711                     T8;
1712   def MOVBE64rm : RI<0xF0, MRMSrcMem, (outs GR64:$dst), (ins i64mem:$src),
1713                      "movbe{q}\t{$src, $dst|$dst, $src}",
1714                      [(set GR64:$dst, (bswap (loadi64 addr:$src)))], IIC_MOVBE>,
1715                      T8;
1716   }
1717   let SchedRW = [WriteStore] in {
1718   def MOVBE16mr : I<0xF1, MRMDestMem, (outs), (ins i16mem:$dst, GR16:$src),
1719                     "movbe{w}\t{$src, $dst|$dst, $src}",
1720                     [(store (bswap GR16:$src), addr:$dst)], IIC_MOVBE>,
1721                     OpSize, T8;
1722   def MOVBE32mr : I<0xF1, MRMDestMem, (outs), (ins i32mem:$dst, GR32:$src),
1723                     "movbe{l}\t{$src, $dst|$dst, $src}",
1724                     [(store (bswap GR32:$src), addr:$dst)], IIC_MOVBE>,
1725                     T8;
1726   def MOVBE64mr : RI<0xF1, MRMDestMem, (outs), (ins i64mem:$dst, GR64:$src),
1727                      "movbe{q}\t{$src, $dst|$dst, $src}",
1728                      [(store (bswap GR64:$src), addr:$dst)], IIC_MOVBE>,
1729                      T8;
1730   }
1731 }
1732
1733 //===----------------------------------------------------------------------===//
1734 // RDRAND Instruction
1735 //
1736 let Predicates = [HasRDRAND], Defs = [EFLAGS] in {
1737   def RDRAND16r : I<0xC7, MRM6r, (outs GR16:$dst), (ins),
1738                     "rdrand{w}\t$dst",
1739                     [(set GR16:$dst, EFLAGS, (X86rdrand))]>, OpSize, TB;
1740   def RDRAND32r : I<0xC7, MRM6r, (outs GR32:$dst), (ins),
1741                     "rdrand{l}\t$dst",
1742                     [(set GR32:$dst, EFLAGS, (X86rdrand))]>, TB;
1743   def RDRAND64r : RI<0xC7, MRM6r, (outs GR64:$dst), (ins),
1744                      "rdrand{q}\t$dst",
1745                      [(set GR64:$dst, EFLAGS, (X86rdrand))]>, TB;
1746 }
1747
1748 //===----------------------------------------------------------------------===//
1749 // RDSEED Instruction
1750 //
1751 let Predicates = [HasRDSEED], Defs = [EFLAGS] in {
1752   def RDSEED16r : I<0xC7, MRM7r, (outs GR16:$dst), (ins),
1753                     "rdseed{w}\t$dst",
1754                     [(set GR16:$dst, EFLAGS, (X86rdseed))]>, OpSize, TB;
1755   def RDSEED32r : I<0xC7, MRM7r, (outs GR32:$dst), (ins),
1756                     "rdseed{l}\t$dst",
1757                     [(set GR32:$dst, EFLAGS, (X86rdseed))]>, TB;
1758   def RDSEED64r : RI<0xC7, MRM7r, (outs GR64:$dst), (ins),
1759                      "rdseed{q}\t$dst",
1760                      [(set GR64:$dst, EFLAGS, (X86rdseed))]>, TB;
1761 }
1762
1763 //===----------------------------------------------------------------------===//
1764 // LZCNT Instruction
1765 //
1766 let Predicates = [HasLZCNT], Defs = [EFLAGS] in {
1767   def LZCNT16rr : I<0xBD, MRMSrcReg, (outs GR16:$dst), (ins GR16:$src),
1768                     "lzcnt{w}\t{$src, $dst|$dst, $src}",
1769                     [(set GR16:$dst, (ctlz GR16:$src)), (implicit EFLAGS)]>, XS,
1770                     OpSize;
1771   def LZCNT16rm : I<0xBD, MRMSrcMem, (outs GR16:$dst), (ins i16mem:$src),
1772                     "lzcnt{w}\t{$src, $dst|$dst, $src}",
1773                     [(set GR16:$dst, (ctlz (loadi16 addr:$src))),
1774                      (implicit EFLAGS)]>, XS, OpSize;
1775
1776   def LZCNT32rr : I<0xBD, MRMSrcReg, (outs GR32:$dst), (ins GR32:$src),
1777                     "lzcnt{l}\t{$src, $dst|$dst, $src}",
1778                     [(set GR32:$dst, (ctlz GR32:$src)), (implicit EFLAGS)]>, XS;
1779   def LZCNT32rm : I<0xBD, MRMSrcMem, (outs GR32:$dst), (ins i32mem:$src),
1780                     "lzcnt{l}\t{$src, $dst|$dst, $src}",
1781                     [(set GR32:$dst, (ctlz (loadi32 addr:$src))),
1782                      (implicit EFLAGS)]>, XS;
1783
1784   def LZCNT64rr : RI<0xBD, MRMSrcReg, (outs GR64:$dst), (ins GR64:$src),
1785                      "lzcnt{q}\t{$src, $dst|$dst, $src}",
1786                      [(set GR64:$dst, (ctlz GR64:$src)), (implicit EFLAGS)]>,
1787                      XS;
1788   def LZCNT64rm : RI<0xBD, MRMSrcMem, (outs GR64:$dst), (ins i64mem:$src),
1789                      "lzcnt{q}\t{$src, $dst|$dst, $src}",
1790                      [(set GR64:$dst, (ctlz (loadi64 addr:$src))),
1791                       (implicit EFLAGS)]>, XS;
1792 }
1793
1794 //===----------------------------------------------------------------------===//
1795 // BMI Instructions
1796 //
1797 let Predicates = [HasBMI], Defs = [EFLAGS] in {
1798   def TZCNT16rr : I<0xBC, MRMSrcReg, (outs GR16:$dst), (ins GR16:$src),
1799                     "tzcnt{w}\t{$src, $dst|$dst, $src}",
1800                     [(set GR16:$dst, (cttz GR16:$src)), (implicit EFLAGS)]>, XS,
1801                     OpSize;
1802   def TZCNT16rm : I<0xBC, MRMSrcMem, (outs GR16:$dst), (ins i16mem:$src),
1803                     "tzcnt{w}\t{$src, $dst|$dst, $src}",
1804                     [(set GR16:$dst, (cttz (loadi16 addr:$src))),
1805                      (implicit EFLAGS)]>, XS, OpSize;
1806
1807   def TZCNT32rr : I<0xBC, MRMSrcReg, (outs GR32:$dst), (ins GR32:$src),
1808                     "tzcnt{l}\t{$src, $dst|$dst, $src}",
1809                     [(set GR32:$dst, (cttz GR32:$src)), (implicit EFLAGS)]>, XS;
1810   def TZCNT32rm : I<0xBC, MRMSrcMem, (outs GR32:$dst), (ins i32mem:$src),
1811                     "tzcnt{l}\t{$src, $dst|$dst, $src}",
1812                     [(set GR32:$dst, (cttz (loadi32 addr:$src))),
1813                      (implicit EFLAGS)]>, XS;
1814
1815   def TZCNT64rr : RI<0xBC, MRMSrcReg, (outs GR64:$dst), (ins GR64:$src),
1816                      "tzcnt{q}\t{$src, $dst|$dst, $src}",
1817                      [(set GR64:$dst, (cttz GR64:$src)), (implicit EFLAGS)]>,
1818                      XS;
1819   def TZCNT64rm : RI<0xBC, MRMSrcMem, (outs GR64:$dst), (ins i64mem:$src),
1820                      "tzcnt{q}\t{$src, $dst|$dst, $src}",
1821                      [(set GR64:$dst, (cttz (loadi64 addr:$src))),
1822                       (implicit EFLAGS)]>, XS;
1823 }
1824
1825 multiclass bmi_bls<string mnemonic, Format RegMRM, Format MemMRM,
1826                   RegisterClass RC, X86MemOperand x86memop, SDNode OpNode,
1827                   PatFrag ld_frag> {
1828   def rr : I<0xF3, RegMRM, (outs RC:$dst), (ins RC:$src),
1829              !strconcat(mnemonic, "\t{$src, $dst|$dst, $src}"),
1830              [(set RC:$dst, (OpNode RC:$src)), (implicit EFLAGS)]>, T8, VEX_4V;
1831   def rm : I<0xF3, MemMRM, (outs RC:$dst), (ins x86memop:$src),
1832              !strconcat(mnemonic, "\t{$src, $dst|$dst, $src}"),
1833              [(set RC:$dst, (OpNode (ld_frag addr:$src))), (implicit EFLAGS)]>,
1834              T8, VEX_4V;
1835 }
1836
1837 let Predicates = [HasBMI], Defs = [EFLAGS] in {
1838   defm BLSR32 : bmi_bls<"blsr{l}", MRM1r, MRM1m, GR32, i32mem,
1839                         X86blsr, loadi32>;
1840   defm BLSR64 : bmi_bls<"blsr{q}", MRM1r, MRM1m, GR64, i64mem,
1841                         X86blsr, loadi64>, VEX_W;
1842   defm BLSMSK32 : bmi_bls<"blsmsk{l}", MRM2r, MRM2m, GR32, i32mem,
1843                           X86blsmsk, loadi32>;
1844   defm BLSMSK64 : bmi_bls<"blsmsk{q}", MRM2r, MRM2m, GR64, i64mem,
1845                           X86blsmsk, loadi64>, VEX_W;
1846   defm BLSI32 : bmi_bls<"blsi{l}", MRM3r, MRM3m, GR32, i32mem,
1847                         X86blsi, loadi32>;
1848   defm BLSI64 : bmi_bls<"blsi{q}", MRM3r, MRM3m, GR64, i64mem,
1849                         X86blsi, loadi64>, VEX_W;
1850 }
1851
1852 multiclass bmi_bextr_bzhi<bits<8> opc, string mnemonic, RegisterClass RC,
1853                           X86MemOperand x86memop, Intrinsic Int,
1854                           PatFrag ld_frag> {
1855   def rr : I<opc, MRMSrcReg, (outs RC:$dst), (ins RC:$src1, RC:$src2),
1856              !strconcat(mnemonic, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
1857              [(set RC:$dst, (Int RC:$src1, RC:$src2)), (implicit EFLAGS)]>,
1858              T8, VEX_4VOp3;
1859   def rm : I<opc, MRMSrcMem, (outs RC:$dst), (ins x86memop:$src1, RC:$src2),
1860              !strconcat(mnemonic, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
1861              [(set RC:$dst, (Int (ld_frag addr:$src1), RC:$src2)),
1862               (implicit EFLAGS)]>, T8, VEX_4VOp3;
1863 }
1864
1865 let Predicates = [HasBMI], Defs = [EFLAGS] in {
1866   defm BEXTR32 : bmi_bextr_bzhi<0xF7, "bextr{l}", GR32, i32mem,
1867                                 int_x86_bmi_bextr_32, loadi32>;
1868   defm BEXTR64 : bmi_bextr_bzhi<0xF7, "bextr{q}", GR64, i64mem,
1869                                 int_x86_bmi_bextr_64, loadi64>, VEX_W;
1870 }
1871
1872 let Predicates = [HasBMI2], Defs = [EFLAGS] in {
1873   defm BZHI32 : bmi_bextr_bzhi<0xF5, "bzhi{l}", GR32, i32mem,
1874                                int_x86_bmi_bzhi_32, loadi32>;
1875   defm BZHI64 : bmi_bextr_bzhi<0xF5, "bzhi{q}", GR64, i64mem,
1876                                int_x86_bmi_bzhi_64, loadi64>, VEX_W;
1877 }
1878
1879 def : Pat<(X86bzhi GR32:$src1, GR8:$src2),
1880           (BZHI32rr GR32:$src1,
1881                     (INSERT_SUBREG (i32 (IMPLICIT_DEF)), GR8:$src2, sub_8bit))>;
1882 def : Pat<(X86bzhi (loadi32 addr:$src1), GR8:$src2),
1883           (BZHI32rm addr:$src1,
1884                     (INSERT_SUBREG (i32 (IMPLICIT_DEF)), GR8:$src2, sub_8bit))>;
1885 def : Pat<(X86bzhi GR64:$src1, GR8:$src2),
1886           (BZHI64rr GR64:$src1,
1887                     (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GR8:$src2, sub_8bit))>;
1888 def : Pat<(X86bzhi (loadi64 addr:$src1), GR8:$src2),
1889           (BZHI64rm addr:$src1,
1890                     (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GR8:$src2, sub_8bit))>;
1891
1892 let Predicates = [HasBMI] in {
1893   def : Pat<(X86bextr GR32:$src1, GR32:$src2),
1894             (BEXTR32rr GR32:$src1, GR32:$src2)>;
1895   def : Pat<(X86bextr (loadi32 addr:$src1), GR32:$src2),
1896             (BEXTR32rm addr:$src1, GR32:$src2)>;
1897   def : Pat<(X86bextr GR64:$src1, GR64:$src2),
1898             (BEXTR64rr GR64:$src1, GR64:$src2)>;
1899   def : Pat<(X86bextr (loadi64 addr:$src1), GR64:$src2),
1900             (BEXTR64rm addr:$src1, GR64:$src2)>;
1901 } // HasBMI
1902
1903 multiclass bmi_pdep_pext<string mnemonic, RegisterClass RC,
1904                          X86MemOperand x86memop, Intrinsic Int,
1905                          PatFrag ld_frag> {
1906   def rr : I<0xF5, MRMSrcReg, (outs RC:$dst), (ins RC:$src1, RC:$src2),
1907              !strconcat(mnemonic, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
1908              [(set RC:$dst, (Int RC:$src1, RC:$src2))]>,
1909              VEX_4V;
1910   def rm : I<0xF5, MRMSrcMem, (outs RC:$dst), (ins RC:$src1, x86memop:$src2),
1911              !strconcat(mnemonic, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
1912              [(set RC:$dst, (Int RC:$src1, (ld_frag addr:$src2)))]>, VEX_4V;
1913 }
1914
1915 let Predicates = [HasBMI2] in {
1916   defm PDEP32 : bmi_pdep_pext<"pdep{l}", GR32, i32mem,
1917                                int_x86_bmi_pdep_32, loadi32>, T8XD;
1918   defm PDEP64 : bmi_pdep_pext<"pdep{q}", GR64, i64mem,
1919                                int_x86_bmi_pdep_64, loadi64>, T8XD, VEX_W;
1920   defm PEXT32 : bmi_pdep_pext<"pext{l}", GR32, i32mem,
1921                                int_x86_bmi_pext_32, loadi32>, T8XS;
1922   defm PEXT64 : bmi_pdep_pext<"pext{q}", GR64, i64mem,
1923                                int_x86_bmi_pext_64, loadi64>, T8XS, VEX_W;
1924 }
1925
1926 //===----------------------------------------------------------------------===//
1927 // TBM Instructions
1928 //
1929 let Predicates = [HasTBM], Defs = [EFLAGS] in {
1930
1931 multiclass tbm_ternary_imm_intr<bits<8> opc, RegisterClass RC, string OpcodeStr,
1932                                 X86MemOperand x86memop, PatFrag ld_frag,
1933                                 Intrinsic Int, Operand immtype,
1934                                 SDPatternOperator immoperator> {
1935   def ri : Ii32<opc,  MRMSrcReg, (outs RC:$dst), (ins RC:$src1, immtype:$cntl),
1936                 !strconcat(OpcodeStr,
1937                            "\t{$cntl, $src1, $dst|$dst, $src1, $cntl}"),
1938                 [(set RC:$dst, (Int RC:$src1, immoperator:$cntl))]>,
1939            XOP, XOPA, VEX;
1940   def mi : Ii32<opc,  MRMSrcMem, (outs RC:$dst),
1941                 (ins x86memop:$src1, immtype:$cntl),
1942                 !strconcat(OpcodeStr,
1943                            "\t{$cntl, $src1, $dst|$dst, $src1, $cntl}"),
1944                 [(set RC:$dst, (Int (ld_frag addr:$src1), immoperator:$cntl))]>,
1945            XOP, XOPA, VEX;
1946 }
1947
1948 defm BEXTRI32 : tbm_ternary_imm_intr<0x10, GR32, "bextr", i32mem, loadi32,
1949                                      int_x86_tbm_bextri_u32, i32imm, imm>;
1950 defm BEXTRI64 : tbm_ternary_imm_intr<0x10, GR64, "bextr", i64mem, loadi64,
1951                                      int_x86_tbm_bextri_u64, i64i32imm,
1952                                      i64immSExt32>, VEX_W;
1953
1954 multiclass tbm_binary_rm<bits<8> opc, Format FormReg, Format FormMem,
1955                          RegisterClass RC, string OpcodeStr,
1956                          X86MemOperand x86memop, PatFrag ld_frag> {
1957 let hasSideEffects = 0 in {
1958   def rr : I<opc,  FormReg, (outs RC:$dst), (ins RC:$src),
1959              !strconcat(OpcodeStr,"\t{$src, $dst|$dst, $src}"),
1960              []>, XOP, XOP9, VEX_4V;
1961   let mayLoad = 1 in
1962   def rm : I<opc,  FormMem, (outs RC:$dst), (ins x86memop:$src),
1963              !strconcat(OpcodeStr,"\t{$src, $dst|$dst, $src}"),
1964              []>, XOP, XOP9, VEX_4V;
1965 }
1966 }
1967
1968 multiclass tbm_binary_intr<bits<8> opc, string OpcodeStr,
1969                            Format FormReg, Format FormMem> {
1970   defm NAME#32 : tbm_binary_rm<opc, FormReg, FormMem, GR32, OpcodeStr, i32mem,
1971                                loadi32>;
1972   defm NAME#64 : tbm_binary_rm<opc, FormReg, FormMem, GR64, OpcodeStr, i64mem,
1973                                loadi64>, VEX_W;
1974 }
1975
1976 defm BLCFILL : tbm_binary_intr<0x01, "blcfill", MRM1r, MRM1m>;
1977 defm BLCI    : tbm_binary_intr<0x02, "blci", MRM6r, MRM6m>;
1978 defm BLCIC   : tbm_binary_intr<0x01, "blcic", MRM5r, MRM5m>;
1979 defm BLCMSK  : tbm_binary_intr<0x02, "blcmsk", MRM1r, MRM1m>;
1980 defm BLCS    : tbm_binary_intr<0x01, "blcs", MRM3r, MRM3m>;
1981 defm BLSFILL : tbm_binary_intr<0x01, "blsfill", MRM2r, MRM2m>;
1982 defm BLSIC   : tbm_binary_intr<0x01, "blsic", MRM6r, MRM6m>;
1983 defm T1MSKC  : tbm_binary_intr<0x01, "t1mskc", MRM7r, MRM7m>;
1984 defm TZMSK   : tbm_binary_intr<0x01, "tzmsk", MRM4r, MRM4m>;
1985 } // HasTBM, EFLAGS
1986
1987 //===----------------------------------------------------------------------===//
1988 // Pattern fragments to auto generate TBM instructions.
1989 //===----------------------------------------------------------------------===//
1990
1991 let Predicates = [HasTBM] in {
1992   def : Pat<(X86bextr GR32:$src1, (i32 imm:$src2)),
1993             (BEXTRI32ri GR32:$src1, imm:$src2)>;
1994   def : Pat<(X86bextr (loadi32 addr:$src1), (i32 imm:$src2)),
1995             (BEXTRI32mi addr:$src1, imm:$src2)>;
1996   def : Pat<(X86bextr GR64:$src1, i64immSExt32:$src2),
1997             (BEXTRI64ri GR64:$src1, i64immSExt32:$src2)>;
1998   def : Pat<(X86bextr (loadi64 addr:$src1), i64immSExt32:$src2),
1999             (BEXTRI64mi addr:$src1, i64immSExt32:$src2)>;
2000
2001   // FIXME: patterns for the load versions are not implemented
2002   def : Pat<(and GR32:$src, (add GR32:$src, 1)),
2003             (BLCFILL32rr GR32:$src)>;
2004   def : Pat<(and GR64:$src, (add GR64:$src, 1)),
2005             (BLCFILL64rr GR64:$src)>;
2006
2007   def : Pat<(or GR32:$src, (not (add GR32:$src, 1))),
2008             (BLCI32rr GR32:$src)>;
2009   def : Pat<(or GR64:$src, (not (add GR64:$src, 1))),
2010             (BLCI64rr GR64:$src)>;
2011
2012   // Extra patterns because opt can optimize the above patterns to this.
2013   def : Pat<(or GR32:$src, (sub -2, GR32:$src)),
2014             (BLCI32rr GR32:$src)>;
2015   def : Pat<(or GR64:$src, (sub -2, GR64:$src)),
2016             (BLCI64rr GR64:$src)>;
2017
2018   def : Pat<(and (not GR32:$src), (add GR32:$src, 1)),
2019             (BLCIC32rr GR32:$src)>;
2020   def : Pat<(and (not GR64:$src), (add GR64:$src, 1)),
2021             (BLCIC64rr GR64:$src)>;
2022
2023   def : Pat<(xor GR32:$src, (add GR32:$src, 1)),
2024             (BLCMSK32rr GR32:$src)>;
2025   def : Pat<(xor GR64:$src, (add GR64:$src, 1)),
2026             (BLCMSK64rr GR64:$src)>;
2027
2028   def : Pat<(or GR32:$src, (add GR32:$src, 1)),
2029             (BLCS32rr GR32:$src)>;
2030   def : Pat<(or GR64:$src, (add GR64:$src, 1)),
2031             (BLCS64rr GR64:$src)>;
2032
2033   def : Pat<(or GR32:$src, (add GR32:$src, -1)),
2034             (BLSFILL32rr GR32:$src)>;
2035   def : Pat<(or GR64:$src, (add GR64:$src, -1)),
2036             (BLSFILL64rr GR64:$src)>;
2037
2038   def : Pat<(or (not GR32:$src), (add GR32:$src, -1)),
2039             (BLSIC32rr GR32:$src)>;
2040   def : Pat<(or (not GR64:$src), (add GR64:$src, -1)),
2041             (BLSIC64rr GR64:$src)>;
2042
2043   def : Pat<(or (not GR32:$src), (add GR32:$src, 1)),
2044             (T1MSKC32rr GR32:$src)>;
2045   def : Pat<(or (not GR64:$src), (add GR64:$src, 1)),
2046             (T1MSKC64rr GR64:$src)>;
2047
2048   def : Pat<(and (not GR32:$src), (add GR32:$src, -1)),
2049             (TZMSK32rr GR32:$src)>;
2050   def : Pat<(and (not GR64:$src), (add GR64:$src, -1)),
2051             (TZMSK64rr GR64:$src)>;
2052 } // HasTBM
2053
2054 //===----------------------------------------------------------------------===//
2055 // Subsystems.
2056 //===----------------------------------------------------------------------===//
2057
2058 include "X86InstrArithmetic.td"
2059 include "X86InstrCMovSetCC.td"
2060 include "X86InstrExtension.td"
2061 include "X86InstrControl.td"
2062 include "X86InstrShiftRotate.td"
2063
2064 // X87 Floating Point Stack.
2065 include "X86InstrFPStack.td"
2066
2067 // SIMD support (SSE, MMX and AVX)
2068 include "X86InstrFragmentsSIMD.td"
2069
2070 // FMA - Fused Multiply-Add support (requires FMA)
2071 include "X86InstrFMA.td"
2072
2073 // XOP
2074 include "X86InstrXOP.td"
2075
2076 // SSE, MMX and 3DNow! vector support.
2077 include "X86InstrSSE.td"
2078 include "X86InstrAVX512.td"
2079 include "X86InstrMMX.td"
2080 include "X86Instr3DNow.td"
2081
2082 include "X86InstrVMX.td"
2083 include "X86InstrSVM.td"
2084
2085 include "X86InstrTSX.td"
2086
2087 // System instructions.
2088 include "X86InstrSystem.td"
2089
2090 // Compiler Pseudo Instructions and Pat Patterns
2091 include "X86InstrCompiler.td"
2092
2093 //===----------------------------------------------------------------------===//
2094 // Assembler Mnemonic Aliases
2095 //===----------------------------------------------------------------------===//
2096
2097 def : MnemonicAlias<"call", "calll", "att">, Requires<[Not64BitMode]>;
2098 def : MnemonicAlias<"call", "callq", "att">, Requires<[In64BitMode]>;
2099
2100 def : MnemonicAlias<"cbw",  "cbtw", "att">;
2101 def : MnemonicAlias<"cwde", "cwtl", "att">;
2102 def : MnemonicAlias<"cwd",  "cwtd", "att">;
2103 def : MnemonicAlias<"cdq",  "cltd", "att">;
2104 def : MnemonicAlias<"cdqe", "cltq", "att">;
2105 def : MnemonicAlias<"cqo",  "cqto", "att">;
2106
2107 // lret maps to lretl, it is not ambiguous with lretq.
2108 def : MnemonicAlias<"lret", "lretl", "att">;
2109
2110 def : MnemonicAlias<"leavel", "leave", "att">, Requires<[Not64BitMode]>;
2111 def : MnemonicAlias<"leaveq", "leave", "att">, Requires<[In64BitMode]>;
2112
2113 def : MnemonicAlias<"loopz",  "loope",  "att">;
2114 def : MnemonicAlias<"loopnz", "loopne", "att">;
2115
2116 def : MnemonicAlias<"pop",   "popl",  "att">, Requires<[Not64BitMode]>;
2117 def : MnemonicAlias<"pop",   "popq",  "att">, Requires<[In64BitMode]>;
2118 def : MnemonicAlias<"popf",  "popfl", "att">, Requires<[Not64BitMode]>;
2119 def : MnemonicAlias<"popf",  "popfq", "att">, Requires<[In64BitMode]>;
2120 def : MnemonicAlias<"popfd", "popfl", "att">;
2121
2122 // FIXME: This is wrong for "push reg".  "push %bx" should turn into pushw in
2123 // all modes.  However: "push (addr)" and "push $42" should default to
2124 // pushl/pushq depending on the current mode.  Similar for "pop %bx"
2125 def : MnemonicAlias<"push",   "pushl",  "att">, Requires<[Not64BitMode]>;
2126 def : MnemonicAlias<"push",   "pushq",  "att">, Requires<[In64BitMode]>;
2127 def : MnemonicAlias<"pushf",  "pushfl", "att">, Requires<[Not64BitMode]>;
2128 def : MnemonicAlias<"pushf",  "pushfq", "att">, Requires<[In64BitMode]>;
2129 def : MnemonicAlias<"pushfd", "pushfl", "att">;
2130
2131 def : MnemonicAlias<"popad",   "popa", "intel">, Requires<[Not64BitMode]>;
2132 def : MnemonicAlias<"pushad",  "pusha", "intel">, Requires<[Not64BitMode]>;
2133
2134 def : MnemonicAlias<"repe",  "rep",   "att">;
2135 def : MnemonicAlias<"repz",  "rep",   "att">;
2136 def : MnemonicAlias<"repnz", "repne", "att">;
2137
2138 def : MnemonicAlias<"retl", "ret", "att">, Requires<[Not64BitMode]>;
2139 def : MnemonicAlias<"retq", "ret", "att">, Requires<[In64BitMode]>;
2140
2141 def : MnemonicAlias<"salb", "shlb", "att">;
2142 def : MnemonicAlias<"salw", "shlw", "att">;
2143 def : MnemonicAlias<"sall", "shll", "att">;
2144 def : MnemonicAlias<"salq", "shlq", "att">;
2145
2146 def : MnemonicAlias<"smovb", "movsb", "att">;
2147 def : MnemonicAlias<"smovw", "movsw", "att">;
2148 def : MnemonicAlias<"smovl", "movsl", "att">;
2149 def : MnemonicAlias<"smovq", "movsq", "att">;
2150
2151 def : MnemonicAlias<"ud2a",  "ud2",  "att">;
2152 def : MnemonicAlias<"verrw", "verr", "att">;
2153
2154 // System instruction aliases.
2155 def : MnemonicAlias<"iret",    "iretl",    "att">;
2156 def : MnemonicAlias<"sysret",  "sysretl",  "att">;
2157 def : MnemonicAlias<"sysexit", "sysexitl", "att">;
2158
2159 def : MnemonicAlias<"lgdtl", "lgdt", "att">, Requires<[Not64BitMode]>;
2160 def : MnemonicAlias<"lgdtq", "lgdt", "att">, Requires<[In64BitMode]>;
2161 def : MnemonicAlias<"lidtl", "lidt", "att">, Requires<[Not64BitMode]>;
2162 def : MnemonicAlias<"lidtq", "lidt", "att">, Requires<[In64BitMode]>;
2163 def : MnemonicAlias<"sgdtl", "sgdt", "att">, Requires<[Not64BitMode]>;
2164 def : MnemonicAlias<"sgdtq", "sgdt", "att">, Requires<[In64BitMode]>;
2165 def : MnemonicAlias<"sidtl", "sidt", "att">, Requires<[Not64BitMode]>;
2166 def : MnemonicAlias<"sidtq", "sidt", "att">, Requires<[In64BitMode]>;
2167
2168
2169 // Floating point stack aliases.
2170 def : MnemonicAlias<"fcmovz",   "fcmove",   "att">;
2171 def : MnemonicAlias<"fcmova",   "fcmovnbe", "att">;
2172 def : MnemonicAlias<"fcmovnae", "fcmovb",   "att">;
2173 def : MnemonicAlias<"fcmovna",  "fcmovbe",  "att">;
2174 def : MnemonicAlias<"fcmovae",  "fcmovnb",  "att">;
2175 def : MnemonicAlias<"fcomip",   "fcompi",   "att">;
2176 def : MnemonicAlias<"fildq",    "fildll",   "att">;
2177 def : MnemonicAlias<"fistpq",   "fistpll",  "att">;
2178 def : MnemonicAlias<"fisttpq",  "fisttpll", "att">;
2179 def : MnemonicAlias<"fldcww",   "fldcw",    "att">;
2180 def : MnemonicAlias<"fnstcww",  "fnstcw",   "att">;
2181 def : MnemonicAlias<"fnstsww",  "fnstsw",   "att">;
2182 def : MnemonicAlias<"fucomip",  "fucompi",  "att">;
2183 def : MnemonicAlias<"fwait",    "wait",     "att">;
2184
2185
2186 class CondCodeAlias<string Prefix,string Suffix, string OldCond, string NewCond,
2187                     string VariantName>
2188   : MnemonicAlias<!strconcat(Prefix, OldCond, Suffix),
2189                   !strconcat(Prefix, NewCond, Suffix), VariantName>;
2190
2191 /// IntegerCondCodeMnemonicAlias - This multiclass defines a bunch of
2192 /// MnemonicAlias's that canonicalize the condition code in a mnemonic, for
2193 /// example "setz" -> "sete".
2194 multiclass IntegerCondCodeMnemonicAlias<string Prefix, string Suffix,
2195                                         string V = ""> {
2196   def C   : CondCodeAlias<Prefix, Suffix, "c",   "b",  V>; // setc   -> setb
2197   def Z   : CondCodeAlias<Prefix, Suffix, "z" ,  "e",  V>; // setz   -> sete
2198   def NA  : CondCodeAlias<Prefix, Suffix, "na",  "be", V>; // setna  -> setbe
2199   def NB  : CondCodeAlias<Prefix, Suffix, "nb",  "ae", V>; // setnb  -> setae
2200   def NC  : CondCodeAlias<Prefix, Suffix, "nc",  "ae", V>; // setnc  -> setae
2201   def NG  : CondCodeAlias<Prefix, Suffix, "ng",  "le", V>; // setng  -> setle
2202   def NL  : CondCodeAlias<Prefix, Suffix, "nl",  "ge", V>; // setnl  -> setge
2203   def NZ  : CondCodeAlias<Prefix, Suffix, "nz",  "ne", V>; // setnz  -> setne
2204   def PE  : CondCodeAlias<Prefix, Suffix, "pe",  "p",  V>; // setpe  -> setp
2205   def PO  : CondCodeAlias<Prefix, Suffix, "po",  "np", V>; // setpo  -> setnp
2206
2207   def NAE : CondCodeAlias<Prefix, Suffix, "nae", "b",  V>; // setnae -> setb
2208   def NBE : CondCodeAlias<Prefix, Suffix, "nbe", "a",  V>; // setnbe -> seta
2209   def NGE : CondCodeAlias<Prefix, Suffix, "nge", "l",  V>; // setnge -> setl
2210   def NLE : CondCodeAlias<Prefix, Suffix, "nle", "g",  V>; // setnle -> setg
2211 }
2212
2213 // Aliases for set<CC>
2214 defm : IntegerCondCodeMnemonicAlias<"set", "">;
2215 // Aliases for j<CC>
2216 defm : IntegerCondCodeMnemonicAlias<"j", "">;
2217 // Aliases for cmov<CC>{w,l,q}
2218 defm : IntegerCondCodeMnemonicAlias<"cmov", "w", "att">;
2219 defm : IntegerCondCodeMnemonicAlias<"cmov", "l", "att">;
2220 defm : IntegerCondCodeMnemonicAlias<"cmov", "q", "att">;
2221 // No size suffix for intel-style asm.
2222 defm : IntegerCondCodeMnemonicAlias<"cmov", "", "intel">;
2223
2224
2225 //===----------------------------------------------------------------------===//
2226 // Assembler Instruction Aliases
2227 //===----------------------------------------------------------------------===//
2228
2229 // aad/aam default to base 10 if no operand is specified.
2230 def : InstAlias<"aad", (AAD8i8 10)>;
2231 def : InstAlias<"aam", (AAM8i8 10)>;
2232
2233 // Disambiguate the mem/imm form of bt-without-a-suffix as btl.
2234 // Likewise for btc/btr/bts.
2235 def : InstAlias<"bt {$imm, $mem|$mem, $imm}",
2236                 (BT32mi8 i32mem:$mem, i32i8imm:$imm), 0>;
2237 def : InstAlias<"btc {$imm, $mem|$mem, $imm}",
2238                 (BTC32mi8 i32mem:$mem, i32i8imm:$imm), 0>;
2239 def : InstAlias<"btr {$imm, $mem|$mem, $imm}",
2240                 (BTR32mi8 i32mem:$mem, i32i8imm:$imm), 0>;
2241 def : InstAlias<"bts {$imm, $mem|$mem, $imm}",
2242                 (BTS32mi8 i32mem:$mem, i32i8imm:$imm), 0>;
2243
2244 // clr aliases.
2245 def : InstAlias<"clrb $reg", (XOR8rr  GR8 :$reg, GR8 :$reg), 0>;
2246 def : InstAlias<"clrw $reg", (XOR16rr GR16:$reg, GR16:$reg), 0>;
2247 def : InstAlias<"clrl $reg", (XOR32rr GR32:$reg, GR32:$reg), 0>;
2248 def : InstAlias<"clrq $reg", (XOR64rr GR64:$reg, GR64:$reg), 0>;
2249
2250 // div and idiv aliases for explicit A register.
2251 def : InstAlias<"div{b}\t{$src, %al|al, $src}", (DIV8r  GR8 :$src)>;
2252 def : InstAlias<"div{w}\t{$src, %ax|ax, $src}", (DIV16r GR16:$src)>;
2253 def : InstAlias<"div{l}\t{$src, %eax|eax, $src}", (DIV32r GR32:$src)>;
2254 def : InstAlias<"div{q}\t{$src, %rax|rax, $src}", (DIV64r GR64:$src)>;
2255 def : InstAlias<"div{b}\t{$src, %al|al, $src}", (DIV8m  i8mem :$src)>;
2256 def : InstAlias<"div{w}\t{$src, %ax|ax, $src}", (DIV16m i16mem:$src)>;
2257 def : InstAlias<"div{l}\t{$src, %eax|eax, $src}", (DIV32m i32mem:$src)>;
2258 def : InstAlias<"div{q}\t{$src, %rax|rax, $src}", (DIV64m i64mem:$src)>;
2259 def : InstAlias<"idiv{b}\t{$src, %al|al, $src}", (IDIV8r  GR8 :$src)>;
2260 def : InstAlias<"idiv{w}\t{$src, %ax|ax, $src}", (IDIV16r GR16:$src)>;
2261 def : InstAlias<"idiv{l}\t{$src, %eax|eax, $src}", (IDIV32r GR32:$src)>;
2262 def : InstAlias<"idiv{q}\t{$src, %rax|rax, $src}", (IDIV64r GR64:$src)>;
2263 def : InstAlias<"idiv{b}\t{$src, %al|al, $src}", (IDIV8m  i8mem :$src)>;
2264 def : InstAlias<"idiv{w}\t{$src, %ax|ax, $src}", (IDIV16m i16mem:$src)>;
2265 def : InstAlias<"idiv{l}\t{$src, %eax|eax, $src}", (IDIV32m i32mem:$src)>;
2266 def : InstAlias<"idiv{q}\t{$src, %rax|rax, $src}", (IDIV64m i64mem:$src)>;
2267
2268
2269
2270 // Various unary fpstack operations default to operating on on ST1.
2271 // For example, "fxch" -> "fxch %st(1)"
2272 def : InstAlias<"faddp",        (ADD_FPrST0  ST1), 0>;
2273 def : InstAlias<"fsub{|r}p",    (SUBR_FPrST0 ST1), 0>;
2274 def : InstAlias<"fsub{r|}p",    (SUB_FPrST0  ST1), 0>;
2275 def : InstAlias<"fmulp",        (MUL_FPrST0  ST1), 0>;
2276 def : InstAlias<"fdiv{|r}p",    (DIVR_FPrST0 ST1), 0>;
2277 def : InstAlias<"fdiv{r|}p",    (DIV_FPrST0  ST1), 0>;
2278 def : InstAlias<"fxch",         (XCH_F       ST1), 0>;
2279 def : InstAlias<"fcom",         (COM_FST0r   ST1), 0>;
2280 def : InstAlias<"fcomp",        (COMP_FST0r  ST1), 0>;
2281 def : InstAlias<"fcomi",        (COM_FIr     ST1), 0>;
2282 def : InstAlias<"fcompi",       (COM_FIPr    ST1), 0>;
2283 def : InstAlias<"fucom",        (UCOM_Fr     ST1), 0>;
2284 def : InstAlias<"fucomp",       (UCOM_FPr    ST1), 0>;
2285 def : InstAlias<"fucomi",       (UCOM_FIr    ST1), 0>;
2286 def : InstAlias<"fucompi",      (UCOM_FIPr   ST1), 0>;
2287
2288 // Handle fmul/fadd/fsub/fdiv instructions with explicitly written st(0) op.
2289 // For example, "fadd %st(4), %st(0)" -> "fadd %st(4)".  We also disambiguate
2290 // instructions like "fadd %st(0), %st(0)" as "fadd %st(0)" for consistency with
2291 // gas.
2292 multiclass FpUnaryAlias<string Mnemonic, Instruction Inst, bit EmitAlias = 1> {
2293  def : InstAlias<!strconcat(Mnemonic, "\t{$op, %st(0)|st(0), $op}"),
2294                  (Inst RST:$op), EmitAlias>;
2295  def : InstAlias<!strconcat(Mnemonic, "\t{%st(0), %st(0)|st(0), st(0)}"),
2296                  (Inst ST0), EmitAlias>;
2297 }
2298
2299 defm : FpUnaryAlias<"fadd",   ADD_FST0r>;
2300 defm : FpUnaryAlias<"faddp",  ADD_FPrST0, 0>;
2301 defm : FpUnaryAlias<"fsub",   SUB_FST0r>;
2302 defm : FpUnaryAlias<"fsub{|r}p",  SUBR_FPrST0>;
2303 defm : FpUnaryAlias<"fsubr",  SUBR_FST0r>;
2304 defm : FpUnaryAlias<"fsub{r|}p", SUB_FPrST0>;
2305 defm : FpUnaryAlias<"fmul",   MUL_FST0r>;
2306 defm : FpUnaryAlias<"fmulp",  MUL_FPrST0>;
2307 defm : FpUnaryAlias<"fdiv",   DIV_FST0r>;
2308 defm : FpUnaryAlias<"fdiv{|r}p",  DIVR_FPrST0>;
2309 defm : FpUnaryAlias<"fdivr",  DIVR_FST0r>;
2310 defm : FpUnaryAlias<"fdiv{r|}p", DIV_FPrST0>;
2311 defm : FpUnaryAlias<"fcomi",   COM_FIr, 0>;
2312 defm : FpUnaryAlias<"fucomi",  UCOM_FIr, 0>;
2313 defm : FpUnaryAlias<"fcompi",   COM_FIPr>;
2314 defm : FpUnaryAlias<"fucompi",  UCOM_FIPr>;
2315
2316
2317 // Handle "f{mulp,addp} st(0), $op" the same as "f{mulp,addp} $op", since they
2318 // commute.  We also allow fdiv[r]p/fsubrp even though they don't commute,
2319 // solely because gas supports it.
2320 def : InstAlias<"faddp\t{%st(0), $op|$op, st(0)}", (ADD_FPrST0 RST:$op), 0>;
2321 def : InstAlias<"fmulp\t{%st(0), $op|$op, st(0)}", (MUL_FPrST0 RST:$op)>;
2322 def : InstAlias<"fsub{|r}p\t{%st(0), $op|$op, st(0)}", (SUBR_FPrST0 RST:$op)>;
2323 def : InstAlias<"fsub{r|}p\t{%st(0), $op|$op, st(0)}", (SUB_FPrST0 RST:$op)>;
2324 def : InstAlias<"fdiv{|r}p\t{%st(0), $op|$op, st(0)}", (DIVR_FPrST0 RST:$op)>;
2325 def : InstAlias<"fdiv{r|}p\t{%st(0), $op|$op, st(0)}", (DIV_FPrST0 RST:$op)>;
2326
2327 // We accept "fnstsw %eax" even though it only writes %ax.
2328 def : InstAlias<"fnstsw\t{%eax|eax}", (FNSTSW16r)>;
2329 def : InstAlias<"fnstsw\t{%al|al}" , (FNSTSW16r)>;
2330 def : InstAlias<"fnstsw"     , (FNSTSW16r)>;
2331
2332 // lcall and ljmp aliases.  This seems to be an odd mapping in 64-bit mode, but
2333 // this is compatible with what GAS does.
2334 def : InstAlias<"lcall $seg, $off", (FARCALL32i i32imm:$off, i16imm:$seg)>;
2335 def : InstAlias<"ljmp $seg, $off",  (FARJMP32i  i32imm:$off, i16imm:$seg)>;
2336 def : InstAlias<"lcall *$dst",      (FARCALL32m opaque48mem:$dst)>;
2337 def : InstAlias<"ljmp *$dst",       (FARJMP32m  opaque48mem:$dst)>;
2338
2339 // "imul <imm>, B" is an alias for "imul <imm>, B, B".
2340 def : InstAlias<"imulw $imm, $r", (IMUL16rri  GR16:$r, GR16:$r, i16imm:$imm)>;
2341 def : InstAlias<"imulw $imm, $r", (IMUL16rri8 GR16:$r, GR16:$r, i16i8imm:$imm)>;
2342 def : InstAlias<"imull $imm, $r", (IMUL32rri  GR32:$r, GR32:$r, i32imm:$imm)>;
2343 def : InstAlias<"imull $imm, $r", (IMUL32rri8 GR32:$r, GR32:$r, i32i8imm:$imm)>;
2344 def : InstAlias<"imulq $imm, $r",(IMUL64rri32 GR64:$r, GR64:$r,i64i32imm:$imm)>;
2345 def : InstAlias<"imulq $imm, $r", (IMUL64rri8 GR64:$r, GR64:$r, i64i8imm:$imm)>;
2346
2347 // inb %dx -> inb %al, %dx
2348 def : InstAlias<"inb\t{%dx|dx}", (IN8rr), 0>;
2349 def : InstAlias<"inw\t{%dx|dx}", (IN16rr), 0>;
2350 def : InstAlias<"inl\t{%dx|dx}", (IN32rr), 0>;
2351 def : InstAlias<"inb\t$port", (IN8ri i8imm:$port), 0>;
2352 def : InstAlias<"inw\t$port", (IN16ri i8imm:$port), 0>;
2353 def : InstAlias<"inl\t$port", (IN32ri i8imm:$port), 0>;
2354
2355
2356 // jmp and call aliases for lcall and ljmp.  jmp $42,$5 -> ljmp
2357 def : InstAlias<"call $seg, $off",  (FARCALL32i i32imm:$off, i16imm:$seg)>;
2358 def : InstAlias<"jmp $seg, $off",   (FARJMP32i  i32imm:$off, i16imm:$seg)>;
2359 def : InstAlias<"callw $seg, $off", (FARCALL16i i16imm:$off, i16imm:$seg)>;
2360 def : InstAlias<"jmpw $seg, $off",  (FARJMP16i  i16imm:$off, i16imm:$seg)>;
2361 def : InstAlias<"calll $seg, $off", (FARCALL32i i32imm:$off, i16imm:$seg)>;
2362 def : InstAlias<"jmpl $seg, $off",  (FARJMP32i  i32imm:$off, i16imm:$seg)>;
2363
2364 // Force mov without a suffix with a segment and mem to prefer the 'l' form of
2365 // the move.  All segment/mem forms are equivalent, this has the shortest
2366 // encoding.
2367 def : InstAlias<"mov $mem, $seg", (MOV32sm SEGMENT_REG:$seg, i32mem:$mem)>;
2368 def : InstAlias<"mov $seg, $mem", (MOV32ms i32mem:$mem, SEGMENT_REG:$seg)>;
2369
2370 // Match 'movq <largeimm>, <reg>' as an alias for movabsq.
2371 def : InstAlias<"movq $imm, $reg", (MOV64ri GR64:$reg, i64imm:$imm)>;
2372
2373 // Match 'movq GR64, MMX' as an alias for movd.
2374 def : InstAlias<"movq $src, $dst",
2375                 (MMX_MOVD64to64rr VR64:$dst, GR64:$src), 0>;
2376 def : InstAlias<"movq $src, $dst",
2377                 (MMX_MOVD64from64rr GR64:$dst, VR64:$src), 0>;
2378
2379 // movsd with no operands (as opposed to the SSE scalar move of a double) is an
2380 // alias for movsl. (as in rep; movsd)
2381 def : InstAlias<"movsd", (MOVSD), 0>;
2382
2383 // movsx aliases
2384 def : InstAlias<"movsx $src, $dst", (MOVSX16rr8 GR16:$dst, GR8:$src), 0>;
2385 def : InstAlias<"movsx $src, $dst", (MOVSX16rm8 GR16:$dst, i8mem:$src), 0>;
2386 def : InstAlias<"movsx $src, $dst", (MOVSX32rr8 GR32:$dst, GR8:$src), 0>;
2387 def : InstAlias<"movsx $src, $dst", (MOVSX32rr16 GR32:$dst, GR16:$src), 0>;
2388 def : InstAlias<"movsx $src, $dst", (MOVSX64rr8 GR64:$dst, GR8:$src), 0>;
2389 def : InstAlias<"movsx $src, $dst", (MOVSX64rr16 GR64:$dst, GR16:$src), 0>;
2390 def : InstAlias<"movsx $src, $dst", (MOVSX64rr32 GR64:$dst, GR32:$src), 0>;
2391
2392 // movzx aliases
2393 def : InstAlias<"movzx $src, $dst", (MOVZX16rr8 GR16:$dst, GR8:$src), 0>;
2394 def : InstAlias<"movzx $src, $dst", (MOVZX16rm8 GR16:$dst, i8mem:$src), 0>;
2395 def : InstAlias<"movzx $src, $dst", (MOVZX32rr8 GR32:$dst, GR8:$src), 0>;
2396 def : InstAlias<"movzx $src, $dst", (MOVZX32rr16 GR32:$dst, GR16:$src), 0>;
2397 def : InstAlias<"movzx $src, $dst", (MOVZX64rr8_Q GR64:$dst, GR8:$src), 0>;
2398 def : InstAlias<"movzx $src, $dst", (MOVZX64rr16_Q GR64:$dst, GR16:$src), 0>;
2399 // Note: No GR32->GR64 movzx form.
2400
2401 // outb %dx -> outb %al, %dx
2402 def : InstAlias<"outb\t{%dx|dx}", (OUT8rr), 0>;
2403 def : InstAlias<"outw\t{%dx|dx}", (OUT16rr), 0>;
2404 def : InstAlias<"outl\t{%dx|dx}", (OUT32rr), 0>;
2405 def : InstAlias<"outb\t$port", (OUT8ir i8imm:$port), 0>;
2406 def : InstAlias<"outw\t$port", (OUT16ir i8imm:$port), 0>;
2407 def : InstAlias<"outl\t$port", (OUT32ir i8imm:$port), 0>;
2408
2409 // 'sldt <mem>' can be encoded with either sldtw or sldtq with the same
2410 // effect (both store to a 16-bit mem).  Force to sldtw to avoid ambiguity
2411 // errors, since its encoding is the most compact.
2412 def : InstAlias<"sldt $mem", (SLDT16m i16mem:$mem)>;
2413
2414 // shld/shrd op,op -> shld op, op, CL
2415 def : InstAlias<"shld{w}\t{$r2, $r1|$r1, $r2}", (SHLD16rrCL GR16:$r1, GR16:$r2), 0>;
2416 def : InstAlias<"shld{l}\t{$r2, $r1|$r1, $r2}", (SHLD32rrCL GR32:$r1, GR32:$r2), 0>;
2417 def : InstAlias<"shld{q}\t{$r2, $r1|$r1, $r2}", (SHLD64rrCL GR64:$r1, GR64:$r2), 0>;
2418 def : InstAlias<"shrd{w}\t{$r2, $r1|$r1, $r2}", (SHRD16rrCL GR16:$r1, GR16:$r2), 0>;
2419 def : InstAlias<"shrd{l}\t{$r2, $r1|$r1, $r2}", (SHRD32rrCL GR32:$r1, GR32:$r2), 0>;
2420 def : InstAlias<"shrd{q}\t{$r2, $r1|$r1, $r2}", (SHRD64rrCL GR64:$r1, GR64:$r2), 0>;
2421
2422 def : InstAlias<"shld{w}\t{$reg, $mem|$mem, $reg}", (SHLD16mrCL i16mem:$mem, GR16:$reg), 0>;
2423 def : InstAlias<"shld{l}\t{$reg, $mem|$mem, $reg}", (SHLD32mrCL i32mem:$mem, GR32:$reg), 0>;
2424 def : InstAlias<"shld{q}\t{$reg, $mem|$mem, $reg}", (SHLD64mrCL i64mem:$mem, GR64:$reg), 0>;
2425 def : InstAlias<"shrd{w}\t{$reg, $mem|$mem, $reg}", (SHRD16mrCL i16mem:$mem, GR16:$reg), 0>;
2426 def : InstAlias<"shrd{l}\t{$reg, $mem|$mem, $reg}", (SHRD32mrCL i32mem:$mem, GR32:$reg), 0>;
2427 def : InstAlias<"shrd{q}\t{$reg, $mem|$mem, $reg}", (SHRD64mrCL i64mem:$mem, GR64:$reg), 0>;
2428
2429 /*  FIXME: This is disabled because the asm matcher is currently incapable of
2430  *  matching a fixed immediate like $1.
2431 // "shl X, $1" is an alias for "shl X".
2432 multiclass ShiftRotateByOneAlias<string Mnemonic, string Opc> {
2433  def : InstAlias<!strconcat(Mnemonic, "b $op, $$1"),
2434                  (!cast<Instruction>(!strconcat(Opc, "8r1")) GR8:$op)>;
2435  def : InstAlias<!strconcat(Mnemonic, "w $op, $$1"),
2436                  (!cast<Instruction>(!strconcat(Opc, "16r1")) GR16:$op)>;
2437  def : InstAlias<!strconcat(Mnemonic, "l $op, $$1"),
2438                  (!cast<Instruction>(!strconcat(Opc, "32r1")) GR32:$op)>;
2439  def : InstAlias<!strconcat(Mnemonic, "q $op, $$1"),
2440                  (!cast<Instruction>(!strconcat(Opc, "64r1")) GR64:$op)>;
2441  def : InstAlias<!strconcat(Mnemonic, "b $op, $$1"),
2442                  (!cast<Instruction>(!strconcat(Opc, "8m1")) i8mem:$op)>;
2443  def : InstAlias<!strconcat(Mnemonic, "w $op, $$1"),
2444                  (!cast<Instruction>(!strconcat(Opc, "16m1")) i16mem:$op)>;
2445  def : InstAlias<!strconcat(Mnemonic, "l $op, $$1"),
2446                  (!cast<Instruction>(!strconcat(Opc, "32m1")) i32mem:$op)>;
2447  def : InstAlias<!strconcat(Mnemonic, "q $op, $$1"),
2448                  (!cast<Instruction>(!strconcat(Opc, "64m1")) i64mem:$op)>;
2449 }
2450
2451 defm : ShiftRotateByOneAlias<"rcl", "RCL">;
2452 defm : ShiftRotateByOneAlias<"rcr", "RCR">;
2453 defm : ShiftRotateByOneAlias<"rol", "ROL">;
2454 defm : ShiftRotateByOneAlias<"ror", "ROR">;
2455 FIXME */
2456
2457 // test: We accept "testX <reg>, <mem>" and "testX <mem>, <reg>" as synonyms.
2458 def : InstAlias<"test{b}\t{$val, $mem|$mem, $val}", (TEST8rm  GR8 :$val, i8mem :$mem)>;
2459 def : InstAlias<"test{w}\t{$val, $mem|$mem, $val}", (TEST16rm GR16:$val, i16mem:$mem)>;
2460 def : InstAlias<"test{l}\t{$val, $mem|$mem, $val}", (TEST32rm GR32:$val, i32mem:$mem)>;
2461 def : InstAlias<"test{q}\t{$val, $mem|$mem, $val}", (TEST64rm GR64:$val, i64mem:$mem)>;
2462
2463 // xchg: We accept "xchgX <reg>, <mem>" and "xchgX <mem>, <reg>" as synonyms.
2464 def : InstAlias<"xchg{b}\t{$mem, $val|$val, $mem}", (XCHG8rm  GR8 :$val, i8mem :$mem)>;
2465 def : InstAlias<"xchg{w}\t{$mem, $val|$val, $mem}", (XCHG16rm GR16:$val, i16mem:$mem)>;
2466 def : InstAlias<"xchg{l}\t{$mem, $val|$val, $mem}", (XCHG32rm GR32:$val, i32mem:$mem)>;
2467 def : InstAlias<"xchg{q}\t{$mem, $val|$val, $mem}", (XCHG64rm GR64:$val, i64mem:$mem)>;
2468
2469 // xchg: We accept "xchgX <reg>, %eax" and "xchgX %eax, <reg>" as synonyms.
2470 def : InstAlias<"xchg{w}\t{%ax, $src|$src, ax}", (XCHG16ar GR16:$src)>;
2471 def : InstAlias<"xchg{l}\t{%eax, $src|$src, eax}", (XCHG32ar GR32:$src)>, Requires<[Not64BitMode]>;
2472 def : InstAlias<"xchg{l}\t{%eax, $src|$src, eax}", (XCHG32ar64 GR32_NOAX:$src)>, Requires<[In64BitMode]>;
2473 def : InstAlias<"xchg{q}\t{%rax, $src|$src, rax}", (XCHG64ar GR64:$src)>;