CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 4)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  19
  20 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  21 if ( LLVM_USE_FOLDERS )
  22   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  23 endif()
  24
  25 if(MSVC AND NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11))
  26   # set stack reserved size to ~10MB
  27   # CMake previously automatically set this value for MSVC builds, but the
  28   # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
  29   # value (1 MB) which is not enough for us in tasks such as parsing recursive
  30   # C++ templates in Clang.
  31   set(CMAKE_CXX_STACK_SIZE "10000000")
  32 endif()
  33
  34 include(VersionFromVCS)
  35
  36 option(LLVM_APPEND_VC_REV
  37   "Append the version control system revision id to LLVM version" OFF)
  38
  39 if( LLVM_APPEND_VC_REV )
  40   add_version_info_from_vcs(PACKAGE_VERSION)
  41 endif()
  42
  43 set(PACKAGE_NAME LLVM)
  44 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  45 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  46
  47 # Configure CPack.
  48 set(CPACK_PACKAGE_VENDOR "LLVM")
  49 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  50 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  51 if( LLVM_APPEND_VC_REV )
  52   add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
  53 else()
  54   set(CPACK_PACKAGE_VERSION_PATCH "svn")
  55 endif()
  56 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  57 if(WIN32 AND NOT UNIX)
  58   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  59   set(CPACK_NSIS_MODIFY_PATH "ON")
  60   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  61   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  62     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  63   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  64     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  65 endif()
  66 include(CPack)
  67
  68 # Sanity check our source directory to make sure that we are not trying to
  69 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  70 # sure that we don't have any stray generated files lying around in the tree
  71 # (which would end up getting picked up by header search, instead of the correct
  72 # versions).
  73 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  74   message(FATAL_ERROR "In-source builds are not allowed.
  75 CMake would overwrite the makefiles distributed with LLVM.
  76 Please create a directory and run cmake from there, passing the path
  77 to this source directory as the last argument.
  78 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  79 Please delete them.")
  80 endif()
  81 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  82   file(GLOB_RECURSE
  83     tablegenned_files_on_include_dir
  84     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  85   file(GLOB_RECURSE
  86     tablegenned_files_on_lib_dir
  87     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  88   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  89     message(FATAL_ERROR "Apparently there is a previous in-source build,
  90 probably as the result of running `configure' and `make' on
  91 ${CMAKE_CURRENT_SOURCE_DIR}.
  92 This may cause problems. The suspicious files are:
  93 ${tablegenned_files_on_lib_dir}
  94 ${tablegenned_files_on_include_dir}
  95 Please clean the source directory.")
  96   endif()
  97 endif()
  98
  99 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 100
 101 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 102 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
 103 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 104 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
 105 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 106 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 107
 108 set(LLVM_ALL_TARGETS
 109   AArch64
 110   ARM
 111   CppBackend
 112   Hexagon
 113   Mips
 114   MSP430
 115   NVPTX
 116   PowerPC
 117   R600
 118   Sparc
 119   SystemZ
 120   X86
 121   XCore
 122   )
 123
 124 # List of targets with JIT support:
 125 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 126
 127 set(LLVM_TARGETS_TO_BUILD "all"
 128     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 129
 130 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 131   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 132
 133 option(BUILD_SHARED_LIBS
 134   "Build all libraries as shared libraries instead of static" OFF)
 135
 136 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 137 if(LLVM_ENABLE_CBE_PRINTF_A)
 138   set(ENABLE_CBE_PRINTF_A 1)
 139 endif()
 140
 141 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 142 if(LLVM_ENABLE_TIMESTAMPS)
 143   set(ENABLE_TIMESTAMPS 1)
 144 endif()
 145
 146 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 147 if(LLVM_ENABLE_BACKTRACES)
 148   set(ENABLE_BACKTRACES 1)
 149 endif()
 150
 151 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 152 if(LLVM_ENABLE_CRASH_OVERRIDES)
 153   set(ENABLE_CRASH_OVERRIDES 1)
 154 endif()
 155
 156 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 157 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 158 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 159
 160 set(LLVM_TARGET_ARCH "host"
 161   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 162
 163 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 164
 165 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 166
 167 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 168
 169 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 170   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 171 endif()
 172
 173 set(LLVM_TARGETS_TO_BUILD
 174    ${LLVM_TARGETS_TO_BUILD}
 175    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 176 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 177
 178 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 179
 180 include(AddLLVMDefinitions)
 181
 182 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 183
 184 # MSVC has a gazillion warnings with this.
 185 if( MSVC )
 186   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 187 else( MSVC )
 188   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 189 endif()
 190
 191 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 192 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 193
 194 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 195   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 196 else()
 197   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 198 endif()
 199
 200 option(LLVM_USE_INTEL_JITEVENTS
 201   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 202   OFF)
 203
 204 if( LLVM_USE_INTEL_JITEVENTS )
 205   # Verify we are on a supported platform
 206   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 207     message(FATAL_ERROR
 208       "Intel JIT API support is available on Linux and Windows only.")
 209   endif()
 210 endif( LLVM_USE_INTEL_JITEVENTS )
 211
 212 option(LLVM_USE_OPROFILE
 213   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 214
 215 # If enabled, verify we are on a platform that supports oprofile.
 216 if( LLVM_USE_OPROFILE )
 217   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 218     message(FATAL_ERROR "OProfile support is available on Linux only.")
 219   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 220 endif( LLVM_USE_OPROFILE )
 221
 222 set(LLVM_USE_SANITIZER "" CACHE STRING
 223   "Define the sanitizer used to build binaries and tests.")
 224
 225 option(LLVM_USE_SPLIT_DWARF
 226   "Use -gsplit-dwarf when compiling llvm." OFF)
 227
 228 # Define an option controlling whether we should build for 32-bit on 64-bit
 229 # platforms, where supported.
 230 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 231   # TODO: support other platforms and toolchains.
 232   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 233 endif()
 234
 235 # Define the default arguments to use with 'lit', and an option for the user to
 236 # override.
 237 set(LIT_ARGS_DEFAULT "-sv")
 238 if (MSVC OR XCODE)
 239   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 240 endif()
 241 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 242
 243 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 244 if( WIN32 AND NOT CYGWIN )
 245   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 246 endif()
 247
 248 # Define options to control the inclusion and default build behavior for
 249 # components which may not strictly be necessary (tools, examples, and tests).
 250 #
 251 # This is primarily to support building smaller or faster project files.
 252 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 253 option(LLVM_BUILD_TOOLS
 254   "Build the LLVM tools. If OFF, just generate build targets." ON)
 255
 256 option(LLVM_BUILD_EXAMPLES
 257   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 258 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 259
 260 option(LLVM_BUILD_TESTS
 261   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 262 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 263
 264 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 265 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 266 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 267
 268 # All options referred to from HandleLLVMOptions have to be specified
 269 # BEFORE this include, otherwise options will not be correctly set on
 270 # first cmake run
 271 include(config-ix)
 272
 273 # By default, we target the host, but this can be overridden at CMake
 274 # invocation time.
 275 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 276   "Default target for which LLVM will generate code." )
 277 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 278
 279 include(HandleLLVMOptions)
 280
 281 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 282 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5 2.4)
 283 include(FindPythonInterp)
 284 if( NOT PYTHONINTERP_FOUND )
 285   message(FATAL_ERROR
 286 "Unable to find Python interpreter, required for builds and testing.
 287
 288 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 289 endif()
 290
 291 ######
 292 # LLVMBuild Integration
 293 #
 294 # We use llvm-build to generate all the data required by the CMake based
 295 # build system in one swoop:
 296 #
 297 #  - We generate a file (a CMake fragment) in the object root which contains
 298 #    all the definitions that are required by CMake.
 299 #
 300 #  - We generate the library table used by llvm-config.
 301 #
 302 #  - We generate the dependencies for the CMake fragment, so that we will
 303 #    automatically reconfigure outselves.
 304
 305 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 306 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 307   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 308 set(LLVMBUILDCMAKEFRAG
 309   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 310
 311 # Create the list of optional components that are enabled
 312 if (LLVM_USE_INTEL_JITEVENTS)
 313   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 314 endif (LLVM_USE_INTEL_JITEVENTS)
 315 if (LLVM_USE_OPROFILE)
 316   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 317 endif (LLVM_USE_OPROFILE)
 318
 319 message(STATUS "Constructing LLVMBuild project information")
 320 execute_process(
 321   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 322             --native-target "${LLVM_NATIVE_ARCH}"
 323             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 324             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 325             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 326             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 327             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 328             ERROR_VARIABLE LLVMBUILDERRORS
 329             OUTPUT_STRIP_TRAILING_WHITESPACE
 330             ERROR_STRIP_TRAILING_WHITESPACE
 331   RESULT_VARIABLE LLVMBUILDRESULT)
 332
 333 # On Win32, CMake doesn't properly handle piping the default output/error
 334 # streams into the GUI console. So, we explicitly catch and report them.
 335 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 336   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 337 endif()
 338 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 339   message(FATAL_ERROR
 340     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 341 endif()
 342
 343 # Include the generated CMake fragment. This will define properties from the
 344 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 345 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 346 # files change.
 347 include(${LLVMBUILDCMAKEFRAG})
 348
 349 ######
 350
 351 # Configure all of the various header file fragments LLVM uses which depend on
 352 # configuration variables.
 353 set(LLVM_ENUM_TARGETS "")
 354 set(LLVM_ENUM_ASM_PRINTERS "")
 355 set(LLVM_ENUM_ASM_PARSERS "")
 356 set(LLVM_ENUM_DISASSEMBLERS "")
 357 foreach(t ${LLVM_TARGETS_TO_BUILD})
 358   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 359
 360   list(FIND LLVM_ALL_TARGETS ${t} idx)
 361   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 362   if( idx LESS 0 AND idy LESS 0 )
 363     message(FATAL_ERROR "The target `${t}' does not exist.
 364     It should be one of\n${LLVM_ALL_TARGETS}")
 365   else()
 366     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 367   endif()
 368
 369   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 370   if( asmp_file )
 371     set(LLVM_ENUM_ASM_PRINTERS
 372       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 373   endif()
 374   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 375     set(LLVM_ENUM_ASM_PARSERS
 376       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 377   endif()
 378   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 379     set(LLVM_ENUM_DISASSEMBLERS
 380       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 381   endif()
 382 endforeach(t)
 383
 384 # Produce the target definition files, which provide a way for clients to easily
 385 # include various classes of targets.
 386 configure_file(
 387   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 388   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 389   )
 390 configure_file(
 391   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 392   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 393   )
 394 configure_file(
 395   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 396   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 397   )
 398 configure_file(
 399   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 400   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 401   )
 402
 403 # Configure the three LLVM configuration header files.
 404 configure_file(
 405   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 406   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 407 configure_file(
 408   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 409   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 410 configure_file(
 411   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 412   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 413
 414 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 415 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 416 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 417
 418 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 419
 420 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 421
 422 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 423   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 424   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 425   include_directories("/usr/local/include")
 426   link_directories("/usr/local/lib")
 427 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 428
 429 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 430    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 431 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 432
 433 # Make sure we don't get -rdynamic in every binary. For those that need it,
 434 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 435 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 436
 437 include(AddLLVM)
 438 include(TableGen)
 439
 440 if( MINGW )
 441   # People report that -O3 is unreliable on MinGW. The traditional
 442   # build also uses -O2 for that reason:
 443   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 444 endif()
 445
 446 # Put this before tblgen. Else we have a circular dependence.
 447 add_subdirectory(lib/Support)
 448 add_subdirectory(lib/TableGen)
 449
 450 add_subdirectory(utils/TableGen)
 451
 452 add_subdirectory(include/llvm)
 453
 454 add_subdirectory(lib)
 455
 456 add_subdirectory(utils/FileCheck)
 457 add_subdirectory(utils/FileUpdate)
 458 add_subdirectory(utils/count)
 459 add_subdirectory(utils/not)
 460 add_subdirectory(utils/llvm-lit)
 461 add_subdirectory(utils/yaml-bench)
 462
 463 add_subdirectory(projects)
 464
 465 if( LLVM_INCLUDE_TOOLS )
 466   add_subdirectory(tools)
 467 endif()
 468
 469 if( LLVM_INCLUDE_EXAMPLES )
 470   add_subdirectory(examples)
 471 endif()
 472
 473 if( LLVM_INCLUDE_TESTS )
 474   add_subdirectory(test)
 475   add_subdirectory(utils/unittest)
 476   add_subdirectory(unittests)
 477   if (MSVC)
 478     # This utility is used to prevent crashing tests from calling Dr. Watson on
 479     # Windows.
 480     add_subdirectory(utils/KillTheDoctor)
 481   endif()
 482
 483   # Add a global check rule now that all subdirectories have been traversed
 484   # and we know the total set of lit testsuites.
 485   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 486   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 487   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 488   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 489   add_lit_target(check-all
 490     "Running all regression tests"
 491     ${LLVM_LIT_TESTSUITES}
 492     PARAMS ${LLVM_LIT_PARAMS}
 493     DEPENDS ${LLVM_LIT_DEPENDS}
 494     ARGS ${LLVM_LIT_EXTRA_ARGS}
 495     )
 496 endif()
 497
 498 if (LLVM_INCLUDE_DOCS)
 499   add_subdirectory(docs)
 500 endif()
 501
 502 add_subdirectory(cmake/modules)
 503
 504 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 505   install(DIRECTORY include/
 506     DESTINATION include
 507     FILES_MATCHING
 508     PATTERN "*.def"
 509     PATTERN "*.h"
 510     PATTERN "*.td"
 511     PATTERN "*.inc"
 512     PATTERN "LICENSE.TXT"
 513     PATTERN ".svn" EXCLUDE
 514     )
 515
 516   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 517     DESTINATION include
 518     FILES_MATCHING
 519     PATTERN "*.def"
 520     PATTERN "*.h"
 521     PATTERN "*.gen"
 522     PATTERN "*.inc"
 523     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 524     PATTERN "CMakeFiles" EXCLUDE
 525     PATTERN ".svn" EXCLUDE
 526     )
 527 endif()
 528
 529 # Workaround for MSVS10 to avoid the Dialog Hell
 530 # FIXME: This could be removed with future version of CMake.
 531 if(MSVC_VERSION EQUAL 1600)
 532   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 533   if( EXISTS "${LLVM_SLN_FILENAME}" )
 534     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 535   endif()
 536 endif()