autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.2svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [2], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl We need to check for the compiler up here to avoid anything else
  63 dnl starting with a different one.
  64 AC_PROG_CC(clang llvm-gcc gcc)
  65 AC_PROG_CXX(clang++ llvm-g++ g++)
  66 AC_PROG_CPP
  67
  68 dnl Configure all of the projects present in our source tree. While we could
  69 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  70 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  71 dnl Instead we match on the known projects.
  72
  73 dnl
  74 dnl One tricky part of doing this is that some projects depend upon other
  75 dnl projects.  For example, several projects rely upon the LLVM test suite.
  76 dnl We want to configure those projects first so that their object trees are
  77 dnl created before running the configure scripts of projects that depend upon
  78 dnl them.
  79 dnl
  80
  81 dnl Several projects use llvm-gcc, so configure that first
  82 if test -d ${srcdir}/projects/llvm-gcc ; then
  83   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  84 fi
  85
  86 dnl Several projects use the LLVM test suite, so configure it next.
  87 if test -d ${srcdir}/projects/test-suite ; then
  88   AC_CONFIG_SUBDIRS([projects/test-suite])
  89 fi
  90
  91 dnl llvm-test is the old name of the test-suite, kept here for backwards
  92 dnl compatibility
  93 if test -d ${srcdir}/projects/llvm-test ; then
  94   AC_CONFIG_SUBDIRS([projects/llvm-test])
  95 fi
  96
  97 dnl Some projects use poolalloc; configure that next
  98 if test -d ${srcdir}/projects/poolalloc ; then
  99   AC_CONFIG_SUBDIRS([projects/poolalloc])
 100 fi
 101
 102 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 103   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 104 fi
 105
 106 dnl Check for all other projects
 107 for i in `ls ${srcdir}/projects`
 108 do
 109   if test -d ${srcdir}/projects/${i} ; then
 110     case ${i} in
 111       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 112       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 113       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 114       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 115       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 116       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 117       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 118       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 119       compiler-rt)       ;;
 120       llvm-gcc)       ;;
 121       test-suite)     ;;
 122       llvm-test)      ;;
 123       poolalloc)      ;;
 124       llvm-poolalloc) ;;
 125       *)
 126         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 127         ;;
 128     esac
 129   fi
 130 done
 131
 132 dnl Disable the build of polly, even if it is checked out into tools/polly.
 133 AC_ARG_ENABLE(polly,
 134               AS_HELP_STRING([--enable-polly],
 135                              [Use polly if available (default is YES)]),,
 136                              enableval=default)
 137 case "$enableval" in
 138   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 140   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 141   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 142 esac
 143
 144
 145 dnl Check if polly is checked out into tools/polly and configure it if
 146 dnl available.
 147 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 148   AC_SUBST(LLVM_HAS_POLLY,1)
 149   AC_CONFIG_SUBDIRS([tools/polly])
 150 fi
 151
 152 dnl===-----------------------------------------------------------------------===
 153 dnl===
 154 dnl=== SECTION 2: Architecture, target, and host checks
 155 dnl===
 156 dnl===-----------------------------------------------------------------------===
 157
 158 dnl Check the target for which we're compiling and the host that will do the
 159 dnl compilations. This will tell us which LLVM compiler will be used for
 160 dnl compiling SSA into object code. This needs to be done early because
 161 dnl following tests depend on it.
 162 AC_CANONICAL_TARGET
 163
 164 dnl Determine the platform type and cache its value. This helps us configure
 165 dnl the System library to the correct build platform.
 166 AC_CACHE_CHECK([type of operating system we're going to host on],
 167                [llvm_cv_os_type],
 168 [case $host in
 169   *-*-aix*)
 170     llvm_cv_link_all_option="-Wl,--whole-archive"
 171     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 172     llvm_cv_os_type="AIX"
 173     llvm_cv_platform_type="Unix" ;;
 174   *-*-irix*)
 175     llvm_cv_link_all_option="-Wl,--whole-archive"
 176     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 177     llvm_cv_os_type="IRIX"
 178     llvm_cv_platform_type="Unix" ;;
 179   *-*-cygwin*)
 180     llvm_cv_link_all_option="-Wl,--whole-archive"
 181     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 182     llvm_cv_os_type="Cygwin"
 183     llvm_cv_platform_type="Unix" ;;
 184   *-*-darwin*)
 185     llvm_cv_link_all_option="-Wl,-all_load"
 186     llvm_cv_no_link_all_option="-Wl,-noall_load"
 187     llvm_cv_os_type="Darwin"
 188     llvm_cv_platform_type="Unix" ;;
 189   *-*-minix*)
 190     llvm_cv_link_all_option="-Wl,-all_load"
 191     llvm_cv_no_link_all_option="-Wl,-noall_load"
 192     llvm_cv_os_type="Minix"
 193     llvm_cv_platform_type="Unix" ;;
 194   *-*-freebsd* | *-*-kfreebsd-gnu)
 195     llvm_cv_link_all_option="-Wl,--whole-archive"
 196     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 197     llvm_cv_os_type="FreeBSD"
 198     llvm_cv_platform_type="Unix" ;;
 199   *-*-openbsd*)
 200     llvm_cv_link_all_option="-Wl,--whole-archive"
 201     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 202     llvm_cv_os_type="OpenBSD"
 203     llvm_cv_platform_type="Unix" ;;
 204   *-*-netbsd*)
 205     llvm_cv_link_all_option="-Wl,--whole-archive"
 206     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 207     llvm_cv_os_type="NetBSD"
 208     llvm_cv_platform_type="Unix" ;;
 209   *-*-dragonfly*)
 210     llvm_cv_link_all_option="-Wl,--whole-archive"
 211     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 212     llvm_cv_os_type="DragonFly"
 213     llvm_cv_platform_type="Unix" ;;
 214   *-*-hpux*)
 215     llvm_cv_link_all_option="-Wl,--whole-archive"
 216     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 217     llvm_cv_os_type="HP-UX"
 218     llvm_cv_platform_type="Unix" ;;
 219   *-*-interix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="Interix"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-linux*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="Linux"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-gnu*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="GNU"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-solaris*)
 235     llvm_cv_link_all_option="-Wl,-z,allextract"
 236     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 237     llvm_cv_os_type="SunOS"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-auroraux*)
 240     llvm_cv_link_all_option="-Wl,-z,allextract"
 241     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 242     llvm_cv_os_type="AuroraUX"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-win32*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="Win32"
 248     llvm_cv_platform_type="Win32" ;;
 249   *-*-mingw*)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="MingW"
 253     llvm_cv_platform_type="Win32" ;;
 254   *-*-haiku*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="Haiku"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-unknown-eabi*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="Freestanding"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-unknown-elf*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="Freestanding"
 268     llvm_cv_platform_type="Unix" ;;
 269   *)
 270     llvm_cv_link_all_option=""
 271     llvm_cv_no_link_all_option=""
 272     llvm_cv_os_type="Unknown"
 273     llvm_cv_platform_type="Unknown" ;;
 274 esac])
 275
 276 AC_CACHE_CHECK([type of operating system we're going to target],
 277                [llvm_cv_target_os_type],
 278 [case $target in
 279   *-*-aix*)
 280     llvm_cv_target_os_type="AIX" ;;
 281   *-*-irix*)
 282     llvm_cv_target_os_type="IRIX" ;;
 283   *-*-cygwin*)
 284     llvm_cv_target_os_type="Cygwin" ;;
 285   *-*-darwin*)
 286     llvm_cv_target_os_type="Darwin" ;;
 287   *-*-minix*)
 288     llvm_cv_target_os_type="Minix" ;;
 289   *-*-freebsd* | *-*-kfreebsd-gnu)
 290     llvm_cv_target_os_type="FreeBSD" ;;
 291   *-*-openbsd*)
 292     llvm_cv_target_os_type="OpenBSD" ;;
 293   *-*-netbsd*)
 294     llvm_cv_target_os_type="NetBSD" ;;
 295   *-*-dragonfly*)
 296     llvm_cv_target_os_type="DragonFly" ;;
 297   *-*-hpux*)
 298     llvm_cv_target_os_type="HP-UX" ;;
 299   *-*-interix*)
 300     llvm_cv_target_os_type="Interix" ;;
 301   *-*-linux*)
 302     llvm_cv_target_os_type="Linux" ;;
 303   *-*-gnu*)
 304     llvm_cv_target_os_type="GNU" ;;
 305   *-*-solaris*)
 306     llvm_cv_target_os_type="SunOS" ;;
 307   *-*-auroraux*)
 308     llvm_cv_target_os_type="AuroraUX" ;;
 309   *-*-win32*)
 310     llvm_cv_target_os_type="Win32" ;;
 311   *-*-mingw*)
 312     llvm_cv_target_os_type="MingW" ;;
 313   *-*-haiku*)
 314     llvm_cv_target_os_type="Haiku" ;;
 315   *-*-rtems*)
 316     llvm_cv_target_os_type="RTEMS" ;;
 317   *-*-nacl*)
 318     llvm_cv_target_os_type="NativeClient" ;;
 319   *-unknown-eabi*)
 320     llvm_cv_target_os_type="Freestanding" ;;
 321   *)
 322     llvm_cv_target_os_type="Unknown" ;;
 323 esac])
 324
 325 dnl Make sure we aren't attempting to configure for an unknown system
 326 if test "$llvm_cv_os_type" = "Unknown" ; then
 327   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 328 fi
 329
 330 dnl Set the "OS" Makefile variable based on the platform type so the
 331 dnl makefile can configure itself to specific build hosts
 332 AC_SUBST(OS,$llvm_cv_os_type)
 333 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 334 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 335
 336 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 337 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 338 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 339
 340 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 341 dnl This is used by lib/Support to determine the basic kind of implementation
 342 dnl to use.
 343 case $llvm_cv_platform_type in
 344   Unix)
 345     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 346     AC_SUBST(LLVM_ON_UNIX,[1])
 347     AC_SUBST(LLVM_ON_WIN32,[0])
 348     ;;
 349   Win32)
 350     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 351     AC_SUBST(LLVM_ON_UNIX,[0])
 352     AC_SUBST(LLVM_ON_WIN32,[1])
 353     ;;
 354 esac
 355
 356 dnl Determine what our target architecture is and configure accordingly.
 357 dnl This will allow Makefiles to make a distinction between the hardware and
 358 dnl the OS.
 359 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 360 [case $target in
 361   i?86-*)                 llvm_cv_target_arch="x86" ;;
 362   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 363   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 364   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 365   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 366   mips-*)                 llvm_cv_target_arch="Mips" ;;
 367   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 368   xcore-*)                llvm_cv_target_arch="XCore" ;;
 369   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 370   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 371   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 372   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 373   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 374   *)                      llvm_cv_target_arch="Unknown" ;;
 375 esac])
 376
 377 if test "$llvm_cv_target_arch" = "Unknown" ; then
 378   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 379 fi
 380
 381 dnl Determine the LLVM native architecture for the target
 382 case "$llvm_cv_target_arch" in
 383     x86)     LLVM_NATIVE_ARCH="X86" ;;
 384     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 385     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 386 esac
 387
 388 dnl Define a substitution, ARCH, for the target architecture
 389 AC_SUBST(ARCH,$llvm_cv_target_arch)
 390
 391 dnl Check for the endianness of the target
 392 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 393
 394 dnl Check for build platform executable suffix if we're cross-compiling
 395 if test "$cross_compiling" = yes; then
 396   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 397   AC_BUILD_EXEEXT
 398   ac_build_prefix=${build_alias}-
 399   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 400   if test -z "$BUILD_CXX"; then
 401      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 402      if test -z "$BUILD_CXX"; then
 403        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 404      fi
 405   fi
 406 else
 407   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 408 fi
 409
 410 dnl Check to see if there's a .svn or .git directory indicating that this
 411 dnl build is being done from a checkout. This sets up several defaults for
 412 dnl the command line switches. When we build with a checkout directory,
 413 dnl we get a debug with assertions turned on. Without, we assume a source
 414 dnl release and we get an optimized build without assertions.
 415 dnl See --enable-optimized and --enable-assertions below
 416 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 417   cvsbuild="yes"
 418   optimize="no"
 419   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 420 else
 421   cvsbuild="no"
 422   optimize="yes"
 423 fi
 424
 425 dnl===-----------------------------------------------------------------------===
 426 dnl===
 427 dnl=== SECTION 3: Command line arguments for the configure script.
 428 dnl===
 429 dnl===-----------------------------------------------------------------------===
 430
 431 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 432 AC_ARG_ENABLE(libcpp,
 433               AS_HELP_STRING([--enable-libcpp],
 434                              [Use libc++ if available (default is NO)]),,
 435                              enableval=default)
 436 case "$enableval" in
 437   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 438   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 439   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 440   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 441 esac
 442
 443 dnl --enable-optimized : check whether they want to do an optimized build:
 444 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 445  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 446 if test ${enableval} = "no" ; then
 447   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 448 else
 449   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 450 fi
 451
 452 dnl --enable-profiling : check whether they want to do a profile build:
 453 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 454  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 455 if test ${enableval} = "no" ; then
 456   AC_SUBST(ENABLE_PROFILING,[[]])
 457 else
 458   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 459 fi
 460
 461 dnl --enable-assertions : check whether they want to turn on assertions or not:
 462 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 463   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 464 if test ${enableval} = "yes" ; then
 465   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 466 else
 467   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 468 fi
 469
 470 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 471 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 472   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 473 if test ${enableval} = "yes" ; then
 474   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 475   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 476 else
 477   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 478   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 479 fi
 480
 481 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 482 AC_ARG_ENABLE(debug-runtime,
 483    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 484 if test ${enableval} = "no" ; then
 485   AC_SUBST(DEBUG_RUNTIME,[[]])
 486 else
 487   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 488 fi
 489
 490 dnl --enable-debug-symbols : should even optimized compiler libraries
 491 dnl have debug symbols?
 492 AC_ARG_ENABLE(debug-symbols,
 493    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 494 if test ${enableval} = "no" ; then
 495   AC_SUBST(DEBUG_SYMBOLS,[[]])
 496 else
 497   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 498 fi
 499
 500 dnl --enable-jit: check whether they want to enable the jit
 501 AC_ARG_ENABLE(jit,
 502   AS_HELP_STRING(--enable-jit,
 503                  [Enable Just In Time Compiling (default is YES)]),,
 504   enableval=default)
 505 if test ${enableval} = "no"
 506 then
 507   AC_SUBST(JIT,[[]])
 508 else
 509   case "$llvm_cv_target_arch" in
 510     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 511     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 512     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 513     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 514     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 515     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 516     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 517     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 518     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 519     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 520     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 521     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 522     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 523   esac
 524 fi
 525
 526 dnl Allow enablement of building and installing docs
 527 AC_ARG_ENABLE(docs,
 528               AS_HELP_STRING([--enable-docs],
 529                              [Build documents (default is YES)]),,
 530                              enableval=default)
 531 case "$enableval" in
 532   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 533   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 534   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 535   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 536 esac
 537
 538 dnl Allow enablement of doxygen generated documentation
 539 AC_ARG_ENABLE(doxygen,
 540               AS_HELP_STRING([--enable-doxygen],
 541                              [Build doxygen documentation (default is NO)]),,
 542                              enableval=default)
 543 case "$enableval" in
 544   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 545   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 546   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 547   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 548 esac
 549
 550 dnl Allow disablement of threads
 551 AC_ARG_ENABLE(threads,
 552               AS_HELP_STRING([--enable-threads],
 553                              [Use threads if available (default is YES)]),,
 554                              enableval=default)
 555 case "$enableval" in
 556   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 557   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 558   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 559   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 560 esac
 561 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 562                    [Define if threads enabled])
 563
 564 dnl Allow disablement of pthread.h
 565 AC_ARG_ENABLE(pthreads,
 566               AS_HELP_STRING([--enable-pthreads],
 567                              [Use pthreads if available (default is YES)]),,
 568                              enableval=default)
 569 case "$enableval" in
 570   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 571   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 572   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 573   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 574 esac
 575
 576 dnl Allow building without position independent code
 577 AC_ARG_ENABLE(pic,
 578   AS_HELP_STRING([--enable-pic],
 579                  [Build LLVM with Position Independent Code (default is YES)]),,
 580                  enableval=default)
 581 case "$enableval" in
 582   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 583   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 584   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 585   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 586 esac
 587 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 588                    [Define if position independent code is enabled])
 589
 590 dnl Allow building a shared library and linking tools against it.
 591 AC_ARG_ENABLE(shared,
 592   AS_HELP_STRING([--enable-shared],
 593                  [Build a shared library and link tools against it (default is NO)]),,
 594                  enableval=default)
 595 case "$enableval" in
 596   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 597   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 598   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 599   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 600 esac
 601
 602 dnl Allow libstdc++ is embedded in LLVM.dll.
 603 AC_ARG_ENABLE(embed-stdcxx,
 604   AS_HELP_STRING([--enable-embed-stdcxx],
 605                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 606                  enableval=default)
 607 case "$enableval" in
 608   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 609   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 610   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 611   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 612 esac
 613
 614 dnl Enable embedding timestamp information into build.
 615 AC_ARG_ENABLE(timestamps,
 616   AS_HELP_STRING([--enable-timestamps],
 617                  [Enable embedding timestamp information in build (default is YES)]),,
 618                  enableval=default)
 619 case "$enableval" in
 620   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 621   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 622   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 623   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 624 esac
 625 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 626                    [Define if timestamp information (e.g., __DATE___) is allowed])
 627
 628 dnl Allow specific targets to be specified for building (or not)
 629 TARGETS_TO_BUILD=""
 630 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 631     [Build specific host targets: all or target1,target2,... Valid targets are:
 632      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 633      xcore, msp430, ptx, nvptx, and cpp (default=all)]),,
 634     enableval=all)
 635 if test "$enableval" = host-only ; then
 636   enableval=host
 637 fi
 638 case "$enableval" in
 639   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CppBackend MBlaze PTX NVPTX Hexagon" ;;
 640   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 641       case "$a_target" in
 642         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 643         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 644         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 645         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 646         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 647         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 648         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 649         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 650         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 651         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 652         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 653         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 654         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 655         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 656         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 657         host) case "$llvm_cv_target_arch" in
 658             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 659             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 660             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 661             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 662             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 663             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 664             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 665             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 666             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 667             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 668             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 669             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 670             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 671             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 672           esac ;;
 673         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 674       esac
 675   done
 676   ;;
 677 esac
 678 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 679
 680 dnl Determine whether we are building LLVM support for the native architecture.
 681 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 682 for a_target in $TARGETS_TO_BUILD; do
 683   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 684     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 685       [LLVM architecture name for the native architecture, if available])
 686     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 687     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 688     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 689     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 690     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 691       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 692     fi
 693     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 694       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 695     fi
 696     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 697       [LLVM name for the native Target init function, if available])
 698     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 699       [LLVM name for the native TargetInfo init function, if available])
 700     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 701       [LLVM name for the native target MC init function, if available])
 702     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 703       [LLVM name for the native AsmPrinter init function, if available])
 704     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 705       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 706        [LLVM name for the native AsmParser init function, if available])
 707     fi
 708     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 709       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 710        [LLVM name for the native Disassembler init function, if available])
 711     fi
 712   fi
 713 done
 714
 715 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 716 dnl target feature def files.
 717 LLVM_ENUM_TARGETS=""
 718 LLVM_ENUM_ASM_PRINTERS=""
 719 LLVM_ENUM_ASM_PARSERS=""
 720 LLVM_ENUM_DISASSEMBLERS=""
 721 for target_to_build in $TARGETS_TO_BUILD; do
 722   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 723   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 724     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 725   fi
 726   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 727     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 728   fi
 729   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 730     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 731   fi
 732 done
 733 AC_SUBST(LLVM_ENUM_TARGETS)
 734 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 735 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 736 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 737
 738 dnl Override the option to use for optimized builds.
 739 AC_ARG_WITH(optimize-option,
 740   AS_HELP_STRING([--with-optimize-option],
 741                  [Select the compiler options to use for optimized builds]),,
 742                  withval=default)
 743 AC_MSG_CHECKING([optimization flags])
 744 case "$withval" in
 745   default)
 746     case "$llvm_cv_os_type" in
 747     FreeBSD) optimize_option=-O2 ;;
 748     MingW) optimize_option=-O2 ;;
 749     *)     optimize_option=-O3 ;;
 750     esac ;;
 751   *) optimize_option="$withval" ;;
 752 esac
 753 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 754 AC_MSG_RESULT([$optimize_option])
 755
 756 dnl Specify extra build options
 757 AC_ARG_WITH(extra-options,
 758   AS_HELP_STRING([--with-extra-options],
 759                  [Specify additional options to compile LLVM with]),,
 760                  withval=default)
 761 case "$withval" in
 762   default) EXTRA_OPTIONS= ;;
 763   *) EXTRA_OPTIONS=$withval ;;
 764 esac
 765 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 766
 767 dnl Specify extra linker build options
 768 AC_ARG_WITH(extra-ld-options,
 769   AS_HELP_STRING([--with-extra-ld-options],
 770                  [Specify additional options to link LLVM with]),,
 771                  withval=default)
 772 case "$withval" in
 773   default) EXTRA_LD_OPTIONS= ;;
 774   *) EXTRA_LD_OPTIONS=$withval ;;
 775 esac
 776 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 777
 778 dnl Allow specific bindings to be specified for building (or not)
 779 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 780     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 781     enableval=default)
 782 BINDINGS_TO_BUILD=""
 783 case "$enableval" in
 784   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 785   all ) BINDINGS_TO_BUILD="ocaml" ;;
 786   none | no) BINDINGS_TO_BUILD="" ;;
 787   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 788       case "$a_binding" in
 789         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 790         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 791       esac
 792   done
 793   ;;
 794 esac
 795
 796 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 797 dnl script for bindings/ocaml/configure, except that its auto value depends on
 798 dnl OCAMLC, which is found here to support tests.
 799 AC_ARG_WITH([ocaml-libdir],
 800   [AS_HELP_STRING([--with-ocaml-libdir],
 801     [Specify install location for ocaml bindings (default is stdlib)])],
 802   [],
 803   [withval=auto])
 804 case "$withval" in
 805   auto) with_ocaml_libdir="$withval" ;;
 806   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 807   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 808 esac
 809
 810 AC_ARG_WITH(clang-srcdir,
 811   AS_HELP_STRING([--with-clang-srcdir],
 812     [Directory to the out-of-tree Clang source]),,
 813     withval="-")
 814 case "$withval" in
 815   -) clang_src_root="" ;;
 816   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 817   *) clang_src_root="$ac_pwd/$withval" ;;
 818 esac
 819 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 820
 821 AC_ARG_WITH(clang-resource-dir,
 822   AS_HELP_STRING([--with-clang-resource-dir],
 823     [Relative directory from the Clang binary for resource files]),,
 824     withval="")
 825 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 826                    [Relative directory for resource files])
 827
 828 AC_ARG_WITH(c-include-dirs,
 829   AS_HELP_STRING([--with-c-include-dirs],
 830     [Colon separated list of directories clang will search for headers]),,
 831     withval="")
 832 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 833                    [Directories clang will search for headers])
 834
 835 # Clang normally uses the system c++ headers and libraries. With this option,
 836 # clang will use the ones provided by a gcc installation instead. This option should
 837 # be passed the same value that was used with --prefix when configuring gcc.
 838 AC_ARG_WITH(gcc-toolchain,
 839   AS_HELP_STRING([--with-gcc-toolchain],
 840     [Directory where gcc is installed.]),,
 841     withval="")
 842 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 843                    [Directory where gcc is installed.])
 844
 845 AC_ARG_WITH(default-sysroot,
 846   AS_HELP_STRING([--with-default-sysroot],
 847     [Add --sysroot=<path> to all compiler invocations.]),,
 848     withval="")
 849 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
 850                    [Default <path> to all compiler invocations for --sysroot=<path>.])
 851
 852 dnl Allow linking of LLVM with GPLv3 binutils code.
 853 AC_ARG_WITH(binutils-include,
 854   AS_HELP_STRING([--with-binutils-include],
 855     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 856   withval=default)
 857 case "$withval" in
 858   default) WITH_BINUTILS_INCDIR=default ;;
 859   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 860   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 861 esac
 862 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 863   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 864   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 865      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 866      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 867   fi
 868 fi
 869
 870 dnl Specify the URL where bug reports should be submitted.
 871 AC_ARG_WITH(bug-report-url,
 872   AS_HELP_STRING([--with-bug-report-url],
 873     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 874     withval="http://llvm.org/bugs/")
 875 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 876                    [Bug report URL.])
 877
 878 dnl --enable-libffi : check whether the user wants to turn off libffi:
 879 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 880   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 881   [case "$enableval" in
 882     yes) llvm_cv_enable_libffi="yes" ;;
 883     no)  llvm_cv_enable_libffi="no"  ;;
 884     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 885   esac],
 886   llvm_cv_enable_libffi=no)
 887
 888 AC_ARG_WITH(internal-prefix,
 889   AS_HELP_STRING([--with-internal-prefix],
 890     [Installation directory for internal files]),,
 891     withval="")
 892 AC_SUBST(INTERNAL_PREFIX,[$withval])
 893
 894 dnl===-----------------------------------------------------------------------===
 895 dnl===
 896 dnl=== SECTION 4: Check for programs we need and that they are the right version
 897 dnl===
 898 dnl===-----------------------------------------------------------------------===
 899
 900 AC_PROG_NM
 901 AC_SUBST(NM)
 902
 903 dnl Check for the tools that the makefiles require
 904 AC_CHECK_GNU_MAKE
 905 AC_PROG_LN_S
 906 AC_PATH_PROG(CMP, [cmp], [cmp])
 907 AC_PATH_PROG(CP, [cp], [cp])
 908 AC_PATH_PROG(DATE, [date], [date])
 909 AC_PATH_PROG(FIND, [find], [find])
 910 AC_PATH_PROG(GREP, [grep], [grep])
 911 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 912 AC_PATH_PROG(MV,   [mv],   [mv])
 913 AC_PROG_RANLIB
 914 AC_CHECK_TOOL(AR, ar, false)
 915 AC_PATH_PROG(RM,   [rm],   [rm])
 916 AC_PATH_PROG(SED,  [sed],  [sed])
 917 AC_PATH_PROG(TAR,  [tar],  [gtar])
 918 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 919
 920 dnl Looking for misc. graph plotting software
 921 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 922 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 923   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 924   dnl If we're targeting for mingw we should emit windows paths, not msys
 925   if test "$llvm_cv_os_type" = "MingW" ; then
 926     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 927   fi
 928   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 929    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 930 fi
 931 AC_PATH_PROG(DOT, [dot], [echo dot])
 932 if test "$DOT" != "echo dot" ; then
 933   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 934   dnl If we're targeting for mingw we should emit windows paths, not msys
 935   if test "$llvm_cv_os_type" = "MingW" ; then
 936     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 937   fi
 938   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 939    [Define to path to dot program if found or 'echo dot' otherwise])
 940 fi
 941 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 942 if test "$FDP" != "echo fdp" ; then
 943   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 944   dnl If we're targeting for mingw we should emit windows paths, not msys
 945   if test "$llvm_cv_os_type" = "MingW" ; then
 946     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 947   fi
 948   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 949    [Define to path to fdp program if found or 'echo fdp' otherwise])
 950 fi
 951 AC_PATH_PROG(NEATO, [neato], [echo neato])
 952 if test "$NEATO" != "echo neato" ; then
 953   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 954   dnl If we're targeting for mingw we should emit windows paths, not msys
 955   if test "$llvm_cv_os_type" = "MingW" ; then
 956     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 957   fi
 958   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 959    [Define to path to neato program if found or 'echo neato' otherwise])
 960 fi
 961 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 962 if test "$TWOPI" != "echo twopi" ; then
 963   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 964   dnl If we're targeting for mingw we should emit windows paths, not msys
 965   if test "$llvm_cv_os_type" = "MingW" ; then
 966     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 967   fi
 968   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 969    [Define to path to twopi program if found or 'echo twopi' otherwise])
 970 fi
 971 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 972 if test "$CIRCO" != "echo circo" ; then
 973   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 974   dnl If we're targeting for mingw we should emit windows paths, not msys
 975   if test "$llvm_cv_os_type" = "MingW" ; then
 976     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 977   fi
 978   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 979    [Define to path to circo program if found or 'echo circo' otherwise])
 980 fi
 981 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 982 if test "$GV" != "echo gv" ; then
 983   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 984   dnl If we're targeting for mingw we should emit windows paths, not msys
 985   if test "$llvm_cv_os_type" = "MingW" ; then
 986     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 987   fi
 988   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 989    [Define to path to gv program if found or 'echo gv' otherwise])
 990 fi
 991 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 992 if test "$DOTTY" != "echo dotty" ; then
 993   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 994   dnl If we're targeting for mingw we should emit windows paths, not msys
 995   if test "$llvm_cv_os_type" = "MingW" ; then
 996     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 997   fi
 998   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 999    [Define to path to dotty program if found or 'echo dotty' otherwise])
