cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckCXXSourceCompiles)
  11 include(TestBigEndian)
  12
  13 if( UNIX AND NOT BEOS )
  14   # Used by check_symbol_exists:
  15   set(CMAKE_REQUIRED_LIBRARIES m)
  16 endif()
  17
  18 # Helper macros and functions
  19 macro(add_cxx_include result files)
  20   set(${result} "")
  21   foreach (file_name ${files})
  22      set(${result} "${${result}}#include<${file_name}>\n")
  23   endforeach()
  24 endmacro(add_cxx_include files result)
  25
  26 function(check_type_exists type files variable)
  27   add_cxx_include(includes "${files}")
  28   CHECK_CXX_SOURCE_COMPILES("
  29     ${includes} ${type} typeVar;
  30     int main() {
  31         return 0;
  32     }
  33     " ${variable})
  34 endfunction()
  35
  36 # include checks
  37 check_include_file(argz.h HAVE_ARGZ_H)
  38 check_include_file(assert.h HAVE_ASSERT_H)
  39 check_include_file(ctype.h HAVE_CTYPE_H)
  40 check_include_file(dirent.h HAVE_DIRENT_H)
  41 check_include_file(dl.h HAVE_DL_H)
  42 check_include_file(dld.h HAVE_DLD_H)
  43 check_include_file(dlfcn.h HAVE_DLFCN_H)
  44 check_include_file(errno.h HAVE_ERRNO_H)
  45 check_include_file(execinfo.h HAVE_EXECINFO_H)
  46 check_include_file(fcntl.h HAVE_FCNTL_H)
  47 check_include_file(inttypes.h HAVE_INTTYPES_H)
  48 check_include_file(limits.h HAVE_LIMITS_H)
  49 check_include_file(link.h HAVE_LINK_H)
  50 check_include_file(malloc.h HAVE_MALLOC_H)
  51 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  52 check_include_file(memory.h HAVE_MEMORY_H)
  53 check_include_file(ndir.h HAVE_NDIR_H)
  54 if( NOT PURE_WINDOWS )
  55   check_include_file(pthread.h HAVE_PTHREAD_H)
  56 endif()
  57 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  58 check_include_file(setjmp.h HAVE_SETJMP_H)
  59 check_include_file(signal.h HAVE_SIGNAL_H)
  60 check_include_file(stdint.h HAVE_STDINT_H)
  61 check_include_file(stdio.h HAVE_STDIO_H)
  62 check_include_file(stdlib.h HAVE_STDLIB_H)
  63 check_include_file(string.h HAVE_STRING_H)
  64 check_include_file(strings.h HAVE_STRINGS_H)
  65 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  66 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  67 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  68 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  69 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  70 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  71 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  72 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  73 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  74 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  75 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  76 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  77 check_include_file(termios.h HAVE_TERMIOS_H)
  78 check_include_file(unistd.h HAVE_UNISTD_H)
  79 check_include_file(utime.h HAVE_UTIME_H)
  80 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  81 check_include_file(windows.h HAVE_WINDOWS_H)
  82 check_include_file(zlib.h HAVE_ZLIB_H)
  83 check_include_file(fenv.h HAVE_FENV_H)
  84 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  85 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  86
  87 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  88 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  89
  90 # library checks
  91 if( NOT PURE_WINDOWS )
  92   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  93   if (HAVE_LIBPTHREAD)
  94     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  95     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  96     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  97   else()
  98     # this could be Android
  99     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
 100     if (PTHREAD_IN_LIBC)
 101       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
 102       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
 103       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 104     endif()
 105   endif()
 106   check_library_exists(dl dlopen "" HAVE_LIBDL)
 107   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 108   if (LLVM_ENABLE_ZLIB)
 109     check_library_exists(z compress2 "" HAVE_LIBZ)
 110   else()
 111     set(HAVE_LIBZ 0)
 112   endif()
 113 endif()
 114
 115 # function checks
 116 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 117 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 118 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 119 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 120 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 121 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 122 check_symbol_exists(index strings.h HAVE_INDEX)
 123 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 124 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 125 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 126 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 127 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 128 check_symbol_exists(ceilf math.h HAVE_CEILF)
 129 check_symbol_exists(floorf math.h HAVE_FLOORF)
 130 check_symbol_exists(fmodf math.h HAVE_FMODF)
 131 check_symbol_exists(log math.h HAVE_LOG)
 132 check_symbol_exists(log2 math.h HAVE_LOG2)
 133 check_symbol_exists(log10 math.h HAVE_LOG10)
 134 check_symbol_exists(exp math.h HAVE_EXP)
 135 check_symbol_exists(exp2 math.h HAVE_EXP2)
 136 check_symbol_exists(exp10 math.h HAVE_EXP10)
 137 if( HAVE_SETJMP_H )
 138   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 139   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 140   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 141   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 142 endif()
 143 if( HAVE_SYS_UIO_H )
 144   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 145 endif()
 146 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 147 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 148 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 149                     HAVE_MALLOC_ZONE_STATISTICS)
 150 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 151 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 152 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 153 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 154 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 155 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 156 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 157 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 158 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 159 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 160 check_symbol_exists(pread unistd.h HAVE_PREAD)
 161 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 162 check_symbol_exists(strchr string.h HAVE_STRCHR)
 163 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 164 check_symbol_exists(strdup string.h HAVE_STRDUP)
 165 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 166 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 167 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 168 if( HAVE_RAND48_SRAND48 )
 169   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 170   if( HAVE_RAND48_LRAND48 )
 171     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 172     if( HAVE_RAND48_DRAND48 )
 173       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 174     endif()
 175   endif()
 176 endif()
 177 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 178 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 179 check_symbol_exists(strerror string.h HAVE_STRERROR)
 180 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 181 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 182 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 183 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 184 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 185 if( PURE_WINDOWS )
 186   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 187
 188   check_function_exists(_alloca HAVE__ALLOCA)
 189   check_function_exists(__alloca HAVE___ALLOCA)
 190   check_function_exists(__chkstk HAVE___CHKSTK)
 191   check_function_exists(___chkstk HAVE____CHKSTK)
 192
 193   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 194   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 195   check_function_exists(__divdi3 HAVE___DIVDI3)
 196   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 197   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 198   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 199   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 200   check_function_exists(__moddi3 HAVE___MODDI3)
 201   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 202   check_function_exists(__umoddi3 HAVE___UMODDI3)
 203
 204   check_function_exists(__main HAVE___MAIN)
 205   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 206 endif()
 207 if( HAVE_ARGZ_H )
 208   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 209   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 210   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 211   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 212   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 213 endif()
 214 if( HAVE_DLFCN_H )
 215   if( HAVE_LIBDL )
 216     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 217   endif()
 218   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 219   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 220   if( HAVE_LIBDL )
 221     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 222   endif()
 223 endif()
 224
 225 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 226 if( LLVM_USING_GLIBC )
 227   add_llvm_definitions( -D_GNU_SOURCE )
 228 endif()
 229
 230 set(headers "")
 231 if (HAVE_SYS_TYPES_H)
 232   set(headers ${headers} "sys/types.h")
 233 endif()
 234
 235 if (HAVE_INTTYPES_H)
 236   set(headers ${headers} "inttypes.h")
 237 endif()
 238
 239 if (HAVE_STDINT_H)
 240   set(headers ${headers} "stdint.h")
 241 endif()
 242
 243 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 244 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 245 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 246 check_type_exists(error_t errno.h HAVE_ERROR_T)
 247
 248 # available programs checks
 249 function(llvm_find_program name)
 250   string(TOUPPER ${name} NAME)
 251   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 252   find_program(LLVM_PATH_${NAME} ${name})
 253   mark_as_advanced(LLVM_PATH_${NAME})
 254   if(LLVM_PATH_${NAME})
 255     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 256     mark_as_advanced(HAVE_${NAME})
 257   else(LLVM_PATH_${NAME})
 258     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 259   endif(LLVM_PATH_${NAME})
 260 endfunction()
 261
 262 llvm_find_program(gv)
 263 llvm_find_program(circo)
 264 llvm_find_program(twopi)
 265 llvm_find_program(neato)
 266 llvm_find_program(fdp)
 267 llvm_find_program(dot)
 268 llvm_find_program(dotty)
 269 llvm_find_program(xdot.py)
 270 llvm_find_program(Graphviz)
 271
 272 if( LLVM_ENABLE_FFI )
 273   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 274   if( FFI_INCLUDE_PATH )
 275     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 276     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 277   else()
 278     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 279     if( FFI_INCLUDE_PATH )
 280       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 281       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 282     endif()
 283   endif()
 284
 285   if( NOT FFI_HEADER )
 286     message(FATAL_ERROR "libffi includes are not found.")
 287   endif()
 288
 289   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 290   if( NOT FFI_LIBRARY_PATH )
 291     message(FATAL_ERROR "libffi is not found.")
 292   endif()
 293
 294   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 295   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 296   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 297   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 298   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 299 else()
 300   unset(HAVE_FFI_FFI_H CACHE)
 301   unset(HAVE_FFI_H CACHE)
 302   unset(HAVE_FFI_CALL CACHE)
 303 endif( LLVM_ENABLE_FFI )
 304
 305 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 306 include(CheckAtomic)
 307
 308 if( LLVM_ENABLE_PIC )
 309   set(ENABLE_PIC 1)
 310 else()
 311   set(ENABLE_PIC 0)
 312 endif()
 313
 314 find_package(LibXml2)
 315 if (LIBXML2_FOUND)
 316   set(CLANG_HAVE_LIBXML 1)
 317 endif ()
 318
 319 include(CheckCXXCompilerFlag)
 320
 321 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 322
 323 set(USE_NO_MAYBE_UNINITIALIZED 0)
 324 set(USE_NO_UNINITIALIZED 0)
 325
 326 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 327 # false positives.
 328 if (CMAKE_COMPILER_IS_GNUCXX)
 329   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 330   if (HAS_MAYBE_UNINITIALIZED)
 331     set(USE_NO_MAYBE_UNINITIALIZED 1)
 332   else()
 333     # Only recent versions of gcc make the distinction between -Wuninitialized
 334     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 335     # turn off all uninitialized use warnings.
 336     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 337     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 338   endif()
 339 endif()
 340
 341 include(GetHostTriple)
 342 get_host_triple(LLVM_HOST_TRIPLE)
 343
 344 # By default, we target the host, but this can be overridden at CMake
 345 # invocation time.
 346 set(LLVM_HOSTTRIPLE "${LLVM_HOST_TRIPLE}")
 347
 348 # Determine the native architecture.
 349 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 350 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 351   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 352 endif ()
 353
 354 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 355   set(LLVM_NATIVE_ARCH X86)
 356 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 357   set(LLVM_NATIVE_ARCH X86)
 358 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 359   set(LLVM_NATIVE_ARCH X86)
 360 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 361   set(LLVM_NATIVE_ARCH X86)
 362 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 363   set(LLVM_NATIVE_ARCH Sparc)
 364 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 365   set(LLVM_NATIVE_ARCH PowerPC)
 366 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 367   set(LLVM_NATIVE_ARCH ARM)
 368 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 369   set(LLVM_NATIVE_ARCH Mips)
 370 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 371   set(LLVM_NATIVE_ARCH XCore)
 372 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 373   set(LLVM_NATIVE_ARCH MSP430)
 374 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 375   set(LLVM_NATIVE_ARCH Hexagon)
 376 else ()
 377   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 378 endif ()
 379
 380 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 381 if (NATIVE_ARCH_IDX EQUAL -1)
 382   message(STATUS
 383     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 384 else ()
 385   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 386   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 387   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 388   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 389   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 390
 391   # We don't have an ASM parser for all architectures yet.
 392   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 393     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 394   endif ()
 395
 396   # We don't have an disassembler for all architectures yet.
 397   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 398     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 399   endif ()
 400 endif ()
 401
 402 if( MINGW )
 403   set(HAVE_LIBIMAGEHLP 1)
 404   set(HAVE_LIBPSAPI 1)
 405   # TODO: Check existence of libraries.
 406   #   include(CheckLibraryExists)
 407   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 408 endif( MINGW )
 409
 410 if( MSVC )
 411   set(error_t int)
 412   set(LTDL_SHLIBPATH_VAR "PATH")
 413   set(LTDL_SYSSEARCHPATH "")
 414   set(LTDL_DLOPEN_DEPLIBS 1)
 415   set(SHLIBEXT ".lib")
 416   set(LTDL_OBJDIR "_libs")
 417   set(HAVE_STRTOLL 1)
 418   set(strtoll "_strtoi64")
 419   set(strtoull "_strtoui64")
 420   set(stricmp "_stricmp")
 421   set(strdup "_strdup")
 422 else( MSVC )
 423   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 424   set(LTDL_SYSSEARCHPATH "") # TODO
 425   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 426 endif( MSVC )
 427
 428 if( PURE_WINDOWS )
 429   CHECK_CXX_SOURCE_COMPILES("
 430     #include <windows.h>
 431     #include <imagehlp.h>
 432     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 433     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 434     int main(){return 0;}"
 435     HAVE_ELMCB_PCSTR)
 436   if( HAVE_ELMCB_PCSTR )
 437     set(WIN32_ELMCB_PCSTR "PCSTR")
 438   else()
 439     set(WIN32_ELMCB_PCSTR "PSTR")
 440   endif()
 441 endif( PURE_WINDOWS )
 442
 443 # FIXME: Signal handler return type, currently hardcoded to 'void'
 444 set(RETSIGTYPE void)
 445
 446 if( LLVM_ENABLE_THREADS )
 447   # Check if threading primitives aren't supported on this platform
 448   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 449     set(LLVM_ENABLE_THREADS 0)
 450   endif()
 451 endif()
 452
 453 if( LLVM_ENABLE_THREADS )
 454   message(STATUS "Threads enabled.")
 455 else( LLVM_ENABLE_THREADS )
 456   message(STATUS "Threads disabled.")
 457 endif()
 458
 459 if (LLVM_ENABLE_ZLIB )
 460   # Check if zlib is available in the system.
 461   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 462     set(LLVM_ENABLE_ZLIB 0)
 463   endif()
 464 endif()
 465
 466 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})