autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[3.1svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.60 or later.
  42 AC_PREREQ(2.60)
  43
  44 dnl Verify that the source directory is valid. This makes sure that we are
  45 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  46 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  47
  48 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  49 dnl various tools where the m4 autoconf macros are.
  50 AC_CONFIG_AUX_DIR([autoconf])
  51
  52 dnl Quit if the source directory has already been configured.
  53 dnl NOTE: This relies upon undocumented autoconf behavior.
  54 if test ${srcdir} != "." ; then
  55   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  56     AC_MSG_ERROR([Already configured in ${srcdir}])
  57   fi
  58 fi
  59
  60 dnl We need to check for the compiler up here to avoid anything else
  61 dnl starting with a different one.
  62 AC_PROG_CC(clang llvm-gcc gcc)
  63 AC_PROG_CXX(clang++ llvm-g++ g++)
  64 AC_PROG_CPP
  65
  66 dnl Configure all of the projects present in our source tree. While we could
  67 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  68 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  69 dnl Instead we match on the known projects.
  70
  71 dnl
  72 dnl One tricky part of doing this is that some projects depend upon other
  73 dnl projects.  For example, several projects rely upon the LLVM test suite.
  74 dnl We want to configure those projects first so that their object trees are
  75 dnl created before running the configure scripts of projects that depend upon
  76 dnl them.
  77 dnl
  78
  79 dnl Several projects use llvm-gcc, so configure that first
  80 if test -d ${srcdir}/projects/llvm-gcc ; then
  81   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  82 fi
  83
  84 dnl Several projects use the LLVM test suite, so configure it next.
  85 if test -d ${srcdir}/projects/test-suite ; then
  86   AC_CONFIG_SUBDIRS([projects/test-suite])
  87 fi
  88
  89 dnl llvm-test is the old name of the test-suite, kept here for backwards
  90 dnl compatibility
  91 if test -d ${srcdir}/projects/llvm-test ; then
  92   AC_CONFIG_SUBDIRS([projects/llvm-test])
  93 fi
  94
  95 dnl Some projects use poolalloc; configure that next
  96 if test -d ${srcdir}/projects/poolalloc ; then
  97   AC_CONFIG_SUBDIRS([projects/poolalloc])
  98 fi
  99
 100 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 101   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 102 fi
 103
 104 dnl Check for all other projects
 105 for i in `ls ${srcdir}/projects`
 106 do
 107   if test -d ${srcdir}/projects/${i} ; then
 108     case ${i} in
 109       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 110       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 111       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 112       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 113       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 114       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 115       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 116       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 117       llvm-gcc)       ;;
 118       test-suite)     ;;
 119       llvm-test)      ;;
 120       poolalloc)      ;;
 121       llvm-poolalloc) ;;
 122       *)
 123         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 124         ;;
 125     esac
 126   fi
 127 done
 128
 129 dnl Disable the build of polly, even if it is checked out into tools/polly.
 130 AC_ARG_ENABLE(polly,
 131               AS_HELP_STRING([--enable-polly],
 132                              [Use polly if available (default is YES)]),,
 133                              enableval=default)
 134 case "$enableval" in
 135   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 136   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 137   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 138   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 139 esac
 140
 141
 142 dnl Check if polly is checked out into tools/polly and configure it if
 143 dnl available.
 144 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 145   AC_SUBST(LLVM_HAS_POLLY,1)
 146   AC_CONFIG_SUBDIRS([tools/polly])
 147 fi
 148
 149 dnl===-----------------------------------------------------------------------===
 150 dnl===
 151 dnl=== SECTION 2: Architecture, target, and host checks
 152 dnl===
 153 dnl===-----------------------------------------------------------------------===
 154
 155 dnl Check the target for which we're compiling and the host that will do the
 156 dnl compilations. This will tell us which LLVM compiler will be used for
 157 dnl compiling SSA into object code. This needs to be done early because
 158 dnl following tests depend on it.
 159 AC_CANONICAL_TARGET
 160
 161 dnl Determine the platform type and cache its value. This helps us configure
 162 dnl the System library to the correct build platform.
 163 AC_CACHE_CHECK([type of operating system we're going to host on],
 164                [llvm_cv_os_type],
 165 [case $host in
 166   *-*-aix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="AIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-irix*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="IRIX"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-cygwin*)
 177     llvm_cv_link_all_option="-Wl,--whole-archive"
 178     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 179     llvm_cv_os_type="Cygwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-darwin*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Darwin"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-minix*)
 187     llvm_cv_link_all_option="-Wl,-all_load"
 188     llvm_cv_no_link_all_option="-Wl,-noall_load"
 189     llvm_cv_os_type="Minix"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-freebsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="FreeBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-openbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="OpenBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-netbsd*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="NetBSD"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-dragonfly*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="DragonFly"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-hpux*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="HP-UX"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-interix*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Interix"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-linux*)
 222     llvm_cv_link_all_option="-Wl,--whole-archive"
 223     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 224     llvm_cv_os_type="Linux"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-solaris*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="SunOS"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-auroraux*)
 232     llvm_cv_link_all_option="-Wl,-z,allextract"
 233     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 234     llvm_cv_os_type="AuroraUX"
 235     llvm_cv_platform_type="Unix" ;;
 236   *-*-win32*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="Win32"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-mingw*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="MingW"
 245     llvm_cv_platform_type="Win32" ;;
 246   *-*-haiku*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Haiku"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-eabi*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *-unknown-elf*)
 257     llvm_cv_link_all_option="-Wl,--whole-archive"
 258     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 259     llvm_cv_os_type="Freestanding"
 260     llvm_cv_platform_type="Unix" ;;
 261   *)
 262     llvm_cv_link_all_option=""
 263     llvm_cv_no_link_all_option=""
 264     llvm_cv_os_type="Unknown"
 265     llvm_cv_platform_type="Unknown" ;;
 266 esac])
 267
 268 AC_CACHE_CHECK([type of operating system we're going to target],
 269                [llvm_cv_target_os_type],
 270 [case $target in
 271   *-*-aix*)
 272     llvm_cv_target_os_type="AIX" ;;
 273   *-*-irix*)
 274     llvm_cv_target_os_type="IRIX" ;;
 275   *-*-cygwin*)
 276     llvm_cv_target_os_type="Cygwin" ;;
 277   *-*-darwin*)
 278     llvm_cv_target_os_type="Darwin" ;;
 279   *-*-minix*)
 280     llvm_cv_target_os_type="Minix" ;;
 281   *-*-freebsd*)
 282     llvm_cv_target_os_type="FreeBSD" ;;
 283   *-*-openbsd*)
 284     llvm_cv_target_os_type="OpenBSD" ;;
 285   *-*-netbsd*)
 286     llvm_cv_target_os_type="NetBSD" ;;
 287   *-*-dragonfly*)
 288     llvm_cv_target_os_type="DragonFly" ;;
 289   *-*-hpux*)
 290     llvm_cv_target_os_type="HP-UX" ;;
 291   *-*-interix*)
 292     llvm_cv_target_os_type="Interix" ;;
 293   *-*-linux*)
 294     llvm_cv_target_os_type="Linux" ;;
 295   *-*-solaris*)
 296     llvm_cv_target_os_type="SunOS" ;;
 297   *-*-auroraux*)
 298     llvm_cv_target_os_type="AuroraUX" ;;
 299   *-*-win32*)
 300     llvm_cv_target_os_type="Win32" ;;
 301   *-*-mingw*)
 302     llvm_cv_target_os_type="MingW" ;;
 303   *-*-haiku*)
 304     llvm_cv_target_os_type="Haiku" ;;
 305   *-*-rtems*)
 306     llvm_cv_target_os_type="RTEMS" ;;
 307   *-*-nacl*)
 308     llvm_cv_target_os_type="NativeClient" ;;
 309   *-unknown-eabi*)
 310     llvm_cv_target_os_type="Freestanding" ;;
 311   *)
 312     llvm_cv_target_os_type="Unknown" ;;
 313 esac])
 314
 315 dnl Make sure we aren't attempting to configure for an unknown system
 316 if test "$llvm_cv_os_type" = "Unknown" ; then
 317   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 318 fi
 319
 320 dnl Set the "OS" Makefile variable based on the platform type so the
 321 dnl makefile can configure itself to specific build hosts
 322 AC_SUBST(OS,$llvm_cv_os_type)
 323 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 324 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 325
 326 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 327 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 328 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 329
 330 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 331 dnl This is used by lib/Support to determine the basic kind of implementation
 332 dnl to use.
 333 case $llvm_cv_platform_type in
 334   Unix)
 335     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 336     AC_SUBST(LLVM_ON_UNIX,[1])
 337     AC_SUBST(LLVM_ON_WIN32,[0])
 338     ;;
 339   Win32)
 340     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 341     AC_SUBST(LLVM_ON_UNIX,[0])
 342     AC_SUBST(LLVM_ON_WIN32,[1])
 343     ;;
 344 esac
 345
 346 dnl Determine what our target architecture is and configure accordingly.
 347 dnl This will allow Makefiles to make a distinction between the hardware and
 348 dnl the OS.
 349 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 350 [case $target in
 351   i?86-*)                 llvm_cv_target_arch="x86" ;;
 352   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 353   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 354   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 355   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 356   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 357   mips-*)                 llvm_cv_target_arch="Mips" ;;
 358   xcore-*)                llvm_cv_target_arch="XCore" ;;
 359   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 360   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 361   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 362   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 363   *)                      llvm_cv_target_arch="Unknown" ;;
 364 esac])
 365
 366 if test "$llvm_cv_target_arch" = "Unknown" ; then
 367   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 368 fi
 369
 370 # Determine the LLVM native architecture for the target
 371 case "$llvm_cv_target_arch" in
 372     x86)     LLVM_NATIVE_ARCH="X86" ;;
 373     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 374     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 375 esac
 376
 377 dnl Define a substitution, ARCH, for the target architecture
 378 AC_SUBST(ARCH,$llvm_cv_target_arch)
 379
 380 dnl Check for the endianness of the target
 381 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 382
 383 dnl Check for build platform executable suffix if we're crosscompiling
 384 if test "$cross_compiling" = yes; then
 385   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 386   AC_BUILD_EXEEXT
 387   ac_build_prefix=${build_alias}-
 388   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 389   if test -z "$BUILD_CXX"; then
 390      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 391      if test -z "$BUILD_CXX"; then
 392        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 393      fi
 394   fi
 395 else
 396   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 397 fi
 398
 399 dnl Check to see if there's a .svn or .git directory indicating that this
 400 dnl build is being done from a checkout. This sets up several defaults for
 401 dnl the command line switches. When we build with a checkout directory,
 402 dnl we get a debug with assertions turned on. Without, we assume a source
 403 dnl release and we get an optimized build without assertions.
 404 dnl See --enable-optimized and --enable-assertions below
 405 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 406   cvsbuild="yes"
 407   optimize="no"
 408   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 409 else
 410   cvsbuild="no"
 411   optimize="yes"
 412 fi
 413
 414 dnl===-----------------------------------------------------------------------===
 415 dnl===
 416 dnl=== SECTION 3: Command line arguments for the configure script.
 417 dnl===
 418 dnl===-----------------------------------------------------------------------===
 419
 420 dnl --enable-optimized : check whether they want to do an optimized build:
 421 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 422  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 423 if test ${enableval} = "no" ; then
 424   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 425 else
 426   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 427 fi
 428
 429 dnl --enable-profiling : check whether they want to do a profile build:
 430 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 431  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 432 if test ${enableval} = "no" ; then
 433   AC_SUBST(ENABLE_PROFILING,[[]])
 434 else
 435   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 436 fi
 437
 438 dnl --enable-assertions : check whether they want to turn on assertions or not:
 439 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 440   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 441 if test ${enableval} = "yes" ; then
 442   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 443 else
 444   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 445 fi
 446
 447 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 448 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 449   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 450 if test ${enableval} = "yes" ; then
 451   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 452   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 453 else
 454   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 455   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 456 fi
 457
 458 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 459 AC_ARG_ENABLE(debug-runtime,
 460    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 461 if test ${enableval} = "no" ; then
 462   AC_SUBST(DEBUG_RUNTIME,[[]])
 463 else
 464   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 465 fi
 466
 467 dnl --enable-debug-symbols : should even optimized compiler libraries
 468 dnl have debug symbols?
 469 AC_ARG_ENABLE(debug-symbols,
 470    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 471 if test ${enableval} = "no" ; then
 472   AC_SUBST(DEBUG_SYMBOLS,[[]])
 473 else
 474   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 475 fi
 476
 477 dnl --enable-jit: check whether they want to enable the jit
 478 AC_ARG_ENABLE(jit,
 479   AS_HELP_STRING(--enable-jit,
 480                  [Enable Just In Time Compiling (default is YES)]),,
 481   enableval=default)
 482 if test ${enableval} = "no"
 483 then
 484   AC_SUBST(JIT,[[]])
 485 else
 486   case "$llvm_cv_target_arch" in
 487     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 488     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 489     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 490     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 491     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 492     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 493     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 494     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 495     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 496     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 497     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 498     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 499     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 500   esac
 501 fi
 502
 503 dnl Allow enablement of building and installing docs
 504 AC_ARG_ENABLE(docs,
 505               AS_HELP_STRING([--enable-docs],
 506                              [Build documents (default is YES)]),,
 507                              enableval=default)
 508 case "$enableval" in
 509   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 510   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 511   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 512   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 513 esac
 514
 515 dnl Allow enablement of doxygen generated documentation
 516 AC_ARG_ENABLE(doxygen,
 517               AS_HELP_STRING([--enable-doxygen],
 518                              [Build doxygen documentation (default is NO)]),,
 519                              enableval=default)
 520 case "$enableval" in
 521   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 522   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 523   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 524   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 525 esac
 526
 527 dnl Allow disablement of threads
 528 AC_ARG_ENABLE(threads,
 529               AS_HELP_STRING([--enable-threads],
 530                              [Use threads if available (default is YES)]),,
 531                              enableval=default)
 532 case "$enableval" in
 533   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 534   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 535   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 536   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 537 esac
 538 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 539
 540 dnl Allow disablement of pthread.h
 541 AC_ARG_ENABLE(pthreads,
 542               AS_HELP_STRING([--enable-pthreads],
 543                              [Use pthreads if available (default is YES)]),,
 544                              enableval=default)
 545 case "$enableval" in
 546   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 547   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 548   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 549   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 550 esac
 551
 552 dnl Allow building without position independent code
 553 AC_ARG_ENABLE(pic,
 554   AS_HELP_STRING([--enable-pic],
 555                  [Build LLVM with Position Independent Code (default is YES)]),,
 556                  enableval=default)
 557 case "$enableval" in
 558   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 559   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 560   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 561   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 562 esac
 563 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 564                    [Define if position independent code is enabled])
 565
 566 dnl Allow building a shared library and linking tools against it.
 567 AC_ARG_ENABLE(shared,
 568   AS_HELP_STRING([--enable-shared],
 569                  [Build a shared library and link tools against it (default is NO)]),,
 570                  enableval=default)
 571 case "$enableval" in
 572   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 573   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 574   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 575   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 576 esac
 577
 578 dnl Allow libstdc++ is embedded in LLVM.dll.
 579 AC_ARG_ENABLE(embed-stdcxx,
 580   AS_HELP_STRING([--enable-embed-stdcxx],
 581                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 582                  enableval=default)
 583 case "$enableval" in
 584   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 585   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 586   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 587   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 588 esac
 589
 590 dnl Enable embedding timestamp information into build.
 591 AC_ARG_ENABLE(timestamps,
 592   AS_HELP_STRING([--enable-timestamps],
 593                  [Enable embedding timestamp information in build (default is YES)]),,
 594                  enableval=default)
 595 case "$enableval" in
 596   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 597   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 598   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 599   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 600 esac
 601 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 602                    [Define if timestamp information (e.g., __DATE___) is allowed])
 603
 604 dnl Allow specific targets to be specified for building (or not)
 605 TARGETS_TO_BUILD=""
 606 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 607     [Build specific host targets: all or target1,target2,... Valid targets are:
 608      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 609      xcore, msp430, blackfin, ptx, cbe, and cpp (default=all)]),,
 610     enableval=all)
 611 if test "$enableval" = host-only ; then
 612   enableval=host
 613 fi
 614 case "$enableval" in
 615   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 Blackfin CBackend CppBackend MBlaze PTX" ;;
 616   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 617       case "$a_target" in
 618         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 619         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 620         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 621         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 622         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 623         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 624         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 625         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 626         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 627         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 628         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 629         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 630         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 631         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 632         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 633         host) case "$llvm_cv_target_arch" in
 634             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 635             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 636             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 637             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 638             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 639             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 640             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 641             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 642             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 643             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 644             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 645             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 646             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 647             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 648           esac ;;
 649         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 650       esac
 651   done
 652   ;;
 653 esac
 654 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 655
 656 # Determine whether we are building LLVM support for the native architecture.
 657 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 658 for a_target in $TARGETS_TO_BUILD; do
 659   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 660     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 661       [LLVM architecture name for the native architecture, if available])
 662     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 663     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 664     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 665     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 666     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 667       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 668     fi
 669     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 670       [LLVM name for the native Target init function, if available])
 671     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 672       [LLVM name for the native TargetInfo init function, if available])
 673     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 674       [LLVM name for the native target MC init function, if available])
 675     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 676       [LLVM name for the native AsmPrinter init function, if available])
 677     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 678       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 679        [LLVM name for the native AsmParser init function, if available])
 680     fi
 681   fi
 682 done
 683
 684 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 685 # target feature def files.
 686 LLVM_ENUM_TARGETS=""
 687 LLVM_ENUM_ASM_PRINTERS=""
 688 LLVM_ENUM_ASM_PARSERS=""
 689 LLVM_ENUM_DISASSEMBLERS=""
 690 for target_to_build in $TARGETS_TO_BUILD; do
 691   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 692   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 693     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 694   fi
 695   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 696     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 697   fi
 698   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 699     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 700   fi
 701 done
 702 AC_SUBST(LLVM_ENUM_TARGETS)
 703 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 704 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 705 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 706
 707 dnl Prevent the CBackend from using printf("%a") for floating point so older
 708 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 709 dnl can still compile the CBE's output
 710 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 711   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 712   enableval=default)
 713 case "$enableval" in
 714   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 715   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 716   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 717   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 718 esac
 719 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 720                    [Define if CBE is enabled for printf %a output])
 721
 722 dnl Override the option to use for optimized builds.
 723 AC_ARG_WITH(optimize-option,
 724   AS_HELP_STRING([--with-optimize-option],
 725                  [Select the compiler options to use for optimized builds]),,
 726                  withval=default)
 727 AC_MSG_CHECKING([optimization flags])
 728 case "$withval" in
 729   default)
 730     case "$llvm_cv_os_type" in
 731     FreeBSD) optimize_option=-O2 ;;
 732     MingW) optimize_option=-O2 ;;
 733     *)     optimize_option=-O3 ;;
 734     esac ;;
 735   *) optimize_option="$withval" ;;
 736 esac
 737 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 738 AC_MSG_RESULT([$optimize_option])
 739
 740 dnl Specify extra build options
 741 AC_ARG_WITH(extra-options,
 742   AS_HELP_STRING([--with-extra-options],
 743                  [Specify additional options to compile LLVM with]),,
 744                  withval=default)
 745 case "$withval" in
 746   default) EXTRA_OPTIONS= ;;
 747   *) EXTRA_OPTIONS=$withval ;;
 748 esac
 749 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 750
 751 dnl Specify extra linker build options
 752 AC_ARG_WITH(extra-ld-options,
 753   AS_HELP_STRING([--with-extra-ld-options],
 754                  [Specify additional options to link LLVM with]),,
 755                  withval=default)
 756 case "$withval" in
 757   default) EXTRA_LD_OPTIONS= ;;
 758   *) EXTRA_LD_OPTIONS=$withval ;;
 759 esac
 760 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 761
 762 dnl Allow specific bindings to be specified for building (or not)
 763 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 764     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 765     enableval=default)
 766 BINDINGS_TO_BUILD=""
 767 case "$enableval" in
 768   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 769   all ) BINDINGS_TO_BUILD="ocaml" ;;
 770   none | no) BINDINGS_TO_BUILD="" ;;
 771   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 772       case "$a_binding" in
 773         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 774         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 775       esac
 776   done
 777   ;;
 778 esac
 779
 780 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 781 dnl script for bindings/ocaml/configure, except that its auto value depends on
 782 dnl OCAMLC, which is found here to support tests.
 783 AC_ARG_WITH([ocaml-libdir],
 784   [AS_HELP_STRING([--with-ocaml-libdir],
 785     [Specify install location for ocaml bindings (default is stdlib)])],
 786   [],
 787   [withval=auto])
 788 case "$withval" in
 789   auto) with_ocaml_libdir="$withval" ;;
 790   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 791   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 792 esac
 793
 794 AC_ARG_WITH(clang-srcdir,
 795   AS_HELP_STRING([--with-clang-srcdir],
 796     [Directory to the out-of-tree Clang source]),,
 797     withval="-")
 798 case "$withval" in
 799   -) clang_src_root="" ;;
 800   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 801   *) clang_src_root="$ac_pwd/$withval" ;;
 802 esac
 803 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 804
 805 AC_ARG_WITH(clang-resource-dir,
 806   AS_HELP_STRING([--with-clang-resource-dir],
 807     [Relative directory from the Clang binary for resource files]),,
 808     withval="")
 809 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 810                    [Relative directory for resource files])
 811
 812 AC_ARG_WITH(c-include-dirs,
 813   AS_HELP_STRING([--with-c-include-dirs],
 814     [Colon separated list of directories clang will search for headers]),,
 815     withval="")
 816 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 817                    [Directories clang will search for headers])
 818
 819 AC_ARG_WITH(cxx-include-root,
 820   AS_HELP_STRING([--with-cxx-include-root],
 821     [Directory with the libstdc++ headers.]),,
 822     withval="")
 823 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 824                    [Directory with the libstdc++ headers.])
 825
 826 AC_ARG_WITH(cxx-include-arch,
 827   AS_HELP_STRING([--with-cxx-include-arch],
 828     [Architecture of the libstdc++ headers.]),,
 829     withval="")
 830 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 831                    [Arch the libstdc++ headers.])
 832
 833 AC_ARG_WITH(cxx-include-32bit-dir,
 834   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 835     [32 bit multilib dir.]),,
 836     withval="")
 837 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 838                    [32 bit multilib directory.])
 839
 840 AC_ARG_WITH(cxx-include-64bit-dir,
 841   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 842     [64 bit multilib directory.]),,
 843     withval="")
 844 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 845                    [64 bit multilib directory.])
 846
 847 dnl Allow linking of LLVM with GPLv3 binutils code.
 848 AC_ARG_WITH(binutils-include,
 849   AS_HELP_STRING([--with-binutils-include],
 850     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 851   withval=default)
 852 case "$withval" in
 853   default) WITH_BINUTILS_INCDIR=default ;;
 854   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 855   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 856 esac
 857 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 858   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 859   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 860      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 861      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 862   fi
 863 fi
 864
 865 dnl Specify the URL where bug reports should be submitted.
 866 AC_ARG_WITH(bug-report-url,
 867   AS_HELP_STRING([--with-bug-report-url],
 868     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 869     withval="http://llvm.org/bugs/")
 870 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 871                    [Bug report URL.])
 872
 873 dnl --enable-libffi : check whether the user wants to turn off libffi:
 874 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 875   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 876   [case "$enableval" in
 877     yes) llvm_cv_enable_libffi="yes" ;;
 878     no)  llvm_cv_enable_libffi="no"  ;;
 879     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 880   esac],
 881   llvm_cv_enable_libffi=no)
 882
 883 dnl===-----------------------------------------------------------------------===
 884 dnl===
 885 dnl=== SECTION 4: Check for programs we need and that they are the right version
 886 dnl===
 887 dnl===-----------------------------------------------------------------------===
 888
 889 AC_PROG_NM
 890 AC_SUBST(NM)
 891
 892 dnl Check for the tools that the makefiles require
 893 AC_CHECK_GNU_MAKE
 894 AC_PROG_LN_S
 895 AC_PATH_PROG(CMP, [cmp], [cmp])
 896 AC_PATH_PROG(CP, [cp], [cp])
 897 AC_PATH_PROG(DATE, [date], [date])
 898 AC_PATH_PROG(FIND, [find], [find])
 899 AC_PATH_PROG(GREP, [grep], [grep])
 900 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 901 AC_PATH_PROG(MV,   [mv],   [mv])
 902 AC_PROG_RANLIB
 903 AC_CHECK_TOOL(AR, ar, false)
 904 AC_PATH_PROG(RM,   [rm],   [rm])
 905 AC_PATH_PROG(SED,  [sed],  [sed])
 906 AC_PATH_PROG(TAR,  [tar],  [gtar])
 907 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 908
 909 dnl Looking for misc. graph plotting software
 910 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 911 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 912   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 913   dnl If we're targeting for mingw we should emit windows paths, not msys
 914   if test "$llvm_cv_os_type" = "MingW" ; then
 915     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 916   fi
 917   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 918    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 919 fi
 920 AC_PATH_PROG(DOT, [dot], [echo dot])
 921 if test "$DOT" != "echo dot" ; then
 922   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 923   dnl If we're targeting for mingw we should emit windows paths, not msys
 924   if test "$llvm_cv_os_type" = "MingW" ; then
 925     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 926   fi
 927   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 928    [Define to path to dot program if found or 'echo dot' otherwise])
 929 fi
 930 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 931 if test "$FDP" != "echo fdp" ; then
 932   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 933   dnl If we're targeting for mingw we should emit windows paths, not msys
 934   if test "$llvm_cv_os_type" = "MingW" ; then
 935     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 936   fi
 937   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 938    [Define to path to fdp program if found or 'echo fdp' otherwise])
 939 fi
 940 AC_PATH_PROG(NEATO, [neato], [echo neato])
 941 if test "$NEATO" != "echo neato" ; then
 942   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 943   dnl If we're targeting for mingw we should emit windows paths, not msys
 944   if test "$llvm_cv_os_type" = "MingW" ; then
 945     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 946   fi
 947   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 948    [Define to path to neato program if found or 'echo neato' otherwise])
 949 fi
 950 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 951 if test "$TWOPI" != "echo twopi" ; then
 952   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 953   dnl If we're targeting for mingw we should emit windows paths, not msys
 954   if test "$llvm_cv_os_type" = "MingW" ; then
 955     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 956   fi
 957   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 958    [Define to path to twopi program if found or 'echo twopi' otherwise])
 959 fi
 960 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 961 if test "$CIRCO" != "echo circo" ; then
 962   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 963   dnl If we're targeting for mingw we should emit windows paths, not msys
 964   if test "$llvm_cv_os_type" = "MingW" ; then
 965     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 966   fi
 967   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 968    [Define to path to circo program if found or 'echo circo' otherwise])
 969 fi
 970 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 971 if test "$GV" != "echo gv" ; then
 972   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 973   dnl If we're targeting for mingw we should emit windows paths, not msys
 974   if test "$llvm_cv_os_type" = "MingW" ; then
 975     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 976   fi
 977   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 978    [Define to path to gv program if found or 'echo gv' otherwise])
 979 fi
 980 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 981 if test "$DOTTY" != "echo dotty" ; then
 982   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 983   dnl If we're targeting for mingw we should emit windows paths, not msys
 984   if test "$llvm_cv_os_type" = "MingW" ; then
 985     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 986   fi
 987   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 988    [Define to path to dotty program if found or 'echo dotty' otherwise])
 989 fi
 990 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 991 if test "$XDOT_PY" != "echo xdot.py" ; then
 992   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 993   dnl If we're targeting for mingw we should emit windows paths, not msys
 994   if test "$llvm_cv_os_type" = "MingW" ; then
 995     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 996   fi
 997   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 998    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 999 fi
