autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.5cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-interix*)
 116     llvm_cv_os_type="Interix"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-linux*)
 119     llvm_cv_os_type="Linux"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-solaris*)
 122     llvm_cv_os_type="SunOS"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-win32*)
 125     llvm_cv_os_type="Win32"
 126     llvm_cv_platform_type="Win32" ;;
 127   *-*-mingw*)
 128     llvm_cv_os_type="MingW"
 129     llvm_cv_platform_type="Win32" ;;
 130   *)
 131     llvm_cv_os_type="Unknown"
 132     llvm_cv_platform_type="Unknown" ;;
 133 esac])
 134
 135 dnl Make sure we aren't attempting to configure for an unknown system
 136 if test "$llvm_cv_os_type" = "Unknown" ; then
 137   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 138 fi
 139
 140 dnl Set the "OS" Makefile variable based on the platform type so the
 141 dnl makefile can configure itself to specific build hosts
 142 AC_SUBST(OS,$llvm_cv_os_type)
 143
 144 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 145 dnl This is used by lib/System to determine the basic kind of implementation
 146 dnl to use.
 147 case $llvm_cv_platform_type in
 148   Unix)
 149     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 150     AC_SUBST(LLVM_ON_UNIX,[1])
 151     AC_SUBST(LLVM_ON_WIN32,[0])
 152     ;;
 153   Win32)
 154     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 155     AC_SUBST(LLVM_ON_UNIX,[0])
 156     AC_SUBST(LLVM_ON_WIN32,[1])
 157     ;;
 158 esac
 159
 160 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 161 dnl V9, since that is all that we support at the moment, and autoconf will only
 162 dnl tell us we're a sparc.
 163 case $target in
 164   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 165   ;;
 166 esac
 167
 168 dnl Determine what our target architecture is and configure accordingly.
 169 dnl This will allow Makefiles to make a distinction between the hardware and
 170 dnl the OS.
 171 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 172 [case $target in
 173   i?86-*)                 llvm_cv_target_arch="x86" ;;
 174   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 175   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 176   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 177   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 178   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 179   *)                      llvm_cv_target_arch="Unknown" ;;
 180 esac])
 181
 182 if test "$llvm_cv_target_arch" = "Unknown" ; then
 183   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 184 fi
 185
 186 dnl Define a substitution, ARCH, for the target architecture
 187 AC_SUBST(ARCH,$llvm_cv_target_arch)
 188
 189 dnl Check for the endianness of the target
 190 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 191
 192 dnl===-----------------------------------------------------------------------===
 193 dnl===
 194 dnl=== SECTION 3: Command line arguments for the configure script.
 195 dnl===
 196 dnl===-----------------------------------------------------------------------===
 197
 198 dnl --enable-optimized : check whether they want to do an optimized build:
 199 AC_ARG_ENABLE(optimized,
 200               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 201 if test ${enableval} = "no" ; then
 202   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 203 else
 204   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 205 fi
 206
 207 dnl --enable-jit: check whether they want to enable the jit
 208 AC_ARG_ENABLE(jit,
 209   AS_HELP_STRING(--enable-jit,
 210                  [Enable Just In Time Compiling (default is YES)]),,
 211   enableval=default)
 212 if test ${enableval} = "no"
 213 then
 214   AC_SUBST(JIT,[[]])
 215 else
 216   case "$llvm_cv_target_arch" in
 217     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 218     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 219     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 220     x86_64)  AC_SUBST(JIT,[[]]) ;;
 221     Alpha)   AC_SUBST(JIT,[[]]) ;;
 222     IA64)    AC_SUBST(JIT,[[]]) ;;
 223     *)       AC_SUBST(JIT,[[]]) ;;
 224   esac
 225 fi
 226
 227 dnl Allow enablement of doxygen generated documentation
 228 AC_ARG_ENABLE(doxygen,
 229               AS_HELP_STRING([--enable-doxygen],
 230                              [Build doxygen documentation (default is NO)]),,
 231                              enableval=default)
 232 case "$enableval" in
 233   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 234   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 235   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 236   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 237 esac
 238
 239 dnl Allow specific targets to be specified for building (or not)
 240 TARGETS_TO_BUILD=""
 241 AC_ARG_ENABLE([target-this],AS_HELP_STRING([--enable-target-this],
 242 [Build only the current host's target (default is NO)]),,enable_target_this=no)
 243 AC_ARG_ENABLE([target-x86],AS_HELP_STRING([--enable-target-x86],
 244 [Build the x86 target (default is YES)]),,enable_target_x86=yes)
 245 AC_ARG_ENABLE([target-x86-64],AS_HELP_STRING([--enable-target-x86-64],
 246 [Build the x86_64 target (default is YES)]),,enable_target_x86_64=yes)
 247 AC_ARG_ENABLE([target-sparc],AS_HELP_STRING([--enable-target-sparc],
 248 [Build the Sparc target (default is YES)]),,enable_target_sparc=yes)
 249 AC_ARG_ENABLE([target-powerpc],AS_HELP_STRING([--enable-target-powerpc],
 250 [Build the PowerPC target (default is YES)]),,enable_target_powerpc=yes)
 251 AC_ARG_ENABLE([target-alpha],AS_HELP_STRING([--enable-target-alpha],
 252 [Build the Alpha target (default is YES)]),,enable_target_alpha=yes)
 253 AC_ARG_ENABLE(]target-ia64],AS_HELP_STRING([--enable-target-ia64],
 254 [Build the IA64 target (default is YES)]),,enable_target_ia64=yes)
 255
 256 if test "$enable_target_this" = "yes" ; then
 257   case "$llvm_cv_target_arch" in
 258     x86)     TARGETS_TO_BUILD="X86" ;;
 259     x86_64)  TARGETS_TO_BUILD="X86" ;;
 260     Sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9" ;;
 261     PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 262     Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 263     IA64)    TARGETS_TO_BUILD="IA64" ;;
 264     *)       AC_MSG_ERROR([Can not set target to build]) ;;
 265   esac
 266 else
 267   if test "$enable_target_x86" = "yes" -o "$enable_target_x86_64" = "yes" ; then
 268     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD"
 269   fi
 270   if test "$enable_target_sparc" = "yes" ; then
 271     TARGETS_TO_BUILD="SparcV8 SparcV9 $TARGETS_TO_BUILD"
 272   fi
 273   if test "$enable_target_powerpc" = "yes" ; then
 274     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD"
 275   fi
 276   if test "$enable_target_alpha" = "yes" ; then
 277     TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD"
 278   fi
 279   if test "$enable_target_ia64" = "yes" ; then
 280     TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD"
 281   fi
 282 fi
 283
 284 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 285
 286 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 287 AC_ARG_WITH(llvmgccdir,
 288   AS_HELP_STRING([--with-llvmgccdir],
 289     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 290     withval=default)
 291 case "$withval" in
 292   default) WITH_LLVMGCCDIR=default ;;
 293   /*)      WITH_LLVMGCCDIR=$withval ;;
 294   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 295 esac
 296
 297
 298 dnl===-----------------------------------------------------------------------===
 299 dnl===
 300 dnl=== SECTION 4: Check for programs we need and that they are the right version
 301 dnl===
 302 dnl===-----------------------------------------------------------------------===
 303
 304 dnl Check for compilation tools
 305 AC_PROG_CPP
 306 AC_PROG_CC(gcc)
 307 AC_PROG_CXX(g++)
 308 AC_PROG_FLEX
 309 AC_PROG_BISON
 310
 311 dnl Check for the tools that the makefiles require
 312 AC_CHECK_GNU_MAKE
 313 AC_PROG_LN_S
 314 AC_PATH_PROG(CMP, [cmp], [cmp])
 315 AC_PATH_PROG(CP, [cp], [cp])
 316 AC_PATH_PROG(DATE, [date], [date])
 317 AC_PATH_PROG(FIND, [find], [find])
 318 AC_PATH_PROG(GREP, [grep], [grep])
 319 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 320 AC_PATH_PROG(MV,   [mv],   [mv])
 321 AC_PROG_RANLIB
 322 AC_PATH_PROG(RM,   [rm],   [rm])
 323 AC_PATH_PROG(SED,  [sed],  [sed])
 324 AC_PATH_PROG(TAR,  [tar],  [gtar])
 325
 326 dnl Find the install program
 327 AC_PROG_INSTALL
 328
 329 dnl Checks for documentation and testing tools that we can do without. If these
 330 dnl are not found then they are set to "true" which always succeeds but does
 331 dnl nothing. This just lets the build output show that we could have done
 332 dnl something if the tool was available.
 333 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 334 AC_PATH_PROG(DOT,[dot],[true dot])
 335 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 336 AC_PATH_PROG(ETAGS,[etags],[true etags])
 337 AC_PATH_PROG(GROFF,[groff],[true groff])
 338 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 339 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 340 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 341 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 342 DJ_AC_PATH_TCLSH
 343 AC_PATH_PROG(ZIP,[zip],[true zip])
 344
 345 dnl Determine if the linker supports the -R option.
 346 AC_LINK_USE_R
 347
 348 dnl Check for libtool and the library that has dlopen function (which must come
 349 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 350 dnl libtool).
 351 AC_LIBTOOL_DLOPEN
 352 AC_LIB_LTDL
 353 AC_PROG_LIBTOOL
 354
 355 if test "$lt_cv_dlopen_self" = "yes" ; then
 356   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 357               [Define if dlopen(0) will open the symbols of the program])
 358 fi
 359
 360 dnl Check if we know how to tell etags we are using C++:
 361 etags_version=`$ETAGS --version 2>&1`
 362 case "$etags_version" in
 363         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 364         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 365         *) ETAGSFLAGS="" ;;
 366 esac
 367 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 368
 369 if test "$WITH_LLVMGCCDIR" = "default" ; then
 370   AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
 371   AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
 372 else
 373   LLVMGCC=$WITH_LLVMGCCDIR/bin/llvm-gcc
 374   LLVMGXX=$WITH_LLVMGCCDIR/bin/llvm-g++
 375   AC_SUBST(LLVMGCC,$LLVMGCC)
 376   AC_SUBST(LLVMGXX,$LLVMGXX)
 377 fi
 378
 379 AC_MSG_CHECKING([tool compatibility])
 380
 381 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 382 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 383 dnl to support those options.
 384 dnl "icc" emits gcc signatures
 385 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 386 ICC=no
 387 IXX=no
 388 case $CC in
 389   icc*|icpc*)
 390     ICC=yes
 391     IXX=yes
 392     ;;
 393    *)
 394     ;;
 395 esac
 396
 397 if test "$GCC" != "yes" && test "$ICC" != "yes"
 398 then
 399   AC_MSG_ERROR([gcc|icc required but not found])
 400 fi
 401
 402 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 403 if test "$GXX" != "yes" && test "$IXX" != "yes"
 404 then
 405   AC_MSG_ERROR([g++|icc required but not found])
 406 fi
 407
 408 dnl Verify that GCC is version 3.0 or higher
 409 if test "$GCC" = "yes"
 410 then
 411   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 412   if test "$gccmajor" -lt "3"
 413   then
 414     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 415   fi
 416 fi
 417
 418 dnl Check for GNU Make.  We use its extensions, so don't build without it
 419 if test -z "$llvm_cv_gnu_make_command"
 420 then
 421   AC_MSG_ERROR([GNU Make required but not found])
 422 fi
 423
 424 dnl Tool compatibility is okay if we make it here.
 425 AC_MSG_RESULT([ok])
 426
 427 dnl===-----------------------------------------------------------------------===
 428 dnl===
 429 dnl=== SECTION 5: Check for libraries
 430 dnl===
 431 dnl===-----------------------------------------------------------------------===
 432
 433 dnl libelf is for sparc only; we can ignore it if we don't have it
 434 AC_CHECK_LIB(elf, elf_begin)
 435
 436 dnl lt_dlopen may be required for plugin support.
 437 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 438               [Define if lt_dlopen() is available on this platform]),
 439               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 440                            not be available]))
 441
 442 dnl dlopen() is required for plugin support.
 443 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 444                [Define if dlopen() is available on this platform.]),
 445                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 446
 447 dnl mallinfo is optional; the code can compile (minus features) without it
 448 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 449                [Define if mallinfo() is available on this platform.]))
 450
 451 dnl pthread locking functions are optional - but llvm will not be thread-safe
 452 dnl without locks.
 453 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 454                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 455                          [Have pthread_mutex_lock]))
 456
 457 dnl===-----------------------------------------------------------------------===
 458 dnl===
 459 dnl=== SECTION 6: Check for header files
 460 dnl===
 461 dnl===-----------------------------------------------------------------------===
 462
 463 dnl First, use autoconf provided macros for specific headers that we need
 464 dnl We don't check for ancient stuff or things that are guaranteed to be there
 465 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 466 dnl Generally we're looking for POSIX headers.
 467 AC_HEADER_DIRENT
 468 AC_HEADER_MMAP_ANONYMOUS
 469 AC_HEADER_STAT
 470 AC_HEADER_STDC
 471 AC_HEADER_SYS_WAIT
 472 AC_HEADER_TIME
 473
 474 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 475 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 476 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 477 AC_CHECK_HEADERS([rw/stdex/hash_map.h rw/stdex/hash_set.h])
 478
 479 dnl===-----------------------------------------------------------------------===
 480 dnl===
 481 dnl=== SECTION 7: Check for types and structures
 482 dnl===
 483 dnl===-----------------------------------------------------------------------===
 484
 485 AC_TYPE_PID_T
 486 AC_TYPE_SIZE_T
 487 AC_TYPE_SIGNAL
 488 AC_STRUCT_TM
 489 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 490 AC_CHECK_TYPES([uint64_t],,
 491          AC_CHECK_TYPES([u_int64_t],,
 492          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 493
 494 dnl===-----------------------------------------------------------------------===
 495 dnl===
 496 dnl=== SECTION 8: Check for specific functions needed
 497 dnl===
 498 dnl===-----------------------------------------------------------------------===
 499
 500 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 501 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 502 AC_CHECK_FUNCS([realpath sbrk setrlimit strdup strerror strerror_r ])
 503 AC_CHECK_FUNCS([strtoll strtoq sysconf])
 504 AC_C_PRINTF_A
 505 AC_FUNC_ALLOCA
 506 AC_FUNC_RAND48
 507
 508 dnl Check for variations in the Standard C++ library and STL. These macros are
 509 dnl provided by LLVM in the autoconf/m4 directory.
 510 AC_CXX_HAVE_HASH_MAP
 511 AC_CXX_HAVE_HASH_SET
 512 AC_CXX_HAVE_STD_ITERATOR
 513 AC_CXX_HAVE_BI_ITERATOR
 514 AC_CXX_HAVE_FWD_ITERATOR
 515 AC_FUNC_ISNAN
 516 AC_FUNC_ISINF
 517
 518 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 519 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 520 dnl be opened for allocating RWX memory.
 521 AC_FUNC_MMAP
 522 AC_FUNC_MMAP_FILE
 523 AC_NEED_DEV_ZERO_FOR_MMAP
 524 AC_CHECK_FUNC(mprotect,,
 525               AC_MSG_ERROR([Function mprotect() required but not found]))
 526
 527 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 528 then
 529   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 530 fi
 531 if test "$ac_cv_func_mmap_file" = "no"
 532 then
 533   AC_MSG_WARN([mmap() of files required but not found])
 534 fi
 535
 536 dnl===-----------------------------------------------------------------------===
 537 dnl===
 538 dnl=== SECTION 9: Additional checks, variables, etc.
 539 dnl===
 540 dnl===-----------------------------------------------------------------------===
 541
 542 dnl See if the llvm-gcc executable can compile to LLVM assembly
 543 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 544 [llvm_cv_llvmgcc_sanity="no"
 545 if test -x "$LLVMGCC" ; then
 546   cp /dev/null conftest.c
 547   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 548   if test $? -eq 0 ; then
 549     llvm_cv_llvmgcc_sanity="yes"
 550   fi
 551   rm conftest.c
 552 fi])
 553
 554 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 555 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 556   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 557   AC_SUBST(LLVMCC1,$llvmcc1path)
 558   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 559   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 560   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 561   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 562 fi
 563
 564 dnl Propagate the shared library extension that the libltdl checks did to
 565 dnl the Makefiles so we can use it there too
 566 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 567
 568 # Translate the various configuration directories and other basic
 569 # information into substitutions that will end up in Makefile.config.in
 570 # that these configured values can be used by the makefiles
 571 eval LLVM_PREFIX="${prefix}";
 572 eval LLVM_BINDIR="${prefix}/bin";
 573 eval LLVM_LIBDIR="${prefix}/lib";
 574 eval LLVM_DATADIR="${prefix}/share/llvm";
 575 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 576 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 577 eval LLVM_INCLUDEDIR="${prefix}/include";
 578 eval LLVM_INFODIR="${prefix}/info";
 579 eval LLVM_MANDIR="${prefix}/man";
 580 LLVM_CONFIGTIME=`date`
 581 AC_SUBST(LLVM_PREFIX)
 582 AC_SUBST(LLVM_BINDIR)
 583 AC_SUBST(LLVM_LIBDIR)
 584 AC_SUBST(LLVM_DATADIR)
 585 AC_SUBST(LLVM_DOCSDIR)
 586 AC_SUBST(LLVM_ETCDIR)
 587 AC_SUBST(LLVM_INCLUDEDIR)
 588 AC_SUBST(LLVM_INFODIR)
 589 AC_SUBST(LLVM_MANDIR)
 590 AC_SUBST(LLVM_CONFIGTIME)
 591
 592 # Place the various directores into the config.h file as #defines so that we
 593 # can know about the installation paths within LLVM.
 594 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 595                    [Installation prefix directory])
 596 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 597                    [Installation directory for binary executables])
 598 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 599                    [Installation directory for libraries])
 600 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 601                    [Installation directory for data files])
 602 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 603                    [Installation directory for documentation])
 604 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 605                    [Installation directory for config files])
 606 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 607                    [Installation directory for include files])
 608 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 609                    [Installation directory for .info files])
 610 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 611                    [Installation directory for man pages])
 612 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 613                    [Time at which LLVM was configured])
 614
 615 dnl===-----------------------------------------------------------------------===
 616 dnl===
 617 dnl=== SECTION 10: Specify the output files and generate it
 618 dnl===
 619 dnl===-----------------------------------------------------------------------===
 620
 621 dnl Configure header files
 622 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 623
 624 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 625 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 626 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 627 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 628 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 629
 630 dnl Configure the makefile's configuration data
 631 AC_CONFIG_FILES([Makefile.config])
 632
 633 dnl Configure llvmc's configuration files
 634 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 635
 636 dnl Configure doxygen's configuration file
 637 AC_CONFIG_FILES([docs/doxygen.cfg])
 638
 639 dnl Do special configuration of Makefiles
 640 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 641 AC_CONFIG_MAKEFILE(Makefile)
 642 AC_CONFIG_MAKEFILE(Makefile.common)
 643 AC_CONFIG_MAKEFILE(examples/Makefile)
 644 AC_CONFIG_MAKEFILE(lib/Makefile)
 645 AC_CONFIG_MAKEFILE(runtime/Makefile)
 646 AC_CONFIG_MAKEFILE(test/Makefile)
 647 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 648 AC_CONFIG_MAKEFILE(tools/Makefile)
 649 AC_CONFIG_MAKEFILE(utils/Makefile)
 650 AC_CONFIG_MAKEFILE(projects/Makefile)
 651
 652 dnl Finally, crank out the output
 653 AC_OUTPUT
 654
 655 dnl Warn loudly if llvm-gcc was not obviously working
 656 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 657  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 658  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 659  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 660  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 661  AC_MSG_WARN([***** build the llvm tools.])
 662 fi