Merge remote-tracking branch 'lsk/v4.4/topic/mm-kaslr' into linux-linaro-lsk-v4.4
[firefly-linux-kernel-4.4.55.git] / include / asm-generic / vmlinux.lds.h
1 /*
2  * Helper macros to support writing architecture specific
3  * linker scripts.
4  *
5  * A minimal linker scripts has following content:
6  * [This is a sample, architectures may have special requiriements]
7  *
8  * OUTPUT_FORMAT(...)
9  * OUTPUT_ARCH(...)
10  * ENTRY(...)
11  * SECTIONS
12  * {
13  *      . = START;
14  *      __init_begin = .;
15  *      HEAD_TEXT_SECTION
16  *      INIT_TEXT_SECTION(PAGE_SIZE)
17  *      INIT_DATA_SECTION(...)
18  *      PERCPU_SECTION(CACHELINE_SIZE)
19  *      __init_end = .;
20  *
21  *      _stext = .;
22  *      TEXT_SECTION = 0
23  *      _etext = .;
24  *
25  *      _sdata = .;
26  *      RO_DATA_SECTION(PAGE_SIZE)
27  *      RW_DATA_SECTION(...)
28  *      _edata = .;
29  *
30  *      EXCEPTION_TABLE(...)
31  *      NOTES
32  *
33  *      BSS_SECTION(0, 0, 0)
34  *      _end = .;
35  *
36  *      STABS_DEBUG
37  *      DWARF_DEBUG
38  *
39  *      DISCARDS                // must be the last
40  * }
41  *
42  * [__init_begin, __init_end] is the init section that may be freed after init
43  *      // __init_begin and __init_end should be page aligned, so that we can
44  *      // free the whole .init memory
45  * [_stext, _etext] is the text section
46  * [_sdata, _edata] is the data section
47  *
48  * Some of the included output section have their own set of constants.
49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50  *               [__nosave_begin, __nosave_end] for the nosave data
51  */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION()  . = ALIGN(8)
61
62 /*
63  * Align to a 32 byte boundary equal to the
64  * alignment gcc 4.5 uses for a struct
65  */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69 /* The actual configuration determine if the init/exit sections
70  * are handled as text/data or they can be discarded (which
71  * often happens at runtime)
72  */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec)    *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
80
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec)    *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
88
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC()    . = ALIGN(8);                           \
91                         VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92                         *(__mcount_loc)                         \
93                         VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
97
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE()        VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100                                 *(_ftrace_annotated_branch)                           \
101                                 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
105
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE()        VMLINUX_SYMBOL(__start_branch_profile) = .;   \
108                                 *(_ftrace_branch)                             \
109                                 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
113
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST()      . = ALIGN(8);                                 \
116                                 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117                                 *(_kprobe_blacklist)                          \
118                                 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
122
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
125                         VMLINUX_SYMBOL(__start_ftrace_events) = .;      \
126                         *(_ftrace_events)                               \
127                         VMLINUX_SYMBOL(__stop_ftrace_events) = .;       \
128                         VMLINUX_SYMBOL(__start_ftrace_enum_maps) = .;   \
129                         *(_ftrace_enum_map)                             \
130                         VMLINUX_SYMBOL(__stop_ftrace_enum_maps) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
134
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
137                          *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
138                          VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .;  \
140                          *(__tracepoint_str) /* Trace_printk fmt' pointer */ \
141                          VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142 #else
143 #define TRACE_PRINTKS()
144 #define TRACEPOINT_STR()
145 #endif
146
147 #ifdef CONFIG_FTRACE_SYSCALLS
148 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
149                          VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150                          *(__syscalls_metadata)                         \
151                          VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152 #else
153 #define TRACE_SYSCALLS()
154 #endif
155
156 #ifdef CONFIG_SERIAL_EARLYCON
157 #define EARLYCON_TABLE() STRUCT_ALIGN();                        \
158                          VMLINUX_SYMBOL(__earlycon_table) = .;  \
159                          *(__earlycon_table)                    \
160                          *(__earlycon_table_end)
161 #else
162 #define EARLYCON_TABLE()
163 #endif
164
165 #define ___OF_TABLE(cfg, name)  _OF_TABLE_##cfg(name)
166 #define __OF_TABLE(cfg, name)   ___OF_TABLE(cfg, name)
167 #define OF_TABLE(cfg, name)     __OF_TABLE(config_enabled(cfg), name)
168 #define _OF_TABLE_0(name)
169 #define _OF_TABLE_1(name)                                               \
170         . = ALIGN(8);                                                   \
171         VMLINUX_SYMBOL(__##name##_of_table) = .;                        \
172         *(__##name##_of_table)                                          \
173         *(__##name##_of_table_end)
174
175 #define CLKSRC_OF_TABLES()      OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
176 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
177 #define CLK_OF_TABLES()         OF_TABLE(CONFIG_COMMON_CLK, clk)
178 #define IOMMU_OF_TABLES()       OF_TABLE(CONFIG_OF_IOMMU, iommu)
179 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
180 #define CPU_METHOD_OF_TABLES()  OF_TABLE(CONFIG_SMP, cpu_method)
181 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
182 #define EARLYCON_OF_TABLES()    OF_TABLE(CONFIG_SERIAL_EARLYCON, earlycon)
183
184 #ifdef CONFIG_ACPI
185 #define ACPI_PROBE_TABLE(name)                                          \
186         . = ALIGN(8);                                                   \
187         VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .;                \
188         *(__##name##_acpi_probe_table)                                  \
189         VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
190 #else
191 #define ACPI_PROBE_TABLE(name)
192 #endif
193
194 #define KERNEL_DTB()                                                    \
195         STRUCT_ALIGN();                                                 \
196         VMLINUX_SYMBOL(__dtb_start) = .;                                \
197         *(.dtb.init.rodata)                                             \
198         VMLINUX_SYMBOL(__dtb_end) = .;
199
200 /* .data section */
201 #define DATA_DATA                                                       \
202         *(.data)                                                        \
203         *(.ref.data)                                                    \
204         *(.data..shared_aligned) /* percpu related */                   \
205         MEM_KEEP(init.data)                                             \
206         MEM_KEEP(exit.data)                                             \
207         *(.data.unlikely)                                               \
208         STRUCT_ALIGN();                                                 \
209         *(__tracepoints)                                                \
210         /* implement dynamic printk debug */                            \
211         . = ALIGN(8);                                                   \
212         VMLINUX_SYMBOL(__start___jump_table) = .;                       \
213         *(__jump_table)                                                 \
214         VMLINUX_SYMBOL(__stop___jump_table) = .;                        \
215         . = ALIGN(8);                                                   \
216         VMLINUX_SYMBOL(__start___verbose) = .;                          \
217         *(__verbose)                                                    \
218         VMLINUX_SYMBOL(__stop___verbose) = .;                           \
219         LIKELY_PROFILE()                                                \
220         BRANCH_PROFILE()                                                \
221         TRACE_PRINTKS()                                                 \
222         TRACEPOINT_STR()
223
224 /*
225  * Data section helpers
226  */
227 #define NOSAVE_DATA                                                     \
228         . = ALIGN(PAGE_SIZE);                                           \
229         VMLINUX_SYMBOL(__nosave_begin) = .;                             \
230         *(.data..nosave)                                                \
231         . = ALIGN(PAGE_SIZE);                                           \
232         VMLINUX_SYMBOL(__nosave_end) = .;
233
234 #define PAGE_ALIGNED_DATA(page_align)                                   \
235         . = ALIGN(page_align);                                          \
236         *(.data..page_aligned)
237
238 #define READ_MOSTLY_DATA(align)                                         \
239         . = ALIGN(align);                                               \
240         *(.data..read_mostly)                                           \
241         . = ALIGN(align);
242
243 #define CACHELINE_ALIGNED_DATA(align)                                   \
244         . = ALIGN(align);                                               \
245         *(.data..cacheline_aligned)
246
247 #define INIT_TASK_DATA(align)                                           \
248         . = ALIGN(align);                                               \
249         *(.data..init_task)
250
251 /*
252  * Read only Data
253  */
254 #define RO_DATA_SECTION(align)                                          \
255         . = ALIGN((align));                                             \
256         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
257                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
258                 *(.rodata) *(.rodata.*)                                 \
259                 *(.data..ro_after_init) /* Read only after init */      \
260                 *(__vermagic)           /* Kernel version magic */      \
261                 . = ALIGN(8);                                           \
262                 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .;         \
263                 *(__tracepoints_ptrs)   /* Tracepoints: pointer array */\
264                 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .;          \
265                 *(__tracepoints_strings)/* Tracepoints: strings */      \
266         }                                                               \
267                                                                         \
268         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
269                 *(.rodata1)                                             \
270         }                                                               \
271                                                                         \
272         BUG_TABLE                                                       \
273                                                                         \
274         /* PCI quirks */                                                \
275         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
276                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
277                 *(.pci_fixup_early)                                     \
278                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
279                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
280                 *(.pci_fixup_header)                                    \
281                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
282                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
283                 *(.pci_fixup_final)                                     \
284                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
285                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
286                 *(.pci_fixup_enable)                                    \
287                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
288                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
289                 *(.pci_fixup_resume)                                    \
290                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
291                 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;    \
292                 *(.pci_fixup_resume_early)                              \
293                 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;      \
294                 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;         \
295                 *(.pci_fixup_suspend)                                   \
296                 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;           \
297                 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .;    \
298                 *(.pci_fixup_suspend_late)                              \
299                 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .;      \
300         }                                                               \
301                                                                         \
302         /* Built-in firmware blobs */                                   \
303         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
304                 VMLINUX_SYMBOL(__start_builtin_fw) = .;                 \
305                 *(.builtin_fw)                                          \
306                 VMLINUX_SYMBOL(__end_builtin_fw) = .;                   \
307         }                                                               \
308                                                                         \
309         TRACEDATA                                                       \
310                                                                         \
311         /* Kernel symbol table: Normal symbols */                       \
312         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
313                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
314                 *(SORT(___ksymtab+*))                                   \
315                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
316         }                                                               \
317                                                                         \
318         /* Kernel symbol table: GPL-only symbols */                     \
319         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
320                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
321                 *(SORT(___ksymtab_gpl+*))                               \
322                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
323         }                                                               \
324                                                                         \
325         /* Kernel symbol table: Normal unused symbols */                \
326         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
327                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
328                 *(SORT(___ksymtab_unused+*))                            \
329                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
330         }                                                               \
331                                                                         \
332         /* Kernel symbol table: GPL-only unused symbols */              \
333         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
334                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
335                 *(SORT(___ksymtab_unused_gpl+*))                        \
336                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
337         }                                                               \
338                                                                         \
339         /* Kernel symbol table: GPL-future-only symbols */              \
340         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
341                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
342                 *(SORT(___ksymtab_gpl_future+*))                        \
343                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
344         }                                                               \
345                                                                         \
346         /* Kernel symbol table: Normal symbols */                       \
347         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
348                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
349                 *(SORT(___kcrctab+*))                                   \
350                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
351         }                                                               \
352                                                                         \
353         /* Kernel symbol table: GPL-only symbols */                     \
354         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
355                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
356                 *(SORT(___kcrctab_gpl+*))                               \
357                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
358         }                                                               \
359                                                                         \
360         /* Kernel symbol table: Normal unused symbols */                \
361         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
362                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
363                 *(SORT(___kcrctab_unused+*))                            \
364                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
365         }                                                               \
366                                                                         \
367         /* Kernel symbol table: GPL-only unused symbols */              \
368         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
369                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
370                 *(SORT(___kcrctab_unused_gpl+*))                        \
371                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
372         }                                                               \
373                                                                         \
374         /* Kernel symbol table: GPL-future-only symbols */              \
375         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
376                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
377                 *(SORT(___kcrctab_gpl_future+*))                        \
378                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
379         }                                                               \
380                                                                         \
381         /* Kernel symbol table: strings */                              \
382         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
383                 *(__ksymtab_strings)                                    \
384         }                                                               \
385                                                                         \
386         /* __*init sections */                                          \
387         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
388                 *(.ref.rodata)                                          \
389                 MEM_KEEP(init.rodata)                                   \
390                 MEM_KEEP(exit.rodata)                                   \
391         }                                                               \
392                                                                         \
393         /* Built-in module parameters. */                               \
394         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
395                 VMLINUX_SYMBOL(__start___param) = .;                    \
396                 *(__param)                                              \
397                 VMLINUX_SYMBOL(__stop___param) = .;                     \
398         }                                                               \
399                                                                         \
400         /* Built-in module versions. */                                 \
401         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
402                 VMLINUX_SYMBOL(__start___modver) = .;                   \
403                 *(__modver)                                             \
404                 VMLINUX_SYMBOL(__stop___modver) = .;                    \
405                 . = ALIGN((align));                                     \
406                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
407         }                                                               \
408         . = ALIGN((align));
409
410 /* RODATA & RO_DATA provided for backward compatibility.
411  * All archs are supposed to use RO_DATA() */
412 #define RODATA          RO_DATA_SECTION(4096)
413 #define RO_DATA(align)  RO_DATA_SECTION(align)
414
415 #define SECURITY_INIT                                                   \
416         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
417                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
418                 *(.security_initcall.init)                              \
419                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
420         }
421
422 /* .text section. Map to function alignment to avoid address changes
423  * during second ld run in second ld pass when generating System.map */
424 #define TEXT_TEXT                                                       \
425                 ALIGN_FUNCTION();                                       \
426                 *(.text.hot .text .text.fixup .text.unlikely)           \
427                 *(.ref.text)                                            \
428         MEM_KEEP(init.text)                                             \
429         MEM_KEEP(exit.text)                                             \
430
431
432 /* sched.text is aling to function alignment to secure we have same
433  * address even at second ld pass when generating System.map */
434 #define SCHED_TEXT                                                      \
435                 ALIGN_FUNCTION();                                       \
436                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
437                 *(.sched.text)                                          \
438                 VMLINUX_SYMBOL(__sched_text_end) = .;
439
440 /* spinlock.text is aling to function alignment to secure we have same
441  * address even at second ld pass when generating System.map */
442 #define LOCK_TEXT                                                       \
443                 ALIGN_FUNCTION();                                       \
444                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
445                 *(.spinlock.text)                                       \
446                 VMLINUX_SYMBOL(__lock_text_end) = .;
447
448 #define KPROBES_TEXT                                                    \
449                 ALIGN_FUNCTION();                                       \
450                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
451                 *(.kprobes.text)                                        \
452                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
453
454 #define ENTRY_TEXT                                                      \
455                 ALIGN_FUNCTION();                                       \
456                 VMLINUX_SYMBOL(__entry_text_start) = .;                 \
457                 *(.entry.text)                                          \
458                 VMLINUX_SYMBOL(__entry_text_end) = .;
459
460 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
461 #define IRQENTRY_TEXT                                                   \
462                 ALIGN_FUNCTION();                                       \
463                 VMLINUX_SYMBOL(__irqentry_text_start) = .;              \
464                 *(.irqentry.text)                                       \
465                 VMLINUX_SYMBOL(__irqentry_text_end) = .;
466 #else
467 #define IRQENTRY_TEXT
468 #endif
469
470 /* Section used for early init (in .S files) */
471 #define HEAD_TEXT  *(.head.text)
472
473 #define HEAD_TEXT_SECTION                                                       \
474         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
475                 HEAD_TEXT                                               \
476         }
477
478 /*
479  * Exception table
480  */
481 #define EXCEPTION_TABLE(align)                                          \
482         . = ALIGN(align);                                               \
483         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
484                 VMLINUX_SYMBOL(__start___ex_table) = .;                 \
485                 *(__ex_table)                                           \
486                 VMLINUX_SYMBOL(__stop___ex_table) = .;                  \
487         }
488
489 /*
490  * Init task
491  */
492 #define INIT_TASK_DATA_SECTION(align)                                   \
493         . = ALIGN(align);                                               \
494         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
495                 INIT_TASK_DATA(align)                                   \
496         }
497
498 #ifdef CONFIG_CONSTRUCTORS
499 #define KERNEL_CTORS()  . = ALIGN(8);                      \
500                         VMLINUX_SYMBOL(__ctors_start) = .; \
501                         *(.ctors)                          \
502                         *(SORT(.init_array.*))             \
503                         *(.init_array)                     \
504                         VMLINUX_SYMBOL(__ctors_end) = .;
505 #else
506 #define KERNEL_CTORS()
507 #endif
508
509 /* init and exit section handling */
510 #define INIT_DATA                                                       \
511         *(.init.data)                                                   \
512         MEM_DISCARD(init.data)                                          \
513         KERNEL_CTORS()                                                  \
514         MCOUNT_REC()                                                    \
515         *(.init.rodata)                                                 \
516         FTRACE_EVENTS()                                                 \
517         TRACE_SYSCALLS()                                                \
518         KPROBE_BLACKLIST()                                              \
519         MEM_DISCARD(init.rodata)                                        \
520         CLK_OF_TABLES()                                                 \
521         RESERVEDMEM_OF_TABLES()                                         \
522         CLKSRC_OF_TABLES()                                              \
523         IOMMU_OF_TABLES()                                               \
524         CPU_METHOD_OF_TABLES()                                          \
525         CPUIDLE_METHOD_OF_TABLES()                                      \
526         KERNEL_DTB()                                                    \
527         IRQCHIP_OF_MATCH_TABLE()                                        \
528         ACPI_PROBE_TABLE(irqchip)                                       \
529         ACPI_PROBE_TABLE(clksrc)                                        \
530         EARLYCON_TABLE()                                                \
531         EARLYCON_OF_TABLES()
532
533 #define INIT_TEXT                                                       \
534         *(.init.text)                                                   \
535         MEM_DISCARD(init.text)
536
537 #define EXIT_DATA                                                       \
538         *(.exit.data)                                                   \
539         MEM_DISCARD(exit.data)                                          \
540         MEM_DISCARD(exit.rodata)
541
542 #define EXIT_TEXT                                                       \
543         *(.exit.text)                                                   \
544         MEM_DISCARD(exit.text)
545
546 #define EXIT_CALL                                                       \
547         *(.exitcall.exit)
548
549 /*
550  * bss (Block Started by Symbol) - uninitialized data
551  * zeroed during startup
552  */
553 #define SBSS(sbss_align)                                                \
554         . = ALIGN(sbss_align);                                          \
555         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
556                 *(.sbss)                                                \
557                 *(.scommon)                                             \
558         }
559
560 /*
561  * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
562  * sections to the front of bss.
563  */
564 #ifndef BSS_FIRST_SECTIONS
565 #define BSS_FIRST_SECTIONS
566 #endif
567
568 #define BSS(bss_align)                                                  \
569         . = ALIGN(bss_align);                                           \
570         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
571                 BSS_FIRST_SECTIONS                                      \
572                 *(.bss..page_aligned)                                   \
573                 *(.dynbss)                                              \
574                 *(.bss)                                                 \
575                 *(COMMON)                                               \
576         }
577
578 /*
579  * DWARF debug sections.
580  * Symbols in the DWARF debugging sections are relative to
581  * the beginning of the section so we begin them at 0.
582  */
583 #define DWARF_DEBUG                                                     \
584                 /* DWARF 1 */                                           \
585                 .debug          0 : { *(.debug) }                       \
586                 .line           0 : { *(.line) }                        \
587                 /* GNU DWARF 1 extensions */                            \
588                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
589                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
590                 /* DWARF 1.1 and DWARF 2 */                             \
591                 .debug_aranges  0 : { *(.debug_aranges) }               \
592                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
593                 /* DWARF 2 */                                           \
594                 .debug_info     0 : { *(.debug_info                     \
595                                 .gnu.linkonce.wi.*) }                   \
596                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
597                 .debug_line     0 : { *(.debug_line) }                  \
598                 .debug_frame    0 : { *(.debug_frame) }                 \
599                 .debug_str      0 : { *(.debug_str) }                   \
600                 .debug_loc      0 : { *(.debug_loc) }                   \
601                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
602                 /* SGI/MIPS DWARF 2 extensions */                       \
603                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
604                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
605                 .debug_typenames 0 : { *(.debug_typenames) }            \
606                 .debug_varnames  0 : { *(.debug_varnames) }             \
607
608                 /* Stabs debugging sections.  */
609 #define STABS_DEBUG                                                     \
610                 .stab 0 : { *(.stab) }                                  \
611                 .stabstr 0 : { *(.stabstr) }                            \
612                 .stab.excl 0 : { *(.stab.excl) }                        \
613                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
614                 .stab.index 0 : { *(.stab.index) }                      \
615                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
616                 .comment 0 : { *(.comment) }
617
618 #ifdef CONFIG_GENERIC_BUG
619 #define BUG_TABLE                                                       \
620         . = ALIGN(8);                                                   \
621         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
622                 VMLINUX_SYMBOL(__start___bug_table) = .;                \
623                 *(__bug_table)                                          \
624                 VMLINUX_SYMBOL(__stop___bug_table) = .;                 \
625         }
626 #else
627 #define BUG_TABLE
628 #endif
629
630 #ifdef CONFIG_PM_TRACE
631 #define TRACEDATA                                                       \
632         . = ALIGN(4);                                                   \
633         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
634                 VMLINUX_SYMBOL(__tracedata_start) = .;                  \
635                 *(.tracedata)                                           \
636                 VMLINUX_SYMBOL(__tracedata_end) = .;                    \
637         }
638 #else
639 #define TRACEDATA
640 #endif
641
642 #define NOTES                                                           \
643         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
644                 VMLINUX_SYMBOL(__start_notes) = .;                      \
645                 *(.note.*)                                              \
646                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
647         }
648
649 #define INIT_SETUP(initsetup_align)                                     \
650                 . = ALIGN(initsetup_align);                             \
651                 VMLINUX_SYMBOL(__setup_start) = .;                      \
652                 *(.init.setup)                                          \
653                 VMLINUX_SYMBOL(__setup_end) = .;
654
655 #define INIT_CALLS_LEVEL(level)                                         \
656                 VMLINUX_SYMBOL(__initcall##level##_start) = .;          \
657                 *(.initcall##level##.init)                              \
658                 *(.initcall##level##s.init)                             \
659
660 #define INIT_CALLS                                                      \
661                 VMLINUX_SYMBOL(__initcall_start) = .;                   \
662                 *(.initcallearly.init)                                  \
663                 INIT_CALLS_LEVEL(0)                                     \
664                 INIT_CALLS_LEVEL(1)                                     \
665                 INIT_CALLS_LEVEL(2)                                     \
666                 INIT_CALLS_LEVEL(3)                                     \
667                 INIT_CALLS_LEVEL(4)                                     \
668                 INIT_CALLS_LEVEL(5)                                     \
669                 INIT_CALLS_LEVEL(rootfs)                                \
670                 INIT_CALLS_LEVEL(6)                                     \
671                 INIT_CALLS_LEVEL(7)                                     \
672                 VMLINUX_SYMBOL(__initcall_end) = .;
673
674 #define CON_INITCALL                                                    \
675                 VMLINUX_SYMBOL(__con_initcall_start) = .;               \
676                 *(.con_initcall.init)                                   \
677                 VMLINUX_SYMBOL(__con_initcall_end) = .;
678
679 #define SECURITY_INITCALL                                               \
680                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
681                 *(.security_initcall.init)                              \
682                 VMLINUX_SYMBOL(__security_initcall_end) = .;
683
684 #ifdef CONFIG_BLK_DEV_INITRD
685 #define INIT_RAM_FS                                                     \
686         . = ALIGN(4);                                                   \
687         VMLINUX_SYMBOL(__initramfs_start) = .;                          \
688         *(.init.ramfs)                                                  \
689         . = ALIGN(8);                                                   \
690         *(.init.ramfs.info)
691 #else
692 #define INIT_RAM_FS
693 #endif
694
695 /*
696  * Default discarded sections.
697  *
698  * Some archs want to discard exit text/data at runtime rather than
699  * link time due to cross-section references such as alt instructions,
700  * bug table, eh_frame, etc.  DISCARDS must be the last of output
701  * section definitions so that such archs put those in earlier section
702  * definitions.
703  */
704 #define DISCARDS                                                        \
705         /DISCARD/ : {                                                   \
706         EXIT_TEXT                                                       \
707         EXIT_DATA                                                       \
708         EXIT_CALL                                                       \
709         *(.discard)                                                     \
710         *(.discard.*)                                                   \
711         }
712
713 /**
714  * PERCPU_INPUT - the percpu input sections
715  * @cacheline: cacheline size
716  *
717  * The core percpu section names and core symbols which do not rely
718  * directly upon load addresses.
719  *
720  * @cacheline is used to align subsections to avoid false cacheline
721  * sharing between subsections for different purposes.
722  */
723 #define PERCPU_INPUT(cacheline)                                         \
724         VMLINUX_SYMBOL(__per_cpu_start) = .;                            \
725         *(.data..percpu..first)                                         \
726         . = ALIGN(PAGE_SIZE);                                           \
727         *(.data..percpu..page_aligned)                                  \
728         . = ALIGN(cacheline);                                           \
729         *(.data..percpu..read_mostly)                                   \
730         . = ALIGN(cacheline);                                           \
731         *(.data..percpu)                                                \
732         *(.data..percpu..shared_aligned)                                \
733         VMLINUX_SYMBOL(__per_cpu_end) = .;
734
735 /**
736  * PERCPU_VADDR - define output section for percpu area
737  * @cacheline: cacheline size
738  * @vaddr: explicit base address (optional)
739  * @phdr: destination PHDR (optional)
740  *
741  * Macro which expands to output section for percpu area.
742  *
743  * @cacheline is used to align subsections to avoid false cacheline
744  * sharing between subsections for different purposes.
745  *
746  * If @vaddr is not blank, it specifies explicit base address and all
747  * percpu symbols will be offset from the given address.  If blank,
748  * @vaddr always equals @laddr + LOAD_OFFSET.
749  *
750  * @phdr defines the output PHDR to use if not blank.  Be warned that
751  * output PHDR is sticky.  If @phdr is specified, the next output
752  * section in the linker script will go there too.  @phdr should have
753  * a leading colon.
754  *
755  * Note that this macros defines __per_cpu_load as an absolute symbol.
756  * If there is no need to put the percpu section at a predetermined
757  * address, use PERCPU_SECTION.
758  */
759 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
760         VMLINUX_SYMBOL(__per_cpu_load) = .;                             \
761         .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)         \
762                                 - LOAD_OFFSET) {                        \
763                 PERCPU_INPUT(cacheline)                                 \
764         } phdr                                                          \
765         . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
766
767 /**
768  * PERCPU_SECTION - define output section for percpu area, simple version
769  * @cacheline: cacheline size
770  *
771  * Align to PAGE_SIZE and outputs output section for percpu area.  This
772  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
773  * __per_cpu_start will be identical.
774  *
775  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
776  * except that __per_cpu_load is defined as a relative symbol against
777  * .data..percpu which is required for relocatable x86_32 configuration.
778  */
779 #define PERCPU_SECTION(cacheline)                                       \
780         . = ALIGN(PAGE_SIZE);                                           \
781         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
782                 VMLINUX_SYMBOL(__per_cpu_load) = .;                     \
783                 PERCPU_INPUT(cacheline)                                 \
784         }
785
786
787 /*
788  * Definition of the high level *_SECTION macros
789  * They will fit only a subset of the architectures
790  */
791
792
793 /*
794  * Writeable data.
795  * All sections are combined in a single .data section.
796  * The sections following CONSTRUCTORS are arranged so their
797  * typical alignment matches.
798  * A cacheline is typical/always less than a PAGE_SIZE so
799  * the sections that has this restriction (or similar)
800  * is located before the ones requiring PAGE_SIZE alignment.
801  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
802  * matches the requirement of PAGE_ALIGNED_DATA.
803  *
804  * use 0 as page_align if page_aligned data is not used */
805 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
806         . = ALIGN(PAGE_SIZE);                                           \
807         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
808                 INIT_TASK_DATA(inittask)                                \
809                 NOSAVE_DATA                                             \
810                 PAGE_ALIGNED_DATA(pagealigned)                          \
811                 CACHELINE_ALIGNED_DATA(cacheline)                       \
812                 READ_MOSTLY_DATA(cacheline)                             \
813                 DATA_DATA                                               \
814                 CONSTRUCTORS                                            \
815         }
816
817 #define INIT_TEXT_SECTION(inittext_align)                               \
818         . = ALIGN(inittext_align);                                      \
819         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
820                 VMLINUX_SYMBOL(_sinittext) = .;                         \
821                 INIT_TEXT                                               \
822                 VMLINUX_SYMBOL(_einittext) = .;                         \
823         }
824
825 #define INIT_DATA_SECTION(initsetup_align)                              \
826         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
827                 INIT_DATA                                               \
828                 INIT_SETUP(initsetup_align)                             \
829                 INIT_CALLS                                              \
830                 CON_INITCALL                                            \
831                 SECURITY_INITCALL                                       \
832                 INIT_RAM_FS                                             \
833         }
834
835 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
836         . = ALIGN(sbss_align);                                          \
837         VMLINUX_SYMBOL(__bss_start) = .;                                \
838         SBSS(sbss_align)                                                \
839         BSS(bss_align)                                                  \
840         . = ALIGN(stop_align);                                          \
841         VMLINUX_SYMBOL(__bss_stop) = .;