arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so we retain large page mappings for
  47  * boundaries spanning kernel text, rodata and data sections.
  48  *
  49  * However, kernel identity mappings will have different RWX permissions
  50  * to the pages mapping to text and to the pages padding (which are freed) the
  51  * text section. Hence kernel identity mappings will be broken to smaller
  52  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  53  * so we can enable protection checks as well as retain 2MB large page
  54  * mappings for kernel text.
  55  */
  56 #define X64_ALIGN_RODATA_BEGIN  . = ALIGN(HPAGE_SIZE);
  57
  58 #define X64_ALIGN_RODATA_END                                    \
  59                 . = ALIGN(HPAGE_SIZE);                          \
  60                 __end_rodata_hpage_align = .;
  61
  62 #else
  63
  64 #define X64_ALIGN_RODATA_BEGIN
  65 #define X64_ALIGN_RODATA_END
  66
  67 #endif
  68
  69 PHDRS {
  70         text PT_LOAD FLAGS(5);          /* R_E */
  71         data PT_LOAD FLAGS(6);          /* RW_ */
  72 #ifdef CONFIG_X86_64
  73 #ifdef CONFIG_SMP
  74         percpu PT_LOAD FLAGS(6);        /* RW_ */
  75 #endif
  76         init PT_LOAD FLAGS(7);          /* RWE */
  77 #endif
  78         note PT_NOTE FLAGS(0);          /* ___ */
  79 }
  80
  81 SECTIONS
  82 {
  83 #ifdef CONFIG_X86_32
  84         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  85         phys_startup_32 = startup_32 - LOAD_OFFSET;
  86 #else
  87         . = __START_KERNEL;
  88         phys_startup_64 = startup_64 - LOAD_OFFSET;
  89 #endif
  90
  91         /* Text and read-only data */
  92         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  93                 _text = .;
  94                 /* bootstrapping code */
  95                 HEAD_TEXT
  96                 . = ALIGN(8);
  97                 _stext = .;
  98                 TEXT_TEXT
  99                 SCHED_TEXT
 100                 LOCK_TEXT
 101                 KPROBES_TEXT
 102                 ENTRY_TEXT
 103                 IRQENTRY_TEXT
 104                 *(.fixup)
 105                 *(.gnu.warning)
 106                 /* End of text section */
 107                 _etext = .;
 108         } :text = 0x9090
 109
 110         NOTES :text :note
 111
 112         EXCEPTION_TABLE(16) :text = 0x9090
 113
 114         /* .text should occupy whole number of pages */
 115         . = ALIGN(PAGE_SIZE);
 116         X64_ALIGN_RODATA_BEGIN
 117         RO_DATA(PAGE_SIZE)
 118         X64_ALIGN_RODATA_END
 119
 120         /* Data */
 121         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 122                 /* Start of data section */
 123                 _sdata = .;
 124
 125                 /* init_task */
 126                 INIT_TASK_DATA(THREAD_SIZE)
 127
 128 #ifdef CONFIG_X86_32
 129                 /* 32 bit has nosave before _edata */
 130                 NOSAVE_DATA
 131 #endif
 132
 133                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 134
 135                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 136
 137                 DATA_DATA
 138                 CONSTRUCTORS
 139
 140                 /* rarely changed data like cpu maps */
 141                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 142
 143                 /* End of data section */
 144                 _edata = .;
 145         } :data
 146
 147
 148         . = ALIGN(PAGE_SIZE);
 149         __vvar_page = .;
 150
 151         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 152                 /* work around gold bug 13023 */
 153                 __vvar_beginning_hack = .;
 154
 155                 /* Place all vvars at the offsets in asm/vvar.h. */
 156 #define EMIT_VVAR(name, offset)                         \
 157                 . = __vvar_beginning_hack + offset;     \
 158                 *(.vvar_ ## name)
 159 #define __VVAR_KERNEL_LDS
 160 #include <asm/vvar.h>
 161 #undef __VVAR_KERNEL_LDS
 162 #undef EMIT_VVAR
 163
 164                 /*
 165                  * Pad the rest of the page with zeros.  Otherwise the loader
 166                  * can leave garbage here.
 167                  */
 168                 . = __vvar_beginning_hack + PAGE_SIZE;
 169         } :data
 170
 171        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 172
 173         /* Init code and data - will be freed after init */
 174         . = ALIGN(PAGE_SIZE);
 175         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 176                 __init_begin = .; /* paired with __init_end */
 177         }
 178
 179 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 180         /*
 181          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 182          * output PHDR, so the next output section - .init.text - should
 183          * start another segment - init.
 184          */
 185         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 186         ASSERT(SIZEOF(.data..percpu) < CONFIG_PHYSICAL_START,
 187                "per-CPU data too large - increase CONFIG_PHYSICAL_START")
 188 #endif
 189
 190         INIT_TEXT_SECTION(PAGE_SIZE)
 191 #ifdef CONFIG_X86_64
 192         :init
 193 #endif
 194
 195         INIT_DATA_SECTION(16)
 196
 197         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 198                 __x86_cpu_dev_start = .;
 199                 *(.x86_cpu_dev.init)
 200                 __x86_cpu_dev_end = .;
 201         }
 202
 203 #ifdef CONFIG_X86_INTEL_MID
 204         .x86_intel_mid_dev.init : AT(ADDR(.x86_intel_mid_dev.init) - \
 205                                                                 LOAD_OFFSET) {
 206                 __x86_intel_mid_dev_start = .;
 207                 *(.x86_intel_mid_dev.init)
 208                 __x86_intel_mid_dev_end = .;
 209         }
 210 #endif
 211
 212         /*
 213          * start address and size of operations which during runtime
 214          * can be patched with virtualization friendly instructions or
 215          * baremetal native ones. Think page table operations.
 216          * Details in paravirt_types.h
 217          */
 218         . = ALIGN(8);
 219         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 220                 __parainstructions = .;
 221                 *(.parainstructions)
 222                 __parainstructions_end = .;
 223         }
 224
 225         /*
 226          * struct alt_inst entries. From the header (alternative.h):
 227          * "Alternative instructions for different CPU types or capabilities"
 228          * Think locking instructions on spinlocks.
 229          */
 230         . = ALIGN(8);
 231         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 232                 __alt_instructions = .;
 233                 *(.altinstructions)
 234                 __alt_instructions_end = .;
 235         }
 236
 237         /*
 238          * And here are the replacement instructions. The linker sticks
 239          * them as binary blobs. The .altinstructions has enough data to
 240          * get the address and the length of them to patch the kernel safely.
 241          */
 242         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 243                 *(.altinstr_replacement)
 244         }
 245
 246         /*
 247          * struct iommu_table_entry entries are injected in this section.
 248          * It is an array of IOMMUs which during run time gets sorted depending
 249          * on its dependency order. After rootfs_initcall is complete
 250          * this section can be safely removed.
 251          */
 252         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 253                 __iommu_table = .;
 254                 *(.iommu_table)
 255                 __iommu_table_end = .;
 256         }
 257
 258         . = ALIGN(8);
 259         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 260                 __apicdrivers = .;
 261                 *(.apicdrivers);
 262                 __apicdrivers_end = .;
 263         }
 264
 265         . = ALIGN(8);
 266         /*
 267          * .exit.text is discard at runtime, not link time, to deal with
 268          *  references from .altinstructions and .eh_frame
 269          */
 270         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 271                 EXIT_TEXT
 272         }
 273
 274         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 275                 EXIT_DATA
 276         }
 277
 278 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 279         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 280 #endif
 281
 282         . = ALIGN(PAGE_SIZE);
 283
 284         /* freed after init ends here */
 285         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 286                 __init_end = .;
 287         }
 288
 289         /*
 290          * smp_locks might be freed after init
 291          * start/end must be page aligned
 292          */
 293         . = ALIGN(PAGE_SIZE);
 294         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 295                 __smp_locks = .;
 296                 *(.smp_locks)
 297                 . = ALIGN(PAGE_SIZE);
 298                 __smp_locks_end = .;
 299         }
 300
 301 #ifdef CONFIG_X86_64
 302         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 303                 NOSAVE_DATA
 304         }
 305 #endif
 306
 307         /* BSS */
 308         . = ALIGN(PAGE_SIZE);
 309         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 310                 __bss_start = .;
 311                 *(.bss..page_aligned)
 312                 *(.bss)
 313                 . = ALIGN(PAGE_SIZE);
 314                 __bss_stop = .;
 315         }
 316
 317         . = ALIGN(PAGE_SIZE);
 318         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 319                 __brk_base = .;
 320                 . += 64 * 1024;         /* 64k alignment slop space */
 321                 *(.brk_reservation)     /* areas brk users have reserved */
 322                 __brk_limit = .;
 323         }
 324
 325         _end = .;
 326
 327         STABS_DEBUG
 328         DWARF_DEBUG
 329
 330         /* Sections to be discarded */
 331         DISCARDS
 332         /DISCARD/ : { *(.eh_frame) }
 333 }
 334
 335
 336 #ifdef CONFIG_X86_32
 337 /*
 338  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 339  */
 340 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 341            "kernel image bigger than KERNEL_IMAGE_SIZE");
 342 #else
 343 /*
 344  * Per-cpu symbols which need to be offset from __per_cpu_load
 345  * for the boot processor.
 346  */
 347 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 348 INIT_PER_CPU(gdt_page);
 349 INIT_PER_CPU(irq_stack_union);
 350
 351 /*
 352  * Build-time check on the image size:
 353  */
 354 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 355            "kernel image bigger than KERNEL_IMAGE_SIZE");
 356
 357 #ifdef CONFIG_SMP
 358 . = ASSERT((irq_stack_union == 0),
 359            "irq_stack_union is not at start of per-cpu area");
 360 #endif
 361
 362 #endif /* CONFIG_X86_32 */
 363
 364 #ifdef CONFIG_KEXEC_CORE
 365 #include <asm/kexec.h>
 366
 367 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 368            "kexec control code size is too big");
 369 #endif
 370