1000
1001 dnl Look for a sufficiently recent version of Perl.
1002 LLVM_PROG_PERL([5.006])
1003 AC_SUBST(PERL)
1004 if test x"$PERL" = xnone; then
1005    AC_SUBST(HAVE_PERL,0)
1006    AC_MSG_ERROR([perl is required but was not found, please install it])
1007 else
1008    AC_SUBST(HAVE_PERL,1)
1009 fi
1010
1011 dnl Find the install program
1012 AC_PROG_INSTALL
1013 dnl Prepend src dir to install path dir if it's a relative path
1014 dnl This is a hack for installs that take place in something other
1015 dnl than the top level.
1016 case "$INSTALL" in
1017  [[\\/$]]* | ?:[[\\/]]* ) ;;
1018  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1019 esac
1020
1021 dnl Checks for documentation and testing tools that we can do without. If these
1022 dnl are not found then they are set to "true" which always succeeds but does
1023 dnl nothing. This just lets the build output show that we could have done
1024 dnl something if the tool was available.
1025 AC_PATH_PROG(BZIP2, [bzip2])
1026 AC_PATH_PROG(CAT, [cat])
1027 AC_PATH_PROG(DOXYGEN, [doxygen])
1028 AC_PATH_PROG(GROFF, [groff])
1029 AC_PATH_PROG(GZIPBIN, [gzip])
1030 AC_PATH_PROG(POD2HTML, [pod2html])
1031 AC_PATH_PROG(POD2MAN, [pod2man])
1032 AC_PATH_PROG(PDFROFF, [pdfroff])
1033 AC_PATH_PROG(RUNTEST, [runtest])
1034 DJ_AC_PATH_TCLSH
1035 AC_PATH_PROG(ZIP, [zip])
1036 AC_PATH_PROGS(OCAMLC, [ocamlc])
1037 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1038 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1039 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1040 AC_PATH_PROGS(GAS, [gas as])
1041
1042 dnl Get the version of the linker in use.
1043 AC_LINK_GET_VERSION
1044
1045 dnl Determine whether the linker supports the -R option.
1046 AC_LINK_USE_R
1047
1048 dnl Determine whether the linker supports the -export-dynamic option.
1049 AC_LINK_EXPORT_DYNAMIC
1050
1051 dnl Determine whether the linker supports the --version-script option.
1052 AC_LINK_VERSION_SCRIPT
1053
1054 dnl Check for libtool and the library that has dlopen function (which must come
1055 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1056 dnl libtool).
1057 AC_LIBTOOL_DLOPEN
1058 AC_LIB_LTDL
1059
1060 AC_MSG_CHECKING([tool compatibility])
1061
1062 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1063 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1064 dnl to support those options.
1065 dnl "icc" emits gcc signatures
1066 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1067 ICC=no
1068 IXX=no
1069 case $CC in
1070   icc*|icpc*)
1071     ICC=yes
1072     IXX=yes
1073     ;;
1074    *)
1075     ;;
1076 esac
1077
1078 if test "$GCC" != "yes" && test "$ICC" != "yes"
1079 then
1080   AC_MSG_ERROR([gcc|icc required but not found])
1081 fi
1082
1083 dnl Ensure that compilation tools are compatible with GCC extensions
1084 if test "$GXX" != "yes" && test "$IXX" != "yes"
1085 then
1086   AC_MSG_ERROR([g++|clang++|icc required but not found])
1087 fi
1088
1089 dnl Verify that GCC is version 3.0 or higher
1090 if test "$GCC" = "yes"
1091 then
1092   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1093 #error Unsupported GCC version
1094 #endif
1095 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1096 fi
1097
1098 dnl Check for GNU Make.  We use its extensions, so don't build without it
1099 if test -z "$llvm_cv_gnu_make_command"
1100 then
1101   AC_MSG_ERROR([GNU Make required but not found])
1102 fi
1103
1104 dnl Tool compatibility is okay if we make it here.
1105 AC_MSG_RESULT([ok])
1106
1107 dnl Check optional compiler flags.
1108 AC_MSG_CHECKING([optional compiler flags])
1109 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1110 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1111 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1112
1113 dnl===-----------------------------------------------------------------------===
1114 dnl===
1115 dnl=== SECTION 5: Check for libraries
1116 dnl===
1117 dnl===-----------------------------------------------------------------------===
1118
1119 AC_CHECK_LIB(m,sin)
1120 if test "$llvm_cv_os_type" = "MingW" ; then
1121   AC_CHECK_LIB(imagehlp, main)
1122   AC_CHECK_LIB(psapi, main)
1123 fi
1124
1125 dnl dlopen() is required for plugin support.
1126 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1127                [Define if dlopen() is available on this platform.]),
1128                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1129
1130 dnl libffi is optional; used to call external functions from the interpreter
1131 if test "$llvm_cv_enable_libffi" = "yes" ; then
1132   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1133                  [Define if libffi is available on this platform.]),
1134                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1135 fi
1136
1137 dnl mallinfo is optional; the code can compile (minus features) without it
1138 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1139                [Define if mallinfo() is available on this platform.]))
1140
1141 dnl pthread locking functions are optional - but llvm will not be thread-safe
1142 dnl without locks.
1143 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1144   AC_CHECK_LIB(pthread, pthread_mutex_init)
1145   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1146                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1147                            [Have pthread_mutex_lock]))
1148   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1149                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1150                  [Have pthread_rwlock_init]))
1151   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1152                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1153                  [Have pthread_getspecific]))
1154 fi
1155
1156 dnl Allow extra x86-disassembler library
1157 AC_ARG_WITH(udis86,
1158   AS_HELP_STRING([--with-udis86=<path>],
1159     [Use udis86 external x86 disassembler library]),
1160     [
1161       AC_SUBST(USE_UDIS86, [1])
1162       case "$withval" in
1163         /usr/lib|yes) ;;
1164         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1165       esac
1166       AC_CHECK_LIB(udis86, ud_init, [], [
1167         echo "Error! You need to have libudis86 around."
1168         exit -1
1169       ])
1170     ],
1171     AC_SUBST(USE_UDIS86, [0]))
1172 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1173                    [Define if use udis86 library])
1174
1175 dnl Allow OProfile support for JIT output.
1176 AC_ARG_WITH(oprofile,
1177   AS_HELP_STRING([--with-oprofile=<prefix>],
1178     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1179     [
1180       AC_SUBST(USE_OPROFILE, [1])
1181       case "$withval" in
1182         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1183         no) llvm_cv_oppath=
1184             AC_SUBST(USE_OPROFILE, [0]) ;;
1185         *) llvm_cv_oppath="${withval}/lib/oprofile"
1186            CPPFLAGS="-I${withval}/include";;
1187       esac
1188       if test -n "$llvm_cv_oppath" ; then
1189         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1190         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1191         dnl libbfd is not included properly in libopagent in some Debian
1192         dnl versions.  If libbfd isn't found at all, we assume opagent works
1193         dnl anyway.
1194         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1195         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1196           echo "Error! You need to have libopagent around."
1197           exit -1
1198         ])
1199         AC_CHECK_HEADER([opagent.h], [], [
1200           echo "Error! You need to have opagent.h around."
1201           exit -1
1202           ])
1203       fi
1204     ],
1205     [
1206       AC_SUBST(USE_OPROFILE, [0])
1207     ])
1208 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1209                    [Define if we have the oprofile JIT-support library])
1210
1211 dnl===-----------------------------------------------------------------------===
1212 dnl===
1213 dnl=== SECTION 6: Check for header files
1214 dnl===
1215 dnl===-----------------------------------------------------------------------===
1216
1217 dnl First, use autoconf provided macros for specific headers that we need
1218 dnl We don't check for ancient stuff or things that are guaranteed to be there
1219 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1220 dnl Generally we're looking for POSIX headers.
1221 AC_HEADER_DIRENT
1222 AC_HEADER_MMAP_ANONYMOUS
1223 AC_HEADER_STAT
1224 AC_HEADER_SYS_WAIT
1225 AC_HEADER_TIME
1226
1227 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1228 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1229 AC_CHECK_HEADERS([utime.h windows.h])
1230 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1231 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1232 AC_CHECK_HEADERS([valgrind/valgrind.h])
1233 AC_CHECK_HEADERS([fenv.h])
1234 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1235   AC_CHECK_HEADERS(pthread.h,
1236                    AC_SUBST(HAVE_PTHREAD, 1),
1237                    AC_SUBST(HAVE_PTHREAD, 0))
1238 else
1239   AC_SUBST(HAVE_PTHREAD, 0)
1240 fi
1241
1242 dnl Try to find ffi.h.
1243 if test "$llvm_cv_enable_libffi" = "yes" ; then
1244   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1245 fi
1246
1247 dnl Try to find Darwin specific crash reporting libraries.
1248 AC_CHECK_HEADERS([CrashReporterClient.h])
1249
1250 dnl Try to find Darwin specific crash reporting global.
1251 AC_MSG_CHECKING([__crashreporter_info__])
1252 AC_LINK_IFELSE(
1253   AC_LANG_SOURCE(
1254     [[extern const char *__crashreporter_info__;
1255       int main() {
1256         __crashreporter_info__ = "test";
1257         return 0;
1258       }
1259     ]]),
1260   AC_MSG_RESULT(yes)
1261   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1262   AC_MSG_RESULT(no)
1263   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1264             Define if __crashreporter_info__ exists.))
1265
1266 dnl===-----------------------------------------------------------------------===
1267 dnl===
1268 dnl=== SECTION 7: Check for types and structures
1269 dnl===
1270 dnl===-----------------------------------------------------------------------===
1271
1272 AC_HUGE_VAL_CHECK
1273 AC_TYPE_PID_T
1274 AC_TYPE_SIZE_T
1275 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1276 AC_STRUCT_TM
1277 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1278 AC_CHECK_TYPES([uint64_t],,
1279          AC_CHECK_TYPES([u_int64_t],,
1280          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1281
1282 dnl===-----------------------------------------------------------------------===
1283 dnl===
1284 dnl=== SECTION 8: Check for specific functions needed
1285 dnl===
1286 dnl===-----------------------------------------------------------------------===
1287
1288 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1289 AC_CHECK_FUNCS([powf fmodf strtof round ])
1290 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1291 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1292 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1293 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1294 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1295 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1296 AC_C_PRINTF_A
1297 AC_FUNC_RAND48
1298
1299 dnl Check the declaration "Secure API" on Windows environments.
1300 AC_CHECK_DECLS([strerror_s])
1301
1302 dnl Check symbols in libgcc.a for JIT on Mingw.
1303 if test "$llvm_cv_os_type" = "MingW" ; then
1304   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1305   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1306   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1307   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1308
1309   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1310   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1311   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1312   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1313   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1314   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1315   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1316   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1317   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1318   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1319
1320   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1321   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1322 fi
1323
1324 dnl Check Win32 API EnumerateLoadedModules.
1325 if test "$llvm_cv_os_type" = "MingW" ; then
1326   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1327   AC_COMPILE_IFELSE([[#include <windows.h>
1328 #include <imagehlp.h>
1329 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1330 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1331 [
1332   AC_MSG_RESULT([yes])
1333   llvm_cv_win32_elmcb_pcstr="PCSTR"
1334 ],
1335 [
1336   AC_MSG_RESULT([no])
1337   llvm_cv_win32_elmcb_pcstr="PSTR"
1338 ])
1339   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1340 fi
1341
1342 dnl Check for variations in the Standard C++ library and STL. These macros are
1343 dnl provided by LLVM in the autoconf/m4 directory.
1344 AC_FUNC_ISNAN
1345 AC_FUNC_ISINF
1346
1347 dnl Check for mmap support.We also need to know if /dev/zero is required to
1348 dnl be opened for allocating RWX memory.
1349 dnl Make sure we aren't attempting to configure for an unknown system
1350 if test "$llvm_cv_platform_type" = "Unix" ; then
1351   AC_FUNC_MMAP
1352   AC_FUNC_MMAP_FILE
1353   AC_NEED_DEV_ZERO_FOR_MMAP
1354
1355   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1356   then
1357     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1358   fi
1359   if test "$ac_cv_func_mmap_file" = "no"
1360   then
1361     AC_MSG_WARN([mmap() of files required but not found])
1362   fi
1363 fi
1364
1365 dnl atomic builtins are required for threading support.
1366 AC_MSG_CHECKING(for GCC atomic builtins)
1367 dnl Since we'll be using these atomic builtins in C++ files we should test
1368 dnl the C++ compiler.
1369 AC_LANG_PUSH([C++])
1370 AC_LINK_IFELSE(
1371   AC_LANG_SOURCE(
1372     [[int main() {
1373         volatile unsigned long val = 1;
1374         __sync_synchronize();
1375         __sync_val_compare_and_swap(&val, 1, 0);
1376         __sync_add_and_fetch(&val, 1);
1377         __sync_sub_and_fetch(&val, 1);
1378         return 0;
1379       }
1380     ]]),
1381   AC_LANG_POP([C++])
1382   AC_MSG_RESULT(yes)
1383   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1384   AC_MSG_RESULT(no)
1385   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1386   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1387
1388 dnl===-----------------------------------------------------------------------===
1389 dnl===
1390 dnl=== SECTION 9: Additional checks, variables, etc.
1391 dnl===
1392 dnl===-----------------------------------------------------------------------===
1393
1394 dnl Handle 32-bit linux systems running a 64-bit kernel.
1395 dnl This has to come after section 4 because it invokes the compiler.
1396 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1397   AC_IS_LINUX_MIXED
1398   if test "$llvm_cv_linux_mixed" = "yes"; then
1399     llvm_cv_target_arch="x86"
1400     ARCH="x86"
1401   fi
1402 fi
1403
1404 dnl Check whether __dso_handle is present
1405 AC_CHECK_FUNCS([__dso_handle])
1406
1407 dnl Propagate the shared library extension that the libltdl checks did to
1408 dnl the Makefiles so we can use it there too
1409 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1410
1411 dnl Propagate the run-time library path variable that the libltdl
1412 dnl checks found to the Makefiles so we can use it there too
1413 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1414
1415 # Translate the various configuration directories and other basic
1416 # information into substitutions that will end up in Makefile.config.in
1417 # that these configured values can be used by the makefiles
1418 if test "${prefix}" = "NONE" ; then
1419   prefix="/usr/local"
1420 fi
1421 eval LLVM_PREFIX="${prefix}";
1422 eval LLVM_BINDIR="${prefix}/bin";
1423 eval LLVM_LIBDIR="${prefix}/lib";
1424 eval LLVM_DATADIR="${prefix}/share/llvm";
1425 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1426 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1427 eval LLVM_INCLUDEDIR="${prefix}/include";
1428 eval LLVM_INFODIR="${prefix}/info";
1429 eval LLVM_MANDIR="${prefix}/man";
1430 LLVM_CONFIGTIME=`date`
1431 AC_SUBST(LLVM_PREFIX)
1432 AC_SUBST(LLVM_BINDIR)
1433 AC_SUBST(LLVM_LIBDIR)
1434 AC_SUBST(LLVM_DATADIR)
1435 AC_SUBST(LLVM_DOCSDIR)
1436 AC_SUBST(LLVM_ETCDIR)
1437 AC_SUBST(LLVM_INCLUDEDIR)
1438 AC_SUBST(LLVM_INFODIR)
1439 AC_SUBST(LLVM_MANDIR)
1440 AC_SUBST(LLVM_CONFIGTIME)
1441
1442 # Place the various directores into the config.h file as #defines so that we
1443 # can know about the installation paths within LLVM.
1444 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1445                    [Installation prefix directory])
1446 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1447                    [Installation directory for binary executables])
1448 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1449                    [Installation directory for libraries])
1450 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1451                    [Installation directory for data files])
1452 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1453                    [Installation directory for documentation])
1454 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1455                    [Installation directory for config files])
1456 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1457                    [Installation directory for include files])
1458 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1459                    [Installation directory for .info files])
1460 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1461                    [Installation directory for man pages])
1462 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1463                    [Time at which LLVM was configured])
1464 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1465                    [Host triple we were built on])
1466
1467 # Determine which bindings to build.
1468 if test "$BINDINGS_TO_BUILD" = auto ; then
1469   BINDINGS_TO_BUILD=""
1470   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1471     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1472   fi
1473 fi
1474 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1475
1476 # This isn't really configurey, but it avoids having to repeat the list in
1477 # other files.
1478 AC_SUBST(ALL_BINDINGS,ocaml)
1479
1480 # Do any work necessary to ensure that bindings have what they need.
1481 binding_prereqs_failed=0
1482 for a_binding in $BINDINGS_TO_BUILD ; do
1483   case "$a_binding" in
1484   ocaml)
1485     if test "x$OCAMLC" = x ; then
1486       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1487       binding_prereqs_failed=1
1488     fi
1489     if test "x$OCAMLDEP" = x ; then
1490       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1491       binding_prereqs_failed=1
1492     fi
1493     if test "x$OCAMLOPT" = x ; then
1494       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1495       dnl ocamlopt is optional!
1496     fi
1497     if test "x$with_ocaml_libdir" != xauto ; then
1498       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1499     else
1500       ocaml_stdlib="`"$OCAMLC" -where`"
1501       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1502       then
1503         # ocaml stdlib is beneath our prefix; use stdlib
1504         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1505       else
1506         # ocaml stdlib is outside our prefix; use libdir/ocaml
1507         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1508       fi
1509     fi
1510     ;;
1511   esac
1512 done
1513 if test "$binding_prereqs_failed" = 1 ; then
1514   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1515 fi
1516
1517 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1518 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1519
1520 dnl Determine linker rpath flag
1521 if test "$llvm_cv_link_use_r" = "yes" ; then
1522   RPATH="-Wl,-R"
1523 else
1524   RPATH="-Wl,-rpath"
1525 fi
1526 AC_SUBST(RPATH)
1527
1528 dnl Determine linker rdynamic flag
1529 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1530   RDYNAMIC="-Wl,-export-dynamic"
1531 else
1532   RDYNAMIC=""
1533 fi
1534 AC_SUBST(RDYNAMIC)
1535
1536 dnl===-----------------------------------------------------------------------===
1537 dnl===
1538 dnl=== SECTION 10: Specify the output files and generate it
1539 dnl===
1540 dnl===-----------------------------------------------------------------------===
1541
1542 dnl Configure header files
1543 dnl WARNING: dnl If you add or remove any of the following config headers, then
1544 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1545 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1546 dnl files can be updated automatically when their *.in sources change.
1547 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1548 AH_TOP([#ifndef CONFIG_H
1549 #define CONFIG_H])
1550 AH_BOTTOM([#endif])
1551
1552 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1553 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1554 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1555 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1556 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1557
1558 dnl Configure the makefile's configuration data
1559 AC_CONFIG_FILES([Makefile.config])
1560
1561 dnl Configure the RPM spec file for LLVM
1562 AC_CONFIG_FILES([llvm.spec])
1563
1564 dnl Configure doxygen's configuration file
1565 AC_CONFIG_FILES([docs/doxygen.cfg])
1566 if test -f ${srcdir}/tools/clang/README.txt; then
1567   AC_CONFIG_FILES([tools/clang/docs/doxygen.cfg])
1568 fi
1569
1570 dnl Do the first stage of configuration for llvm-config.in.
1571 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1572
1573 dnl OCaml findlib META file
1574 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1575
1576 dnl Do special configuration of Makefiles
1577 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1578 AC_CONFIG_MAKEFILE(Makefile)
1579 AC_CONFIG_MAKEFILE(Makefile.common)
1580 AC_CONFIG_MAKEFILE(examples/Makefile)
1581 AC_CONFIG_MAKEFILE(lib/Makefile)
1582 AC_CONFIG_MAKEFILE(runtime/Makefile)
1583 AC_CONFIG_MAKEFILE(test/Makefile)
1584 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1585 AC_CONFIG_MAKEFILE(unittests/Makefile)
1586 AC_CONFIG_MAKEFILE(tools/Makefile)
1587 AC_CONFIG_MAKEFILE(utils/Makefile)
1588 AC_CONFIG_MAKEFILE(projects/Makefile)
1589 AC_CONFIG_MAKEFILE(bindings/Makefile)
1590 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1591
1592 dnl Finally, crank out the output
1593 AC_OUTPUT