lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 /// SDTCisIntVectorOfSameSize - This indicates that ThisOp and OtherOp are
  55 /// packed vector types, and that ThisOp is the result of
  56 /// MVT::getIntVectorWithNumElements with the number of elements that ThisOp
  57 /// has.
  58 class SDTCisIntVectorOfSameSize<int ThisOp, int OtherOp>
  59   : SDTypeConstraint<ThisOp> {
  60   int OtherOpNum = OtherOp;
  61 }
  62
  63 //===----------------------------------------------------------------------===//
  64 // Selection DAG Type Profile definitions.
  65 //
  66 // These use the constraints defined above to describe the type requirements of
  67 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  68 // add their own if needed.
  69 //
  70
  71 // SDTypeProfile - This profile describes the type requirements of a Selection
  72 // DAG node.
  73 class SDTypeProfile<int numresults, int numoperands,
  74                     list<SDTypeConstraint> constraints> {
  75   int NumResults = numresults;
  76   int NumOperands = numoperands;
  77   list<SDTypeConstraint> Constraints = constraints;
  78 }
  79
  80 // Builtin profiles.
  81 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  82 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  83 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  84 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  85 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  86 def SDTUnaryOp  : SDTypeProfile<1, 1, []>; // bitconvert
  87
  88 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  89   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  92   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  93 ]>;
  94 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  95   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  96 ]>;
  97 def SDTFPSignOp : SDTypeProfile<1, 2, [      // fcopysign.
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
  99 ]>;
 100 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
 101   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
 102 ]>;
 103 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
 104   SDTCisSameAs<0, 1>, SDTCisInt<0>
 105 ]>;
 106 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
 107   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
 108 ]>;
 109 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 110   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 111 ]>;
 112 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 113   SDTCisSameAs<0, 1>, SDTCisFP<0>
 114 ]>;
 115 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 116   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 117 ]>;
 118 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 119   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 120 ]>;
 121 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 122   SDTCisFP<0>, SDTCisInt<1>
 123 ]>;
 124 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 125   SDTCisInt<0>, SDTCisFP<1>
 126 ]>;
 127 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 128   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 129   SDTCisVTSmallerThanOp<2, 1>
 130 ]>;
 131
 132 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 133   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 134 ]>;
 135
 136 def SDTSelect : SDTypeProfile<1, 3, [ // select
 137   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 138 ]>;
 139
 140 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 141   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 142   SDTCisVT<5, OtherVT>
 143 ]>;
 144
 145 def SDTBr : SDTypeProfile<0, 1, [ // br
 146   SDTCisVT<0, OtherVT>
 147 ]>;
 148
 149 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 150   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 151 ]>;
 152
 153 def SDTBrind : SDTypeProfile<0, 1, [ // brind
 154   SDTCisPtrTy<0>
 155 ]>;
 156
 157 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 158
 159 def SDTLoad : SDTypeProfile<1, 1, [ // load
 160   SDTCisPtrTy<1>
 161 ]>;
 162
 163 def SDTStore : SDTypeProfile<0, 2, [ // store
 164   SDTCisPtrTy<1>
 165 ]>;
 166
 167 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 168   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 169 ]>;
 170
 171 def SDTVecShuffle : SDTypeProfile<1, 3, [
 172   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisIntVectorOfSameSize<3, 0>
 173 ]>;
 174
 175 //===----------------------------------------------------------------------===//
 176 // Selection DAG Node Properties.
 177 //
 178 // Note: These are hard coded into tblgen.
 179 //
 180 class SDNodeProperty;
 181 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 182 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 183 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 184 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 185 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 186 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 187
 188 //===----------------------------------------------------------------------===//
 189 // Selection DAG Node definitions.
 190 //
 191 class SDNode<string opcode, SDTypeProfile typeprof,
 192              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 193   string Opcode  = opcode;
 194   string SDClass = sdclass;
 195   list<SDNodeProperty> Properties = props;
 196   SDTypeProfile TypeProfile = typeprof;
 197 }
 198
 199 def set;
 200 def node;
 201 def srcvalue;
 202
 203 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 204 def fpimm      : SDNode<"ISD::TargetConstantFP",
 205                          SDTFPLeaf, [], "ConstantFPSDNode">;
 206 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 207 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 208 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 209 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 210 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 211                         "GlobalAddressSDNode">;
 212 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 213                          "GlobalAddressSDNode">;
 214 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 215                          "ConstantPoolSDNode">;
 216 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 217                          "ConstantPoolSDNode">;
 218 def jumptable   : SDNode<"ISD::JumpTable",            SDTPtrLeaf, [],
 219                          "JumpTableSDNode">;
 220 def tjumptable  : SDNode<"ISD::TargetJumpTable",      SDTPtrLeaf, [],
 221                          "JumpTableSDNode">;
 222 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 223                          "FrameIndexSDNode">;
 224 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 225                          "FrameIndexSDNode">;
 226 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 227                          "ExternalSymbolSDNode">;
 228 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 229                          "ExternalSymbolSDNode">;
 230
 231 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 232                         [SDNPCommutative, SDNPAssociative]>;
 233 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 234 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 235                         [SDNPCommutative, SDNPAssociative]>;
 236 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 237 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 238 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 239 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 240 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 241 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 242 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 243 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 244 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 245 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 246 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 247 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 248                         [SDNPCommutative, SDNPAssociative]>;
 249 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 250                         [SDNPCommutative, SDNPAssociative]>;
 251 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 252                         [SDNPCommutative, SDNPAssociative]>;
 253 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 254                         [SDNPCommutative, SDNPOutFlag]>;
 255 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 256                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 257 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 258                         [SDNPOutFlag]>;
 259 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 260                         [SDNPOutFlag, SDNPInFlag]>;
 261
 262 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 263 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 264 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 265 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 266 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 267 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 268 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 269 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 270 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 271 def bitconvert : SDNode<"ISD::BIT_CONVERT", SDTUnaryOp>;
 272
 273 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 274 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 275 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 276 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 277 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 278 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 279 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 280 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 281 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 282 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 283
 284 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 285 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 286 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 287
 288 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 289 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 290 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 291 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 292
 293 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 294 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 295 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 296
 297 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 298 def brind      : SDNode<"ISD::BRIND"      , SDTBrind,  [SDNPHasChain]>;
 299 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 300 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 301
 302 // Do not use ld directly. Use load, extload, sextload, zextload (see below).
 303 def ld         : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 304 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 305
 306 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 307
 308 def vector_shuffle : SDNode<"ISD::VECTOR_SHUFFLE", SDTVecShuffle, []>;
 309 def build_vector : SDNode<"ISD::BUILD_VECTOR", SDTypeProfile<1, 0, []>, []>;
 310 def scalar_to_vector : SDNode<"ISD::SCALAR_TO_VECTOR", SDTypeProfile<1, 1, []>,
 311                               []>;
 312 def vector_extract : SDNode<"ISD::EXTRACT_VECTOR_ELT",
 313     SDTypeProfile<1, 2, [SDTCisPtrTy<2>]>, []>;
 314 def vector_insert : SDNode<"ISD::INSERT_VECTOR_ELT",
 315     SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 316
 317 // Nodes for intrinsics, you should use the intrinsic itself and let tblgen use
 318 // these internally.  Don't reference these directly.
 319 def intrinsic_void : SDNode<"ISD::INTRINSIC_VOID",
 320                             SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>,
 321                             [SDNPHasChain]>;
 322 def intrinsic_w_chain : SDNode<"ISD::INTRINSIC_W_CHAIN",
 323                                SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>,
 324                                [SDNPHasChain]>;
 325 def intrinsic_wo_chain : SDNode<"ISD::INTRINSIC_WO_CHAIN",
 326                                 SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>, []>;
 327
 328
 329 //===----------------------------------------------------------------------===//
 330 // Selection DAG Condition Codes
 331
 332 class CondCode; // ISD::CondCode enums
 333 def SETOEQ : CondCode; def SETOGT : CondCode;
 334 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 335 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 336 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 337 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 338
 339 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 340 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 341
 342
 343 //===----------------------------------------------------------------------===//
 344 // Selection DAG Node Transformation Functions.
 345 //
 346 // This mechanism allows targets to manipulate nodes in the output DAG once a
 347 // match has been formed.  This is typically used to manipulate immediate
 348 // values.
 349 //
 350 class SDNodeXForm<SDNode opc, code xformFunction> {
 351   SDNode Opcode = opc;
 352   code XFormFunction = xformFunction;
 353 }
 354
 355 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 356
 357
 358 //===----------------------------------------------------------------------===//
 359 // Selection DAG Pattern Fragments.
 360 //
 361 // Pattern fragments are reusable chunks of dags that match specific things.
 362 // They can take arguments and have C++ predicates that control whether they
 363 // match.  They are intended to make the patterns for common instructions more
 364 // compact and readable.
 365 //
 366
 367 /// PatFrag - Represents a pattern fragment.  This can match something on the
 368 /// DAG, frame a single node to multiply nested other fragments.
 369 ///
 370 class PatFrag<dag ops, dag frag, code pred = [{}],
 371               SDNodeXForm xform = NOOP_SDNodeXForm> {
 372   dag Operands = ops;
 373   dag Fragment = frag;
 374   code Predicate = pred;
 375   SDNodeXForm OperandTransform = xform;
 376 }
 377
 378 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 379 // to define immediates and other common things concisely.
 380 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 381  : PatFrag<(ops), frag, pred, xform>;
 382
 383 // Leaf fragments.
 384
 385 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 386 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 387
 388 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 389 def immAllOnesV: PatLeaf<(build_vector), [{
 390   return ISD::isBuildVectorAllOnes(N);
 391 }]>;
 392 def immAllZerosV: PatLeaf<(build_vector), [{
 393   return ISD::isBuildVectorAllZeros(N);
 394 }]>;
 395
 396 def immAllOnesV_bc: PatLeaf<(bitconvert), [{
 397   return ISD::isBuildVectorAllOnes(N);
 398 }]>;
 399
 400
 401 // Other helper fragments.
 402 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 403 def vnot : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV)>;
 404 def vnot_conv : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV_bc)>;
 405 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 406
 407 def load : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 408   return ISD::isNON_EXTLoad(N);
 409 }]>;
 410
 411 // extending load & truncstore fragments.
 412 def extloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 413   if (ISD::isEXTLoad(N))
 414     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i1;
 415   return false;
 416 }]>;
 417 def extloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 418   if (ISD::isEXTLoad(N))
 419     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i8;
 420   return false;
 421 }]>;
 422 def extloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 423   if (ISD::isEXTLoad(N))
 424     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i16;
 425   return false;
 426 }]>;
 427 def extloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 428   if (ISD::isEXTLoad(N))
 429     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i32;
 430   return false;
 431 }]>;
 432 def extloadf32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 433   if (ISD::isEXTLoad(N))
 434     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::f32;
 435   return false;
 436 }]>;
 437
 438 def sextloadi1 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 439   if (ISD::isSEXTLoad(N))
 440     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i1;
 441   return false;
 442 }]>;
 443 def sextloadi8 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 444   if (ISD::isSEXTLoad(N))
 445     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i8;
 446   return false;
 447 }]>;
 448 def sextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 449   if (ISD::isSEXTLoad(N))
 450     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i16;
 451   return false;
 452 }]>;
 453 def sextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 454   if (ISD::isSEXTLoad(N))
 455     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i32;
 456   return false;
 457 }]>;
 458
 459 def zextloadi1 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 460   if (ISD::isZEXTLoad(N))
 461     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i1;
 462   return false;
 463 }]>;
 464 def zextloadi8 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 465   if (ISD::isZEXTLoad(N))
 466     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i8;
 467   return false;
 468 }]>;
 469 def zextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 470   if (ISD::isZEXTLoad(N))
 471     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i16;
 472   return false;
 473 }]>;
 474 def zextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 475   if (ISD::isZEXTLoad(N))
 476     return cast<LoadSDNode>(N)->getLoadedVT() == MVT::i32;
 477   return false;
 478 }]>;
 479
 480 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 481                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 482                             node:$vt)>;
 483
 484 // setcc convenience fragments.
 485 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 486                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 487 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 488                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 489 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 490                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 491 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 492                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 493 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 494                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 495 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 496                      (setcc node:$lhs, node:$rhs, SETONE)>;
 497 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 498                      (setcc node:$lhs, node:$rhs, SETO)>;
 499 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 500                      (setcc node:$lhs, node:$rhs, SETUO)>;
 501 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 502                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 503 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 504                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 505 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 506                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 507 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 508                      (setcc node:$lhs, node:$rhs, SETULT)>;
 509 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 510                      (setcc node:$lhs, node:$rhs, SETULE)>;
 511 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 512                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 513 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 514                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 515 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 516                      (setcc node:$lhs, node:$rhs, SETGT)>;
 517 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 518                      (setcc node:$lhs, node:$rhs, SETGE)>;
 519 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 520                      (setcc node:$lhs, node:$rhs, SETLT)>;
 521 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 522                      (setcc node:$lhs, node:$rhs, SETLE)>;
 523 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 524                      (setcc node:$lhs, node:$rhs, SETNE)>;
 525
 526 //===----------------------------------------------------------------------===//
 527 // Selection DAG Pattern Support.
 528 //
 529 // Patterns are what are actually matched against the target-flavored
 530 // instruction selection DAG.  Instructions defined by the target implicitly
 531 // define patterns in most cases, but patterns can also be explicitly added when
 532 // an operation is defined by a sequence of instructions (e.g. loading a large
 533 // immediate value on RISC targets that do not support immediates as large as
 534 // their GPRs).
 535 //
 536
 537 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 538   dag             PatternToMatch  = patternToMatch;
 539   list<dag>       ResultInstrs    = resultInstrs;
 540   list<Predicate> Predicates      = [];  // See class Instruction in Target.td.
 541   int             AddedComplexity = 0;  // See class Instruction in Target.td.
 542 }
 543
 544 // Pat - A simple (but common) form of a pattern, which produces a simple result
 545 // not needing a full list.
 546 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 547
 548 //===----------------------------------------------------------------------===//
 549 // Complex pattern definitions.
 550 //
 551 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 552 // in C++. NumOperands is the number of operands returned by the select function;
 553 // SelectFunc is the name of the function used to pattern match the max. pattern;
 554 // RootNodes are the list of possible root nodes of the sub-dags to match.
 555 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 556 //
 557 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 558   ValueType Ty = ty;
 559   int NumOperands = numops;
 560   string SelectFunc = fn;
 561   list<SDNode> RootNodes = roots;
 562 }
 563
 564 //===----------------------------------------------------------------------===//
 565 // Dwarf support.
 566 //
 567 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 568                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 569 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 570
 571 def SDT_dwarf_label : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 572 def dwarf_label : SDNode<"ISD::DEBUG_LABEL", SDT_dwarf_label,[SDNPHasChain]>;
 573
 574
 575