lib/Target/X86/X86InstrFMA.td

   1 //===-- X86InstrFMA.td - FMA Instruction Set ---------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes FMA (Fused Multiply-Add) instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // FMA3 - Intel 3 operand Fused Multiply-Add instructions
  16 //===----------------------------------------------------------------------===//
  17
  18 let Constraints = "$src1 = $dst" in {
  19 multiclass fma3p_rm<bits<8> opc, string OpcodeStr,
  20                     PatFrag MemFrag128, PatFrag MemFrag256,
  21                     ValueType OpVT128, ValueType OpVT256,
  22                     SDPatternOperator Op = null_frag, bit MayLoad = 1> {
  23   def r     : FMA3<opc, MRMSrcReg, (outs VR128:$dst),
  24                    (ins VR128:$src1, VR128:$src2, VR128:$src3),
  25                    !strconcat(OpcodeStr,
  26                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  27                    [(set VR128:$dst, (OpVT128 (Op VR128:$src2,
  28                                                VR128:$src1, VR128:$src3)))]>;
  29
  30   let mayLoad = MayLoad in
  31   def m     : FMA3<opc, MRMSrcMem, (outs VR128:$dst),
  32                    (ins VR128:$src1, VR128:$src2, f128mem:$src3),
  33                    !strconcat(OpcodeStr,
  34                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  35                    [(set VR128:$dst, (OpVT128 (Op VR128:$src2, VR128:$src1,
  36                                                (MemFrag128 addr:$src3))))]>;
  37
  38   def rY    : FMA3<opc, MRMSrcReg, (outs VR256:$dst),
  39                    (ins VR256:$src1, VR256:$src2, VR256:$src3),
  40                    !strconcat(OpcodeStr,
  41                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  42                    [(set VR256:$dst, (OpVT256 (Op VR256:$src2, VR256:$src1,
  43                                                VR256:$src3)))]>;
  44
  45   let mayLoad = MayLoad in
  46   def mY    : FMA3<opc, MRMSrcMem, (outs VR256:$dst),
  47                    (ins VR256:$src1, VR256:$src2, f256mem:$src3),
  48                    !strconcat(OpcodeStr,
  49                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
  50                    [(set VR256:$dst,
  51                      (OpVT256 (Op VR256:$src2, VR256:$src1,
  52                                (MemFrag256 addr:$src3))))]>;
  53 }
  54 } // Constraints = "$src1 = $dst"
  55
  56 multiclass fma3p_forms<bits<8> opc132, bits<8> opc213, bits<8> opc231,
  57                        string OpcodeStr, string PackTy,
  58                        PatFrag MemFrag128, PatFrag MemFrag256,
  59                        SDNode Op, ValueType OpTy128, ValueType OpTy256> {
  60   defm r213 : fma3p_rm<opc213,
  61                        !strconcat(OpcodeStr, !strconcat("213", PackTy)),
  62                        MemFrag128, MemFrag256, OpTy128, OpTy256, Op, 0>;
  63 let neverHasSideEffects = 1 in {
  64   defm r132 : fma3p_rm<opc132,
  65                        !strconcat(OpcodeStr, !strconcat("132", PackTy)),
  66                        MemFrag128, MemFrag256, OpTy128, OpTy256>;
  67   defm r231 : fma3p_rm<opc231,
  68                        !strconcat(OpcodeStr, !strconcat("231", PackTy)),
  69                        MemFrag128, MemFrag256, OpTy128, OpTy256>;
  70 } // neverHasSideEffects = 1
  71 }
  72
  73 // Fused Multiply-Add
  74 let ExeDomain = SSEPackedSingle in {
  75   defm VFMADDPS    : fma3p_forms<0x98, 0xA8, 0xB8, "vfmadd", "ps", memopv4f32,
  76                                  memopv8f32, X86Fmadd, v4f32, v8f32>;
  77   defm VFMSUBPS    : fma3p_forms<0x9A, 0xAA, 0xBA, "vfmsub", "ps", memopv4f32,
  78                                  memopv8f32, X86Fmsub, v4f32, v8f32>;
  79   defm VFMADDSUBPS : fma3p_forms<0x96, 0xA6, 0xB6, "vfmaddsub", "ps",
  80                                  memopv4f32, memopv8f32, X86Fmaddsub,
  81                                  v4f32, v8f32>;
  82   defm VFMSUBADDPS : fma3p_forms<0x97, 0xA7, 0xB7, "vfmsubadd", "ps",
  83                                  memopv4f32, memopv8f32, X86Fmsubadd,
  84                                  v4f32, v8f32>;
  85 }
  86
  87 let ExeDomain = SSEPackedDouble in {
  88   defm VFMADDPD    : fma3p_forms<0x98, 0xA8, 0xB8, "vfmadd", "pd", memopv2f64,
  89                                  memopv4f64, X86Fmadd, v2f64, v4f64>, VEX_W;
  90   defm VFMSUBPD    : fma3p_forms<0x9A, 0xAA, 0xBA, "vfmsub", "pd", memopv2f64,
  91                                  memopv4f64, X86Fmsub, v2f64, v4f64>, VEX_W;
  92   defm VFMADDSUBPD : fma3p_forms<0x96, 0xA6, 0xB6, "vfmaddsub", "pd",
  93                                  memopv2f64, memopv4f64, X86Fmaddsub,
  94                                  v2f64, v4f64>, VEX_W;
  95   defm VFMSUBADDPD : fma3p_forms<0x97, 0xA7, 0xB7, "vfmsubadd", "pd",
  96                                  memopv2f64, memopv4f64, X86Fmsubadd,
  97                                  v2f64, v4f64>, VEX_W;
  98 }
  99
 100 // Fused Negative Multiply-Add
 101 let ExeDomain = SSEPackedSingle in {
 102   defm VFNMADDPS : fma3p_forms<0x9C, 0xAC, 0xBC, "vfnmadd", "ps",  memopv4f32,
 103                                memopv8f32, X86Fnmadd, v4f32, v8f32>;
 104   defm VFNMSUBPS : fma3p_forms<0x9E, 0xAE, 0xBE, "vfnmsub", "ps",  memopv4f32,
 105                                memopv8f32, X86Fnmsub, v4f32, v8f32>;
 106 }
 107 let ExeDomain = SSEPackedDouble in {
 108   defm VFNMADDPD : fma3p_forms<0x9C, 0xAC, 0xBC, "vfnmadd", "pd", memopv2f64,
 109                                memopv4f64, X86Fnmadd, v2f64, v4f64>, VEX_W;
 110   defm VFNMSUBPD : fma3p_forms<0x9E, 0xAE, 0xBE, "vfnmsub", "pd",
 111                                memopv2f64, memopv4f64, X86Fnmsub, v2f64,
 112                                v4f64>, VEX_W;
 113 }
 114
 115 let Predicates = [HasFMA] in {
 116   def : Pat<(int_x86_fma_vfmadd_ps VR128:$src2, VR128:$src1, VR128:$src3),
 117             (VFMADDPSr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 118   def : Pat<(int_x86_fma_vfmadd_ps VR128:$src2, VR128:$src1,
 119              (memopv4f32 addr:$src3)),
 120             (VFMADDPSr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 121   def : Pat<(int_x86_fma_vfmsub_ps VR128:$src2, VR128:$src1, VR128:$src3),
 122             (VFMSUBPSr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 123   def : Pat<(int_x86_fma_vfmsub_ps VR128:$src2, VR128:$src1,
 124              (memopv4f32 addr:$src3)),
 125             (VFMSUBPSr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 126   def : Pat<(int_x86_fma_vfmaddsub_ps VR128:$src2, VR128:$src1, VR128:$src3),
 127             (VFMADDSUBPSr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 128   def : Pat<(int_x86_fma_vfmaddsub_ps VR128:$src2, VR128:$src1,
 129              (memopv4f32 addr:$src3)),
 130             (VFMADDSUBPSr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 131   def : Pat<(int_x86_fma_vfmsubadd_ps VR128:$src2, VR128:$src1, VR128:$src3),
 132             (VFMSUBADDPSr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 133   def : Pat<(int_x86_fma_vfmsubadd_ps VR128:$src2, VR128:$src1,
 134              (memopv4f32 addr:$src3)),
 135             (VFMSUBADDPSr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 136
 137   def : Pat<(int_x86_fma_vfmadd_ps_256 VR256:$src2, VR256:$src1, VR256:$src3),
 138             (VFMADDPSr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 139   def : Pat<(int_x86_fma_vfmadd_ps_256 VR256:$src2, VR256:$src1,
 140              (memopv8f32 addr:$src3)),
 141             (VFMADDPSr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 142   def : Pat<(int_x86_fma_vfmsub_ps_256 VR256:$src2, VR256:$src1, VR256:$src3),
 143             (VFMSUBPSr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 144   def : Pat<(int_x86_fma_vfmsub_ps_256 VR256:$src2, VR256:$src1,
 145              (memopv8f32 addr:$src3)),
 146             (VFMSUBPSr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 147   def : Pat<(int_x86_fma_vfmaddsub_ps_256 VR256:$src2, VR256:$src1, VR256:$src3),
 148             (VFMADDSUBPSr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 149   def : Pat<(int_x86_fma_vfmaddsub_ps_256 VR256:$src2, VR256:$src1,
 150              (memopv8f32 addr:$src3)),
 151             (VFMADDSUBPSr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 152   def : Pat<(int_x86_fma_vfmsubadd_ps_256 VR256:$src2, VR256:$src1, VR256:$src3),
 153             (VFMSUBADDPSr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 154   def : Pat<(int_x86_fma_vfmsubadd_ps_256 VR256:$src2, VR256:$src1,
 155              (memopv8f32 addr:$src3)),
 156             (VFMSUBADDPSr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 157
 158   def : Pat<(int_x86_fma_vfmadd_pd VR128:$src2, VR128:$src1, VR128:$src3),
 159             (VFMADDPDr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 160   def : Pat<(int_x86_fma_vfmadd_pd VR128:$src2, VR128:$src1,
 161              (memopv2f64 addr:$src3)),
 162             (VFMADDPDr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 163   def : Pat<(int_x86_fma_vfmsub_pd VR128:$src2, VR128:$src1, VR128:$src3),
 164             (VFMSUBPDr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 165   def : Pat<(int_x86_fma_vfmsub_pd VR128:$src2, VR128:$src1,
 166              (memopv2f64 addr:$src3)),
 167             (VFMSUBPDr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 168   def : Pat<(int_x86_fma_vfmaddsub_pd VR128:$src2, VR128:$src1, VR128:$src3),
 169             (VFMADDSUBPDr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 170   def : Pat<(int_x86_fma_vfmaddsub_pd VR128:$src2, VR128:$src1,
 171              (memopv2f64 addr:$src3)),
 172             (VFMADDSUBPDr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 173   def : Pat<(int_x86_fma_vfmsubadd_pd VR128:$src2, VR128:$src1, VR128:$src3),
 174             (VFMSUBADDPDr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 175   def : Pat<(int_x86_fma_vfmsubadd_pd VR128:$src2, VR128:$src1,
 176              (memopv2f64 addr:$src3)),
 177             (VFMSUBADDPDr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 178
 179   def : Pat<(int_x86_fma_vfmadd_pd_256 VR256:$src2, VR256:$src1, VR256:$src3),
 180             (VFMADDPDr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 181   def : Pat<(int_x86_fma_vfmadd_pd_256 VR256:$src2, VR256:$src1,
 182              (memopv4f64 addr:$src3)),
 183             (VFMADDPDr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 184   def : Pat<(int_x86_fma_vfmsub_pd_256 VR256:$src2, VR256:$src1, VR256:$src3),
 185             (VFMSUBPDr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 186   def : Pat<(int_x86_fma_vfmsub_pd_256 VR256:$src2, VR256:$src1,
 187              (memopv4f64 addr:$src3)),
 188             (VFMSUBPDr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 189   def : Pat<(int_x86_fma_vfmaddsub_pd_256 VR256:$src2, VR256:$src1, VR256:$src3),
 190             (VFMADDSUBPDr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 191   def : Pat<(int_x86_fma_vfmaddsub_pd_256 VR256:$src2, VR256:$src1,
 192              (memopv4f64 addr:$src3)),
 193             (VFMADDSUBPDr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 194   def : Pat<(int_x86_fma_vfmsubadd_pd_256 VR256:$src2, VR256:$src1, VR256:$src3),
 195             (VFMSUBADDPDr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 196   def : Pat<(int_x86_fma_vfmsubadd_pd_256 VR256:$src2, VR256:$src1,
 197              (memopv4f64 addr:$src3)),
 198             (VFMSUBADDPDr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 199
 200   def : Pat<(int_x86_fma_vfnmadd_ps VR128:$src2, VR128:$src1, VR128:$src3),
 201             (VFNMADDPSr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 202   def : Pat<(int_x86_fma_vfnmadd_ps VR128:$src2, VR128:$src1,
 203              (memopv4f32 addr:$src3)),
 204             (VFNMADDPSr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 205   def : Pat<(int_x86_fma_vfnmsub_ps VR128:$src2, VR128:$src1, VR128:$src3),
 206             (VFNMSUBPSr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 207   def : Pat<(int_x86_fma_vfnmsub_ps VR128:$src2, VR128:$src1,
 208              (memopv4f32 addr:$src3)),
 209             (VFNMSUBPSr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 210
 211   def : Pat<(int_x86_fma_vfnmadd_ps_256 VR256:$src2, VR256:$src1, VR256:$src3),
 212             (VFNMADDPSr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 213   def : Pat<(int_x86_fma_vfnmadd_ps_256 VR256:$src2, VR256:$src1,
 214              (memopv8f32 addr:$src3)),
 215             (VFNMADDPSr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 216   def : Pat<(int_x86_fma_vfnmsub_ps_256 VR256:$src2, VR256:$src1, VR256:$src3),
 217             (VFNMSUBPSr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 218   def : Pat<(int_x86_fma_vfnmsub_ps_256 VR256:$src2, VR256:$src1,
 219              (memopv8f32 addr:$src3)),
 220             (VFNMSUBPSr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 221
 222   def : Pat<(int_x86_fma_vfnmadd_pd VR128:$src2, VR128:$src1, VR128:$src3),
 223             (VFNMADDPDr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 224   def : Pat<(int_x86_fma_vfnmadd_pd VR128:$src2, VR128:$src1,
 225              (memopv2f64 addr:$src3)),
 226             (VFNMADDPDr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 227   def : Pat<(int_x86_fma_vfnmsub_pd VR128:$src2, VR128:$src1, VR128:$src3),
 228             (VFNMSUBPDr213r VR128:$src1, VR128:$src2, VR128:$src3)>;
 229   def : Pat<(int_x86_fma_vfnmsub_pd VR128:$src2, VR128:$src1,
 230              (memopv2f64 addr:$src3)),
 231             (VFNMSUBPDr213m VR128:$src1, VR128:$src2, addr:$src3)>;
 232
 233   def : Pat<(int_x86_fma_vfnmadd_pd_256 VR256:$src2, VR256:$src1, VR256:$src3),
 234             (VFNMADDPDr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 235   def : Pat<(int_x86_fma_vfnmadd_pd_256 VR256:$src2, VR256:$src1,
 236              (memopv4f64 addr:$src3)),
 237             (VFNMADDPDr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 238   def : Pat<(int_x86_fma_vfnmsub_pd_256 VR256:$src2, VR256:$src1, VR256:$src3),
 239             (VFNMSUBPDr213rY VR256:$src1, VR256:$src2, VR256:$src3)>;
 240   def : Pat<(int_x86_fma_vfnmsub_pd_256 VR256:$src2, VR256:$src1,
 241              (memopv4f64 addr:$src3)),
 242             (VFNMSUBPDr213mY VR256:$src1, VR256:$src2, addr:$src3)>;
 243
 244 } // Predicates = [HasFMA]
 245
 246 let Constraints = "$src1 = $dst" in {
 247 multiclass fma3s_rm<bits<8> opc, string OpcodeStr, X86MemOperand x86memop,
 248                     RegisterClass RC> {
 249 let neverHasSideEffects = 1 in {
 250   def r : FMA3<opc, MRMSrcReg, (outs RC:$dst),
 251                (ins RC:$src1, RC:$src2, RC:$src3),
 252                !strconcat(OpcodeStr,
 253                           "\t{$src3, $src2, $dst|$dst, $src2, $src3}"), []>;
 254   let mayLoad = 1 in
 255   def m : FMA3<opc, MRMSrcMem, (outs RC:$dst),
 256                (ins RC:$src1, RC:$src2, x86memop:$src3),
 257                !strconcat(OpcodeStr,
 258                           "\t{$src3, $src2, $dst|$dst, $src2, $src3}"), []>;
 259 } // neverHasSideEffects = 1
 260 }
 261
 262 multiclass fma3s_rm_int<bits<8> opc, string OpcodeStr, Operand memop,
 263                         ComplexPattern mem_cpat, Intrinsic IntId,
 264                         RegisterClass RC, SDNode OpNode, ValueType OpVT> {
 265   def r_Int : FMA3<opc, MRMSrcReg, (outs VR128:$dst),
 266                    (ins VR128:$src1, VR128:$src2, VR128:$src3),
 267                    !strconcat(OpcodeStr,
 268                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
 269                    [(set VR128:$dst, (IntId VR128:$src2, VR128:$src1,
 270                      VR128:$src3))]>;
 271   def m_Int : FMA3<opc, MRMSrcMem, (outs VR128:$dst),
 272                    (ins VR128:$src1, VR128:$src2, memop:$src3),
 273                    !strconcat(OpcodeStr,
 274                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
 275                    [(set VR128:$dst,
 276                      (IntId VR128:$src2, VR128:$src1, mem_cpat:$src3))]>;
 277   def r     : FMA3<opc, MRMSrcReg, (outs RC:$dst),
 278                    (ins RC:$src1, RC:$src2, RC:$src3),
 279                    !strconcat(OpcodeStr,
 280                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"),
 281                    [(set RC:$dst,
 282                      (OpVT (OpNode RC:$src2, RC:$src1, RC:$src3)))]>;
 283   let mayLoad = 1 in
 284   def m     : FMA3<opc, MRMSrcMem, (outs RC:$dst),
 285                    (ins RC:$src1, RC:$src2, memop:$src3),
 286                    !strconcat(OpcodeStr,
 287                               "\t{$src3, $src2, $dst|$dst, $src2, $src3}"), []>;
 288 }
 289 } // Constraints = "$src1 = $dst"
 290
 291 multiclass fma3s_forms<bits<8> opc132, bits<8> opc213, bits<8> opc231,
 292                        string OpStr, Intrinsic IntF32, Intrinsic IntF64,
 293                        SDNode OpNode> {
 294   defm SSr132 : fma3s_rm<opc132, !strconcat(OpStr, "132ss"), f32mem, FR32>;
 295   defm SSr231 : fma3s_rm<opc231, !strconcat(OpStr, "231ss"), f32mem, FR32>;
 296   defm SDr132 : fma3s_rm<opc132, !strconcat(OpStr, "132sd"), f64mem, FR64>,
 297                         VEX_W;
 298   defm SDr231 : fma3s_rm<opc231, !strconcat(OpStr, "231sd"), f64mem, FR64>,
 299                         VEX_W;
 300   defm SSr213 : fma3s_rm_int <opc213, !strconcat(OpStr, "213ss"), ssmem,
 301                               sse_load_f32, IntF32, FR32, OpNode, f32>;
 302   defm SDr213 : fma3s_rm_int <opc213, !strconcat(OpStr, "213sd"), sdmem,
 303                               sse_load_f64, IntF64, FR64, OpNode, f64>, VEX_W;
 304 }
 305
 306 defm VFMADD : fma3s_forms<0x99, 0xA9, 0xB9, "vfmadd", int_x86_fma_vfmadd_ss,
 307                           int_x86_fma_vfmadd_sd, X86Fmadd>, VEX_LIG;
 308 defm VFMSUB : fma3s_forms<0x9B, 0xAB, 0xBB, "vfmsub", int_x86_fma_vfmsub_ss,
 309                           int_x86_fma_vfmsub_sd, X86Fmsub>, VEX_LIG;
 310
 311 defm VFNMADD : fma3s_forms<0x9D, 0xAD, 0xBD, "vfnmadd", int_x86_fma_vfnmadd_ss,
 312                            int_x86_fma_vfnmadd_sd, X86Fnmadd>, VEX_LIG;
 313 defm VFNMSUB : fma3s_forms<0x9F, 0xAF, 0xBF, "vfnmsub", int_x86_fma_vfnmsub_ss,
 314                            int_x86_fma_vfnmsub_sd, X86Fnmsub>, VEX_LIG;
 315
 316
 317 //===----------------------------------------------------------------------===//
 318 // FMA4 - AMD 4 operand Fused Multiply-Add instructions
 319 //===----------------------------------------------------------------------===//
 320
 321
 322 multiclass fma4s<bits<8> opc, string OpcodeStr, Operand memop,
 323                  ComplexPattern mem_cpat, Intrinsic Int> {
 324   def rr : FMA4<opc, MRMSrcReg, (outs VR128:$dst),
 325            (ins VR128:$src1, VR128:$src2, VR128:$src3),
 326            !strconcat(OpcodeStr,
 327            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 328            [(set VR128:$dst,
 329              (Int VR128:$src1, VR128:$src2, VR128:$src3))]>, VEX_W, MemOp4;
 330   def rm : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 331            (ins VR128:$src1, VR128:$src2, memop:$src3),
 332            !strconcat(OpcodeStr,
 333            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 334            [(set VR128:$dst,
 335              (Int VR128:$src1, VR128:$src2, mem_cpat:$src3))]>, VEX_W, MemOp4;
 336   def mr : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 337            (ins VR128:$src1, memop:$src2, VR128:$src3),
 338            !strconcat(OpcodeStr,
 339            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 340            [(set VR128:$dst,
 341              (Int VR128:$src1, mem_cpat:$src2, VR128:$src3))]>;
 342 // For disassembler
 343 let isCodeGenOnly = 1 in
 344   def rr_REV : FMA4<opc, MRMSrcReg, (outs VR128:$dst),
 345                (ins VR128:$src1, VR128:$src2, VR128:$src3),
 346                !strconcat(OpcodeStr,
 347                "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"), []>;
 348 }
 349
 350 multiclass fma4p<bits<8> opc, string OpcodeStr,
 351                  Intrinsic Int128, Intrinsic Int256,
 352                  PatFrag ld_frag128, PatFrag ld_frag256> {
 353   def rr : FMA4<opc, MRMSrcReg, (outs VR128:$dst),
 354            (ins VR128:$src1, VR128:$src2, VR128:$src3),
 355            !strconcat(OpcodeStr,
 356            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 357            [(set VR128:$dst,
 358              (Int128 VR128:$src1, VR128:$src2, VR128:$src3))]>, VEX_W, MemOp4;
 359   def rm : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 360            (ins VR128:$src1, VR128:$src2, f128mem:$src3),
 361            !strconcat(OpcodeStr,
 362            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 363            [(set VR128:$dst, (Int128 VR128:$src1, VR128:$src2,
 364                               (ld_frag128 addr:$src3)))]>, VEX_W, MemOp4;
 365   def mr : FMA4<opc, MRMSrcMem, (outs VR128:$dst),
 366            (ins VR128:$src1, f128mem:$src2, VR128:$src3),
 367            !strconcat(OpcodeStr,
 368            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 369            [(set VR128:$dst,
 370              (Int128 VR128:$src1, (ld_frag128 addr:$src2), VR128:$src3))]>;
 371   def rrY : FMA4<opc, MRMSrcReg, (outs VR256:$dst),
 372            (ins VR256:$src1, VR256:$src2, VR256:$src3),
 373            !strconcat(OpcodeStr,
 374            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 375            [(set VR256:$dst,
 376              (Int256 VR256:$src1, VR256:$src2, VR256:$src3))]>, VEX_W, MemOp4;
 377   def rmY : FMA4<opc, MRMSrcMem, (outs VR256:$dst),
 378            (ins VR256:$src1, VR256:$src2, f256mem:$src3),
 379            !strconcat(OpcodeStr,
 380            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 381            [(set VR256:$dst, (Int256 VR256:$src1, VR256:$src2,
 382                               (ld_frag256 addr:$src3)))]>, VEX_W, MemOp4;
 383   def mrY : FMA4<opc, MRMSrcMem, (outs VR256:$dst),
 384            (ins VR256:$src1, f256mem:$src2, VR256:$src3),
 385            !strconcat(OpcodeStr,
 386            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 387            [(set VR256:$dst,
 388              (Int256 VR256:$src1, (ld_frag256 addr:$src2), VR256:$src3))]>;
 389 // For disassembler
 390 let isCodeGenOnly = 1 in {
 391   def rr_REV : FMA4<opc, MRMSrcReg, (outs VR128:$dst),
 392                (ins VR128:$src1, VR128:$src2, VR128:$src3),
 393                !strconcat(OpcodeStr,
 394                "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"), []>;
 395   def rrY_REV : FMA4<opc, MRMSrcReg, (outs VR256:$dst),
 396                 (ins VR256:$src1, VR256:$src2, VR256:$src3),
 397                 !strconcat(OpcodeStr,
 398                 "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"), []>;
 399 } // isCodeGenOnly = 1
 400 }
 401
 402 let Predicates = [HasFMA4] in {
 403
 404 defm VFMADDSS4    : fma4s<0x6A, "vfmaddss", ssmem, sse_load_f32,
 405                           int_x86_fma_vfmadd_ss>;
 406 defm VFMADDSD4    : fma4s<0x6B, "vfmaddsd", sdmem, sse_load_f64,
 407                           int_x86_fma_vfmadd_sd>;
 408 defm VFMADDPS4    : fma4p<0x68, "vfmaddps", int_x86_fma_vfmadd_ps,
 409                           int_x86_fma_vfmadd_ps_256, memopv4f32, memopv8f32>;
 410 defm VFMADDPD4    : fma4p<0x69, "vfmaddpd", int_x86_fma_vfmadd_pd,
 411                           int_x86_fma_vfmadd_pd_256, memopv2f64, memopv4f64>;
 412 defm VFMSUBSS4    : fma4s<0x6E, "vfmsubss", ssmem, sse_load_f32,
 413                           int_x86_fma_vfmsub_ss>;
 414 defm VFMSUBSD4    : fma4s<0x6F, "vfmsubsd", sdmem, sse_load_f64,
 415                           int_x86_fma_vfmsub_sd>;
 416 defm VFMSUBPS4    : fma4p<0x6C, "vfmsubps", int_x86_fma_vfmsub_ps,
 417                           int_x86_fma_vfmsub_ps_256, memopv4f32, memopv8f32>;
 418 defm VFMSUBPD4    : fma4p<0x6D, "vfmsubpd", int_x86_fma_vfmsub_pd,
 419                           int_x86_fma_vfmsub_pd_256, memopv2f64, memopv4f64>;
 420 defm VFNMADDSS4   : fma4s<0x7A, "vfnmaddss", ssmem, sse_load_f32,
 421                           int_x86_fma_vfnmadd_ss>;
 422 defm VFNMADDSD4   : fma4s<0x7B, "vfnmaddsd", sdmem, sse_load_f64,
 423                           int_x86_fma_vfnmadd_sd>;
 424 defm VFNMADDPS4   : fma4p<0x78, "vfnmaddps", int_x86_fma_vfnmadd_ps,
 425                           int_x86_fma_vfnmadd_ps_256, memopv4f32, memopv8f32>;
 426 defm VFNMADDPD4   : fma4p<0x79, "vfnmaddpd", int_x86_fma_vfnmadd_pd,
 427                           int_x86_fma_vfnmadd_pd_256, memopv2f64, memopv4f64>;
 428 defm VFNMSUBSS4   : fma4s<0x7E, "vfnmsubss", ssmem, sse_load_f32,
 429                           int_x86_fma_vfnmsub_ss>;
 430 defm VFNMSUBSD4   : fma4s<0x7F, "vfnmsubsd", sdmem, sse_load_f64,
 431                           int_x86_fma_vfnmsub_sd>;
 432 defm VFNMSUBPS4   : fma4p<0x7C, "vfnmsubps", int_x86_fma_vfnmsub_ps,
 433                           int_x86_fma_vfnmsub_ps_256, memopv4f32, memopv8f32>;
 434 defm VFNMSUBPD4   : fma4p<0x7D, "vfnmsubpd", int_x86_fma_vfnmsub_pd,
 435                           int_x86_fma_vfnmsub_pd_256, memopv2f64, memopv4f64>;
 436 defm VFMADDSUBPS4 : fma4p<0x5C, "vfmaddsubps", int_x86_fma_vfmaddsub_ps,
 437                           int_x86_fma_vfmaddsub_ps_256, memopv4f32, memopv8f32>;
 438 defm VFMADDSUBPD4 : fma4p<0x5D, "vfmaddsubpd", int_x86_fma_vfmaddsub_pd,
 439                           int_x86_fma_vfmaddsub_pd_256, memopv2f64, memopv4f64>;
 440 defm VFMSUBADDPS4 : fma4p<0x5E, "vfmsubaddps", int_x86_fma_vfmsubadd_ps,
 441                           int_x86_fma_vfmsubadd_ps_256, memopv4f32, memopv8f32>;
 442 defm VFMSUBADDPD4 : fma4p<0x5F, "vfmsubaddpd", int_x86_fma_vfmsubadd_pd,
 443                           int_x86_fma_vfmsubadd_pd_256, memopv2f64, memopv4f64>;
 444 } // HasFMA4
 445