autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.9cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "privbracket")  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  73       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_os_type="AIX"
 106     llvm_cv_platform_type="Unix" ;;
 107   *-*-cygwin*)
 108     llvm_cv_os_type="Cygwin"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-darwin*)
 111     llvm_cv_os_type="Darwin"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-freebsd*)
 114     llvm_cv_os_type="FreeBSD"
 115     llvm_cv_platform_type="Unix" ;;
 116   *-*-openbsd*)
 117     llvm_cv_os_type="OpenBSD"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-hpux*)
 120     llvm_cv_os_type="HP-UX"
 121     llvm_cv_platform_type="Unix" ;;
 122   *-*-interix*)
 123     llvm_cv_os_type="Interix"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-linux*)
 126     llvm_cv_os_type="Linux"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-solaris*)
 129     llvm_cv_os_type="SunOS"
 130     llvm_cv_platform_type="Unix" ;;
 131   *-*-win32*)
 132     llvm_cv_os_type="Win32"
 133     llvm_cv_platform_type="Win32" ;;
 134   *-*-mingw*)
 135     llvm_cv_os_type="MingW"
 136     llvm_cv_platform_type="Win32" ;;
 137   *)
 138     llvm_cv_os_type="Unknown"
 139     llvm_cv_platform_type="Unknown" ;;
 140 esac])
 141
 142 dnl Make sure we aren't attempting to configure for an unknown system
 143 if test "$llvm_cv_os_type" = "Unknown" ; then
 144   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 145 fi
 146
 147 dnl Set the "OS" Makefile variable based on the platform type so the
 148 dnl makefile can configure itself to specific build hosts
 149 AC_SUBST(OS,$llvm_cv_os_type)
 150
 151 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 152 dnl This is used by lib/System to determine the basic kind of implementation
 153 dnl to use.
 154 case $llvm_cv_platform_type in
 155   Unix)
 156     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 157     AC_SUBST(LLVM_ON_UNIX,[1])
 158     AC_SUBST(LLVM_ON_WIN32,[0])
 159     ;;
 160   Win32)
 161     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 162     AC_SUBST(LLVM_ON_UNIX,[0])
 163     AC_SUBST(LLVM_ON_WIN32,[1])
 164     ;;
 165 esac
 166
 167 dnl Determine what our target architecture is and configure accordingly.
 168 dnl This will allow Makefiles to make a distinction between the hardware and
 169 dnl the OS.
 170 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 171 [case $target in
 172   i?86-*)                 llvm_cv_target_arch="x86" ;;
 173   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 174   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 175   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 176   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 177   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 178   *)                      llvm_cv_target_arch="Unknown" ;;
 179 esac])
 180
 181 if test "$llvm_cv_target_arch" = "Unknown" ; then
 182   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 183 fi
 184
 185 dnl Define a substitution, ARCH, for the target architecture
 186 AC_SUBST(ARCH,$llvm_cv_target_arch)
 187
 188 dnl Check for the endianness of the target
 189 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 190
 191 dnl Check for build platform executable suffix if we're crosscompiling
 192 if test "$cross_compiling" = yes; then
 193   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 194   AC_BUILD_EXEEXT
 195 else
 196   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 197 fi
 198
 199 dnl Check to see if there's a "CVS" directory indicating that this build is
 200 dnl being done from a CVS checkout. This sets up several defaults for the
 201 dnl command line switches. When we build with a CVS directory, we get a
 202 dnl debug with assertions turned on. Without, we assume a source release and we
 203 dnl get an optimized build without assertions. See --enable-optimized and
 204 dnl --enable-assertions below
 205 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 206   cvsbuild="yes"
 207   optimize="no"
 208   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 209 else
 210   cvsbuild="no"
 211   optimize="yes"
 212 fi
 213
 214 dnl===-----------------------------------------------------------------------===
 215 dnl===
 216 dnl=== SECTION 3: Command line arguments for the configure script.
 217 dnl===
 218 dnl===-----------------------------------------------------------------------===
 219
 220 dnl --enable-optimized : check whether they want to do an optimized build:
 221 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 222  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 223 if test ${enableval} = "no" ; then
 224   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 225 else
 226   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 227 fi
 228
 229 dnl --enable-assertions : check whether they want to turn on assertions or not:
 230 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 231   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 232 if test ${enableval} = "yes" ; then
 233   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 234 else
 235   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 236 fi
 237
 238 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 239 AC_ARG_ENABLE(debug-runtime,
 240    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 241 if test ${enableval} = "no" ; then
 242   AC_SUBST(DEBUG_RUNTIME,[[]])
 243 else
 244   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 245 fi
 246
 247 dnl --enable-jit: check whether they want to enable the jit
 248 AC_ARG_ENABLE(jit,
 249   AS_HELP_STRING(--enable-jit,
 250                  [Enable Just In Time Compiling (default is YES)]),,
 251   enableval=default)
 252 if test ${enableval} = "no"
 253 then
 254   AC_SUBST(JIT,[[]])
 255 else
 256   case "$llvm_cv_target_arch" in
 257     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 258     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 259     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 260     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 261     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 262     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 263     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 264   esac
 265 fi
 266
 267 dnl Allow enablement of doxygen generated documentation
 268 AC_ARG_ENABLE(doxygen,
 269               AS_HELP_STRING([--enable-doxygen],
 270                              [Build doxygen documentation (default is NO)]),,
 271                              enableval=default)
 272 case "$enableval" in
 273   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 274   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 275   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 276   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 277 esac
 278
 279 dnl Allow disablement of threads
 280 AC_ARG_ENABLE(threads,
 281               AS_HELP_STRING([--enable-threads],
 282                              [Use threads if available (default is YES)]),,
 283                              enableval=yes)
 284 case "$enableval" in
 285   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 286   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 287   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 288 esac
 289 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 290
 291 dnl Allow specific targets to be specified for building (or not)
 292 TARGETS_TO_BUILD=""
 293 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 294     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 295     enableval=all)
 296 case "$enableval" in
 297   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 298   host-only)
 299     case "$llvm_cv_target_arch" in
 300       x86)     TARGETS_TO_BUILD="X86" ;;
 301       x86_64)  TARGETS_TO_BUILD="X86" ;;
 302       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 303       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 304       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 305       IA64)    TARGETS_TO_BUILD="IA64" ;;
 306       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 307     esac
 308     ;;
 309   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 310       case "$a_target" in
 311         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 312         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 313         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 314         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 315         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 316         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 317         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 318       esac
 319   done
 320   ;;
 321 esac
 322 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 323 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 324
 325 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 326 AC_ARG_WITH(llvmgccdir,
 327   AS_HELP_STRING([--with-llvmgccdir],
 328     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 329     withval=default)
 330 case "$withval" in
 331   default) WITH_LLVMGCCDIR=default ;;
 332   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 333   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 334 esac
 335
 336 dnl Specify extra build options
 337 AC_ARG_WITH(extra-options,
 338   AS_HELP_STRING([--with-extra-options],
 339                  [Specify addtional options to compile LLVM with]),,
 340                  extraopts=default)
 341 case "$extraopts" in
 342   default) EXTRA_OPTIONS= ;;
 343   *) EXTRA_OPTIONS=$extraopts ;;
 344 esac
 345 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 346
 347 dnl===-----------------------------------------------------------------------===
 348 dnl===
 349 dnl=== SECTION 4: Check for programs we need and that they are the right version
 350 dnl===
 351 dnl===-----------------------------------------------------------------------===
 352
 353 dnl Check for compilation tools
 354 AC_PROG_CPP
 355 AC_PROG_CC(gcc)
 356 AC_PROG_CXX(g++)
 357 AC_PROG_FLEX
 358 AC_PROG_BISON
 359
 360 AC_PROG_NM
 361 AC_SUBST(NM)
 362
 363 dnl Check for the tools that the makefiles require
 364 AC_CHECK_GNU_MAKE
 365 AC_PROG_LN_S
 366 AC_PATH_PROG(CMP, [cmp], [cmp])
 367 AC_PATH_PROG(CP, [cp], [cp])
 368 AC_PATH_PROG(DATE, [date], [date])
 369 AC_PATH_PROG(FIND, [find], [find])
 370 AC_PATH_PROG(GREP, [grep], [grep])
 371 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 372 AC_PATH_PROG(MV,   [mv],   [mv])
 373 AC_PROG_RANLIB
 374 AC_PATH_PROG(RM,   [rm],   [rm])
 375 AC_PATH_PROG(SED,  [sed],  [sed])
 376 AC_PATH_PROG(TAR,  [tar],  [gtar])
 377 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 378
 379 dnl Looking for misc. graph plotting software
 380 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 381 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 382   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 383   dnl If we're targeting for mingw we should emit windows paths, not msys
 384   if test "$llvm_cv_os_type" == "MingW" ; then
 385     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 386   fi
 387   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 388    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 389 fi
 390 AC_PATH_PROG(DOT, [dot], [echo dot])
 391 if test "$DOT" != "echo dot" ; then
 392   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 393   dnl If we're targeting for mingw we should emit windows paths, not msys
 394   if test "$llvm_cv_os_type" == "MingW" ; then
 395     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 396   fi
 397   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 398    [Define to path to dot program if found or 'echo dot' otherwise])
 399 fi
 400 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 401 if test "$GV" != "echo gv" ; then
 402   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 403   dnl If we're targeting for mingw we should emit windows paths, not msys
 404   if test "$llvm_cv_os_type" == "MingW" ; then
 405     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 406   fi
 407   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 408    [Define to path to gv program if found or 'echo gv' otherwise])
 409 fi
 410 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 411 if test "$DOTTY" != "echo dotty" ; then
 412   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 413   dnl If we're targeting for mingw we should emit windows paths, not msys
 414   if test "$llvm_cv_os_type" == "MingW" ; then
 415     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 416   fi
 417   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 418    [Define to path to dotty program if found or 'echo dotty' otherwise])
 419 fi
 420
 421 dnl Look for a sufficiently recent version of Perl.
 422 LLVM_PROG_PERL([5.006])
 423 AC_SUBST(PERL)
 424 if test x"$PERL" = xnone; then
 425    AC_SUBST(HAVE_PERL,0)
 426 else
 427    AC_SUBST(HAVE_PERL,1)
 428 fi
 429
 430 dnl Find the install program
 431 AC_PROG_INSTALL
 432
 433 dnl Checks for documentation and testing tools that we can do without. If these
 434 dnl are not found then they are set to "true" which always succeeds but does
 435 dnl nothing. This just lets the build output show that we could have done
 436 dnl something if the tool was available.
 437 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 438 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 439 AC_PATH_PROG(ETAGS,[etags],[echo "Skipped: etags not found"])
 440 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 441 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 442 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 443 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 444 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 445 DJ_AC_PATH_TCLSH
 446 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 447
 448 dnl Determine if the linker supports the -R option.
 449 AC_LINK_USE_R
 450
 451 dnl Check for libtool and the library that has dlopen function (which must come
 452 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 453 dnl libtool).
 454 AC_LIBTOOL_DLOPEN
 455 AC_LIB_LTDL
 456 AC_PROG_LIBTOOL
 457
 458 if test "$lt_cv_dlopen_self" = "yes" ; then
 459   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 460               [Define if dlopen(0) will open the symbols of the program])
 461 fi
 462
 463 dnl Check if we know how to tell etags we are using C++:
 464 etags_version=`$ETAGS --version 2>&1`
 465 case "$etags_version" in
 466         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 467         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 468         *) ETAGSFLAGS="" ;;
 469 esac
 470 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 471
 472 if test "$WITH_LLVMGCCDIR" = "default" ; then
 473   LLVMGCC="llvm-gcc${EXEEXT}"
 474   LLVMGXX="llvm-g++${EXEEXT}"
 475   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 476   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 477 else
 478   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 479   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 480   AC_SUBST(LLVMGCC,$LLVMGCC)
 481   AC_SUBST(LLVMGXX,$LLVMGXX)
 482 fi
 483
 484 AC_MSG_CHECKING([tool compatibility])
 485
 486 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 487 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 488 dnl to support those options.
 489 dnl "icc" emits gcc signatures
 490 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 491 ICC=no
 492 IXX=no
 493 case $CC in
 494   icc*|icpc*)
 495     ICC=yes
 496     IXX=yes
 497     ;;
 498    *)
 499     ;;
 500 esac
 501
 502 if test "$GCC" != "yes" && test "$ICC" != "yes"
 503 then
 504   AC_MSG_ERROR([gcc|icc required but not found])
 505 fi
 506
 507 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 508 if test "$GXX" != "yes" && test "$IXX" != "yes"
 509 then
 510   AC_MSG_ERROR([g++|icc required but not found])
 511 fi
 512
 513 dnl Verify that GCC is version 3.0 or higher
 514 if test "$GCC" = "yes"
 515 then
 516   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 517   if test "$gccmajor" -lt "3"
 518   then
 519     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 520   fi
 521 fi
 522
 523 dnl Check for GNU Make.  We use its extensions, so don't build without it
 524 if test -z "$llvm_cv_gnu_make_command"
 525 then
 526   AC_MSG_ERROR([GNU Make required but not found])
 527 fi
 528
 529 dnl Tool compatibility is okay if we make it here.
 530 AC_MSG_RESULT([ok])
 531
 532 dnl===-----------------------------------------------------------------------===
 533 dnl===
 534 dnl=== SECTION 5: Check for libraries
 535 dnl===
 536 dnl===-----------------------------------------------------------------------===
 537
 538 dnl libelf is for sparc only; we can ignore it if we don't have it
 539 AC_CHECK_LIB(elf, elf_begin)
 540 AC_CHECK_LIB(m,sin)
 541 if test "$llvm_cv_os_type" == "MingW" ; then
 542   AC_CHECK_LIB(imagehlp, main)
 543   AC_CHECK_LIB(psapi, main)
 544 fi
 545
 546 dnl lt_dlopen may be required for plugin support.
 547 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 548               [Define if lt_dlopen() is available on this platform]),
 549               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 550                            not be available]))
 551
 552 dnl dlopen() is required for plugin support.
 553 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 554                [Define if dlopen() is available on this platform.]),
 555                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 556
 557 dnl mallinfo is optional; the code can compile (minus features) without it
 558 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 559                [Define if mallinfo() is available on this platform.]))
 560
 561 dnl pthread locking functions are optional - but llvm will not be thread-safe
 562 dnl without locks.
 563 if test "$ENABLE_THREADS" -eq 1 ; then
 564   AC_CHECK_LIB(pthread,pthread_mutex_init)
 565   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 566                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 567                            [Have pthread_mutex_lock]))
 568 fi
 569
 570 dnl===-----------------------------------------------------------------------===
 571 dnl===
 572 dnl=== SECTION 6: Check for header files
 573 dnl===
 574 dnl===-----------------------------------------------------------------------===
 575
 576 dnl First, use autoconf provided macros for specific headers that we need
 577 dnl We don't check for ancient stuff or things that are guaranteed to be there
 578 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 579 dnl Generally we're looking for POSIX headers.
 580 AC_HEADER_DIRENT
 581 AC_HEADER_MMAP_ANONYMOUS
 582 AC_HEADER_STAT
 583 AC_HEADER_STDC
 584 AC_HEADER_SYS_WAIT
 585 AC_HEADER_TIME
 586
 587 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 588 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 589 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 590 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h])
 591 if test "$ENABLE_THREADS" -eq 1 ; then
 592   AC_CHECK_HEADERS(pthread.h)
 593 fi
 594
 595 dnl===-----------------------------------------------------------------------===
 596 dnl===
 597 dnl=== SECTION 7: Check for types and structures
 598 dnl===
 599 dnl===-----------------------------------------------------------------------===
 600
 601 AC_TYPE_PID_T
 602 AC_TYPE_SIZE_T
 603 AC_TYPE_SIGNAL
 604 AC_STRUCT_TM
 605 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 606 AC_CHECK_TYPES([uint64_t],,
 607          AC_CHECK_TYPES([u_int64_t],,
 608          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 609
 610 dnl===-----------------------------------------------------------------------===
 611 dnl===
 612 dnl=== SECTION 8: Check for specific functions needed
 613 dnl===
 614 dnl===-----------------------------------------------------------------------===
 615
 616 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 617 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 618 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 619 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 620 AC_CHECK_FUNCS([_setjmp _longjmp setjmp longjmp sigsetjmp siglongjmp])
 621 AC_C_PRINTF_A
 622 AC_FUNC_ALLOCA
 623 AC_FUNC_RAND48
 624
 625 dnl Check for variations in the Standard C++ library and STL. These macros are
 626 dnl provided by LLVM in the autoconf/m4 directory.
 627 AC_CXX_HAVE_HASH_MAP
 628 AC_CXX_HAVE_HASH_SET
 629 AC_CXX_HAVE_STD_ITERATOR
 630 AC_CXX_HAVE_BI_ITERATOR
 631 AC_CXX_HAVE_FWD_ITERATOR
 632 AC_FUNC_ISNAN
 633 AC_FUNC_ISINF
 634
 635 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 636 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 637 dnl be opened for allocating RWX memory.
 638 AC_FUNC_MMAP
 639 AC_FUNC_MMAP_FILE
 640 AC_NEED_DEV_ZERO_FOR_MMAP
 641 AC_CHECK_FUNC(mprotect,,
 642               AC_MSG_ERROR([Function mprotect() required but not found]))
 643
 644 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 645 then
 646   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 647 fi
 648 if test "$ac_cv_func_mmap_file" = "no"
 649 then
 650   AC_MSG_WARN([mmap() of files required but not found])
 651 fi
 652
 653 dnl===-----------------------------------------------------------------------===
 654 dnl===
 655 dnl=== SECTION 9: Additional checks, variables, etc.
 656 dnl===
 657 dnl===-----------------------------------------------------------------------===
 658
 659 dnl See if the llvm-gcc executable can compile to LLVM assembly
 660 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 661 [llvm_cv_llvmgcc_sanity="no"
 662 if test -x "$LLVMGCC" ; then
 663   cp /dev/null conftest.c
 664   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 665   if test $? -eq 0 ; then
 666     llvm_cv_llvmgcc_sanity="yes"
 667   fi
 668   rm conftest.c
 669 fi])
 670
 671 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 672 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 673   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 674   AC_SUBST(LLVMCC1,$llvmcc1path)
 675   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 676   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 677   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 678   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 679   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 680   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 681   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 682   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 683 fi
 684
 685 dnl Propagate the shared library extension that the libltdl checks did to
 686 dnl the Makefiles so we can use it there too
 687 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 688
 689 # Translate the various configuration directories and other basic
 690 # information into substitutions that will end up in Makefile.config.in
 691 # that these configured values can be used by the makefiles
 692 if test "${prefix}" == "NONE" ; then
 693   prefix="/usr/local"
 694 fi
 695 eval LLVM_PREFIX="${prefix}";
 696 eval LLVM_BINDIR="${prefix}/bin";
 697 eval LLVM_LIBDIR="${prefix}/lib";
 698 eval LLVM_DATADIR="${prefix}/share/llvm";
 699 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 700 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 701 eval LLVM_INCLUDEDIR="${prefix}/include";
 702 eval LLVM_INFODIR="${prefix}/info";
 703 eval LLVM_MANDIR="${prefix}/man";
 704 LLVM_CONFIGTIME=`date`
 705 AC_SUBST(LLVM_PREFIX)
 706 AC_SUBST(LLVM_BINDIR)
 707 AC_SUBST(LLVM_LIBDIR)
 708 AC_SUBST(LLVM_DATADIR)
 709 AC_SUBST(LLVM_DOCSDIR)
 710 AC_SUBST(LLVM_ETCDIR)
 711 AC_SUBST(LLVM_INCLUDEDIR)
 712 AC_SUBST(LLVM_INFODIR)
 713 AC_SUBST(LLVM_MANDIR)
 714 AC_SUBST(LLVM_CONFIGTIME)
 715
 716 # Place the various directores into the config.h file as #defines so that we
 717 # can know about the installation paths within LLVM.
 718 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 719                    [Installation prefix directory])
 720 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 721                    [Installation directory for binary executables])
 722 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 723                    [Installation directory for libraries])
 724 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 725                    [Installation directory for data files])
 726 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 727                    [Installation directory for documentation])
 728 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 729                    [Installation directory for config files])
 730 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 731                    [Installation directory for include files])
 732 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 733                    [Installation directory for .info files])
 734 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 735                    [Installation directory for man pages])
 736 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 737                    [Time at which LLVM was configured])
 738
 739 dnl===-----------------------------------------------------------------------===
 740 dnl===
 741 dnl=== SECTION 10: Specify the output files and generate it
 742 dnl===
 743 dnl===-----------------------------------------------------------------------===
 744
 745 dnl Configure header files
 746 dnl WARNING: dnl If you add or remove any of the following config headers, then
 747 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 748 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 749 dnl files can be updated automatically when their *.in sources change.
 750 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 751 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 752 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 753 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 754 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 755
 756 dnl Configure the makefile's configuration data
 757 AC_CONFIG_FILES([Makefile.config])
 758
 759 dnl Configure doxygen's configuration file
 760 AC_CONFIG_FILES([docs/doxygen.cfg])
 761
 762 dnl Do the first stage of configuration for llvm-config.in.
 763 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 764
 765 dnl Do special configuration of Makefiles
 766 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 767 AC_CONFIG_MAKEFILE(Makefile)
 768 AC_CONFIG_MAKEFILE(Makefile.common)
 769 AC_CONFIG_MAKEFILE(examples/Makefile)
 770 AC_CONFIG_MAKEFILE(lib/Makefile)
 771 AC_CONFIG_MAKEFILE(runtime/Makefile)
 772 AC_CONFIG_MAKEFILE(test/Makefile)
 773 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 774 AC_CONFIG_MAKEFILE(tools/Makefile)
 775 AC_CONFIG_MAKEFILE(utils/Makefile)
 776 AC_CONFIG_MAKEFILE(projects/Makefile)
 777
 778 dnl Finally, crank out the output
 779 AC_OUTPUT
 780
 781 dnl Warn loudly if llvm-gcc was not obviously working
 782 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 783  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 784  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 785  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 786  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 787  AC_MSG_WARN([***** build the llvm tools.])
 788 fi