cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25     if (CLANG_CL)
  26       # FIXME: Remove this once clang-cl supports SEH
  27       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  28     endif()
  29   endif()
  30
  31   # LLVM_REQUIRES_RTTI is an internal flag that individual
  32   # targets can use to force RTTI
  33   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  34     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  35     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  36       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  37     elseif (MSVC)
  38       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  39     endif ()
  40   endif()
  41
  42   # Assume that;
  43   #   - LLVM_COMPILE_FLAGS is list.
  44   #   - PROPERTY COMPILE_FLAGS is string.
  45   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  46
  47   if(update_src_props)
  48     foreach(fn ${sources})
  49       get_filename_component(suf ${fn} EXT)
  50       if("${suf}" STREQUAL ".cpp")
  51         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  52           COMPILE_FLAGS "${target_compile_flags}")
  53       endif()
  54     endforeach()
  55   else()
  56     # Update target props, since all sources are C++.
  57     set_property(TARGET ${name} APPEND_STRING PROPERTY
  58       COMPILE_FLAGS "${target_compile_flags}")
  59   endif()
  60
  61   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  62 endfunction()
  63
  64 function(add_llvm_symbol_exports target_name export_file)
  65   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  66     set(native_export_file "${target_name}.exports")
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  69       DEPENDS ${export_file}
  70       VERBATIM
  71       COMMENT "Creating export file for ${target_name}")
  72     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  73                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  74   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  75     # Gold and BFD ld require a version script rather than a plain list.
  76     set(native_export_file "${target_name}.exports")
  77     # FIXME: Don't write the "local:" line on OpenBSD.
  78     add_custom_command(OUTPUT ${native_export_file}
  79       COMMAND echo "{" > ${native_export_file}
  80       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  81       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  82       COMMAND echo "  local: *;" >> ${native_export_file}
  83       COMMAND echo "};" >> ${native_export_file}
  84       DEPENDS ${export_file}
  85       VERBATIM
  86       COMMENT "Creating export file for ${target_name}")
  87     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89   else()
  90     set(native_export_file "${target_name}.def")
  91
  92     set(CAT "cat")
  93     set(export_file_nativeslashes ${export_file})
  94     if(WIN32 AND NOT CYGWIN)
  95       set(CAT "type")
  96       # Convert ${export_file} to native format (backslashes) for "type"
  97       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  98       # path but a build-system specific format (see CMake bug
  99       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
 100       string(REPLACE / \\ export_file_nativeslashes ${export_file})
 101     endif()
 102
 103     add_custom_command(OUTPUT ${native_export_file}
 104       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 105       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 106       DEPENDS ${export_file}
 107       VERBATIM
 108       COMMENT "Creating export file for ${target_name}")
 109     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 110     if(MSVC)
 111       set(export_file_linker_flag "/DEF:${export_file_linker_flag}")
 112     endif()
 113     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 114                  LINK_FLAGS " ${export_file_linker_flag}")
 115   endif()
 116
 117   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 118   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 119
 120   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 121   foreach(src ${srcs})
 122     get_filename_component(extension ${src} EXT)
 123     if(extension STREQUAL ".cpp")
 124       set(first_source_file ${src})
 125       break()
 126     endif()
 127   endforeach()
 128
 129   # Force re-linking when the exports file changes. Actually, it
 130   # forces recompilation of the source file. The LINK_DEPENDS target
 131   # property only works for makefile-based generators.
 132   # FIXME: This is not safe because this will create the same target
 133   # ${native_export_file} in several different file:
 134   # - One where we emitted ${target_name}_exports
 135   # - One where we emitted the build command for the following object.
 136   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 137   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 138
 139   set_property(DIRECTORY APPEND
 140     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 141
 142   add_dependencies(${target_name} ${target_name}_exports)
 143
 144   # Add dependency to *_exports later -- CMake issue 14747
 145   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 146   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 147 endfunction(add_llvm_symbol_exports)
 148
 149 if(NOT WIN32 AND NOT APPLE)
 150   execute_process(
 151     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 152     OUTPUT_VARIABLE stdout
 153     ERROR_QUIET
 154     )
 155   if("${stdout}" MATCHES "GNU gold")
 156     set(LLVM_LINKER_IS_GOLD ON)
 157   endif()
 158 endif()
 159
 160 function(add_link_opts target_name)
 161   # Pass -O3 to the linker. This enabled different optimizations on different
 162   # linkers. Don't do it in debug builds since it slows down the linker
 163   # in a context where the optimizations are not important.
 164   if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32) AND
 165      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 166     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                  LINK_FLAGS " -Wl,-O3")
 168   endif()
 169
 170   if(LLVM_LINKER_IS_GOLD)
 171     # With gold gc-sections is always safe.
 172     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 173                  LINK_FLAGS " -Wl,--gc-sections")
 174     # Note that there is a bug with -Wl,--icf=safe so it is not safe
 175     # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 176   endif()
 177
 178   if(NOT LLVM_NO_DEAD_STRIP)
 179     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 180       # ld64's implementation of -dead_strip breaks tools that use plugins.
 181       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 182                    LINK_FLAGS " -Wl,-dead_strip")
 183     elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 184       # Object files are compiled with -ffunction-data-sections.
 185       # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 186       # tools that use plugins. Always pass --gc-sections once we require
 187       # a newer linker.
 188       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 189                    LINK_FLAGS " -Wl,--gc-sections")
 190     endif()
 191   endif()
 192 endfunction(add_link_opts)
 193
 194 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 195 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 196 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 197 function(set_output_directory target bindir libdir)
 198   # Do nothing if *_OUTPUT_INTDIR is empty.
 199   if("${bindir}" STREQUAL "")
 200     return()
 201   endif()
 202
 203   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 204   # It affects output of add_library(MODULE).
 205   if(WIN32 OR CYGWIN)
 206     # DLL platform
 207     set(moddir ${bindir})
 208   else()
 209     set(moddir ${libdir})
 210   endif()
 211   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 212     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 213       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 214       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 215       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 216       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 217       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 218       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 219       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 220     endforeach()
 221   else()
 222     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 223     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 224     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 225   endif()
 226 endfunction()
 227
 228 # llvm_add_library(name sources...
 229 #   SHARED;STATIC
 230 #     STATIC by default w/o BUILD_SHARED_LIBS.
 231 #     SHARED by default w/  BUILD_SHARED_LIBS.
 232 #   MODULE
 233 #     Target ${name} might not be created on unsupported platforms.
 234 #     Check with "if(TARGET ${name})".
 235 #   OUTPUT_NAME name
 236 #     Corresponds to OUTPUT_NAME in target properties.
 237 #   DEPENDS targets...
 238 #     Same semantics as add_dependencies().
 239 #   LINK_COMPONENTS components...
 240 #     Same as the variable LLVM_LINK_COMPONENTS.
 241 #   LINK_LIBS lib_targets...
 242 #     Same semantics as target_link_libraries().
 243 #   ADDITIONAL_HEADERS
 244 #     May specify header files for IDE generators.
 245 #   )
 246 function(llvm_add_library name)
 247   cmake_parse_arguments(ARG
 248     "MODULE;SHARED;STATIC"
 249     "OUTPUT_NAME"
 250     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 251     ${ARGN})
 252   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 253   if(ARG_ADDITIONAL_HEADERS)
 254     # Pass through ADDITIONAL_HEADERS.
 255     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 256   endif()
 257   if(ARG_OBJLIBS)
 258     set(ALL_FILES ${ARG_OBJLIBS})
 259   else()
 260     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 261   endif()
 262
 263   if(ARG_MODULE)
 264     if(ARG_SHARED OR ARG_STATIC)
 265       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 266     endif()
 267     if(NOT LLVM_ENABLE_PLUGINS)
 268       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 269       return()
 270     endif()
 271   else()
 272     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 273       set(ARG_SHARED TRUE)
 274     endif()
 275     if(NOT ARG_SHARED)
 276       set(ARG_STATIC TRUE)
 277     endif()
 278   endif()
 279
 280   # Generate objlib
 281   if(ARG_SHARED AND ARG_STATIC)
 282     # Generate an obj library for both targets.
 283     set(obj_name "obj.${name}")
 284     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 285       ${ALL_FILES}
 286       )
 287     llvm_update_compile_flags(${obj_name})
 288     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 289
 290     # Do add_dependencies(obj) later due to CMake issue 14747.
 291     list(APPEND objlibs ${obj_name})
 292
 293     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 294   endif()
 295
 296   if(ARG_SHARED AND ARG_STATIC)
 297     # static
 298     set(name_static "${name}_static")
 299     if(ARG_OUTPUT_NAME)
 300       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 301     endif()
 302     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 303     llvm_add_library(${name_static} STATIC
 304       ${output_name}
 305       OBJLIBS ${ALL_FILES} # objlib
 306       LINK_LIBS ${ARG_LINK_LIBS}
 307       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 308       )
 309     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 310     set(ARG_STATIC)
 311   endif()
 312
 313   if(ARG_MODULE)
 314     add_library(${name} MODULE ${ALL_FILES})
 315   elseif(ARG_SHARED)
 316     add_library(${name} SHARED ${ALL_FILES})
 317   else()
 318     add_library(${name} STATIC ${ALL_FILES})
 319   endif()
 320   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 321   llvm_update_compile_flags(${name})
 322   add_link_opts( ${name} )
 323   if(ARG_OUTPUT_NAME)
 324     set_target_properties(${name}
 325       PROPERTIES
 326       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 327       )
 328   endif()
 329
 330   if(ARG_MODULE)
 331     set_target_properties(${name} PROPERTIES
 332       PREFIX ""
 333       SUFFIX ${LLVM_PLUGIN_EXT}
 334       )
 335   endif()
 336
 337   if(ARG_SHARED)
 338     if(WIN32)
 339       set_target_properties(${name} PROPERTIES
 340         PREFIX ""
 341         )
 342     endif()
 343
 344     set_target_properties(${name}
 345       PROPERTIES
 346       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 347       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 348   endif()
 349
 350   if(ARG_MODULE OR ARG_SHARED)
 351     # Do not add -Dname_EXPORTS to the command-line when building files in this
 352     # target. Doing so is actively harmful for the modules build because it
 353     # creates extra module variants, and not useful because we don't use these
 354     # macros.
 355     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 356
 357     if (LLVM_EXPORTED_SYMBOL_FILE)
 358       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 359     endif()
 360   endif()
 361
 362   # Add the explicit dependency information for this library.
 363   #
 364   # It would be nice to verify that we have the dependencies for this library
 365   # name, but using get_property(... SET) doesn't suffice to determine if a
 366   # property has been set to an empty value.
 367   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 368
 369   llvm_map_components_to_libnames(llvm_libs
 370     ${ARG_LINK_COMPONENTS}
 371     ${LLVM_LINK_COMPONENTS}
 372     )
 373
 374   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 375     # Link libs w/o keywords, assuming PUBLIC.
 376     target_link_libraries(${name}
 377       ${ARG_LINK_LIBS}
 378       ${lib_deps}
 379       ${llvm_libs}
 380       )
 381   elseif(ARG_STATIC)
 382     target_link_libraries(${name} INTERFACE
 383       ${ARG_LINK_LIBS}
 384       ${lib_deps}
 385       ${llvm_libs}
 386       )
 387   else()
 388     # We can use PRIVATE since SO knows its dependent libs.
 389     target_link_libraries(${name} PRIVATE
 390       ${ARG_LINK_LIBS}
 391       ${lib_deps}
 392       ${llvm_libs}
 393       )
 394   endif()
 395
 396   if(LLVM_COMMON_DEPENDS)
 397     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 398     # Add dependencies also to objlibs.
 399     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 400     foreach(objlib ${objlibs})
 401       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 402     endforeach()
 403   endif()
 404 endfunction()
 405
 406 macro(add_llvm_library name)
 407   if( BUILD_SHARED_LIBS )
 408     llvm_add_library(${name} SHARED ${ARGN})
 409   else()
 410     llvm_add_library(${name} ${ARGN})
 411   endif()
 412   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 413
 414   if( EXCLUDE_FROM_ALL )
 415     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 416   else()
 417     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 418       install(TARGETS ${name}
 419         EXPORT LLVMExports
 420         RUNTIME DESTINATION bin
 421         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 422         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 423         COMPONENT ${name})
 424
 425       if (NOT CMAKE_CONFIGURATION_TYPES)
 426         add_custom_target(install-${name}
 427                           DEPENDS ${name}
 428                           COMMAND "${CMAKE_COMMAND}"
 429                                   -DCMAKE_INSTALL_COMPONENT=${name}
 430                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 431       endif()
 432     endif()
 433     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 434   endif()
 435   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 436 endmacro(add_llvm_library name)
 437
 438 macro(add_llvm_loadable_module name)
 439   llvm_add_library(${name} MODULE ${ARGN})
 440   if(NOT TARGET ${name})
 441     # Add empty "phony" target
 442     add_custom_target(${name})
 443   else()
 444     if( EXCLUDE_FROM_ALL )
 445       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 446     else()
 447       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 448         if(WIN32 OR CYGWIN)
 449           # DLL platform
 450           set(dlldir "bin")
 451         else()
 452           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 453         endif()
 454         install(TARGETS ${name}
 455           EXPORT LLVMExports
 456           LIBRARY DESTINATION ${dlldir}
 457           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 458       endif()
 459       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 460     endif()
 461   endif()
 462
 463   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 464 endmacro(add_llvm_loadable_module name)
 465
 466
 467 macro(add_llvm_executable name)
 468   llvm_process_sources( ALL_FILES ${ARGN} )
 469   if( EXCLUDE_FROM_ALL )
 470     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 471   else()
 472     add_executable(${name} ${ALL_FILES})
 473   endif()
 474   llvm_update_compile_flags(${name})
 475   add_link_opts( ${name} )
 476
 477   # Do not add -Dname_EXPORTS to the command-line when building files in this
 478   # target. Doing so is actively harmful for the modules build because it
 479   # creates extra module variants, and not useful because we don't use these
 480   # macros.
 481   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 482
 483   if (LLVM_EXPORTED_SYMBOL_FILE)
 484     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 485   endif(LLVM_EXPORTED_SYMBOL_FILE)
 486
 487   set(EXCLUDE_FROM_ALL OFF)
 488   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 489   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 490   if( LLVM_COMMON_DEPENDS )
 491     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 492   endif( LLVM_COMMON_DEPENDS )
 493 endmacro(add_llvm_executable name)
 494
 495 function(export_executable_symbols target)
 496   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 497     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 498   endif()
 499 endfunction()
 500
 501
 502 set (LLVM_TOOLCHAIN_TOOLS
 503   llvm-ar
 504   llvm-objdump
 505   )
 506
 507 macro(add_llvm_tool name)
 508   if( NOT LLVM_BUILD_TOOLS )
 509     set(EXCLUDE_FROM_ALL ON)
 510   endif()
 511   add_llvm_executable(${name} ${ARGN})
 512
 513   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 514   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 515     if( LLVM_BUILD_TOOLS )
 516       install(TARGETS ${name}
 517               EXPORT LLVMExports
 518               RUNTIME DESTINATION bin
 519               COMPONENT ${name})
 520
 521       if (NOT CMAKE_CONFIGURATION_TYPES)
 522         add_custom_target(install-${name}
 523                           DEPENDS ${name}
 524                           COMMAND "${CMAKE_COMMAND}"
 525                                   -DCMAKE_INSTALL_COMPONENT=${name}
 526                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 527       endif()
 528     endif()
 529   endif()
 530   if( LLVM_BUILD_TOOLS )
 531     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 532   endif()
 533   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 534 endmacro(add_llvm_tool name)
 535
 536
 537 macro(add_llvm_example name)
 538   if( NOT LLVM_BUILD_EXAMPLES )
 539     set(EXCLUDE_FROM_ALL ON)
 540   endif()
 541   add_llvm_executable(${name} ${ARGN})
 542   if( LLVM_BUILD_EXAMPLES )
 543     install(TARGETS ${name} RUNTIME DESTINATION examples)
 544   endif()
 545   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 546 endmacro(add_llvm_example name)
 547
 548
 549 macro(add_llvm_utility name)
 550   add_llvm_executable(${name} ${ARGN})
 551   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 552   if( LLVM_INSTALL_UTILS )
 553     install (TARGETS ${name}
 554       RUNTIME DESTINATION bin
 555       COMPONENT ${name})
 556     if (NOT CMAKE_CONFIGURATION_TYPES)
 557       add_custom_target(install-${name}
 558                         DEPENDS ${name}
 559                         COMMAND "${CMAKE_COMMAND}"
 560                                 -DCMAKE_INSTALL_COMPONENT=${name}
 561                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 562     endif()
 563   endif()
 564 endmacro(add_llvm_utility name)
 565
 566
 567 macro(add_llvm_target target_name)
 568   include_directories(BEFORE
 569     ${CMAKE_CURRENT_BINARY_DIR}
 570     ${CMAKE_CURRENT_SOURCE_DIR})
 571   add_llvm_library(LLVM${target_name} ${ARGN})
 572   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 573 endmacro(add_llvm_target)
 574
 575 # Add external project that may want to be built as part of llvm such as Clang,
 576 # lld, and Polly. This adds two options. One for the source directory of the
 577 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 578 # enable or disable building it with everything else.
 579 # Additional parameter can be specified as the name of directory.
 580 macro(add_llvm_external_project name)
 581   set(add_llvm_external_dir "${ARGN}")
 582   if("${add_llvm_external_dir}" STREQUAL "")
 583     set(add_llvm_external_dir ${name})
 584   endif()
 585   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 586   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 587   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 588   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 589       CACHE PATH "Path to ${name} source directory")
 590   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 591       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 592     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 593            "Whether to build ${name} as part of LLVM" ON)
 594     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 595       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 596     endif()
 597   endif()
 598 endmacro(add_llvm_external_project)
 599
 600 macro(add_llvm_tool_subdirectory name)
 601   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 602   add_subdirectory(${name})
 603 endmacro(add_llvm_tool_subdirectory)
 604
 605 macro(ignore_llvm_tool_subdirectory name)
 606   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 607 endmacro(ignore_llvm_tool_subdirectory)
 608
 609 function(add_llvm_implicit_external_projects)
 610   set(list_of_implicit_subdirs "")
 611   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 612   foreach(dir ${sub-dirs})
 613     if(IS_DIRECTORY "${dir}")
 614       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 615       if( tool_subdir_ignore EQUAL -1
 616           AND EXISTS "${dir}/CMakeLists.txt")
 617         get_filename_component(fn "${dir}" NAME)
 618         list(APPEND list_of_implicit_subdirs "${fn}")
 619       endif()
 620     endif()
 621   endforeach()
 622
 623   foreach(external_proj ${list_of_implicit_subdirs})
 624     add_llvm_external_project("${external_proj}")
 625   endforeach()
 626 endfunction(add_llvm_implicit_external_projects)
 627
 628 # Generic support for adding a unittest.
 629 function(add_unittest test_suite test_name)
 630   if( NOT LLVM_BUILD_TESTS )
 631     set(EXCLUDE_FROM_ALL ON)
 632   endif()
 633
 634   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 635   if (NOT LLVM_ENABLE_THREADS)
 636     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 637   endif ()
 638
 639   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 640     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 641   endif ()
 642
 643   set(LLVM_REQUIRES_RTTI OFF)
 644
 645   add_llvm_executable(${test_name} ${ARGN})
 646   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 647   set_output_directory(${test_name} ${outdir} ${outdir})
 648   target_link_libraries(${test_name}
 649     gtest
 650     gtest_main
 651     LLVMSupport # gtest needs it for raw_ostream.
 652     )
 653
 654   add_dependencies(${test_suite} ${test_name})
 655   get_target_property(test_suite_folder ${test_suite} FOLDER)
 656   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 657     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 658   endif ()
 659 endfunction()
 660
 661 function(llvm_add_go_executable binary pkgpath)
 662   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 663
 664   if(LLVM_BINDINGS MATCHES "go")
 665     # FIXME: This should depend only on the libraries Go needs.
 666     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 667     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 668     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 669     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 670     set(cppflags "")
 671     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 672     foreach(d ${include_dirs})
 673       set(cppflags "${cppflags} -I${d}")
 674     endforeach(d)
 675     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 676     add_custom_command(OUTPUT ${binpath}
 677       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 678               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 679       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 680               ${llvmlibs} ${ARG_DEPENDS}
 681       COMMENT "Building Go executable ${binary}"
 682       VERBATIM)
 683     if (ARG_ALL)
 684       add_custom_target(${binary} ALL DEPENDS ${binpath})
 685     else()
 686       add_custom_target(${binary} DEPENDS ${binpath})
 687     endif()
 688   endif()
 689 endfunction()
 690
 691 # This function provides an automatic way to 'configure'-like generate a file
 692 # based on a set of common and custom variables, specifically targeting the
 693 # variables needed for the 'lit.site.cfg' files. This function bundles the
 694 # common variables that any Lit instance is likely to need, and custom
 695 # variables can be passed in.
 696 function(configure_lit_site_cfg input output)
 697   foreach(c ${LLVM_TARGETS_TO_BUILD})
 698     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 699   endforeach(c)
 700   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 701
 702   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 703
 704   # Configuration-time: See Unit/lit.site.cfg.in
 705   if (CMAKE_CFG_INTDIR STREQUAL ".")
 706     set(LLVM_BUILD_MODE ".")
 707   else ()
 708     set(LLVM_BUILD_MODE "%(build_mode)s")
 709   endif ()
 710
 711   # They below might not be the build tree but provided binary tree.
 712   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 713   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 714   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 715   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 716
 717   # SHLIBDIR points the build tree.
 718   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 719
 720   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 721   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 722   # plugins. We may rename it.
 723   if(LLVM_ENABLE_PLUGINS)
 724     set(ENABLE_SHARED "1")
 725   else()
 726     set(ENABLE_SHARED "0")
 727   endif()
 728
 729   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 730     set(ENABLE_ASSERTIONS "1")
 731   else()
 732     set(ENABLE_ASSERTIONS "0")
 733   endif()
 734
 735   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 736   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 737
 738   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 739   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 740   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 741
 742   configure_file(${input} ${output} @ONLY)
 743 endfunction()
 744
 745 # A raw function to create a lit target. This is used to implement the testuite
 746 # management functions.
 747 function(add_lit_target target comment)
 748   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 749   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 750   separate_arguments(LIT_ARGS)
 751   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 752     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 753   endif ()
 754   if (LLVM_MAIN_SRC_DIR)
 755     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 756   else()
 757     find_program(LIT_COMMAND llvm-lit)
 758   endif ()
 759   list(APPEND LIT_COMMAND ${LIT_ARGS})
 760   foreach(param ${ARG_PARAMS})
 761     list(APPEND LIT_COMMAND --param ${param})
 762   endforeach()
 763   if (ARG_DEFAULT_ARGS)
 764     add_custom_target(${target}
 765       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 766       COMMENT "${comment}"
 767       ${cmake_3_2_USES_TERMINAL}
 768       )
 769   else()
 770     add_custom_target(${target}
 771       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 772     message(STATUS "${target} does nothing.")
 773   endif()
 774   if (ARG_DEPENDS)
 775     add_dependencies(${target} ${ARG_DEPENDS})
 776   endif()
 777
 778   # Tests should be excluded from "Build Solution".
 779   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 780 endfunction()
 781
 782 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 783 function(add_lit_testsuite target comment)
 784   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 785
 786   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 787   if(NOT EXCLUDE_FROM_ALL)
 788     # Register the testsuites, params and depends for the global check rule.
 789     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 790     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 791     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 792     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 793   endif()
 794
 795   # Produce a specific suffixed check rule.
 796   add_lit_target(${target} ${comment}
 797     ${ARG_DEFAULT_ARGS}
 798     PARAMS ${ARG_PARAMS}
 799     DEPENDS ${ARG_DEPENDS}
 800     ARGS ${ARG_ARGS}
 801     )
 802 endfunction()
 803
 804 function(add_lit_testsuites project directory)
 805   if (NOT CMAKE_CONFIGURATION_TYPES)
 806     parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 807     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 808     set(lit_suites)
 809     foreach(f ${litCfg})
 810       get_filename_component(dir ${f} DIRECTORY)
 811       set(lit_suites ${lit_suites} ${dir})
 812     endforeach()
 813     list(REMOVE_DUPLICATES lit_suites)
 814     foreach(dir ${lit_suites})
 815       string(REPLACE ${directory} "" name_slash ${dir})
 816       if (name_slash)
 817         string(REPLACE "/" "-" name_slash ${name_slash})
 818         string(REPLACE "\\" "-" name_dashes ${name_slash})
 819         string(TOLOWER "${project}${name_dashes}" name_var)
 820         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
 821           ${dir}
 822           PARAMS ${ARG_PARAMS}
 823           DEPENDS ${ARG_DEPENDS}
 824           ARGS ${ARG_ARGS}
 825         )
 826       endif()
 827     endforeach()
 828   endif()
 829 endfunction()