lib/Target/X86/X86InstrFormats.td

   1 //===- X86InstrFormats.td - X86 Instruction Formats --------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<6> val> {
  18   bits<6> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>;
  25 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  26 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  27 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  28 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  29 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  30 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  31 def MRMInitReg : Format<32>;
  32 def MRM_C1 : Format<33>;
  33 def MRM_C2 : Format<34>;
  34 def MRM_C3 : Format<35>;
  35 def MRM_C4 : Format<36>;
  36 def MRM_C8 : Format<37>;
  37 def MRM_C9 : Format<38>;
  38 def MRM_E8 : Format<39>;
  39 def MRM_F0 : Format<40>;
  40 def MRM_F8 : Format<41>;
  41 def MRM_F9 : Format<42>;
  42
  43 // ImmType - This specifies the immediate type used by an instruction. This is
  44 // part of the ad-hoc solution used to emit machine instruction encodings by our
  45 // machine code emitter.
  46 class ImmType<bits<3> val> {
  47   bits<3> Value = val;
  48 }
  49 def NoImm      : ImmType<0>;
  50 def Imm8       : ImmType<1>;
  51 def Imm8PCRel  : ImmType<2>;
  52 def Imm16      : ImmType<3>;
  53 def Imm32      : ImmType<4>;
  54 def Imm32PCRel : ImmType<5>;
  55 def Imm64      : ImmType<6>;
  56
  57 // FPFormat - This specifies what form this FP instruction has.  This is used by
  58 // the Floating-Point stackifier pass.
  59 class FPFormat<bits<3> val> {
  60   bits<3> Value = val;
  61 }
  62 def NotFP      : FPFormat<0>;
  63 def ZeroArgFP  : FPFormat<1>;
  64 def OneArgFP   : FPFormat<2>;
  65 def OneArgFPRW : FPFormat<3>;
  66 def TwoArgFP   : FPFormat<4>;
  67 def CompareFP  : FPFormat<5>;
  68 def CondMovFP  : FPFormat<6>;
  69 def SpecialFP  : FPFormat<7>;
  70
  71 // Class specifying the SSE execution domain, used by the SSEDomainFix pass.
  72 // Keep in sync with tables in X86InstrInfo.cpp.
  73 class Domain<bits<2> val> {
  74   bits<2> Value = val;
  75 }
  76 def GenericDomain   : Domain<0>;
  77 def SSEPackedSingle : Domain<1>;
  78 def SSEPackedDouble : Domain<2>;
  79 def SSEPackedInt    : Domain<3>;
  80
  81 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  82 // emitter that various prefix bytes are required.
  83 class OpSize { bit hasOpSizePrefix = 1; }
  84 class AdSize { bit hasAdSizePrefix = 1; }
  85 class REX_W  { bit hasREX_WPrefix = 1; }
  86 class VEX_4V { bit hasVEX_4VPrefix = 1; }
  87 class LOCK   { bit hasLockPrefix = 1; }
  88 class SegFS  { bits<2> SegOvrBits = 1; }
  89 class SegGS  { bits<2> SegOvrBits = 2; }
  90 class TB     { bits<4> Prefix = 1; }
  91 class REP    { bits<4> Prefix = 2; }
  92 class D8     { bits<4> Prefix = 3; }
  93 class D9     { bits<4> Prefix = 4; }
  94 class DA     { bits<4> Prefix = 5; }
  95 class DB     { bits<4> Prefix = 6; }
  96 class DC     { bits<4> Prefix = 7; }
  97 class DD     { bits<4> Prefix = 8; }
  98 class DE     { bits<4> Prefix = 9; }
  99 class DF     { bits<4> Prefix = 10; }
 100 class XD     { bits<4> Prefix = 11; }
 101 class XS     { bits<4> Prefix = 12; }
 102 class T8     { bits<4> Prefix = 13; }
 103 class TA     { bits<4> Prefix = 14; }
 104 class TF     { bits<4> Prefix = 15; }
 105
 106 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
 107               string AsmStr, Domain d = GenericDomain>
 108   : Instruction {
 109   let Namespace = "X86";
 110
 111   bits<8> Opcode = opcod;
 112   Format Form = f;
 113   bits<6> FormBits = Form.Value;
 114   ImmType ImmT = i;
 115
 116   dag OutOperandList = outs;
 117   dag InOperandList = ins;
 118   string AsmString = AsmStr;
 119
 120   //
 121   // Attributes specific to X86 instructions...
 122   //
 123   bit hasOpSizePrefix = 0;  // Does this inst have a 0x66 prefix?
 124   bit hasAdSizePrefix = 0;  // Does this inst have a 0x67 prefix?
 125
 126   bits<4> Prefix = 0;       // Which prefix byte does this inst have?
 127   bit hasREX_WPrefix  = 0;  // Does this inst requires the REX.W prefix?
 128   bit hasVEX_4VPrefix  = 0;  // Does this inst requires the VEX.VVVV prefix?
 129   FPFormat FPForm = NotFP;  // What flavor of FP instruction is this?
 130   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 131   bits<2> SegOvrBits = 0;   // Segment override prefix.
 132   Domain ExeDomain = d;
 133
 134   // TSFlags layout should be kept in sync with X86InstrInfo.h.
 135   let TSFlags{5-0}   = FormBits;
 136   let TSFlags{6}     = hasOpSizePrefix;
 137   let TSFlags{7}     = hasAdSizePrefix;
 138   let TSFlags{11-8}  = Prefix;
 139   let TSFlags{12}    = hasREX_WPrefix;
 140   let TSFlags{15-13} = ImmT.Value;
 141   let TSFlags{18-16} = FPForm.Value;
 142   let TSFlags{19}    = hasLockPrefix;
 143   let TSFlags{21-20} = SegOvrBits;
 144   let TSFlags{23-22} = ExeDomain.Value;
 145   let TSFlags{31-24} = Opcode;
 146   let TSFlags{32}    = hasVEX_4VPrefix;
 147 }
 148
 149 class I<bits<8> o, Format f, dag outs, dag ins, string asm,
 150         list<dag> pattern, Domain d = GenericDomain>
 151   : X86Inst<o, f, NoImm, outs, ins, asm, d> {
 152   let Pattern = pattern;
 153   let CodeSize = 3;
 154 }
 155 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm,
 156            list<dag> pattern, Domain d = GenericDomain>
 157   : X86Inst<o, f, Imm8, outs, ins, asm, d> {
 158   let Pattern = pattern;
 159   let CodeSize = 3;
 160 }
 161 class Ii8PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 162                list<dag> pattern>
 163   : X86Inst<o, f, Imm8PCRel, outs, ins, asm> {
 164   let Pattern = pattern;
 165   let CodeSize = 3;
 166 }
 167 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm,
 168            list<dag> pattern>
 169   : X86Inst<o, f, Imm16, outs, ins, asm> {
 170   let Pattern = pattern;
 171   let CodeSize = 3;
 172 }
 173 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm,
 174            list<dag> pattern>
 175   : X86Inst<o, f, Imm32, outs, ins, asm> {
 176   let Pattern = pattern;
 177   let CodeSize = 3;
 178 }
 179
 180 class Ii32PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 181            list<dag> pattern>
 182   : X86Inst<o, f, Imm32PCRel, outs, ins, asm> {
 183   let Pattern = pattern;
 184   let CodeSize = 3;
 185 }
 186
 187 // FPStack Instruction Templates:
 188 // FPI - Floating Point Instruction template.
 189 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm>
 190   : I<o, F, outs, ins, asm, []> {}
 191
 192 // FpI_ - Floating Point Psuedo Instruction template. Not Predicated.
 193 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern>
 194   : X86Inst<0, Pseudo, NoImm, outs, ins, ""> {
 195   let FPForm = fp;
 196   let Pattern = pattern;
 197 }
 198
 199 // Templates for instructions that use a 16- or 32-bit segmented address as
 200 //  their only operand: lcall (FAR CALL) and ljmp (FAR JMP)
 201 //
 202 //   Iseg16 - 16-bit segment selector, 16-bit offset
 203 //   Iseg32 - 16-bit segment selector, 32-bit offset
 204
 205 class Iseg16 <bits<8> o, Format f, dag outs, dag ins, string asm,
 206               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 207   let Pattern = pattern;
 208   let CodeSize = 3;
 209 }
 210
 211 class Iseg32 <bits<8> o, Format f, dag outs, dag ins, string asm,
 212               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 213   let Pattern = pattern;
 214   let CodeSize = 3;
 215 }
 216
 217 // SI - SSE 1 & 2 scalar instructions
 218 class SI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 219       : I<o, F, outs, ins, asm, pattern> {
 220   let Predicates = !if(hasVEX_4VPrefix /* VEX_4V */,
 221             !if(!eq(Prefix, 11 /* XD */), [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 222             !if(!eq(Prefix, 12 /* XS */), [HasSSE2], [HasSSE1]));
 223
 224   // AVX instructions have a 'v' prefix in the mnemonic
 225   let AsmString = !if(hasVEX_4VPrefix, !strconcat("v", asm), asm);
 226 }
 227
 228 // SSE1 Instruction Templates:
 229 //
 230 //   SSI   - SSE1 instructions with XS prefix.
 231 //   PSI   - SSE1 instructions with TB prefix.
 232 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and TB prefix.
 233 //   VSSI  - SSE1 instructions with XS prefix in AVX form.
 234 //   VPSI  - SSE1 instructions with TB prefix in AVX form.
 235
 236 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 237       : I<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 238 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 239             list<dag> pattern>
 240       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 241 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 242       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 243         Requires<[HasSSE1]>;
 244 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 245             list<dag> pattern>
 246       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 247         Requires<[HasSSE1]>;
 248 class VSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 249            list<dag> pattern>
 250       : I<o, F, outs, ins, !strconcat("v", asm), pattern>, XS, VEX_4V,
 251         Requires<[HasAVX, HasSSE1]>;
 252 class VPSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 253            list<dag> pattern>
 254       : I<o, F, outs, ins, !strconcat("v", asm), pattern, SSEPackedSingle>,
 255         VEX_4V, Requires<[HasAVX, HasSSE1]>;
 256
 257 // SSE2 Instruction Templates:
 258 //
 259 //   SDI    - SSE2 instructions with XD prefix.
 260 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 261 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 262 //   PDI    - SSE2 instructions with TB and OpSize prefixes.
 263 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and TB and OpSize prefixes.
 264 //   VSDI   - SSE2 instructions with XD prefix in AVX form.
 265 //   VPDI   - SSE2 instructions with TB and OpSize prefixes in AVX form.
 266
 267 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 268       : I<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 269 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 270             list<dag> pattern>
 271       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 272 class SSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 273              list<dag> pattern>
 274       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 275 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 276       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 277         Requires<[HasSSE2]>;
 278 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 279             list<dag> pattern>
 280       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 281         Requires<[HasSSE2]>;
 282 class VSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 283            list<dag> pattern>
 284       : I<o, F, outs, ins, !strconcat("v", asm), pattern>, XD, VEX_4V,
 285         Requires<[HasAVX, HasSSE2]>;
 286 class VPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 287            list<dag> pattern>
 288       : I<o, F, outs, ins, !strconcat("v", asm), pattern, SSEPackedDouble>,
 289         VEX_4V, OpSize, Requires<[HasAVX, HasSSE2]>;
 290
 291 // SSE3 Instruction Templates:
 292 //
 293 //   S3I   - SSE3 instructions with TB and OpSize prefixes.
 294 //   S3SI  - SSE3 instructions with XS prefix.
 295 //   S3DI  - SSE3 instructions with XD prefix.
 296
 297 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 298            list<dag> pattern>
 299       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, XS,
 300         Requires<[HasSSE3]>;
 301 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm,
 302            list<dag> pattern>
 303       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, XD,
 304         Requires<[HasSSE3]>;
 305 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 306       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 307         Requires<[HasSSE3]>;
 308
 309
 310 // SSSE3 Instruction Templates:
 311 //
 312 //   SS38I - SSSE3 instructions with T8 prefix.
 313 //   SS3AI - SSSE3 instructions with TA prefix.
 314 //
 315 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 316 // uses the MMX registers. We put those instructions here because they better
 317 // fit into the SSSE3 instruction category rather than the MMX category.
 318
 319 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 320             list<dag> pattern>
 321       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 322         Requires<[HasSSSE3]>;
 323 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 324             list<dag> pattern>
 325       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 326         Requires<[HasSSSE3]>;
 327
 328 // SSE4.1 Instruction Templates:
 329 //
 330 //   SS48I - SSE 4.1 instructions with T8 prefix.
 331 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 332 //
 333 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 334             list<dag> pattern>
 335       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 336         Requires<[HasSSE41]>;
 337 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 338             list<dag> pattern>
 339       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 340         Requires<[HasSSE41]>;
 341
 342 // SSE4.2 Instruction Templates:
 343 //
 344 //   SS428I - SSE 4.2 instructions with T8 prefix.
 345 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 346              list<dag> pattern>
 347       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 348         Requires<[HasSSE42]>;
 349
 350 //   SS42FI - SSE 4.2 instructions with TF prefix.
 351 class SS42FI<bits<8> o, Format F, dag outs, dag ins, string asm,
 352               list<dag> pattern>
 353       : I<o, F, outs, ins, asm, pattern>, TF, Requires<[HasSSE42]>;
 354
 355 //   SS42AI = SSE 4.2 instructions with TA prefix
 356 class SS42AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 357              list<dag> pattern>
 358       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 359         Requires<[HasSSE42]>;
 360
 361 // AES Instruction Templates:
 362 //
 363 // AES8I
 364 // These use the same encoding as the SSE4.2 T8 and TA encodings.
 365 class AES8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 366             list<dag>pattern>
 367       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 368         Requires<[HasAES]>;
 369
 370 class AESAI<bits<8> o, Format F, dag outs, dag ins, string asm,
 371             list<dag> pattern>
 372       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 373         Requires<[HasAES]>;
 374
 375 // X86-64 Instruction templates...
 376 //
 377
 378 class RI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 379       : I<o, F, outs, ins, asm, pattern>, REX_W;
 380 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 381             list<dag> pattern>
 382       : Ii8<o, F, outs, ins, asm, pattern>, REX_W;
 383 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 384              list<dag> pattern>
 385       : Ii32<o, F, outs, ins, asm, pattern>, REX_W;
 386
 387 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 388             list<dag> pattern>
 389   : X86Inst<o, f, Imm64, outs, ins, asm>, REX_W {
 390   let Pattern = pattern;
 391   let CodeSize = 3;
 392 }
 393
 394 class RSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 395            list<dag> pattern>
 396       : SSI<o, F, outs, ins, asm, pattern>, REX_W;
 397 class RSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 398            list<dag> pattern>
 399       : SDI<o, F, outs, ins, asm, pattern>, REX_W;
 400 class RPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 401            list<dag> pattern>
 402       : PDI<o, F, outs, ins, asm, pattern>, REX_W;
 403
 404 // MMX Instruction templates
 405 //
 406
 407 // MMXI   - MMX instructions with TB prefix.
 408 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 409 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
 410 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 411 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 412 // MMXID  - MMX instructions with XD prefix.
 413 // MMXIS  - MMX instructions with XS prefix.
 414 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm,
 415            list<dag> pattern>
 416       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 417 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm,
 418              list<dag> pattern>
 419       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX,In64BitMode]>;
 420 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm,
 421             list<dag> pattern>
 422       : I<o, F, outs, ins, asm, pattern>, TB, REX_W, Requires<[HasMMX]>;
 423 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 424             list<dag> pattern>
 425       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasMMX]>;
 426 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 427              list<dag> pattern>
 428       : Ii8<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 429 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm,
 430             list<dag> pattern>
 431       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasMMX]>;
 432 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm,
 433             list<dag> pattern>
 434       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasMMX]>;