cmake/config-ix.cmake

   1
   2 # include checks
   3 include(CheckIncludeFile)
   4 check_include_file(alloca.h HAVE_ALLOCA_H)
   5 check_include_file(argz.h HAVE_ARGZ_H)
   6 check_include_file(assert.h HAVE_ASSERT_H)
   7 check_include_file(dirent.h HAVE_DIRENT_H)
   8 check_include_file(dl.h HAVE_DL_H)
   9 check_include_file(dld.h HAVE_DLD_H)
  10 check_include_file(dlfcn.h HAVE_DLFCN_H)
  11 check_include_file(errno.h HAVE_ERRNO_H)
  12 check_include_file(execinfo.h HAVE_EXECINFO_H)
  13 check_include_file(fcntl.h HAVE_FCNTL_H)
  14 check_include_file(inttypes.h HAVE_INTTYPES_H)
  15 check_include_file(limits.h HAVE_LIMITS_H)
  16 check_include_file(link.h HAVE_LINK_H)
  17 check_include_file(malloc.h HAVE_MALLOC_H)
  18 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  19 check_include_file(memory.h HAVE_MEMORY_H)
  20 check_include_file(ndir.h HAVE_NDIR_H)
  21 check_include_file(pthread.h HAVE_PTHREAD_H)
  22 check_include_file(setjmp.h HAVE_SETJMP_H)
  23 check_include_file(signal.h HAVE_SIGNAL_H)
  24 check_include_file(stdint.h HAVE_STDINT_H)
  25 check_include_file(stdio.h HAVE_STDIO_H)
  26 check_include_file(stdlib.h HAVE_STDLIB_H)
  27 check_include_file(string.h HAVE_STRING_H)
  28 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  29 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  30 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  31 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  32 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  33 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  34 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  35 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  36 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  37 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  38 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  39 check_include_file(termios.h HAVE_TERMIOS_H)
  40 check_include_file(unistd.h HAVE_UNISTD_H)
  41 check_include_file(utime.h HAVE_UTIME_H)
  42 check_include_file(windows.h HAVE_WINDOWS_H)
  43
  44 # library checks
  45 include(CheckLibraryExists)
  46 check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  47 check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  48 check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  49 check_library_exists(dl dlopen "" HAVE_LIBDL)
  50
  51 # function checks
  52 include(CheckSymbolExists)
  53 include(CheckFunctionExists)
  54 check_symbol_exists(alloca alloca.h HAVE_ALLOCA)
  55 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  56 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  57 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  58 check_function_exists(isatty HAVE_ISATTY)
  59 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  60 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  61 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  62 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  63 check_symbol_exists(ceilf math.h HAVE_CEILF)
  64 check_symbol_exists(floorf math.h HAVE_FLOORF)
  65 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  66 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  67                     HAVE_MALLOC_ZONE_STATISTICS)
  68 check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
  69 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
  70
  71 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
  72 if( LLVM_USING_GLIBC )
  73   add_llvm_definitions( -D_GNU_SOURCE )
  74 endif()
  75
  76 include(CheckCXXCompilerFlag)
  77 check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  78
  79 include(GetTargetTriple)
  80 get_target_triple(LLVM_HOSTTRIPLE)
  81 message(STATUS "LLVM_HOSTTRIPLE: ${LLVM_HOSTTRIPLE}")
  82
  83 # Determine the native architecture.
  84 # FIXME: this will have to change for cross-compiling.
  85 string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
  86 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
  87   set(LLVM_NATIVE_ARCH X86)
  88 elseif (LLVM_NATIVE_ARCH STREQUAL amd64)
  89   set(LLVM_NATIVE_ARCH X86)
  90 elseif (LLVM_NATIVE_ARCH STREQUAL x86_64)
  91   set(LLVM_NATIVE_ARCH X86)
  92 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
  93   set(LLVM_NATIVE_ARCH Sparc)
  94 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
  95   set(LLVM_NATIVE_ARCH PowerPC)
  96 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
  97   set(LLVM_NATIVE_ARCH Alpha)
  98 elseif (LLVM_NATIVE_ARCH MATCHES "ia64")
  99   set(LLVM_NATIVE_ARCH IA64)
 100 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 101   set(LLVM_NATIVE_ARCH ARM)
 102 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 103   set(LLVM_NATIVE_ARCH Mips)
 104 elseif (LLVM_NATIVE_ARCH MATCHES "pic16")
 105   set(LLVM_NATIVE_ARCH "PIC16")
 106 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 107   set(LLVM_NATIVE_ARCH XCore)
 108 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 109   set(LLVM_NATIVE_ARCH MSP430)
 110 else ()
 111   message(STATUS
 112     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 113   set(LLVM_NATIVE_ARCH)
 114 endif ()
 115
 116 if (LLVM_NATIVE_ARCH)
 117   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 118   if (NATIVE_ARCH_IDX EQUAL -1)
 119     message(STATUS
 120       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 121     set(LLVM_NATIVE_ARCH)
 122   else ()
 123     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 124   endif ()
 125 endif()
 126
 127 if( MINGW )
 128   set(HAVE_LIBIMAGEHLP 1)
 129   set(HAVE_LIBPSAPI 1)
 130   # TODO: Check existence of libraries.
 131   #   include(CheckLibraryExists)
 132   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 133 endif( MINGW )
 134
 135 if( MSVC )
 136   set(error_t int)
 137   set(mode_t "unsigned short")
 138   set(LTDL_SHLIBPATH_VAR "PATH")
 139   set(LTDL_SYSSEARCHPATH "")
 140   set(LTDL_DLOPEN_DEPLIBS 1)
 141   set(SHLIBEXT ".lib")
 142   set(LTDL_OBJDIR "_libs")
 143   set(HAVE_STRTOLL 1)
 144   set(strtoll "_strtoi64")
 145   set(strtoull "_strtoui64")
 146   set(stricmp "_stricmp")
 147   set(strdup "_strdup")
 148 else( MSVC )
 149   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 150   set(LTDL_SYSSEARCHPATH "") # TODO
 151   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 152 endif( MSVC )
 153
 154 # FIXME: Signal handler return type, currently hardcoded to 'void'
 155 set(RETSIGTYPE void)
 156
 157 if( LLVM_ENABLE_THREADS )
 158   if( HAVE_PTHREAD_H OR WIN32 )
 159     set(ENABLE_THREADS 1)
 160   endif()
 161 endif()
 162
 163 if( ENABLE_THREADS )
 164   message(STATUS "Threads enabled.")
 165 else( ENABLE_THREADS )
 166   message(STATUS "Threads disabled.")
 167 endif()
 168
 169 configure_file(
 170   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 171   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 172   )
 173
 174 configure_file(
 175   ${LLVM_MAIN_INCLUDE_DIR}/llvm/ADT/iterator.cmake
 176   ${LLVM_BINARY_DIR}/include/llvm/ADT/iterator.h
 177   )
 178
 179 configure_file(
 180   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 181   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 182   )
 183