arch/arm64/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make ARM Linux kernel
   3  * taken from the i386 version by Russell King
   4  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/kernel-pgtable.h>
  10 #include <asm/thread_info.h>
  11 #include <asm/memory.h>
  12 #include <asm/page.h>
  13 #include <asm/pgtable.h>
  14
  15 #include "image.h"
  16
  17 /* .exit.text needed in case of alternative patching */
  18 #define ARM_EXIT_KEEP(x)        x
  19 #define ARM_EXIT_DISCARD(x)
  20
  21 OUTPUT_ARCH(aarch64)
  22 ENTRY(_text)
  23
  24 jiffies = jiffies_64;
  25
  26 #define HYPERVISOR_TEXT                                 \
  27         /*                                              \
  28          * Align to 4 KB so that                        \
  29          * a) the HYP vector table is at its minimum    \
  30          *    alignment of 2048 bytes                   \
  31          * b) the HYP init code will not cross a page   \
  32          *    boundary if its size does not exceed      \
  33          *    4 KB (see related ASSERT() below)         \
  34          */                                             \
  35         . = ALIGN(SZ_4K);                               \
  36         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;     \
  37         *(.hyp.idmap.text)                              \
  38         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;       \
  39         VMLINUX_SYMBOL(__hyp_text_start) = .;           \
  40         *(.hyp.text)                                    \
  41         VMLINUX_SYMBOL(__hyp_text_end) = .;
  42
  43 #define IDMAP_TEXT                                      \
  44         . = ALIGN(SZ_4K);                               \
  45         VMLINUX_SYMBOL(__idmap_text_start) = .;         \
  46         *(.idmap.text)                                  \
  47         VMLINUX_SYMBOL(__idmap_text_end) = .;
  48
  49 #ifdef CONFIG_HIBERNATION
  50 #define HIBERNATE_TEXT                                  \
  51         . = ALIGN(SZ_4K);                               \
  52         VMLINUX_SYMBOL(__hibernate_exit_text_start) = .;\
  53         *(.hibernate_exit.text)                         \
  54         VMLINUX_SYMBOL(__hibernate_exit_text_end) = .;
  55 #else
  56 #define HIBERNATE_TEXT
  57 #endif
  58
  59 /*
  60  * The size of the PE/COFF section that covers the kernel image, which
  61  * runs from stext to _edata, must be a round multiple of the PE/COFF
  62  * FileAlignment, which we set to its minimum value of 0x200. 'stext'
  63  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
  64  * boundary should be sufficient.
  65  */
  66 PECOFF_FILE_ALIGNMENT = 0x200;
  67
  68 #ifdef CONFIG_EFI
  69 #define PECOFF_EDATA_PADDING    \
  70         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
  71 #else
  72 #define PECOFF_EDATA_PADDING
  73 #endif
  74
  75 #if defined(CONFIG_DEBUG_ALIGN_RODATA)
  76 #define ALIGN_DEBUG_RO                  . = ALIGN(1<<SECTION_SHIFT);
  77 #define ALIGN_DEBUG_RO_MIN(min)         ALIGN_DEBUG_RO
  78 #elif defined(CONFIG_DEBUG_RODATA)
  79 #define ALIGN_DEBUG_RO                  . = ALIGN(1<<PAGE_SHIFT);
  80 #define ALIGN_DEBUG_RO_MIN(min)         ALIGN_DEBUG_RO
  81 #else
  82 #define ALIGN_DEBUG_RO
  83 #define ALIGN_DEBUG_RO_MIN(min)         . = ALIGN(min);
  84 #endif
  85
  86 SECTIONS
  87 {
  88         /*
  89          * XXX: The linker does not define how output sections are
  90          * assigned to input sections when there are multiple statements
  91          * matching the same input section name.  There is no documented
  92          * order of matching.
  93          */
  94         /DISCARD/ : {
  95                 ARM_EXIT_DISCARD(EXIT_TEXT)
  96                 ARM_EXIT_DISCARD(EXIT_DATA)
  97                 EXIT_CALL
  98                 *(.discard)
  99                 *(.discard.*)
 100         }
 101
 102         . = PAGE_OFFSET + TEXT_OFFSET;
 103
 104         .head.text : {
 105                 _text = .;
 106                 HEAD_TEXT
 107         }
 108         ALIGN_DEBUG_RO
 109         .text : {                       /* Real text segment            */
 110                 _stext = .;             /* Text and read-only data      */
 111                         __exception_text_start = .;
 112                         *(.exception.text)
 113                         __exception_text_end = .;
 114                         IRQENTRY_TEXT
 115                         ENTRY_TEXT
 116                         TEXT_TEXT
 117                         SCHED_TEXT
 118                         LOCK_TEXT
 119                         KPROBES_TEXT
 120                         HYPERVISOR_TEXT
 121                         IDMAP_TEXT
 122                         HIBERNATE_TEXT
 123                         *(.fixup)
 124                         *(.gnu.warning)
 125                 . = ALIGN(16);
 126                 *(.got)                 /* Global offset table          */
 127         }
 128
 129         ALIGN_DEBUG_RO
 130         RO_DATA(PAGE_SIZE)
 131         EXCEPTION_TABLE(8)
 132         NOTES
 133         ALIGN_DEBUG_RO
 134         _etext = .;                     /* End of text and rodata section */
 135
 136         ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
 137         __init_begin = .;
 138
 139         INIT_TEXT_SECTION(8)
 140         .exit.text : {
 141                 ARM_EXIT_KEEP(EXIT_TEXT)
 142         }
 143
 144         ALIGN_DEBUG_RO_MIN(16)
 145         .init.data : {
 146                 INIT_DATA
 147                 INIT_SETUP(16)
 148                 INIT_CALLS
 149                 CON_INITCALL
 150                 SECURITY_INITCALL
 151                 INIT_RAM_FS
 152         }
 153         .exit.data : {
 154                 ARM_EXIT_KEEP(EXIT_DATA)
 155         }
 156
 157         PERCPU_SECTION(L1_CACHE_BYTES)
 158
 159         . = ALIGN(4);
 160         .altinstructions : {
 161                 __alt_instructions = .;
 162                 *(.altinstructions)
 163                 __alt_instructions_end = .;
 164         }
 165         .altinstr_replacement : {
 166                 *(.altinstr_replacement)
 167         }
 168
 169         . = ALIGN(PAGE_SIZE);
 170         __init_end = .;
 171
 172         _data = .;
 173         _sdata = .;
 174         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
 175         PECOFF_EDATA_PADDING
 176         _edata = .;
 177
 178         BSS_SECTION(0, 0, 0)
 179
 180         . = ALIGN(PAGE_SIZE);
 181         idmap_pg_dir = .;
 182         . += IDMAP_DIR_SIZE;
 183         swapper_pg_dir = .;
 184         . += SWAPPER_DIR_SIZE;
 185
 186         _end = .;
 187
 188         STABS_DEBUG
 189
 190         HEAD_SYMBOLS
 191 }
 192
 193 /*
 194  * The HYP init code and ID map text can't be longer than a page each,
 195  * and should not cross a page boundary.
 196  */
 197 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 198         "HYP init code too big or misaligned")
 199 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 200         "ID map text too big or misaligned")
 201 #ifdef CONFIG_HIBERNATION
 202 ASSERT(__hibernate_exit_text_end - (__hibernate_exit_text_start & ~(SZ_4K - 1))
 203         <= SZ_4K, "Hibernate exit text too big or misaligned")
 204 #endif
 205
 206 /*
 207  * If padding is applied before .head.text, virt<->phys conversions will fail.
 208  */
 209 ASSERT(_text == (PAGE_OFFSET + TEXT_OFFSET), "HEAD is misaligned")