1000 fi
1001 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1002 if test "$XDOT_PY" != "echo xdot.py" ; then
1003   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1004   dnl If we're targeting for mingw we should emit windows paths, not msys
1005   if test "$llvm_cv_os_type" = "MingW" ; then
1006     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1007   fi
1008   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1009    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1010 fi
1011
1012 dnl Find the install program
1013 AC_PROG_INSTALL
1014 dnl Prepend src dir to install path dir if it's a relative path
1015 dnl This is a hack for installs that take place in something other
1016 dnl than the top level.
1017 case "$INSTALL" in
1018  [[\\/$]]* | ?:[[\\/]]* ) ;;
1019  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1020 esac
1021
1022 dnl Checks for documentation and testing tools that we can do without. If these
1023 dnl are not found then they are set to "true" which always succeeds but does
1024 dnl nothing. This just lets the build output show that we could have done
1025 dnl something if the tool was available.
1026 AC_PATH_PROG(BZIP2, [bzip2])
1027 AC_PATH_PROG(CAT, [cat])
1028 AC_PATH_PROG(DOXYGEN, [doxygen])
1029 AC_PATH_PROG(GZIPBIN, [gzip])
1030 DJ_AC_PATH_TCLSH
1031 AC_PATH_PROG(ZIP, [zip])
1032 AC_PATH_PROGS(OCAMLC, [ocamlc])
1033 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1034 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1035 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1036
1037 dnl Get the version of the linker in use.
1038 AC_LINK_GET_VERSION
1039
1040 dnl Determine whether the linker supports the -R option.
1041 AC_LINK_USE_R
1042
1043 dnl Determine whether the linker supports the -export-dynamic option.
1044 AC_LINK_EXPORT_DYNAMIC
1045
1046 dnl Determine whether the linker supports the --version-script option.
1047 AC_LINK_VERSION_SCRIPT
1048
1049 dnl Check for libtool and the library that has dlopen function (which must come
1050 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1051 dnl libtool).
1052 AC_LIBTOOL_DLOPEN
1053 AC_LIB_LTDL
1054
1055 AC_MSG_CHECKING([tool compatibility])
1056
1057 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1058 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1059 dnl to support those options.
1060 dnl "icc" emits gcc signatures
1061 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1062 ICC=no
1063 IXX=no
1064 case $CC in
1065   icc*|icpc*)
1066     ICC=yes
1067     IXX=yes
1068     ;;
1069    *)
1070     ;;
1071 esac
1072
1073 if test "$GCC" != "yes" && test "$ICC" != "yes"
1074 then
1075   AC_MSG_ERROR([gcc|icc required but not found])
1076 fi
1077
1078 dnl Ensure that compilation tools are compatible with GCC extensions
1079 if test "$GXX" != "yes" && test "$IXX" != "yes"
1080 then
1081   AC_MSG_ERROR([g++|clang++|icc required but not found])
1082 fi
1083
1084 dnl Verify that GCC is version 3.0 or higher
1085 if test "$GCC" = "yes"
1086 then
1087   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1088 #error Unsupported GCC version
1089 #endif
1090 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1091 fi
1092
1093 dnl Check for GNU Make.  We use its extensions, so don't build without it
1094 if test -z "$llvm_cv_gnu_make_command"
1095 then
1096   AC_MSG_ERROR([GNU Make required but not found])
1097 fi
1098
1099 dnl Tool compatibility is okay if we make it here.
1100 AC_MSG_RESULT([ok])
1101
1102 dnl Check optional compiler flags.
1103 AC_MSG_CHECKING([optional compiler flags])
1104 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1105 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1106 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1107 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1108
1109 dnl===-----------------------------------------------------------------------===
1110 dnl===
1111 dnl=== SECTION 5: Check for libraries
1112 dnl===
1113 dnl===-----------------------------------------------------------------------===
1114
1115 AC_CHECK_LIB(m,sin)
1116 if test "$llvm_cv_os_type" = "MingW" ; then
1117   AC_CHECK_LIB(imagehlp, main)
1118   AC_CHECK_LIB(psapi, main)
1119 fi
1120
1121 dnl dlopen() is required for plugin support.
1122 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1123                [Define if dlopen() is available on this platform.]),
1124                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1125
1126 dnl libffi is optional; used to call external functions from the interpreter
1127 if test "$llvm_cv_enable_libffi" = "yes" ; then
1128   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1129                  [Define if libffi is available on this platform.]),
1130                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1131 fi
1132
1133 dnl mallinfo is optional; the code can compile (minus features) without it
1134 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1135                [Define if mallinfo() is available on this platform.]))
1136
1137 dnl pthread locking functions are optional - but llvm will not be thread-safe
1138 dnl without locks.
1139 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1140   AC_CHECK_LIB(pthread, pthread_mutex_init)
1141   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1142                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1143                            [Have pthread_mutex_lock]))
1144   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1145                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1146                  [Have pthread_rwlock_init]))
1147   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1148                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1149                  [Have pthread_getspecific]))
1150 fi
1151
1152 dnl Allow extra x86-disassembler library
1153 AC_ARG_WITH(udis86,
1154   AS_HELP_STRING([--with-udis86=<path>],
1155     [Use udis86 external x86 disassembler library]),
1156     [
1157       AC_SUBST(USE_UDIS86, [1])
1158       case "$withval" in
1159         /usr/lib|yes) ;;
1160         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1161       esac
1162       AC_CHECK_LIB(udis86, ud_init, [], [
1163         echo "Error! You need to have libudis86 around."
1164         exit -1
1165       ])
1166     ],
1167     AC_SUBST(USE_UDIS86, [0]))
1168 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1169                    [Define if use udis86 library])
1170
1171 dnl Allow OProfile support for JIT output.
1172 AC_ARG_WITH(oprofile,
1173   AS_HELP_STRING([--with-oprofile=<prefix>],
1174     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1175     [
1176       AC_SUBST(USE_OPROFILE, [1])
1177       case "$withval" in
1178         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1179         no) llvm_cv_oppath=
1180             AC_SUBST(USE_OPROFILE, [0]) ;;
1181         *) llvm_cv_oppath="${withval}/lib/oprofile"
1182            CPPFLAGS="-I${withval}/include";;
1183       esac
1184       case $llvm_cv_os_type in
1185         Linux)
1186           if test -n "$llvm_cv_oppath" ; then
1187             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1188             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1189             dnl libbfd is not included properly in libopagent in some Debian
1190             dnl versions.  If libbfd isn't found at all, we assume opagent works
1191             dnl anyway.
1192             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1193             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1194               echo "Error! You need to have libopagent around."
1195               exit -1
1196             ])
1197             AC_CHECK_HEADER([opagent.h], [], [
1198               echo "Error! You need to have opagent.h around."
1199               exit -1
1200               ])
1201           fi ;;
1202         *)
1203           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1204       esac
1205     ],
1206     [
1207       AC_SUBST(USE_OPROFILE, [0])
1208     ])
1209 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1210                    [Define if we have the oprofile JIT-support library])
1211
1212 dnl Enable support for Intel JIT Events API.
1213 AC_ARG_WITH(intel-jitevents,
1214   AS_HELP_STRING([--with-intel-jitevents=<vtune-amplifier-dir>],
1215     [Specify location of run-time support library for Intel JIT API (default=/opt/intel/vtune_amplifier_xe_2011)]),
1216     [
1217       case $llvm_cv_os_type in
1218         Linux|Win32|Cygwin|MingW) ;;
1219         *)
1220           AC_MSG_ERROR([
1221             Intel JIT API support is available on Linux and Windows only."]) ;;
1222       esac
1223
1224       AC_SUBST(USE_INTEL_JITEVENTS, [1])
1225       case "$llvm_cv_target_arch" in
1226         x86)    llvm_intel_jitevents_archdir="lib32";;
1227         x86_64) llvm_intel_jitevents_archdir="lib64";;
1228         *)      echo "Target architecture $llvm_cv_target_arch does not support Intel JIT Events API"
1229                 exit -1;;
1230       esac
1231       INTEL_JITEVENTS_INCDIR="/opt/intel/vtune_amplifier_xe_2011/include"
1232       INTEL_JITEVENTS_LIBDIR="/opt/intel/vtune_amplifier_xe_2011/$llvm_intel_jitevents_archdir"
1233       case "$withval" in
1234         /* | [[A-Za-z]]:[[\\/]]*) INTEL_JITEVENTS_INCDIR=$withval/include
1235                                   INTEL_JITEVENTS_LIBDIR=$withval/$llvm_intel_jitevents_archdir ;;
1236         *) ;;
1237       esac
1238
1239       AC_SUBST(INTEL_JITEVENTS_INCDIR)
1240       AC_SUBST(INTEL_JITEVENTS_LIBDIR)
1241
1242       LIBS="$LIBS -L${INTEL_JITEVENTS_LIBDIR}"
1243       CPPFLAGS="$CPPFLAGS -I$INTEL_JITEVENTS_INCDIR"
1244
1245       AC_SEARCH_LIBS(iJIT_IsProfilingActive, jitprofiling, [], [
1246         echo "Error! Cannot find libjitprofiling.a. Please check path specified in flag --with-intel-jitevents"
1247         exit -1
1248       ])
1249       AC_CHECK_HEADER([jitprofiling.h], [], [
1250         echo "Error! Cannot find jitprofiling.h. Please check path specified in flag --with-intel-jitevents"
1251         exit -1
1252       ])
1253
1254     ],
1255     [
1256       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1257     ])
1258 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1259                    [Define if we have the Intel JIT API runtime support library])
1260
1261 dnl===-----------------------------------------------------------------------===
1262 dnl===
1263 dnl=== SECTION 6: Check for header files
1264 dnl===
1265 dnl===-----------------------------------------------------------------------===
1266
1267 dnl First, use autoconf provided macros for specific headers that we need
1268 dnl We don't check for ancient stuff or things that are guaranteed to be there
1269 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1270 dnl Generally we're looking for POSIX headers.
1271 AC_HEADER_DIRENT
1272 AC_HEADER_MMAP_ANONYMOUS
1273 AC_HEADER_STAT
1274 AC_HEADER_SYS_WAIT
1275 AC_HEADER_TIME
1276
1277 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1278 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1279 AC_CHECK_HEADERS([utime.h windows.h])
1280 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1281 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1282 AC_CHECK_HEADERS([valgrind/valgrind.h])
1283 AC_CHECK_HEADERS([fenv.h])
1284 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1285   AC_CHECK_HEADERS(pthread.h,
1286                    AC_SUBST(HAVE_PTHREAD, 1),
1287                    AC_SUBST(HAVE_PTHREAD, 0))
1288 else
1289   AC_SUBST(HAVE_PTHREAD, 0)
1290 fi
1291
1292 dnl Try to find ffi.h.
1293 if test "$llvm_cv_enable_libffi" = "yes" ; then
1294   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1295 fi
1296
1297 dnl Try to find Darwin specific crash reporting libraries.
1298 AC_CHECK_HEADERS([CrashReporterClient.h])
1299
1300 dnl Try to find Darwin specific crash reporting global.
1301 AC_MSG_CHECKING([__crashreporter_info__])
1302 AC_LINK_IFELSE(
1303   AC_LANG_SOURCE(
1304     [[extern const char *__crashreporter_info__;
1305       int main() {
1306         __crashreporter_info__ = "test";
1307         return 0;
1308       }
1309     ]]),
1310   AC_MSG_RESULT(yes)
1311   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1312   AC_MSG_RESULT(no)
1313   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1314             Define if __crashreporter_info__ exists.))
1315
1316 dnl===-----------------------------------------------------------------------===
1317 dnl===
1318 dnl=== SECTION 7: Check for types and structures
1319 dnl===
1320 dnl===-----------------------------------------------------------------------===
1321
1322 AC_HUGE_VAL_CHECK
1323 AC_TYPE_PID_T
1324 AC_TYPE_SIZE_T
1325 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1326 AC_STRUCT_TM
1327 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1328 AC_CHECK_TYPES([uint64_t],,
1329          AC_CHECK_TYPES([u_int64_t],,
1330          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1331
1332 dnl===-----------------------------------------------------------------------===
1333 dnl===
1334 dnl=== SECTION 8: Check for specific functions needed
1335 dnl===
1336 dnl===-----------------------------------------------------------------------===
1337
1338 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1339 AC_CHECK_FUNCS([powf fmodf strtof round ])
1340 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1341 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1342 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1343 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1344 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1345 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1346 AC_C_PRINTF_A
1347 AC_FUNC_RAND48
1348
1349 dnl Check the declaration "Secure API" on Windows environments.
1350 AC_CHECK_DECLS([strerror_s])
1351
1352 dnl Check symbols in libgcc.a for JIT on Mingw.
1353 if test "$llvm_cv_os_type" = "MingW" ; then
1354   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1355   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1356   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1357   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1358
1359   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1360   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1361   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1362   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1363   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1364   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1365   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1366   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1367   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1368   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1369
1370   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1371   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1372 fi
1373
1374 dnl Check Win32 API EnumerateLoadedModules.
1375 if test "$llvm_cv_os_type" = "MingW" ; then
1376   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1377   AC_COMPILE_IFELSE([[#include <windows.h>
1378 #include <imagehlp.h>
1379 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1380 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1381 [
1382   AC_MSG_RESULT([yes])
1383   llvm_cv_win32_elmcb_pcstr="PCSTR"
1384 ],
1385 [
1386   AC_MSG_RESULT([no])
1387   llvm_cv_win32_elmcb_pcstr="PSTR"
1388 ])
1389   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1390 fi
1391
1392 dnl Check for variations in the Standard C++ library and STL. These macros are
1393 dnl provided by LLVM in the autoconf/m4 directory.
1394 AC_FUNC_ISNAN
1395 AC_FUNC_ISINF
1396
1397 dnl Check for mmap support.We also need to know if /dev/zero is required to
1398 dnl be opened for allocating RWX memory.
1399 dnl Make sure we aren't attempting to configure for an unknown system
1400 if test "$llvm_cv_platform_type" = "Unix" ; then
1401   AC_FUNC_MMAP
1402   AC_FUNC_MMAP_FILE
1403   AC_NEED_DEV_ZERO_FOR_MMAP
1404
1405   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1406   then
1407     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1408   fi
1409   if test "$ac_cv_func_mmap_file" = "no"
1410   then
1411     AC_MSG_WARN([mmap() of files required but not found])
1412   fi
1413 fi
1414
1415 dnl atomic builtins are required for threading support.
1416 AC_MSG_CHECKING(for GCC atomic builtins)
1417 dnl Since we'll be using these atomic builtins in C++ files we should test
1418 dnl the C++ compiler.
1419 AC_LANG_PUSH([C++])
1420 AC_LINK_IFELSE(
1421   AC_LANG_SOURCE(
1422     [[int main() {
1423         volatile unsigned long val = 1;
1424         __sync_synchronize();
1425         __sync_val_compare_and_swap(&val, 1, 0);
1426         __sync_add_and_fetch(&val, 1);
1427         __sync_sub_and_fetch(&val, 1);
1428         return 0;
1429       }
1430     ]]),
1431   AC_LANG_POP([C++])
1432   AC_MSG_RESULT(yes)
1433   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1434   AC_MSG_RESULT(no)
1435   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1436   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1437
1438 dnl===-----------------------------------------------------------------------===
1439 dnl===
1440 dnl=== SECTION 9: Additional checks, variables, etc.
1441 dnl===
1442 dnl===-----------------------------------------------------------------------===
1443
1444 dnl Handle 32-bit linux systems running a 64-bit kernel.
1445 dnl This has to come after section 4 because it invokes the compiler.
1446 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1447   AC_IS_LINUX_MIXED
1448   if test "$llvm_cv_linux_mixed" = "yes"; then
1449     llvm_cv_target_arch="x86"
1450     ARCH="x86"
1451   fi
1452 fi
1453
1454 dnl Check whether __dso_handle is present
1455 AC_CHECK_FUNCS([__dso_handle])
1456
1457 dnl Propagate the shared library extension that the libltdl checks did to
1458 dnl the Makefiles so we can use it there too
1459 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1460
1461 dnl Propagate the run-time library path variable that the libltdl
1462 dnl checks found to the Makefiles so we can use it there too
1463 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1464
1465 dnl Translate the various configuration directories and other basic
1466 dnl information into substitutions that will end up in Makefile.config.in
1467 dnl that these configured values can be used by the makefiles
1468 if test "${prefix}" = "NONE" ; then
1469   prefix="/usr/local"
1470 fi
1471 eval LLVM_PREFIX="${prefix}";
1472 eval LLVM_BINDIR="${prefix}/bin";
1473 eval LLVM_LIBDIR="${prefix}/lib";
1474 eval LLVM_DATADIR="${prefix}/share/llvm";
1475 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1476 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1477 eval LLVM_INCLUDEDIR="${prefix}/include";
1478 eval LLVM_INFODIR="${prefix}/info";
1479 eval LLVM_MANDIR="${prefix}/man";
1480 LLVM_CONFIGTIME=`date`
1481 AC_SUBST(LLVM_PREFIX)
1482 AC_SUBST(LLVM_BINDIR)
1483 AC_SUBST(LLVM_LIBDIR)
1484 AC_SUBST(LLVM_DATADIR)
1485 AC_SUBST(LLVM_DOCSDIR)
1486 AC_SUBST(LLVM_ETCDIR)
1487 AC_SUBST(LLVM_INCLUDEDIR)
1488 AC_SUBST(LLVM_INFODIR)
1489 AC_SUBST(LLVM_MANDIR)
1490 AC_SUBST(LLVM_CONFIGTIME)
1491
1492 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1493 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1494   LLVM_CONFIGTIME="(timestamp not enabled)"
1495 fi
1496
1497 dnl Place the various directories into the config.h file as #defines so that we
1498 dnl can know about the installation paths within LLVM.
1499 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1500                    [Installation prefix directory])
1501 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1502                    [Installation directory for binary executables])
1503 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1504                    [Installation directory for libraries])
1505 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1506                    [Installation directory for data files])
1507 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1508                    [Installation directory for documentation])
1509 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1510                    [Installation directory for config files])
1511 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1512                    [Installation directory for include files])
1513 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1514                    [Installation directory for .info files])
1515 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1516                    [Installation directory for man pages])
1517 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1518                    [Time at which LLVM was configured])
1519 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1520                    [Target triple LLVM will generate code for by default])
1521
1522 dnl Determine which bindings to build.
1523 if test "$BINDINGS_TO_BUILD" = auto ; then
1524   BINDINGS_TO_BUILD=""
1525   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1526     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1527   fi
1528 fi
1529 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1530
1531 dnl This isn't really configurey, but it avoids having to repeat the list in
1532 dnl other files.
1533 AC_SUBST(ALL_BINDINGS,ocaml)
1534
1535 dnl Do any work necessary to ensure that bindings have what they need.
1536 binding_prereqs_failed=0
1537 for a_binding in $BINDINGS_TO_BUILD ; do
1538   case "$a_binding" in
1539   ocaml)
1540     if test "x$OCAMLC" = x ; then
1541       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1542       binding_prereqs_failed=1
1543     fi
1544     if test "x$OCAMLDEP" = x ; then
1545       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1546       binding_prereqs_failed=1
1547     fi
1548     if test "x$OCAMLOPT" = x ; then
1549       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1550       dnl ocamlopt is optional!
1551     fi
1552     if test "x$with_ocaml_libdir" != xauto ; then
1553       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1554     else
1555       ocaml_stdlib="`"$OCAMLC" -where`"
1556       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1557       then
1558         # ocaml stdlib is beneath our prefix; use stdlib
1559         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1560       else
1561         # ocaml stdlib is outside our prefix; use libdir/ocaml
1562         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1563       fi
1564     fi
1565     ;;
1566   esac
1567 done
1568 if test "$binding_prereqs_failed" = 1 ; then
1569   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1570 fi
1571
1572 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1573 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1574
1575 dnl Determine linker rpath flag
1576 if test "$llvm_cv_link_use_r" = "yes" ; then
1577   RPATH="-Wl,-R"
1578 else
1579   RPATH="-Wl,-rpath"
1580 fi
1581 AC_SUBST(RPATH)
1582
1583 dnl Determine linker rdynamic flag
1584 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1585   RDYNAMIC="-Wl,-export-dynamic"
1586 else
1587   RDYNAMIC=""
1588 fi
1589 AC_SUBST(RDYNAMIC)
1590
1591 dnl===-----------------------------------------------------------------------===
1592 dnl===
1593 dnl=== SECTION 10: Specify the output files and generate it
1594 dnl===
1595 dnl===-----------------------------------------------------------------------===
1596
1597 dnl Configure header files
1598 dnl WARNING: dnl If you add or remove any of the following config headers, then
1599 dnl you MUST also update Makefile so that the variable FilesToConfig
1600 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1601 dnl files can be updated automatically when their *.in sources change.
1602 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1603 AH_TOP([#ifndef CONFIG_H
1604 #define CONFIG_H])
1605 AH_BOTTOM([#endif])
1606
1607 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1608 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1609 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1610 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1611 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1612
1613 dnl Configure the makefile's configuration data
1614 AC_CONFIG_FILES([Makefile.config])
1615
1616 dnl Configure the RPM spec file for LLVM
1617 AC_CONFIG_FILES([llvm.spec])
1618
1619 dnl Configure doxygen's configuration file
1620 AC_CONFIG_FILES([docs/doxygen.cfg])
1621
1622 dnl Configure clang, if present
1623 if test "${clang_src_root}" = ""; then
1624   clang_src_root="$srcdir/tools/clang"
1625 fi
1626 if test -f ${clang_src_root}/README.txt; then
1627   dnl Use variables to stay under 80 columns.
1628   configh="include/clang/Config/config.h"
1629   doxy="docs/doxygen.cfg"
1630   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1631   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1632 fi
1633
1634 dnl OCaml findlib META file
1635 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1636
1637 dnl Do special configuration of Makefiles
1638 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1639 AC_CONFIG_MAKEFILE(Makefile)
1640 AC_CONFIG_MAKEFILE(Makefile.common)
1641 AC_CONFIG_MAKEFILE(examples/Makefile)
1642 AC_CONFIG_MAKEFILE(lib/Makefile)
1643 AC_CONFIG_MAKEFILE(runtime/Makefile)
1644 AC_CONFIG_MAKEFILE(test/Makefile)
1645 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1646 AC_CONFIG_MAKEFILE(unittests/Makefile)
1647 AC_CONFIG_MAKEFILE(tools/Makefile)
1648 AC_CONFIG_MAKEFILE(utils/Makefile)
1649 AC_CONFIG_MAKEFILE(projects/Makefile)
1650 AC_CONFIG_MAKEFILE(bindings/Makefile)
1651 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1652
1653 dnl Finally, crank out the output
1654 AC_OUTPUT