build/cmake/TargetArch.cmake

   1 # Source: https://github.com/axr/solar-cmake
   2 # Based on the Qt 5 processor detection code, so should be very accurate
   3 # https://qt.gitorious.org/qt/qtbase/blobs/master/src/corelib/global/qprocessordetection.h
   4 # Currently handles arm (v5, v6, v7), x86 (32/64), ia64, and ppc (32/64)
   5
   6 # Regarding POWER/PowerPC, just as is noted in the Qt source,
   7 # "There are many more known variants/revisions that we do not handle/detect."
   8
   9 set(archdetect_c_code "
  10 #if defined(__arm__) || defined(__TARGET_ARCH_ARM)
  11     #if defined(__ARM_ARCH_7__) \\
  12         || defined(__ARM_ARCH_7A__) \\
  13         || defined(__ARM_ARCH_7R__) \\
  14         || defined(__ARM_ARCH_7M__) \\
  15         || (defined(__TARGET_ARCH_ARM) && __TARGET_ARCH_ARM-0 >= 7)
  16         #error cmake_ARCH armv7
  17     #elif defined(__ARM_ARCH_6__) \\
  18         || defined(__ARM_ARCH_6J__) \\
  19         || defined(__ARM_ARCH_6T2__) \\
  20         || defined(__ARM_ARCH_6Z__) \\
  21         || defined(__ARM_ARCH_6K__) \\
  22         || defined(__ARM_ARCH_6ZK__) \\
  23         || defined(__ARM_ARCH_6M__) \\
  24         || (defined(__TARGET_ARCH_ARM) && __TARGET_ARCH_ARM-0 >= 6)
  25         #error cmake_ARCH armv6
  26     #elif defined(__ARM_ARCH_5TEJ__) \\
  27         || (defined(__TARGET_ARCH_ARM) && __TARGET_ARCH_ARM-0 >= 5)
  28         #error cmake_ARCH armv5
  29     #else
  30         #error cmake_ARCH arm
  31     #endif
  32 #elif defined(__i386) || defined(__i386__) || defined(_M_IX86)
  33     #error cmake_ARCH i386
  34 #elif defined(__x86_64) || defined(__x86_64__) || defined(__amd64) || defined(_M_X64)
  35     #error cmake_ARCH x86_64
  36 #elif defined(__ia64) || defined(__ia64__) || defined(_M_IA64)
  37     #error cmake_ARCH ia64
  38 #elif defined(__ppc__) || defined(__ppc) || defined(__powerpc__) \\
  39       || defined(_ARCH_COM) || defined(_ARCH_PWR) || defined(_ARCH_PPC)  \\
  40       || defined(_M_MPPC) || defined(_M_PPC)
  41     #if defined(__ppc64__) || defined(__powerpc64__) || defined(__64BIT__)
  42         #error cmake_ARCH ppc64
  43     #else
  44         #error cmake_ARCH ppc
  45     #endif
  46 #endif
  47
  48 #error cmake_ARCH unknown
  49 ")
  50
  51 # Set ppc_support to TRUE before including this file or ppc and ppc64
  52 # will be treated as invalid architectures since they are no longer supported by Apple
  53
  54 function(target_architecture output_var)
  55     if(APPLE AND CMAKE_OSX_ARCHITECTURES)
  56         # On OS X we use CMAKE_OSX_ARCHITECTURES *if* it was set
  57         # First let's normalize the order of the values
  58
  59         # Note that it's not possible to compile PowerPC applications if you are using
  60         # the OS X SDK version 10.6 or later - you'll need 10.4/10.5 for that, so we
  61         # disable it by default
  62         # See this page for more information:
  63         # http://stackoverflow.com/questions/5333490/how-can-we-restore-ppc-ppc64-as-well-as-full-10-4-10-5-sdk-support-to-xcode-4
  64
  65         # Architecture defaults to i386 or ppc on OS X 10.5 and earlier, depending on the CPU type detected at runtime.
  66         # On OS X 10.6+ the default is x86_64 if the CPU supports it, i386 otherwise.
  67
  68         foreach(osx_arch ${CMAKE_OSX_ARCHITECTURES})
  69             if("${osx_arch}" STREQUAL "ppc" AND ppc_support)
  70                 set(osx_arch_ppc TRUE)
  71             elseif("${osx_arch}" STREQUAL "i386")
  72                 set(osx_arch_i386 TRUE)
  73             elseif("${osx_arch}" STREQUAL "x86_64")
  74                 set(osx_arch_x86_64 TRUE)
  75             elseif("${osx_arch}" STREQUAL "ppc64" AND ppc_support)
  76                 set(osx_arch_ppc64 TRUE)
  77             else()
  78                 message(FATAL_ERROR "Invalid OS X arch name: ${osx_arch}")
  79             endif()
  80         endforeach()
  81
  82         # Now add all the architectures in our normalized order
  83         if(osx_arch_ppc)
  84             list(APPEND ARCH ppc)
  85         endif()
  86
  87         if(osx_arch_i386)
  88             list(APPEND ARCH i386)
  89         endif()
  90
  91         if(osx_arch_x86_64)
  92             list(APPEND ARCH x86_64)
  93         endif()
  94
  95         if(osx_arch_ppc64)
  96             list(APPEND ARCH ppc64)
  97         endif()
  98     else()
  99         file(WRITE "${CMAKE_BINARY_DIR}/arch.c" "${archdetect_c_code}")
 100
 101         enable_language(C)
 102
 103         # Detect the architecture in a rather creative way...
 104         # This compiles a small C program which is a series of ifdefs that selects a
 105         # particular #error preprocessor directive whose message string contains the
 106         # target architecture. The program will always fail to compile (both because
 107         # file is not a valid C program, and obviously because of the presence of the
 108         # #error preprocessor directives... but by exploiting the preprocessor in this
 109         # way, we can detect the correct target architecture even when cross-compiling,
 110         # since the program itself never needs to be run (only the compiler/preprocessor)
 111         try_run(
 112             run_result_unused
 113             compile_result_unused
 114             "${CMAKE_BINARY_DIR}"
 115             "${CMAKE_BINARY_DIR}/arch.c"
 116             COMPILE_OUTPUT_VARIABLE ARCH
 117             CMAKE_FLAGS CMAKE_OSX_ARCHITECTURES=${CMAKE_OSX_ARCHITECTURES}
 118         )
 119
 120         # Parse the architecture name from the compiler output
 121         string(REGEX MATCH "cmake_ARCH ([a-zA-Z0-9_]+)" ARCH "${ARCH}")
 122
 123         # Get rid of the value marker leaving just the architecture name
 124         string(REPLACE "cmake_ARCH " "" ARCH "${ARCH}")
 125
 126         # If we are compiling with an unknown architecture this variable should
 127         # already be set to "unknown" but in the case that it's empty (i.e. due
 128         # to a typo in the code), then set it to unknown
 129         if (NOT ARCH)
 130             set(ARCH unknown)
 131         endif()
 132     endif()
 133
 134     set(${output_var} "${ARCH}" PARENT_SCOPE)
 135 endfunction()