autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-interix*)
 116     llvm_cv_os_type="Interix"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-linux*)
 119     llvm_cv_os_type="Linux"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-solaris*)
 122     llvm_cv_os_type="SunOS"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-win32*)
 125     llvm_cv_os_type="Win32"
 126     llvm_cv_platform_type="Win32" ;;
 127   *-*-mingw*)
 128     llvm_cv_os_type="MingW"
 129     llvm_cv_platform_type="Win32" ;;
 130   *)
 131     llvm_cv_os_type="Unknown"
 132     llvm_cv_platform_type="Unknown" ;;
 133 esac])
 134
 135 dnl Make sure we aren't attempting to configure for an unknown system
 136 if test "$llvm_cv_os_type" = "Unknown" ; then
 137   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 138 fi
 139
 140 dnl Set the "OS" Makefile variable based on the platform type so the
 141 dnl makefile can configure itself to specific build hosts
 142 AC_SUBST(OS,$llvm_cv_os_type)
 143
 144 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 145 dnl This is used by lib/System to determine the basic kind of implementation
 146 dnl to use.
 147 case $llvm_cv_platform_type in
 148   Unix)
 149     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 150     AC_SUBST(LLVM_ON_UNIX,[1])
 151     AC_SUBST(LLVM_ON_WIN32,[0])
 152     ;;
 153   Win32)
 154     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 155     AC_SUBST(LLVM_ON_UNIX,[0])
 156     AC_SUBST(LLVM_ON_WIN32,[1])
 157     ;;
 158 esac
 159
 160 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 161 dnl V9, since that is all that we support at the moment, and autoconf will only
 162 dnl tell us we're a sparc.
 163 case $target in
 164   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 165   ;;
 166 esac
 167
 168 dnl Determine what our target architecture is and configure accordingly.
 169 dnl This will allow Makefiles to make a distinction between the hardware and
 170 dnl the OS.
 171 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 172 [case $target in
 173   i?86-*)                 llvm_cv_target_arch="x86" ;;
 174   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 175   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 176   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 177   *)                      llvm_cv_target_arch="Unknown" ;;
 178 esac])
 179
 180 if test "$llvm_cv_target_arch" = "Unknown" ; then
 181   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 182 fi
 183
 184 dnl Define a substitution, ARCH, for the target architecture
 185 AC_SUBST(ARCH,$llvm_cv_target_arch)
 186
 187 dnl Check for the endianness of the target
 188 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 189
 190 dnl===-----------------------------------------------------------------------===
 191 dnl===
 192 dnl=== SECTION 3: Command line arguments for the configure script.
 193 dnl===
 194 dnl===-----------------------------------------------------------------------===
 195
 196 dnl --enable-optimized : check whether they want to do an optimized build:
 197 AC_ARG_ENABLE(optimized,
 198               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 199 if test ${enableval} = "no" ; then
 200   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 201 else
 202   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 203 fi
 204
 205 dnl --enable-jit: check whether they want to enable the jit
 206 AC_ARG_ENABLE(jit,
 207   AS_HELP_STRING(--enable-jit,
 208                  [Enable Just In Time Compiling (default is YES)]),,
 209   enableval=default)
 210 if test ${enableval} = "no"
 211 then
 212   AC_SUBST(JIT,[[]])
 213 else
 214   case "$llvm_cv_target_arch" in
 215     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 216     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 217     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 218     x86_64)  AC_SUBST(JIT,[[]]) ;;
 219     *)       AC_SUBST(JIT,[[]]) ;;
 220   esac
 221 fi
 222
 223 dnl Allow enablement of doxygen generated documentation
 224 AC_ARG_ENABLE(doxygen,
 225               AS_HELP_STRING([--enable-doxygen],
 226                              [Build doxygen documentation (default is NO)]),,
 227                              enableval=default)
 228 case "$enableval" in
 229   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 230   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 231   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 232   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 233 esac
 234
 235 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 236 AC_ARG_WITH(llvmgccdir,
 237   AS_HELP_STRING([--with-llvmgccdir],
 238     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 239     withval=default)
 240 case "$withval" in
 241   default) WITH_LLVMGCCDIR=default ;;
 242   /*)      WITH_LLVMGCCDIR=$withval ;;
 243   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 244 esac
 245
 246 dnl===-----------------------------------------------------------------------===
 247 dnl===
 248 dnl=== SECTION 4: Check for programs we need and that they are the right version
 249 dnl===
 250 dnl===-----------------------------------------------------------------------===
 251
 252 dnl Check for compilation tools
 253 AC_PROG_CPP
 254 AC_PROG_CC(gcc)
 255 AC_PROG_CXX(g++)
 256 AC_PROG_FLEX
 257 AC_PROG_BISON
 258
 259 dnl Check for the tools that the makefiles require
 260 AC_CHECK_GNU_MAKE
 261 AC_PROG_LN_S
 262 AC_PATH_PROG(CMP, [cmp], [cmp])
 263 AC_PATH_PROG(CP, [cp], [cp])
 264 AC_PATH_PROG(DATE, [date], [date])
 265 AC_PATH_PROG(FIND, [find], [find])
 266 AC_PATH_PROG(GREP, [grep], [grep])
 267 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 268 AC_PATH_PROG(MV,   [mv],   [mv])
 269 AC_PATH_PROG(PAX,  [pax],  [pax])
 270 AC_PROG_RANLIB
 271 AC_PATH_PROG(RM,   [rm],   [rm])
 272 AC_PATH_PROG(SED,  [sed],  [sed])
 273 AC_PATH_PROG(TAR,  [tar],  [gtar])
 274
 275 dnl Find the install program
 276 AC_PROG_INSTALL
 277
 278 dnl Checks for documentation and testing tools that we can do without. If these
 279 dnl are not found then they are set to "true" which always succeeds but does
 280 dnl nothing. This just lets the build output show that we could have done
 281 dnl something if the tool was available.
 282 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 283 AC_PATH_PROG(DOT,[dot],[true dot])
 284 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 285 AC_PATH_PROG(ETAGS,[etags],[true etags])
 286 AC_PATH_PROG(GROFF,[groff],[true groff])
 287 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 288 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 289 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 290 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 291 DJ_AC_PATH_TCLSH
 292 AC_PATH_PROG(ZIP,[zip],[true zip])
 293
 294 dnl Determine if the linker supports the -R option.
 295 AC_LINK_USE_R
 296
 297 dnl Check for libtool and the library that has dlopen function (which must come
 298 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 299 dnl libtool).
 300 AC_LIBTOOL_DLOPEN
 301 AC_LIB_LTDL
 302 AC_PROG_LIBTOOL
 303
 304 if test "$lt_cv_dlopen_self" = "yes" ; then
 305   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 306               [Define if dlopen(0) will open the symbols of the program])
 307 fi
 308
 309 dnl Check if we know how to tell etags we are using C++:
 310 etags_version=`$ETAGS --version 2>&1`
 311 case "$etags_version" in
 312         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 313         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 314         *) ETAGSFLAGS="" ;;
 315 esac
 316 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 317
 318 if test "$WITH_LLVMGCCDIR" = "default" ; then
 319   AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
 320   AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
 321 else
 322   LLVMGCC=$WITH_LLVMGCCDIR/bin/llvm-gcc
 323   LLVMGXX=$WITH_LLVMGCCDIR/bin/llvm-g++
 324   AC_SUBST(LLVMGCC,$LLVMGCC)
 325   AC_SUBST(LLVMGXX,$LLVMGXX)
 326 fi
 327
 328 AC_MSG_CHECKING([tool compatibility])
 329
 330 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 331 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 332 dnl to support those options.
 333 dnl "icc" emits gcc signatures
 334 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 335 ICC=no
 336 IXX=no
 337 case $CC in
 338   icc*|icpc*)
 339     ICC=yes
 340     IXX=yes
 341     ;;
 342    *)
 343     ;;
 344 esac
 345
 346 if test "$GCC" != "yes" && test "$ICC" != "yes"
 347 then
 348   AC_MSG_ERROR([gcc|icc required but not found])
 349 fi
 350
 351 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 352 if test "$GXX" != "yes" && test "$IXX" != "yes"
 353 then
 354   AC_MSG_ERROR([g++|icc required but not found])
 355 fi
 356
 357 dnl Verify that GCC is version 3.0 or higher
 358 if test "$GCC" = "yes"
 359 then
 360   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 361   if test "$gccmajor" -lt "3"
 362   then
 363     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 364   fi
 365 fi
 366
 367 dnl Check for GNU Make.  We use its extensions, so don't build without it
 368 if test -z "$llvm_cv_gnu_make_command"
 369 then
 370   AC_MSG_ERROR([GNU Make required but not found])
 371 fi
 372
 373 dnl Tool compatibility is okay if we make it here.
 374 AC_MSG_RESULT([ok])
 375
 376 dnl===-----------------------------------------------------------------------===
 377 dnl===
 378 dnl=== SECTION 5: Check for libraries
 379 dnl===
 380 dnl===-----------------------------------------------------------------------===
 381
 382 dnl libelf is for sparc only; we can ignore it if we don't have it
 383 AC_CHECK_LIB(elf, elf_begin)
 384
 385 dnl lt_dlopen may be required for plugin support.
 386 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 387               [Define if lt_dlopen() is available on this platform]),
 388               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 389                            not be available]))
 390
 391 dnl dlopen() is required for plugin support.
 392 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 393                [Define if dlopen() is available on this platform.]),
 394                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 395
 396 dnl mallinfo is optional; the code can compile (minus features) without it
 397 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 398                [Define if mallinfo() is available on this platform.]))
 399
 400 dnl pthread locking functions are optional - but llvm will not be thread-safe
 401 dnl without locks.
 402 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 403                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 404                          [Have pthread_mutex_lock]))
 405
 406 dnl===-----------------------------------------------------------------------===
 407 dnl===
 408 dnl=== SECTION 6: Check for header files
 409 dnl===
 410 dnl===-----------------------------------------------------------------------===
 411
 412 dnl First, use autoconf provided macros for specific headers that we need
 413 dnl We don't check for ancient stuff or things that are guaranteed to be there
 414 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 415 dnl Generally we're looking for POSIX headers.
 416 AC_HEADER_DIRENT
 417 AC_HEADER_MMAP_ANONYMOUS
 418 AC_HEADER_STAT
 419 AC_HEADER_STDC
 420 AC_HEADER_SYS_WAIT
 421 AC_HEADER_TIME
 422
 423 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 424 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 425 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 426
 427 dnl===-----------------------------------------------------------------------===
 428 dnl===
 429 dnl=== SECTION 7: Check for types and structures
 430 dnl===
 431 dnl===-----------------------------------------------------------------------===
 432
 433 AC_TYPE_PID_T
 434 AC_TYPE_SIZE_T
 435 AC_TYPE_SIGNAL
 436 AC_STRUCT_TM
 437 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 438 AC_CHECK_TYPES([uint64_t],,
 439          AC_CHECK_TYPES([u_int64_t],,
 440          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 441
 442 dnl===-----------------------------------------------------------------------===
 443 dnl===
 444 dnl=== SECTION 8: Check for specific functions needed
 445 dnl===
 446 dnl===-----------------------------------------------------------------------===
 447
 448 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 449 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 450 AC_CHECK_FUNCS([realpath sbrk setrlimit strdup strerror strerror_r ])
 451 AC_CHECK_FUNCS([strtoll strtoq sysconf])
 452 AC_C_PRINTF_A
 453 AC_FUNC_ALLOCA
 454 AC_FUNC_RAND48
 455
 456 dnl Check for variations in the Standard C++ library and STL. These macros are
 457 dnl provided by LLVM in the autoconf/m4 directory.
 458 AC_CXX_HAVE_HASH_MAP
 459 AC_CXX_HAVE_HASH_SET
 460 AC_CXX_HAVE_STD_ITERATOR
 461 AC_CXX_HAVE_BI_ITERATOR
 462 AC_CXX_HAVE_FWD_ITERATOR
 463 AC_FUNC_ISNAN
 464 AC_FUNC_ISINF
 465
 466 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 467 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 468 dnl be opened for allocating RWX memory.
 469 AC_FUNC_MMAP
 470 AC_FUNC_MMAP_FILE
 471 AC_NEED_DEV_ZERO_FOR_MMAP
 472 AC_CHECK_FUNC(mprotect,,
 473               AC_MSG_ERROR([Function mprotect() required but not found]))
 474
 475 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 476 then
 477   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 478 fi
 479 if test "$ac_cv_func_mmap_file" = "no"
 480 then
 481   AC_MSG_WARN([mmap() of files required but not found])
 482 fi
 483
 484 dnl===-----------------------------------------------------------------------===
 485 dnl===
 486 dnl=== SECTION 9: Additional checks, variables, etc.
 487 dnl===
 488 dnl===-----------------------------------------------------------------------===
 489
 490 dnl See if the llvm-gcc executable can compile to LLVM assembly
 491 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 492 [llvm_cv_llvmgcc_sanity="no"
 493 if test -x "$LLVMGCC" ; then
 494   cp /dev/null conftest.c
 495   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 496   if test $? -eq 0 ; then
 497     llvm_cv_llvmgcc_sanity="yes"
 498   fi
 499   rm conftest.c
 500 fi])
 501
 502 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 503 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 504   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 505   AC_SUBST(LLVMCC1,$llvmcc1path)
 506   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 507   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 508   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 509   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 510 fi
 511
 512 dnl Propagate the shared library extension that the libltdl checks did to
 513 dnl the Makefiles so we can use it there too
 514 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 515
 516 # Translate the various configuration directories and other basic
 517 # information into substitutions that will end up in Makefile.config.in
 518 # that these configured values can be used by the makefiles
 519 eval LLVM_PREFIX="${prefix}";
 520 eval LLVM_BINDIR="${prefix}/bin";
 521 eval LLVM_LIBDIR="${prefix}/lib";
 522 eval LLVM_DATADIR="${prefix}/share/llvm";
 523 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 524 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 525 eval LLVM_INCLUDEDIR="${prefix}/include";
 526 eval LLVM_INFODIR="${prefix}/info";
 527 eval LLVM_MANDIR="${prefix}/man";
 528 LLVM_CONFIGTIME=`date`
 529 AC_SUBST(LLVM_PREFIX)
 530 AC_SUBST(LLVM_BINDIR)
 531 AC_SUBST(LLVM_LIBDIR)
 532 AC_SUBST(LLVM_DATADIR)
 533 AC_SUBST(LLVM_DOCSDIR)
 534 AC_SUBST(LLVM_ETCDIR)
 535 AC_SUBST(LLVM_INCLUDEDIR)
 536 AC_SUBST(LLVM_INFODIR)
 537 AC_SUBST(LLVM_MANDIR)
 538 AC_SUBST(LLVM_CONFIGTIME)
 539
 540 # Place the various directores into the config.h file as #defines so that we
 541 # can know about the installation paths within LLVM.
 542 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 543                    [Installation prefix directory])
 544 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 545                    [Installation directory for binary executables])
 546 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 547                    [Installation directory for libraries])
 548 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 549                    [Installation directory for data files])
 550 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 551                    [Installation directory for documentation])
 552 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 553                    [Installation directory for config files])
 554 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 555                    [Installation directory for include files])
 556 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 557                    [Installation directory for .info files])
 558 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 559                    [Installation directory for man pages])
 560 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 561                    [Time at which LLVM was configured])
 562
 563 dnl===-----------------------------------------------------------------------===
 564 dnl===
 565 dnl=== SECTION 10: Specify the output files and generate it
 566 dnl===
 567 dnl===-----------------------------------------------------------------------===
 568
 569 dnl Configure header files
 570 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 571
 572 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 573 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 574 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 575 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 576 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 577
 578 dnl Configure the makefile's configuration data
 579 AC_CONFIG_FILES([Makefile.config])
 580
 581 dnl Configure llvmc's configuration files
 582 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 583
 584 dnl Configure doxygen's configuration file
 585 AC_CONFIG_FILES([docs/doxygen.cfg])
 586
 587 dnl Do special configuration of Makefiles
 588 AC_CONFIG_MAKEFILE(Makefile)
 589 AC_CONFIG_MAKEFILE(Makefile.common)
 590 AC_CONFIG_MAKEFILE(examples/Makefile)
 591 AC_CONFIG_MAKEFILE(lib/Makefile)
 592 AC_CONFIG_MAKEFILE(runtime/Makefile)
 593 AC_CONFIG_MAKEFILE(test/Makefile)
 594 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 595 AC_CONFIG_MAKEFILE(tools/Makefile)
 596 AC_CONFIG_MAKEFILE(utils/Makefile)
 597 AC_CONFIG_MAKEFILE(projects/Makefile)
 598
 599 dnl Finally, crank out the output
 600 AC_OUTPUT
 601
 602 dnl Warn loudly if llvm-gcc was not obviously working
 603 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 604  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 605  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 606  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 607  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 608  AC_MSG_WARN([***** build the llvm tools.])
 609 fi