CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(PACKAGE_VERSION "3.0")
  14
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 include(VersionFromVCS)
  18
  19 option(LLVM_APPEND_VC_REV
  20   "Append the version control system revision id to LLVM version" OFF)
  21
  22 if( LLVM_APPEND_VC_REV )
  23   add_version_info_from_vcs(PACKAGE_VERSION)
  24 endif()
  25
  26 set(PACKAGE_NAME llvm)
  27 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  28 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  29
  30 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  31   message(FATAL_ERROR "In-source builds are not allowed.
  32 CMake would overwrite the makefiles distributed with LLVM.
  33 Please create a directory and run cmake from there, passing the path
  34 to this source directory as the last argument.
  35 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  36 Please delete them.")
  37 endif()
  38
  39 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  40
  41 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  42 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  43 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  44 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  45 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  46 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  47
  48 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  49   file(GLOB_RECURSE
  50     tablegenned_files_on_include_dir
  51     "${LLVM_MAIN_SRC_DIR}/include/llvm/*.gen")
  52   file(GLOB_RECURSE
  53     tablegenned_files_on_lib_dir
  54     "${LLVM_MAIN_SRC_DIR}/lib/Target/*.inc")
  55   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  56     message(FATAL_ERROR "Apparently there is a previous in-source build,
  57 probably as the result of running `configure' and `make' on
  58 ${LLVM_MAIN_SRC_DIR}.
  59 This may cause problems. The suspicious files are:
  60 ${tablegenned_files_on_lib_dir}
  61 ${tablegenned_files_on_include_dir}
  62 Please clean the source directory.")
  63   endif()
  64 endif()
  65
  66 set(LLVM_ALL_TARGETS
  67   ARM
  68   CBackend
  69   CellSPU
  70   CppBackend
  71   Mips
  72   MBlaze
  73   MSP430
  74   PowerPC
  75   PTX
  76   Sparc
  77   X86
  78   XCore
  79   )
  80
  81 # List of targets with JIT support:
  82 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  83
  84 if( MSVC )
  85   set(LLVM_TARGETS_TO_BUILD X86
  86     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  87 else( MSVC )
  88   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  89     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  90 endif( MSVC )
  91
  92 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
  93 if(LLVM_ENABLE_CBE_PRINTF_A)
  94   set(ENABLE_CBE_PRINTF_A 1)
  95 endif()
  96
  97 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
  98 if(LLVM_ENABLE_TIMESTAMPS)
  99   set(ENABLE_TIMESTAMPS 1)
 100 endif()
 101
 102 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 103 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 104 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 105
 106 set(LLVM_TARGET_ARCH "host"
 107   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 108
 109 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 110
 111 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 112   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 113 endif()
 114
 115 set(LLVM_ENUM_TARGETS "")
 116 foreach(c ${LLVM_TARGETS_TO_BUILD})
 117   list(FIND LLVM_ALL_TARGETS ${c} idx)
 118   if( idx LESS 0 )
 119     message(FATAL_ERROR "The target `${c}' does not exist.
 120     It should be one of\n${LLVM_ALL_TARGETS}")
 121   else()
 122     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 123   endif()
 124 endforeach(c)
 125
 126 # Produce llvm/Config/Targets.def
 127 configure_file(
 128   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 129   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 130   )
 131
 132 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 133
 134 include(AddLLVMDefinitions)
 135
 136 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 137
 138 # MSVC has a gazillion warnings with this.
 139 if( MSVC )
 140   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 141 else( MSVC )
 142   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 143 endif()
 144
 145 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 146 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 147
 148 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 149   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 150 else()
 151   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 152 endif()
 153
 154 # Define an option controlling whether we should build for 32-bit on 64-bit
 155 # platforms, where supported.
 156 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 157   # TODO: support other platforms and toolchains.
 158   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 159 endif()
 160
 161 # Define an option controlling whether or not we include the test targets in the
 162 # project.
 163 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 164
 165 # Define the default arguments to use with 'lit', and an option for the user to
 166 # override.
 167 set(LIT_ARGS_DEFAULT "-sv")
 168 if (MSVC OR XCODE)
 169   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 170 endif()
 171 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 172
 173 # On Win32/Cygwin, provide an option to specify the path to the GnuWin32 tools.
 174 if( WIN32 AND CYGWIN )
 175   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 176 endif()
 177
 178 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 179 # to use.
 180 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 181   # Only Visual Studio 2008 and 2010 officially supports /MP.  Visual Studio
 182   # 2005 supports it but it is experimental.
 183   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 184     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 185 endif()
 186
 187 # All options referred to from HandleLLVMOptions have to be specified
 188 # BEFORE this include, otherwise options will not be correctly set on
 189 # first cmake run
 190 include(config-ix)
 191 include(HandleLLVMOptions)
 192
 193 configure_file(
 194   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 195   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 196
 197 configure_file(
 198   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 199   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 200
 201 configure_file(
 202   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 203   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 204
 205 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 206 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 207 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 208
 209 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 210
 211 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 212
 213 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 214    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 215 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 216
 217 include(AddLLVM)
 218 include(TableGen)
 219
 220 if( MINGW )
 221   # People report that -O3 is unreliable on MinGW. The traditional
 222   # build also uses -O2 for that reason:
 223   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 224 endif()
 225
 226 # Put this before tblgen. Else we have a circular dependence.
 227 add_subdirectory(lib/Support)
 228 add_subdirectory(lib/TableGen)
 229
 230 add_subdirectory(utils/TableGen)
 231
 232 add_subdirectory(include/llvm)
 233
 234 add_subdirectory(lib)
 235
 236 add_subdirectory(utils/FileCheck)
 237 add_subdirectory(utils/FileUpdate)
 238 add_subdirectory(utils/count)
 239 add_subdirectory(utils/not)
 240 add_subdirectory(utils/llvm-lit)
 241
 242 add_subdirectory(projects)
 243
 244 option(LLVM_BUILD_TOOLS
 245   "Build the LLVM tools. If OFF, just generate build targets." ON)
 246 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 247 if( LLVM_INCLUDE_TOOLS )
 248   add_subdirectory(tools)
 249 endif()
 250
 251 option(LLVM_BUILD_RUNTIME
 252   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 253 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 254 if( LLVM_INCLUDE_RUNTIME )
 255   add_subdirectory(runtime)
 256 endif()
 257
 258 option(LLVM_BUILD_EXAMPLES
 259   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 260 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 261 if( LLVM_INCLUDE_EXAMPLES )
 262   add_subdirectory(examples)
 263 endif()
 264
 265 option(LLVM_BUILD_TESTS
 266   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 267 if( LLVM_INCLUDE_TESTS )
 268   add_subdirectory(test)
 269   add_subdirectory(utils/unittest)
 270   add_subdirectory(unittests)
 271   if (MSVC)
 272     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 273     # Windows.
 274     add_subdirectory(utils/KillTheDoctor)
 275   endif()
 276 endif()
 277
 278 add_subdirectory(cmake/modules)
 279
 280 install(DIRECTORY include/
 281   DESTINATION include
 282   FILES_MATCHING
 283   PATTERN "*.def"
 284   PATTERN "*.h"
 285   PATTERN "*.td"
 286   PATTERN "*.inc"
 287   PATTERN "LICENSE.TXT"
 288   PATTERN ".svn" EXCLUDE
 289   )
 290
 291 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 292   DESTINATION include
 293   FILES_MATCHING
 294   PATTERN "*.def"
 295   PATTERN "*.h"
 296   PATTERN "*.gen"
 297   PATTERN "*.inc"
 298   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 299   PATTERN "CMakeFiles" EXCLUDE
 300   PATTERN ".svn" EXCLUDE
 301   )
 302
 303 # TODO: make and install documentation.
 304
 305 set(CPACK_PACKAGE_VENDOR "LLVM")
 306 set(CPACK_PACKAGE_VERSION_MAJOR 2)
 307 set(CPACK_PACKAGE_VERSION_MINOR 9)
 308 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 309 include(CPack)
 310
 311 # Workaround for MSVS10 to avoid the Dialog Hell
 312 # FIXME: This could be removed with future version of CMake.
 313 if(MSVC_VERSION EQUAL 1600)
 314   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 315   if( EXISTS "${LLVM_SLN_FILENAME}" )
 316     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 317   endif()
 318 endif()