autoconf/configure.ac

   1 dnl Initialize autoconf
   2 AC_INIT([[LLVM]],[[1.4]],[llvmbugs@cs.uiuc.edu])
   3
   4 dnl Place all of the extra autoconf files into the config subdirectory
   5 dnl Tell various tools where the m4 autoconf macros are
   6 dnl Have configure verify that the source directory is valid.
   7 AC_CONFIG_AUX_DIR([autoconf])
   8 dnl AC_CONFIG_MACRO_DIR(autoconf/m4)
   9 dnl Verify that the source directory is valid
  10 AC_CONFIG_SRCDIR(["Makefile.config.in"])
  11
  12 dnl Quit if the source directory has already been configured.
  13 dnl NOTE: This relies upon undocumented autoconf behavior.
  14 if test ${srcdir} != "." ; then
  15         if test -f ${srcdir}/include/llvm/Config/config.h ; then
  16                 AC_MSG_ERROR([Already configured in ${srcdir}])
  17         fi
  18 fi
  19
  20 dnl Configure all of the projects present in our source tree.
  21 for i in `ls ${srcdir}/projects`
  22 do
  23   if test -d ${srcdir}/projects/${i} ; then
  24     case ${i} in
  25       "CVS") ;;
  26       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  27       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  28       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  29       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  30       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  31       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  32       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  33       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  34       *)
  35         AC_MSG_WARN([Unknown projects (${i})won't be configured automatically])
  36         ;;
  37     esac
  38   fi
  39 done
  40
  41 dnl Configure header files
  42 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
  43
  44 dnl Configure other output file
  45 AC_CONFIG_FILES(Makefile.config
  46  include/llvm/Support/ThreadSupport.h
  47  include/llvm/ADT/iterator)
  48 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
  49 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
  50 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
  51
  52 dnl Do special configuration of Makefiles
  53 AC_CONFIG_MAKEFILE(Makefile)
  54 AC_CONFIG_MAKEFILE(Makefile.common)
  55 AC_CONFIG_MAKEFILE(examples/Makefile)
  56 AC_CONFIG_MAKEFILE(lib/Makefile)
  57 AC_CONFIG_MAKEFILE(runtime/Makefile)
  58 AC_CONFIG_MAKEFILE(test/Makefile)
  59 AC_CONFIG_MAKEFILE(test/Makefile.tests)
  60 AC_CONFIG_MAKEFILE(test/QMTest/llvm.py)
  61 AC_CONFIG_MAKEFILE(test/QMTest/llvmdb.py)
  62 AC_CONFIG_MAKEFILE(tools/Makefile)
  63 AC_CONFIG_MAKEFILE(utils/Makefile)
  64 AC_CONFIG_MAKEFILE(projects/Makefile)
  65
  66 dnl Find the install program (needs to be done before canonical stuff)
  67 AC_PROG_INSTALL
  68
  69 dnl Check which host for which we're compiling.  This will tell us which LLVM
  70 dnl compiler will be used for compiling SSA into object code.
  71 AC_CANONICAL_TARGET
  72
  73 dnl Set the "OS" Makefile variable based on the system we are building on.
  74 dnl We will use the build machine information to set some variables.
  75
  76 AC_MSG_CHECKING([support for generic build operating system])
  77 case $build in
  78         *-*-aix*)
  79              AC_SUBST(OS,[AIX])
  80              platform_type="AIX"
  81              ;;
  82         *-*-cygwin*)
  83              AC_SUBST(OS,[Cygwin])
  84              platform_type="Cygwin"
  85              ;;
  86         *-*-darwin*)
  87              AC_SUBST(OS,[Darwin])
  88              platform_type="Darwin"
  89              ;;
  90         *-*-freebsd*)
  91              AC_SUBST(OS,[Linux])
  92              platform_type="FreeBSD"
  93              ;;
  94         *-*-interix*)
  95              AC_SUBST(OS,[SunOS])
  96              platform_type="Interix"
  97              ;;
  98         *-*-linux*)
  99              AC_SUBST(OS,[Linux])
 100              platform_type="Linux"
 101              if test -d /home/vadve/lattner/local/x86/llvm-gcc
 102              then
 103                AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
 104              fi
 105              ;;
 106         *-*-solaris*)
 107              AC_SUBST(OS,[SunOS])
 108              platform_type="SunOS"
 109              if test -d /home/vadve/lattner/local/sparc/llvm-gcc
 110              then
 111                AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 112              fi
 113              ;;
 114         *-*-win32*)
 115              AC_SUBST(OS,[Win32])
 116              platform_type="Win32"
 117              ;;
 118         *-*-mingw*)
 119              AC_SUBST(OS,[Win32])
 120              platform_type="Win32"
 121              ;;
 122         *)
 123              AC_SUBST(OS,[Unknown])
 124              platform_type="Unknown"
 125              ;;
 126 esac
 127
 128 dnl Make sure we aren't attempting to configure for an unknown system
 129 if test "$platform_type" = "Unknown" ; then
 130   AC_MSG_ERROR([Platform is unknown, configure can't continue])
 131 fi
 132
 133 dnl Make a link from lib/System/platform to lib/System/$platform_type
 134 dnl This helps the #inclusion of the system specific include files
 135 dnl for the operating system abstraction library
 136 AC_CONFIG_LINKS(lib/System/platform:lib/System/$platform_type)
 137
 138
 139 AC_MSG_CHECKING(target architecture)
 140 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 141 dnl V9, since that is all that we support at the moment, and autoconf will only
 142 dnl tell us we're a sparc.
 143 case $target in
 144         sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 145                             ;;
 146 esac
 147
 148 dnl Determine what our target architecture is and configure accordingly.
 149 dnl This will allow Makefiles to make a distinction between the hardware and
 150 dnl the OS.
 151 case $target in
 152         i*86-*)
 153           ARCH="x86"
 154           AC_SUBST(ARCH,[x86])
 155           ;;
 156         sparc*-*)
 157           ARCH="Sparc"
 158           AC_SUBST(ARCH,[Sparc])
 159           ;;
 160         powerpc*-*)
 161           ARCH="PowerPC"
 162           AC_SUBST(ARCH,[PowerPC])
 163           ;;
 164         *)
 165           ARCH="Unknown"
 166           AC_SUBST(ARCH,[Unknown])
 167           ;;
 168 esac
 169
 170 AC_MSG_RESULT($ARCH)
 171
 172 dnl Check for compilation tools
 173 AC_PROG_CXX
 174 AC_PROG_CC(gcc)
 175 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 176 if test "$GCC" != "yes"
 177 then
 178         AC_MSG_ERROR([gcc required but not found])
 179 fi
 180 AC_PROG_CPP
 181 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 182 if test "$GXX" != "yes"
 183 then
 184         AC_MSG_ERROR([g++ required but not found])
 185 fi
 186
 187 dnl Verify that GCC is version 3.0 or higher
 188 gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 189 if test "$gccmajor" -lt "3"
 190 then
 191         AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 192 fi
 193
 194 dnl Check for GNU Make.  We use its extensions too, so don't build without it
 195 AC_CHECK_GNU_MAKE
 196 if test -z "$_cv_gnu_make_command"
 197 then
 198         AC_MSG_ERROR([GNU Make required but not found])
 199 fi
 200
 201 dnl Checks for other tools
 202 AC_PROG_FLEX
 203 AC_PROG_BISON
 204 AC_PROG_LIBTOOL
 205
 206 dnl Checks for tools we can get away with not having:
 207 AC_PATH_PROG(DOT,[dot],[true dot])
 208 AC_PATH_PROG(ETAGS,[etags],[true etags])
 209 dnl Check if we know how to tell etags we are using C++:
 210 etags_version=`$ETAGS --version 2>&1`
 211 case "$etags_version" in
 212         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 213         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 214         *) ETAGSFLAGS="" ;;
 215 esac
 216 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 217 AC_PATH_PROG(PYTHON,[python],[true python])
 218 if test "$PYTHON" = "false"
 219 then
 220         AC_MSG_WARN([Python is required for the test suite, but it was not found])
 221 fi
 222 AC_PATH_PROG(QMTEST,[qmtest],[true qmtest])
 223 if test "$QMTEST" = "false"
 224 then
 225         AC_MSG_WARN([QMTest is required for the test suite, but it was not found])
 226 fi
 227
 228 dnl Verify that the version of python available is high enough for qmtest
 229 pyversion=`$PYTHON -V 2>&1 | cut -d\  -f2`
 230 pymajor=`echo $pyversion | cut -d. -f1`
 231 pyminor=`echo $pyversion | cut -d. -f2`
 232
 233 if test "$pymajor" -ge "2"
 234 then
 235         if test "$pymajor" -eq "2"
 236         then
 237                 if test "$pyminor" -lt "2"
 238                 then
 239                         AC_MSG_WARN([QMTest requires Python 2.2 or later])
 240                 fi
 241         fi
 242 else
 243         AC_MSG_WARN([QMTest requires Python 2.2 or later])
 244 fi
 245
 246 dnl Checks for libraries:
 247 dnl libelf is for sparc only; we can ignore it if we don't have it
 248 AC_CHECK_LIB(elf, elf_begin)
 249
 250 dnl dlopen() is required for plugin support.
 251 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],[Define if dlopen() is available on this platform.]),AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 252
 253 dnl mallinfo is optional; the code can compile (minus features) without it
 254 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],[Define if mallinfo() is available on this platform.]))
 255
 256 dnl pthread locking functions are optional - but llvm will not be thread-safe
 257 dnl without locks.
 258 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,HAVE_PTHREAD_MUTEX_LOCK=1,HAVE_PTHREAD_MUTEX_LOCK=0)
 259 AC_SUBST(HAVE_PTHREAD_MUTEX_LOCK)
 260
 261 dnl Checks for header files.
 262 dnl We don't check for ancient stuff or things that are guaranteed to be there
 263 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 264 AC_HEADER_STDC
 265 AC_HEADER_SYS_WAIT
 266
 267 dnl Checks for POSIX and other various system-specific header files
 268 AC_CHECK_HEADERS(fcntl.h limits.h sys/time.h unistd.h malloc.h sys/mman.h sys/resource.h dlfcn.h link.h execinfo.h windows.h)
 269
 270 dnl Check for things that need to be included in public headers, and so
 271 dnl for which we may not have access to a HAVE_* preprocessor #define.
 272 dnl (primarily used in DataTypes.h)
 273 AC_CHECK_HEADER([sys/types.h])
 274 AC_CHECK_HEADER([inttypes.h])
 275 AC_CHECK_HEADER([stdint.h])
 276
 277 dnl Check for types
 278 AC_TYPE_PID_T
 279 AC_TYPE_SIZE_T
 280 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 281 AC_CHECK_TYPES([uint64_t],,
 282                AC_CHECK_TYPES([u_int64_t],,
 283                               AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 284 AC_HEADER_TIME
 285 AC_STRUCT_TM
 286
 287 dnl Check for various C features
 288 AC_C_PRINTF_A
 289
 290 dnl Check for the endianness of the target
 291 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 292
 293 dnl Check for C++ extensions
 294 AC_CXX_HAVE_HASH_MAP
 295 AC_CXX_HAVE_HASH_SET
 296 AC_CXX_HAVE_STD_ITERATOR
 297 AC_CXX_HAVE_BI_ITERATOR
 298 AC_CXX_HAVE_FWD_ITERATOR
 299
 300 AC_FUNC_ISNAN
 301 AC_FUNC_ISINF
 302
 303 dnl Checks for library functions.
 304 AC_FUNC_ALLOCA
 305 AC_FUNC_MMAP
 306 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 307 then
 308         AC_MSG_WARN([mmap() required but not found])
 309 fi
 310 AC_FUNC_MMAP_FILE
 311 if test "$ac_cv_func_mmap_file" = "no"
 312 then
 313         AC_MSG_WARN([mmap() of files required but not found])
 314 fi
 315 AC_HEADER_MMAP_ANONYMOUS
 316 AC_TYPE_SIGNAL
 317 AC_CHECK_FUNCS(getcwd gettimeofday strdup strtoq strtoll backtrace isatty mkstemp getrusage)
 318 AC_CHECK_FUNC(mprotect,,AC_MSG_ERROR([Function mprotect() required but not found]))
 319
 320 dnl Determine if the linker supports the -R option.
 321 AC_LINK_USE_R
 322
 323 dnl --enable/--with command-line options:
 324 dnl Check whether they want to do an optimized build:
 325 AC_ARG_ENABLE(optimized,AS_HELP_STRING(--enable-optimized,Compile with optimizations enabled (default is NO)),,enableval=no)
 326 if test ${enableval} = "no"
 327 then
 328         AC_SUBST(ENABLE_OPTIMIZED,[[]])
 329 else
 330         AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 331 fi
 332
 333 dnl JIT Option
 334 AC_ARG_ENABLE(jit,AS_HELP_STRING(--enable-jit,Enable Just In Time Compiling (default is YES)),,enableval=default)
 335 if test ${enableval} = "no"
 336 then
 337         AC_SUBST(JIT,[[]])
 338 else
 339         case $target in
 340                 *i*86*)
 341                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 342                         ;;
 343                 *sparc*)
 344                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 345                         ;;
 346                 *)
 347                         AC_SUBST(JIT,[[]])
 348                         ;;
 349         esac
 350 fi
 351
 352 dnl Find the LLVM GCC-based C/C++ front end
 353 AC_ARG_WITH(llvmgccdir,AS_HELP_STRING(--with-llvmgccdir,Location of LLVM GCC front-end),AC_SUBST(LLVMGCCDIR,[$withval]))
 354 AC_MSG_CHECKING([for llvm-gcc])
 355 LLVM_GCC_CHECK=no
 356 if test -d "$LLVMGCCDIR"
 357 then
 358         if test -x "$LLVMGCCDIR/bin/gcc"
 359         then
 360                 LLVM_GCC_CHECK="$LLVMGCCDIR/bin/gcc"
 361         fi
 362 fi
 363 llvmgccwarn=no
 364 AC_MSG_RESULT($LLVM_GCC_CHECK)
 365 if test "$LLVM_GCC_CHECK" = "no"
 366 then
 367     llvmgccwarn=yes
 368 fi
 369 AC_MSG_CHECKING([whether llvm-gcc is sane])
 370 LLVM_GCC_SANE=no
 371 if test -x "$LLVM_GCC_CHECK"
 372 then
 373         cp /dev/null conftest.c
 374     "$LLVM_GCC_CHECK" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 375         if test $? -eq 0
 376         then
 377                 LLVM_GCC_SANE=yes
 378         fi
 379         rm conftest.c
 380         llvmcc1path=`"$LLVM_GCC_CHECK" --print-prog-name=cc1`
 381         AC_SUBST(LLVMCC1,$llvmcc1path)
 382         llvmcc1pluspath=`"$LLVM_GCC_CHECK" --print-prog-name=cc1plus`
 383         AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 384 fi
 385 AC_MSG_RESULT($LLVM_GCC_SANE)
 386 if test "$LLVM_GCC_SANE" = "no"
 387 then
 388         llvmgccwarn=yes
 389 fi
 390
 391 dnl Get libtool's idea of what the shared library suffix is.
 392 dnl (This is a hack; it relies on undocumented behavior.)
 393 AC_MSG_CHECKING([for shared library suffix])
 394 eval "SHLIBEXT=$shrext_cmds"
 395 AC_MSG_RESULT($SHLIBEXT)
 396 dnl Propagate it to the Makefiles and config.h (for gccld & bugpoint).
 397 AC_SUBST(SHLIBEXT,$SHLIBEXT)
 398 AC_DEFINE_UNQUOTED(SHLIBEXT,"$SHLIBEXT",
 399                    [Extension that shared libraries have, e.g., ".so".])
 400
 401 # Translate the various configuration directories and other basic
 402 # information into substitutions that will end up in config.h.in so
 403 # that these configured values can be hard-wired into a program.
 404 eval LLVM_PREFIX="${prefix}";
 405 eval LLVM_BINDIR="${prefix}/bin";
 406 eval LLVM_LIBDIR="${prefix}/lib";
 407 eval LLVM_DATADIR="${prefix}/data";
 408 eval LLVM_DOCSDIR="${prefix}/docs";
 409 eval LLVM_ETCDIR="${prefix}/etc";
 410 eval LLVM_INCLUDEDIR="${prefix}/include";
 411 eval LLVM_INFODIR="${prefix}/info";
 412 eval LLVM_MANDIR="${prefix}/man";
 413 LLVM_CONFIGTIME=`date`
 414 AC_SUBST(LLVM_PREFIX)
 415 AC_SUBST(LLVM_BINDIR)
 416 AC_SUBST(LLVM_LIBDIR)
 417 AC_SUBST(LLVM_DATADIR)
 418 AC_SUBST(LLVM_DOCSDIR)
 419 AC_SUBST(LLVM_ETCDIR)
 420 AC_SUBST(LLVM_INCLUDEDIR)
 421 AC_SUBST(LLVM_INFODIR)
 422 AC_SUBST(LLVM_MANDIR)
 423 AC_SUBST(LLVM_CONFIGTIME)
 424 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX", [Installation prefix directory])
 425 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR", [Installation directory for binary executables])
 426 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR", [Installation directory for libraries])
 427 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR", [Installation directory for data files])
 428 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR", [Installation directory for documentation])
 429 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR", [Installation directory for config files])
 430 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR", [Installation directory for include files])
 431 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR", [Installation directory for .info files])
 432 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR", [Installation directory for man pages])
 433 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME", [Time at which LLVM was configured])
 434
 435 dnl Create the output files
 436 AC_OUTPUT
 437
 438 dnl Warn loudly if llvm-gcc was not obviously working
 439 if test $llvmgccwarn = yes
 440 then
 441         AC_MSG_WARN([***** llvm C/C++ front end was not found, or does not])
 442         AC_MSG_WARN([***** appear to be working.])
 443         AC_MSG_WARN([***** ])
 444         AC_MSG_WARN([***** Please check configure's --with-llvmgccdir option.])
 445         AC_MSG_WARN([***** Runtime libraries (in llvm/runtime) will not be built,])
 446         AC_MSG_WARN([***** but you should be able to build the llvm tools.])
 447 fi
 448