lib/Target/X86/X86InstrFormats.td

   1 //===- X86InstrFormats.td - X86 Instruction Formats --------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<6> val> {
  18   bits<6> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>;
  25 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  26 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  27 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  28 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  29 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  30 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  31 def MRMInitReg : Format<32>;
  32
  33
  34 // ImmType - This specifies the immediate type used by an instruction. This is
  35 // part of the ad-hoc solution used to emit machine instruction encodings by our
  36 // machine code emitter.
  37 class ImmType<bits<3> val> {
  38   bits<3> Value = val;
  39 }
  40 def NoImm  : ImmType<0>;
  41 def Imm8   : ImmType<1>;
  42 def Imm16  : ImmType<2>;
  43 def Imm32  : ImmType<3>;
  44 def Imm64  : ImmType<4>;
  45
  46 // FPFormat - This specifies what form this FP instruction has.  This is used by
  47 // the Floating-Point stackifier pass.
  48 class FPFormat<bits<3> val> {
  49   bits<3> Value = val;
  50 }
  51 def NotFP      : FPFormat<0>;
  52 def ZeroArgFP  : FPFormat<1>;
  53 def OneArgFP   : FPFormat<2>;
  54 def OneArgFPRW : FPFormat<3>;
  55 def TwoArgFP   : FPFormat<4>;
  56 def CompareFP  : FPFormat<5>;
  57 def CondMovFP  : FPFormat<6>;
  58 def SpecialFP  : FPFormat<7>;
  59
  60 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  61 // emitter that various prefix bytes are required.
  62 class OpSize { bit hasOpSizePrefix = 1; }
  63 class AdSize { bit hasAdSizePrefix = 1; }
  64 class REX_W  { bit hasREX_WPrefix = 1; }
  65 class LOCK   { bit hasLockPrefix = 1; }
  66 class TB     { bits<4> Prefix = 1; }
  67 class REP    { bits<4> Prefix = 2; }
  68 class D8     { bits<4> Prefix = 3; }
  69 class D9     { bits<4> Prefix = 4; }
  70 class DA     { bits<4> Prefix = 5; }
  71 class DB     { bits<4> Prefix = 6; }
  72 class DC     { bits<4> Prefix = 7; }
  73 class DD     { bits<4> Prefix = 8; }
  74 class DE     { bits<4> Prefix = 9; }
  75 class DF     { bits<4> Prefix = 10; }
  76 class XD     { bits<4> Prefix = 11; }
  77 class XS     { bits<4> Prefix = 12; }
  78 class T8     { bits<4> Prefix = 13; }
  79 class TA     { bits<4> Prefix = 14; }
  80
  81 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
  82               string AsmStr>
  83   : Instruction {
  84   let Namespace = "X86";
  85
  86   bits<8> Opcode = opcod;
  87   Format Form = f;
  88   bits<6> FormBits = Form.Value;
  89   ImmType ImmT = i;
  90   bits<3> ImmTypeBits = ImmT.Value;
  91
  92   dag OutOperandList = outs;
  93   dag InOperandList = ins;
  94   string AsmString = AsmStr;
  95
  96   //
  97   // Attributes specific to X86 instructions...
  98   //
  99   bit hasOpSizePrefix = 0;  // Does this inst have a 0x66 prefix?
 100   bit hasAdSizePrefix = 0;  // Does this inst have a 0x67 prefix?
 101
 102   bits<4> Prefix = 0;       // Which prefix byte does this inst have?
 103   bit hasREX_WPrefix  = 0;  // Does this inst requires the REX.W prefix?
 104   FPFormat FPForm;          // What flavor of FP instruction is this?
 105   bits<3> FPFormBits = 0;
 106   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 107 }
 108
 109 class I<bits<8> o, Format f, dag outs, dag ins, string asm, list<dag> pattern>
 110   : X86Inst<o, f, NoImm, outs, ins, asm> {
 111   let Pattern = pattern;
 112   let CodeSize = 3;
 113 }
 114 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm, list<dag> pattern>
 115   : X86Inst<o, f, Imm8 , outs, ins, asm> {
 116   let Pattern = pattern;
 117   let CodeSize = 3;
 118 }
 119 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm, list<dag> pattern>
 120   : X86Inst<o, f, Imm16, outs, ins, asm> {
 121   let Pattern = pattern;
 122   let CodeSize = 3;
 123 }
 124 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm, list<dag> pattern>
 125   : X86Inst<o, f, Imm32, outs, ins, asm> {
 126   let Pattern = pattern;
 127   let CodeSize = 3;
 128 }
 129
 130 // FPStack Instruction Templates:
 131 // FPI - Floating Point Instruction template.
 132 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm>
 133   : I<o, F, outs, ins, asm, []> {}
 134
 135 // FpI_ - Floating Point Psuedo Instruction template. Not Predicated.
 136 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern>
 137   : X86Inst<0, Pseudo, NoImm, outs, ins, ""> {
 138   let FPForm = fp; let FPFormBits = FPForm.Value;
 139   let Pattern = pattern;
 140 }
 141
 142 // SSE1 Instruction Templates:
 143 //
 144 //   SSI   - SSE1 instructions with XS prefix.
 145 //   PSI   - SSE1 instructions with TB prefix.
 146 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and TB prefix.
 147
 148 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 149       : I<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 150 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 151       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 152 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 153       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasSSE1]>;
 154 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 155             list<dag> pattern>
 156       : Ii8<o, F, outs, ins, asm, pattern>, TB, Requires<[HasSSE1]>;
 157
 158 // SSE2 Instruction Templates:
 159 //
 160 //   SDI    - SSE2 instructions with XD prefix.
 161 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 162 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 163 //   PDI    - SSE2 instructions with TB and OpSize prefixes.
 164 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and TB and OpSize prefixes.
 165
 166 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 167       : I<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 168 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 169             list<dag> pattern>
 170       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 171 class SSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 172              list<dag> pattern>
 173       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 174 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 175       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasSSE2]>;
 176 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 177             list<dag> pattern>
 178       : Ii8<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasSSE2]>;
 179
 180 // SSE3 Instruction Templates:
 181 //
 182 //   S3I   - SSE3 instructions with TB and OpSize prefixes.
 183 //   S3SI  - SSE3 instructions with XS prefix.
 184 //   S3DI  - SSE3 instructions with XD prefix.
 185
 186 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 187       : I<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE3]>;
 188 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 189       : I<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE3]>;
 190 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 191       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasSSE3]>;
 192
 193
 194 // SSSE3 Instruction Templates:
 195 //
 196 //   SS38I - SSSE3 instructions with T8 prefix.
 197 //   SS3AI - SSSE3 instructions with TA prefix.
 198 //
 199 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 200 // uses the MMX registers. We put those instructions here because they better
 201 // fit into the SSSE3 instruction category rather than the MMX category.
 202
 203 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 204             list<dag> pattern>
 205       : I<o, F, outs, ins, asm, pattern>, T8, Requires<[HasSSSE3]>;
 206 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 207             list<dag> pattern>
 208       : I<o, F, outs, ins, asm, pattern>, TA, Requires<[HasSSSE3]>;
 209
 210 // SSE4.1 Instruction Templates:
 211 //
 212 //   SS48I - SSE 4.1 instructions with T8 prefix.
 213 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 214 //
 215 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 216             list<dag> pattern>
 217       : I<o, F, outs, ins, asm, pattern>, T8, Requires<[HasSSE41]>;
 218 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 219             list<dag> pattern>
 220       : Ii8<o, F, outs, ins, asm, pattern>, TA, Requires<[HasSSE41]>;
 221
 222 // SSE4.2 Instruction Templates:
 223 //
 224 //   SS428I - SSE 4.2 instructions with T8 prefix.
 225 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 226              list<dag> pattern>
 227       : I<o, F, outs, ins, asm, pattern>, T8, Requires<[HasSSE42]>;
 228
 229 // X86-64 Instruction templates...
 230 //
 231
 232 class RI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 233       : I<o, F, outs, ins, asm, pattern>, REX_W;
 234 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 235             list<dag> pattern>
 236       : Ii8<o, F, outs, ins, asm, pattern>, REX_W;
 237 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 238              list<dag> pattern>
 239       : Ii32<o, F, outs, ins, asm, pattern>, REX_W;
 240
 241 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 242             list<dag> pattern>
 243   : X86Inst<o, f, Imm64, outs, ins, asm>, REX_W {
 244   let Pattern = pattern;
 245   let CodeSize = 3;
 246 }
 247
 248 class RSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 249            list<dag> pattern>
 250       : SSI<o, F, outs, ins, asm, pattern>, REX_W;
 251 class RSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 252            list<dag> pattern>
 253       : SDI<o, F, outs, ins, asm, pattern>, REX_W;
 254 class RPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 255            list<dag> pattern>
 256       : PDI<o, F, outs, ins, asm, pattern>, REX_W;
 257
 258 // MMX Instruction templates
 259 //
 260
 261 // MMXI   - MMX instructions with TB prefix.
 262 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 263 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
 264 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 265 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 266 // MMXID  - MMX instructions with XD prefix.
 267 // MMXIS  - MMX instructions with XS prefix.
 268 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 269       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 270 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 271       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX,In64BitMode]>;
 272 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 273       : I<o, F, outs, ins, asm, pattern>, TB, REX_W, Requires<[HasMMX]>;
 274 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 275       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasMMX]>;
 276 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 277       : Ii8<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 278 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 279       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasMMX]>;
 280 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 281       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasMMX]>;
 282